qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = W_Name(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else replacement = "batteries"; // ;)
 365                 } else if (escape == "x") {
 366                         replacement = cursor_ent.netname;
 367                         if (replacement == "" || !cursor_ent)
 368                                 replacement = "nothing";
 369                 } else if (escape == "s")
 370                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 371                 else if (escape == "S")
 372                         replacement = ftos(vlen(self.velocity));
 373
 374                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 375                 p = p + strlen(replacement);
 376         }
 377         return msg;
 378 }
 379
 380 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 381         return (value == 0) ? FALSE : TRUE;
 382 }
 383
 384 /*
 385 =============
 386 GetCvars
 387 =============
 388 Called with:
 389   0:  sends the request
 390   >0: receives a cvar from name=argv(f) value=argv(f+1)
 391 */
 392 void GetCvars_handleString(string thisname, float f, .string field, string name)
 393 {
 394         if (f < 0)
 395         {
 396                 if (self.field)
 397                         strunzone(self.field);
 398                 self.field = string_null;
 399         }
 400         else if (f > 0)
 401         {
 402                 if (thisname == name)
 403                 {
 404                         if (self.field)
 405                                 strunzone(self.field);
 406                         self.field = strzone(argv(f + 1));
 407                 }
 408         }
 409         else
 410                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 411 }
 412 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 413 {
 414         GetCvars_handleString(thisname, f, field, name);
 415         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 416                 if (thisname == name)
 417                 {
 418                         string s;
 419                         s = func(strcat1(self.field));
 420                         if (s != self.field)
 421                         {
 422                                 strunzone(self.field);
 423                                 self.field = strzone(s);
 424                         }
 425                 }
 426 }
 427 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 428 {
 429         if (f < 0)
 430         {
 431         }
 432         else if (f > 0)
 433         {
 434                 if (thisname == name)
 435                         self.field = stof(argv(f + 1));
 436         }
 437         else
 438                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 439 }
 440 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 441 {
 442         if (f < 0)
 443         {
 444         }
 445         else if (f > 0)
 446         {
 447                 if (thisname == name)
 448                 {
 449                         if(!self.field)
 450                         {
 451                                 self.field = stof(argv(f + 1));
 452                                 if(!self.field)
 453                                         self.field = -1;
 454                         }
 455                 }
 456         }
 457         else
 458         {
 459                 if(!self.field)
 460                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 461         }
 462 }
 463 float w_getbestweapon(entity e);
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 513
 514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 516
 517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 522
 523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 524         if (f > 0)
 525         {
 526                 if (s == "cl_weaponpriority")
 527                         self.switchweapon = w_getbestweapon(self);
 528                 if (s == "cl_allow_uidtracking")
 529                         PlayerStats_AddPlayer(self);
 530         }
 531 }
 532
 533 // decolorizes and team colors the player name when needed
 534 string playername(entity p)
 535 {
 536     string t;
 537     if (teamplay && !intermission_running && IS_PLAYER(p))
 538     {
 539         t = Team_ColorCode(p.team);
 540         return strcat(t, strdecolorize(p.netname));
 541     }
 542     else
 543         return p.netname;
 544 }
 545
 546 vector randompos(vector m1, vector m2)
 547 {
 548     vector v;
 549     m2 = m2 - m1;
 550     v_x = m2_x * random() + m1_x;
 551     v_y = m2_y * random() + m1_y;
 552     v_z = m2_z * random() + m1_z;
 553     return  v;
 554 }
 555
 556 //#NO AUTOCVARS START
 557
 558 float g_pickup_shells;
 559 float g_pickup_shells_max;
 560 float g_pickup_nails;
 561 float g_pickup_nails_max;
 562 float g_pickup_rockets;
 563 float g_pickup_rockets_max;
 564 float g_pickup_cells;
 565 float g_pickup_cells_max;
 566 float g_pickup_fuel;
 567 float g_pickup_fuel_jetpack;
 568 float g_pickup_fuel_max;
 569 float g_pickup_armorsmall;
 570 float g_pickup_armorsmall_max;
 571 float g_pickup_armorsmall_anyway;
 572 float g_pickup_armormedium;
 573 float g_pickup_armormedium_max;
 574 float g_pickup_armormedium_anyway;
 575 float g_pickup_armorbig;
 576 float g_pickup_armorbig_max;
 577 float g_pickup_armorbig_anyway;
 578 float g_pickup_armorlarge;
 579 float g_pickup_armorlarge_max;
 580 float g_pickup_armorlarge_anyway;
 581 float g_pickup_healthsmall;
 582 float g_pickup_healthsmall_max;
 583 float g_pickup_healthsmall_anyway;
 584 float g_pickup_healthmedium;
 585 float g_pickup_healthmedium_max;
 586 float g_pickup_healthmedium_anyway;
 587 float g_pickup_healthlarge;
 588 float g_pickup_healthlarge_max;
 589 float g_pickup_healthlarge_anyway;
 590 float g_pickup_healthmega;
 591 float g_pickup_healthmega_max;
 592 float g_pickup_healthmega_anyway;
 593 float g_pickup_ammo_anyway;
 594 float g_pickup_weapons_anyway;
 595 float g_weaponarena;
 596 WepSet g_weaponarena_weapons;
 597 float g_weaponarena_random;
 598 float g_weaponarena_random_with_laser;
 599 string g_weaponarena_list;
 600 float g_weaponspeedfactor;
 601 float g_weaponratefactor;
 602 float g_weapondamagefactor;
 603 float g_weaponforcefactor;
 604 float g_weaponspreadfactor;
 605
 606 WepSet start_weapons;
 607 WepSet start_weapons_default;
 608 WepSet start_weapons_defaultmask;
 609 float start_items;
 610 float start_ammo_shells;
 611 float start_ammo_nails;
 612 float start_ammo_rockets;
 613 float start_ammo_cells;
 614 float start_ammo_fuel;
 615 float start_health;
 616 float start_armorvalue;
 617 WepSet warmup_start_weapons;
 618 WepSet warmup_start_weapons_default;
 619 WepSet warmup_start_weapons_defaultmask;
 620 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 621 float warmup_start_ammo_shells;
 622 float warmup_start_ammo_nails;
 623 float warmup_start_ammo_rockets;
 624 float warmup_start_ammo_cells;
 625 float warmup_start_ammo_fuel;
 626 float warmup_start_health;
 627 float warmup_start_armorvalue;
 628 float g_weapon_stay;
 629
 630 entity get_weaponinfo(float w);
 631
 632 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 633 {
 634         var float i = weaponinfo.weapon;
 635         var float d = 0;
 636
 637         if (!i)
 638                 return 0;
 639
 640         if (g_lms || g_ca || allguns)
 641         {
 642                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 643                         d = TRUE;
 644                 else
 645                         d = FALSE;
 646         }
 647         else if (g_cts)
 648                 d = (i == WEP_SHOTGUN);
 649         else if (g_nexball)
 650                 d = 0; // weapon is set a few lines later
 651         else
 652                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 653
 654         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 655                 d |= (i == WEP_HOOK);
 656         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 657                 d = 0;
 658
 659         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 660
 661         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 662
 663         // bit order in t:
 664         // 1: want or not
 665         // 2: is default?
 666         // 4: is set by default?
 667         if(t < 0)
 668                 t = 4 | (3 * d);
 669         else
 670                 t |= (2 * d);
 671
 672         return t;
 673 }
 674
 675 void readplayerstartcvars()
 676 {
 677         entity e;
 678         float i, j, t;
 679         string s;
 680
 681         // initialize starting values for players
 682         start_weapons = '0 0 0';
 683         start_weapons_default = '0 0 0';
 684         start_weapons_defaultmask = '0 0 0';
 685         start_items = 0;
 686         start_ammo_shells = 0;
 687         start_ammo_nails = 0;
 688         start_ammo_rockets = 0;
 689         start_ammo_cells = 0;
 690         start_health = cvar("g_balance_health_start");
 691         start_armorvalue = cvar("g_balance_armor_start");
 692
 693         g_weaponarena = 0;
 694         g_weaponarena_weapons = '0 0 0';
 695
 696         s = cvar_string("g_weaponarena");
 697         if (s == "0" || s == "")
 698         {
 699                 if(g_ca)
 700                         s = "most";
 701         }
 702
 703         if (s == "0" || s == "")
 704         {
 705                 // no arena
 706         }
 707         else if (s == "off")
 708         {
 709                 // forcibly turn off weaponarena
 710         }
 711         else if (s == "all")
 712         {
 713                 g_weaponarena = 1;
 714                 g_weaponarena_list = "All Weapons";
 715                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 716                 {
 717                         e = get_weaponinfo(j);
 718                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 719                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 720                 }
 721         }
 722         else if (s == "most")
 723         {
 724                 g_weaponarena = 1;
 725                 g_weaponarena_list = "Most Weapons";
 726                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 727                 {
 728                         e = get_weaponinfo(j);
 729                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 730                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 731                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 732                 }
 733         }
 734         else if (s == "none")
 735         {
 736                 g_weaponarena = 1;
 737                 g_weaponarena_list = "No Weapons";
 738         }
 739         else
 740         {
 741                 g_weaponarena = 1;
 742                 t = tokenize_console(s);
 743                 g_weaponarena_list = "";
 744                 for (i = 0; i < t; ++i)
 745                 {
 746                         s = argv(i);
 747                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 748                         {
 749                                 e = get_weaponinfo(j);
 750                                 if (e.netname == s)
 751                                 {
 752                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 753                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 754                                         break;
 755                                 }
 756                         }
 757                         if (j > WEP_LAST)
 758                         {
 759                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 760                         }
 761                 }
 762                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 763         }
 764
 765         if(g_weaponarena)
 766                 g_weaponarena_random = cvar("g_weaponarena_random");
 767         else
 768                 g_weaponarena_random = 0;
 769         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 770
 771         if (g_weaponarena)
 772         {
 773                 g_weapon_stay = 0; // incompatible
 774                 start_weapons = g_weaponarena_weapons;
 775                 start_items |= IT_UNLIMITED_AMMO;
 776         }
 777         else
 778         {
 779                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 780                 {
 781                         e = get_weaponinfo(i);
 782                         float w = want_weapon("g_start_weapon_", e, FALSE);
 783                         if(w & 1)
 784                                 start_weapons |= WepSet_FromWeapon(i);
 785                         if(w & 2)
 786                                 start_weapons_default |= WepSet_FromWeapon(i);
 787                         if(w & 4)
 788                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 789                 }
 790         }
 791
 792         if(!cvar("g_use_ammunition"))
 793                 start_items |= IT_UNLIMITED_AMMO;
 794
 795         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 796         {
 797                 start_ammo_rockets = 999;
 798                 start_ammo_shells = 999;
 799                 start_ammo_cells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_fuel = 999;
 802         }
 803         else
 804         {
 805                 start_ammo_shells = cvar("g_start_ammo_shells");
 806                 start_ammo_nails = cvar("g_start_ammo_nails");
 807                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 808                 start_ammo_cells = cvar("g_start_ammo_cells");
 809                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 810         }
 811
 812         if (warmup_stage)
 813         {
 814                 warmup_start_ammo_shells = start_ammo_shells;
 815                 warmup_start_ammo_nails = start_ammo_nails;
 816                 warmup_start_ammo_rockets = start_ammo_rockets;
 817                 warmup_start_ammo_cells = start_ammo_cells;
 818                 warmup_start_ammo_fuel = start_ammo_fuel;
 819                 warmup_start_health = start_health;
 820                 warmup_start_armorvalue = start_armorvalue;
 821                 warmup_start_weapons = start_weapons;
 822                 warmup_start_weapons_default = start_weapons_default;
 823                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 824
 825                 if (!g_weaponarena && !g_ca)
 826                 {
 827                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 828                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 829                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 830                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 831                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 832                         warmup_start_health = cvar("g_warmup_start_health");
 833                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 834                         warmup_start_weapons = '0 0 0';
 835                         warmup_start_weapons_default = '0 0 0';
 836                         warmup_start_weapons_defaultmask = '0 0 0';
 837                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 838                         {
 839                                 e = get_weaponinfo(i);
 840                                 float w = want_weapon("g_start_weapon_", e, g_warmup_allguns);
 841                                 if(w & 1)
 842                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 843                                 if(w & 2)
 844                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 845                                 if(w & 4)
 846                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 847                         }
 848                 }
 849         }
 850
 851         if (g_jetpack)
 852                 start_items |= IT_JETPACK;
 853
 854         MUTATOR_CALLHOOK(SetStartItems);
 855
 856         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 857         {
 858                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 859                 start_items |= IT_FUEL_REGEN;
 860                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 861                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862         }
 863
 864         WepSet precache_weapons = start_weapons;
 865         if (g_warmup_allguns != 1)
 866                 precache_weapons |= warmup_start_weapons;
 867         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 868         {
 869                 e = get_weaponinfo(i);
 870                 if(precache_weapons & WepSet_FromWeapon(i))
 871                         weapon_action(i, WR_PRECACHE);
 872         }
 873
 874         start_ammo_shells = max(0, start_ammo_shells);
 875         start_ammo_nails = max(0, start_ammo_nails);
 876         start_ammo_cells = max(0, start_ammo_cells);
 877         start_ammo_rockets = max(0, start_ammo_rockets);
 878         start_ammo_fuel = max(0, start_ammo_fuel);
 879
 880         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 881         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 882         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 883         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 884         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 885 }
 886
 887 float g_bugrigs;
 888 float g_bugrigs_planar_movement;
 889 float g_bugrigs_planar_movement_car_jumping;
 890 float g_bugrigs_reverse_spinning;
 891 float g_bugrigs_reverse_speeding;
 892 float g_bugrigs_reverse_stopping;
 893 float g_bugrigs_air_steering;
 894 float g_bugrigs_angle_smoothing;
 895 float g_bugrigs_friction_floor;
 896 float g_bugrigs_friction_brake;
 897 float g_bugrigs_friction_air;
 898 float g_bugrigs_accel;
 899 float g_bugrigs_speed_ref;
 900 float g_bugrigs_speed_pow;
 901 float g_bugrigs_steer;
 902
 903 float sv_autotaunt;
 904 float sv_taunt;
 905
 906 string GetGametype(); // g_world.qc
 907 void readlevelcvars(void)
 908 {
 909         // load mutators
 910         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 911                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 912
 913         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 914         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, teamplay);
 915         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 916         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 917         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 918         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 919         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 921         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 922         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 923         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 924         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 925         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
 926         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
 927         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
 928         CHECK_MUTATOR_ADD("g_multijump", mutator_multijump, 1);
 929         CHECK_MUTATOR_ADD("g_melee_only", mutator_melee_only, !cvar("g_minstagib"));
 930         CHECK_MUTATOR_ADD("g_nades", mutator_nades, 1);
 931         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 932         CHECK_MUTATOR_ADD("g_campcheck", mutator_campcheck, 1);
 933
 934         #undef CHECK_MUTATOR_ADD
 935
 936         if(cvar("sv_allow_fullbright"))
 937                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 938
 939     g_bugrigs = cvar("g_bugrigs");
 940     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 941     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 942     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 943     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 944     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 945     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 946     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 947     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 948     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 949     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 950     g_bugrigs_accel = cvar("g_bugrigs_accel");
 951     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 952     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 953     g_bugrigs_steer = cvar("g_bugrigs_steer");
 954
 955         g_minstagib = cvar("g_minstagib");
 956
 957         sv_clones = cvar("sv_clones");
 958         sv_foginterval = cvar("sv_foginterval");
 959         g_cloaked = cvar("g_cloaked");
 960     if(g_cts)
 961         g_cloaked = 1; // always enable cloak in CTS
 962         g_footsteps = cvar("g_footsteps");
 963         g_grappling_hook = cvar("g_grappling_hook");
 964         g_jetpack = cvar("g_jetpack");
 965         sv_maxidle = cvar("sv_maxidle");
 966         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 967         sv_autotaunt = cvar("sv_autotaunt");
 968         sv_taunt = cvar("sv_taunt");
 969
 970         warmup_stage = cvar("g_warmup");
 971         g_warmup_limit = cvar("g_warmup_limit");
 972         g_warmup_allguns = cvar("g_warmup_allguns");
 973         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 974
 975         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 976                 warmup_stage = 0; // these modes cannot work together, sorry
 977
 978         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 979         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 980         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 981         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 982         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 983         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 984         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 985         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 986         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 987         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 988         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 989         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 990         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 991         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 992
 993         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 994         g_weaponratefactor = cvar("g_weaponratefactor");
 995         g_weapondamagefactor = cvar("g_weapondamagefactor");
 996         g_weaponforcefactor = cvar("g_weaponforcefactor");
 997         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 998
 999         g_pickup_shells = cvar("g_pickup_shells");
1000         g_pickup_shells_max = cvar("g_pickup_shells_max");
1001         g_pickup_nails = cvar("g_pickup_nails");
1002         g_pickup_nails_max = cvar("g_pickup_nails_max");
1003         g_pickup_rockets = cvar("g_pickup_rockets");
1004         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1005         g_pickup_cells = cvar("g_pickup_cells");
1006         g_pickup_cells_max = cvar("g_pickup_cells_max");
1007         g_pickup_fuel = cvar("g_pickup_fuel");
1008         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1009         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1010         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1011         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1012         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1013         g_pickup_armormedium = cvar("g_pickup_armormedium");
1014         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1015         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1016         g_pickup_armorbig = cvar("g_pickup_armorbig");
1017         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1018         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1019         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1020         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1021         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1022         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1023         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1024         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1025         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1026         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1027         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1028         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1029         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1030         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1031         g_pickup_healthmega = cvar("g_pickup_healthmega");
1032         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1033         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1034
1035         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1036         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1037
1038     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1039     if(!g_weapon_stay)
1040         g_weapon_stay = cvar("g_weapon_stay");
1041
1042         if (!warmup_stage)
1043                 game_starttime = time + cvar("g_start_delay");
1044
1045         readplayerstartcvars();
1046 }
1047
1048 //#NO AUTOCVARS END
1049
1050 // Sound functions
1051 string precache_sound (string s) = #19;
1052 float precache_sound_index (string s) = #19;
1053
1054 #define SND_VOLUME      1
1055 #define SND_ATTENUATION 2
1056 #define SND_LARGEENTITY 8
1057 #define SND_LARGESOUND  16
1058
1059 float sound_allowed(float dest, entity e)
1060 {
1061     // sounds from world may always pass
1062     for (;;)
1063     {
1064         if (e.classname == "body")
1065             e = e.enemy;
1066         else if (e.realowner && e.realowner != e)
1067             e = e.realowner;
1068         else if (e.owner && e.owner != e)
1069             e = e.owner;
1070         else
1071             break;
1072     }
1073     // sounds to self may always pass
1074     if (dest == MSG_ONE)
1075         if (e == msg_entity)
1076             return TRUE;
1077     // sounds by players can be removed
1078     if (autocvar_bot_sound_monopoly)
1079         if (IS_REAL_CLIENT(e))
1080             return FALSE;
1081     // anything else may pass
1082     return TRUE;
1083 }
1084
1085 #ifdef COMPAT_XON010_CHANNELS
1086 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1087 void sound(entity e, float chan, string samp, float vol, float atten)
1088 {
1089     if (!sound_allowed(MSG_BROADCAST, e))
1090         return;
1091     builtin_sound(e, chan, samp, vol, atten);
1092 }
1093 #else
1094 #undef sound
1095 void sound(entity e, float chan, string samp, float vol, float atten)
1096 {
1097     if (!sound_allowed(MSG_BROADCAST, e))
1098         return;
1099     sound7(e, chan, samp, vol, atten, 0, 0);
1100 }
1101 #endif
1102
1103 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1104 {
1105     float entno, idx;
1106
1107     if (!sound_allowed(dest, e))
1108         return;
1109
1110     entno = num_for_edict(e);
1111     idx = precache_sound_index(samp);
1112
1113     float sflags;
1114     sflags = 0;
1115
1116     atten = floor(atten * 64);
1117     vol = floor(vol * 255);
1118
1119     if (vol != 255)
1120         sflags |= SND_VOLUME;
1121     if (atten != 64)
1122         sflags |= SND_ATTENUATION;
1123     if (entno >= 8192 || chan < 0 || chan > 7)
1124         sflags |= SND_LARGEENTITY;
1125     if (idx >= 256)
1126         sflags |= SND_LARGESOUND;
1127
1128     WriteByte(dest, SVC_SOUND);
1129     WriteByte(dest, sflags);
1130     if (sflags & SND_VOLUME)
1131         WriteByte(dest, vol);
1132     if (sflags & SND_ATTENUATION)
1133         WriteByte(dest, atten);
1134     if (sflags & SND_LARGEENTITY)
1135     {
1136         WriteShort(dest, entno);
1137         WriteByte(dest, chan);
1138     }
1139     else
1140     {
1141         WriteShort(dest, entno * 8 + chan);
1142     }
1143     if (sflags & SND_LARGESOUND)
1144         WriteShort(dest, idx);
1145     else
1146         WriteByte(dest, idx);
1147
1148     WriteCoord(dest, o_x);
1149     WriteCoord(dest, o_y);
1150     WriteCoord(dest, o_z);
1151 }
1152 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1153 {
1154     vector o;
1155
1156     if (!sound_allowed(dest, e))
1157         return;
1158
1159     o = e.origin + 0.5 * (e.mins + e.maxs);
1160     soundtoat(dest, e, o, chan, samp, vol, atten);
1161 }
1162 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1163 {
1164     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1165 }
1166 void stopsoundto(float dest, entity e, float chan)
1167 {
1168     float entno;
1169
1170     if (!sound_allowed(dest, e))
1171         return;
1172
1173     entno = num_for_edict(e);
1174
1175     if (entno >= 8192 || chan < 0 || chan > 7)
1176     {
1177         float idx, sflags;
1178         idx = precache_sound_index("misc/null.wav");
1179         sflags = SND_LARGEENTITY;
1180         if (idx >= 256)
1181             sflags |= SND_LARGESOUND;
1182         WriteByte(dest, SVC_SOUND);
1183         WriteByte(dest, sflags);
1184         WriteShort(dest, entno);
1185         WriteByte(dest, chan);
1186         if (sflags & SND_LARGESOUND)
1187             WriteShort(dest, idx);
1188         else
1189             WriteByte(dest, idx);
1190         WriteCoord(dest, e.origin_x);
1191         WriteCoord(dest, e.origin_y);
1192         WriteCoord(dest, e.origin_z);
1193     }
1194     else
1195     {
1196         WriteByte(dest, SVC_STOPSOUND);
1197         WriteShort(dest, entno * 8 + chan);
1198     }
1199 }
1200 void stopsound(entity e, float chan)
1201 {
1202     if (!sound_allowed(MSG_BROADCAST, e))
1203         return;
1204
1205     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1206     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1207 }
1208
1209 void play2(entity e, string filename)
1210 {
1211     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1212     msg_entity = e;
1213     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1214 }
1215
1216 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1217 .float spamtime;
1218 float spamsound(entity e, float chan, string samp, float vol, float atten)
1219 {
1220     if (!sound_allowed(MSG_BROADCAST, e))
1221         return FALSE;
1222
1223     if (time > e.spamtime)
1224     {
1225         e.spamtime = time;
1226         sound(e, chan, samp, vol, atten);
1227         return TRUE;
1228     }
1229     return FALSE;
1230 }
1231
1232 void play2team(float t, string filename)
1233 {
1234     entity head;
1235
1236     if (autocvar_bot_sound_monopoly)
1237         return;
1238
1239     FOR_EACH_REALPLAYER(head)
1240     {
1241         if (head.team == t)
1242             play2(head, filename);
1243     }
1244 }
1245
1246 void play2all(string samp)
1247 {
1248     if (autocvar_bot_sound_monopoly)
1249         return;
1250
1251     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1252 }
1253
1254 void PrecachePlayerSounds(string f);
1255 void precache_playermodel(string m)
1256 {
1257         float globhandle, i, n;
1258         string f;
1259
1260         if(substring(m, -9,5) == "_lod1")
1261                 return;
1262         if(substring(m, -9,5) == "_lod2")
1263                 return;
1264         precache_model(m);
1265         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1266         if(fexists(f))
1267                 precache_model(f);
1268         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1269         if(fexists(f))
1270                 precache_model(f);
1271
1272         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1273         if (globhandle < 0)
1274                 return;
1275         n = search_getsize(globhandle);
1276         for (i = 0; i < n; ++i)
1277         {
1278                 //print(search_getfilename(globhandle, i), "\n");
1279                 f = search_getfilename(globhandle, i);
1280                 PrecachePlayerSounds(f);
1281         }
1282         search_end(globhandle);
1283 }
1284 void precache_all_playermodels(string pattern)
1285 {
1286         float globhandle, i, n;
1287         string f;
1288
1289         globhandle = search_begin(pattern, TRUE, FALSE);
1290         if (globhandle < 0)
1291                 return;
1292         n = search_getsize(globhandle);
1293         for (i = 0; i < n; ++i)
1294         {
1295                 //print(search_getfilename(globhandle, i), "\n");
1296                 f = search_getfilename(globhandle, i);
1297                 precache_playermodel(f);
1298         }
1299         search_end(globhandle);
1300 }
1301
1302 void precache()
1303 {
1304     // gamemode related things
1305     precache_model ("models/misc/chatbubble.spr");
1306
1307     // Precache all player models if desired
1308     if (autocvar_sv_precacheplayermodels)
1309     {
1310         PrecachePlayerSounds("sound/player/default.sounds");
1311         precache_all_playermodels("models/player/*.zym");
1312         precache_all_playermodels("models/player/*.dpm");
1313         precache_all_playermodels("models/player/*.md3");
1314         precache_all_playermodels("models/player/*.psk");
1315         precache_all_playermodels("models/player/*.iqm");
1316     }
1317
1318     if (autocvar_sv_defaultcharacter)
1319     {
1320         string s;
1321         s = autocvar_sv_defaultplayermodel_red;
1322         if (s != "")
1323             precache_playermodel(s);
1324         s = autocvar_sv_defaultplayermodel_blue;
1325         if (s != "")
1326             precache_playermodel(s);
1327         s = autocvar_sv_defaultplayermodel_yellow;
1328         if (s != "")
1329             precache_playermodel(s);
1330         s = autocvar_sv_defaultplayermodel_pink;
1331         if (s != "")
1332             precache_playermodel(s);
1333         s = autocvar_sv_defaultplayermodel;
1334         if (s != "")
1335             precache_playermodel(s);
1336     }
1337
1338     if (g_footsteps)
1339     {
1340         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1341         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1342     }
1343
1344     // gore and miscellaneous sounds
1345     //precache_sound ("misc/h2ohit.wav");
1346     precache_model ("models/hook.md3");
1347     precache_sound ("misc/armorimpact.wav");
1348     precache_sound ("misc/bodyimpact1.wav");
1349     precache_sound ("misc/bodyimpact2.wav");
1350     precache_sound ("misc/gib.wav");
1351     precache_sound ("misc/gib_splat01.wav");
1352     precache_sound ("misc/gib_splat02.wav");
1353     precache_sound ("misc/gib_splat03.wav");
1354     precache_sound ("misc/gib_splat04.wav");
1355     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1356     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1357     precache_sound ("misc/null.wav");
1358     precache_sound ("misc/spawn.wav");
1359     precache_sound ("misc/talk.wav");
1360     precache_sound ("misc/teleport.wav");
1361     precache_sound ("misc/poweroff.wav");
1362     precache_sound ("player/lava.wav");
1363     precache_sound ("player/slime.wav");
1364
1365     precache_model ("models/sprites/0.spr32");
1366     precache_model ("models/sprites/1.spr32");
1367     precache_model ("models/sprites/2.spr32");
1368     precache_model ("models/sprites/3.spr32");
1369     precache_model ("models/sprites/4.spr32");
1370     precache_model ("models/sprites/5.spr32");
1371     precache_model ("models/sprites/6.spr32");
1372     precache_model ("models/sprites/7.spr32");
1373     precache_model ("models/sprites/8.spr32");
1374     precache_model ("models/sprites/9.spr32");
1375     precache_model ("models/sprites/10.spr32");
1376
1377     // common weapon precaches
1378         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1379     precache_sound ("weapons/weapon_switch.wav");
1380     precache_sound ("weapons/weaponpickup.wav");
1381     precache_sound ("weapons/unavailable.wav");
1382     precache_sound ("weapons/dryfire.wav");
1383     if (g_grappling_hook)
1384     {
1385         precache_sound ("weapons/hook_fire.wav"); // hook
1386         precache_sound ("weapons/hook_impact.wav"); // hook
1387     }
1388
1389     if(autocvar_sv_precacheweapons)
1390     {
1391         //precache weapon models/sounds
1392         float wep;
1393         wep = WEP_FIRST;
1394         while (wep <= WEP_LAST)
1395         {
1396             weapon_action(wep, WR_PRECACHE);
1397             wep = wep + 1;
1398         }
1399     }
1400
1401     precache_model("models/elaser.mdl");
1402     precache_model("models/laser.mdl");
1403     precache_model("models/ebomb.mdl");
1404
1405 #if 0
1406     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1407
1408     if (!self.noise && self.music) // quake 3 uses the music field
1409         self.noise = self.music;
1410
1411     // plays music for the level if there is any
1412     if (self.noise)
1413     {
1414         precache_sound (self.noise);
1415         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1416     }
1417 #endif
1418
1419 #include "precache-for-csqc.inc"
1420 }
1421
1422 // WARNING: this kills the trace globals
1423 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1424 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1425
1426 #define INITPRIO_FIRST              0
1427 #define INITPRIO_GAMETYPE           0
1428 #define INITPRIO_GAMETYPE_FALLBACK  1
1429 #define INITPRIO_FINDTARGET        10
1430 #define INITPRIO_DROPTOFLOOR       20
1431 #define INITPRIO_SETLOCATION       90
1432 #define INITPRIO_LINKDOORS         91
1433 #define INITPRIO_LAST              99
1434
1435 .void(void) initialize_entity;
1436 .float initialize_entity_order;
1437 .entity initialize_entity_next;
1438 entity initialize_entity_first;
1439
1440 void make_safe_for_remove(entity e)
1441 {
1442     if (e.initialize_entity)
1443     {
1444         entity ent, prev = world;
1445         for (ent = initialize_entity_first; ent; )
1446         {
1447             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1448             {
1449                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1450                 // skip it in linked list
1451                 if (prev)
1452                 {
1453                     prev.initialize_entity_next = ent.initialize_entity_next;
1454                     ent = prev.initialize_entity_next;
1455                 }
1456                 else
1457                 {
1458                     initialize_entity_first = ent.initialize_entity_next;
1459                     ent = initialize_entity_first;
1460                 }
1461             }
1462             else
1463             {
1464                 prev = ent;
1465                 ent = ent.initialize_entity_next;
1466             }
1467         }
1468     }
1469 }
1470
1471 void objerror(string s)
1472 {
1473     make_safe_for_remove(self);
1474     builtin_objerror(s);
1475 }
1476
1477 .float remove_except_protected_forbidden;
1478 void remove_except_protected(entity e)
1479 {
1480         if(e.remove_except_protected_forbidden)
1481                 error("not allowed to remove this at this point");
1482         builtin_remove(e);
1483 }
1484
1485 void remove_unsafely(entity e)
1486 {
1487     if(e.classname == "spike")
1488         error("Removing spikes is forbidden (crylink bug), please report");
1489     builtin_remove(e);
1490 }
1491
1492 void remove_safely(entity e)
1493 {
1494     make_safe_for_remove(e);
1495     builtin_remove(e);
1496 }
1497
1498 void InitializeEntity(entity e, void(void) func, float order)
1499 {
1500     entity prev, cur;
1501
1502     if (!e || e.initialize_entity)
1503     {
1504         // make a proxy initializer entity
1505         entity e_old;
1506         e_old = e;
1507         e = spawn();
1508         e.classname = "initialize_entity";
1509         e.enemy = e_old;
1510     }
1511
1512     e.initialize_entity = func;
1513     e.initialize_entity_order = order;
1514
1515     cur = initialize_entity_first;
1516     prev = world;
1517     for (;;)
1518     {
1519         if (!cur || cur.initialize_entity_order > order)
1520         {
1521             // insert between prev and cur
1522             if (prev)
1523                 prev.initialize_entity_next = e;
1524             else
1525                 initialize_entity_first = e;
1526             e.initialize_entity_next = cur;
1527             return;
1528         }
1529         prev = cur;
1530         cur = cur.initialize_entity_next;
1531     }
1532 }
1533 void InitializeEntitiesRun()
1534 {
1535     entity startoflist;
1536     startoflist = initialize_entity_first;
1537     initialize_entity_first = world;
1538     remove = remove_except_protected;
1539     for (self = startoflist; self; self = self.initialize_entity_next)
1540     {
1541         self.remove_except_protected_forbidden = 1;
1542     }
1543     for (self = startoflist; self; )
1544     {
1545         entity e;
1546         var void(void) func;
1547         e = self.initialize_entity_next;
1548         func = self.initialize_entity;
1549         self.initialize_entity_order = 0;
1550         self.initialize_entity = func_null;
1551         self.initialize_entity_next = world;
1552         self.remove_except_protected_forbidden = 0;
1553         if (self.classname == "initialize_entity")
1554         {
1555             entity e_old;
1556             e_old = self.enemy;
1557             builtin_remove(self);
1558             self = e_old;
1559         }
1560         //dprint("Delayed initialization: ", self.classname, "\n");
1561         if(func)
1562             func();
1563         else
1564         {
1565             eprint(self);
1566             backtrace(strcat("Null function in: ", self.classname, "\n"));
1567         }
1568         self = e;
1569     }
1570     remove = remove_unsafely;
1571 }
1572
1573 .float uncustomizeentityforclient_set;
1574 .void(void) uncustomizeentityforclient;
1575 void UncustomizeEntitiesRun()
1576 {
1577     entity oldself;
1578     oldself = self;
1579     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1580         self.uncustomizeentityforclient();
1581     self = oldself;
1582 }
1583 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1584 {
1585     e.customizeentityforclient = customizer;
1586     e.uncustomizeentityforclient = uncustomizer;
1587     e.uncustomizeentityforclient_set = !!uncustomizer;
1588 }
1589
1590 .float nottargeted;
1591 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1592
1593 void() SUB_Remove;
1594 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1595 {
1596     vector mi, ma;
1597
1598     if (e.classname == "")
1599         e.classname = "net_linked";
1600
1601     if (e.model == "" || self.modelindex == 0)
1602     {
1603         mi = e.mins;
1604         ma = e.maxs;
1605         setmodel(e, "null");
1606         setsize(e, mi, ma);
1607     }
1608
1609     e.SendEntity = sendfunc;
1610     e.SendFlags = 0xFFFFFF;
1611
1612     if (!docull)
1613         e.effects |= EF_NODEPTHTEST;
1614
1615     if (dt)
1616     {
1617         e.nextthink = time + dt;
1618         e.think = SUB_Remove;
1619     }
1620 }
1621
1622 void adaptor_think2touch()
1623 {
1624     entity o;
1625     o = other;
1626     other = world;
1627     self.touch();
1628     other = o;
1629 }
1630
1631 void adaptor_think2use()
1632 {
1633     entity o, a;
1634     o = other;
1635     a = activator;
1636     activator = world;
1637     other = world;
1638     self.use();
1639     other = o;
1640     activator = a;
1641 }
1642
1643 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1644 {
1645         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1646                 self.projectiledeathtype |= HITTYPE_SPLASH;
1647         adaptor_think2use();
1648 }
1649
1650 // deferred dropping
1651 void DropToFloor_Handler()
1652 {
1653     builtin_droptofloor();
1654     self.dropped_origin = self.origin;
1655 }
1656
1657 void droptofloor()
1658 {
1659     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1660 }
1661
1662
1663
1664 float trace_hits_box_a0, trace_hits_box_a1;
1665
1666 float trace_hits_box_1d(float end, float thmi, float thma)
1667 {
1668     if (end == 0)
1669     {
1670         // just check if x is in range
1671         if (0 < thmi)
1672             return FALSE;
1673         if (0 > thma)
1674             return FALSE;
1675     }
1676     else
1677     {
1678         // do the trace with respect to x
1679         // 0 -> end has to stay in thmi -> thma
1680         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1681         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1682         if (trace_hits_box_a0 > trace_hits_box_a1)
1683             return FALSE;
1684     }
1685     return TRUE;
1686 }
1687
1688 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1689 {
1690     end -= start;
1691     thmi -= start;
1692     thma -= start;
1693     // now it is a trace from 0 to end
1694
1695     trace_hits_box_a0 = 0;
1696     trace_hits_box_a1 = 1;
1697
1698     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1699         return FALSE;
1700     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1701         return FALSE;
1702     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1703         return FALSE;
1704
1705     return TRUE;
1706 }
1707
1708 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1709 {
1710     return trace_hits_box(start, end, thmi - ma, thma - mi);
1711 }
1712
1713 float SUB_NoImpactCheck()
1714 {
1715         // zero hitcontents = this is not the real impact, but either the
1716         // mirror-impact of something hitting the projectile instead of the
1717         // projectile hitting the something, or a touchareagrid one. Neither of
1718         // these stop the projectile from moving, so...
1719         if(trace_dphitcontents == 0)
1720         {
1721                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1722                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1723                 checkclient();
1724         }
1725     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1726         return 1;
1727     if (other == world && self.size != '0 0 0')
1728     {
1729         vector tic;
1730         tic = self.velocity * sys_frametime;
1731         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1732         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1733         if (trace_fraction >= 1)
1734         {
1735             dprint("Odd... did not hit...?\n");
1736         }
1737         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1738         {
1739             dprint("Detected and prevented the sky-grapple bug.\n");
1740             return 1;
1741         }
1742     }
1743
1744     return 0;
1745 }
1746
1747 #define SUB_OwnerCheck() (other && (other == self.owner))
1748
1749 void RemoveGrapplingHook(entity pl);
1750 void W_Crylink_Dequeue(entity e);
1751 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1752 {
1753         if(SUB_OwnerCheck())
1754                 return TRUE;
1755         if(SUB_NoImpactCheck())
1756         {
1757                 if(self.classname == "grapplinghook")
1758                         RemoveGrapplingHook(self.realowner);
1759                 else if(self.classname == "spike")
1760                 {
1761                         W_Crylink_Dequeue(self);
1762                         remove(self);
1763                 }
1764                 else
1765                         remove(self);
1766                 return TRUE;
1767         }
1768         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1769                 UpdateCSQCProjectile(self);
1770         return FALSE;
1771 }
1772 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1773
1774 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1775 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1776
1777 void URI_Get_Callback(float id, float status, string data)
1778 {
1779         if(url_URI_Get_Callback(id, status, data))
1780         {
1781                 // handled
1782         }
1783         else if (id == URI_GET_DISCARD)
1784         {
1785                 // discard
1786         }
1787         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1788         {
1789                 // sv_cmd curl
1790                 Curl_URI_Get_Callback(id, status, data);
1791         }
1792         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1793         {
1794                 // online ban list
1795                 OnlineBanList_URI_Get_Callback(id, status, data);
1796         }
1797         else
1798         {
1799                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1800         }
1801 }
1802
1803 string uid2name(string myuid) {
1804         string s;
1805         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1806
1807         // FIXME remove this later after 0.6 release
1808         // convert old style broken records to correct style
1809         if(s == "")
1810         {
1811                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1812                 if(s != "")
1813                 {
1814                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1815                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1816                 }
1817         }
1818
1819         if(s == "")
1820                 s = "^1Unregistered Player";
1821         return s;
1822 }
1823
1824 float race_readTime(string map, float pos)
1825 {
1826         string rr;
1827         if(g_cts)
1828                 rr = CTS_RECORD;
1829         else
1830                 rr = RACE_RECORD;
1831
1832         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1833 }
1834
1835 string race_readUID(string map, float pos)
1836 {
1837         string rr;
1838         if(g_cts)
1839                 rr = CTS_RECORD;
1840         else
1841                 rr = RACE_RECORD;
1842
1843         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1844 }
1845
1846 float race_readPos(string map, float t) {
1847         float i;
1848         for (i = 1; i <= RANKINGS_CNT; ++i)
1849                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1850                         return i;
1851
1852         return 0; // pos is zero if unranked
1853 }
1854
1855 void race_writeTime(string map, float t, string myuid)
1856 {
1857         string rr;
1858         if(g_cts)
1859                 rr = CTS_RECORD;
1860         else
1861                 rr = RACE_RECORD;
1862
1863         float newpos;
1864         newpos = race_readPos(map, t);
1865
1866         float i, prevpos = 0;
1867         for(i = 1; i <= RANKINGS_CNT; ++i)
1868         {
1869                 if(race_readUID(map, i) == myuid)
1870                         prevpos = i;
1871         }
1872         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1873                 for (i = prevpos; i > newpos; --i) {
1874                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1875                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1876                 }
1877         } else { // player has no ranked record yet
1878                 for (i = RANKINGS_CNT; i > newpos; --i) {
1879                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1880                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1881                 }
1882         }
1883
1884         // store new time itself
1885         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1886         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1887 }
1888
1889 string race_readName(string map, float pos)
1890 {
1891         string rr;
1892         if(g_cts)
1893                 rr = CTS_RECORD;
1894         else
1895                 rr = RACE_RECORD;
1896
1897         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1898 }
1899
1900 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1901 {
1902     float m, i;
1903     vector start, org, delta, end, enddown, mstart;
1904     entity sp;
1905
1906     m = e.dphitcontentsmask;
1907     e.dphitcontentsmask = goodcontents | badcontents;
1908
1909     org = world.mins;
1910     delta = world.maxs - world.mins;
1911
1912     start = end = org;
1913
1914     for (i = 0; i < attempts; ++i)
1915     {
1916         start_x = org_x + random() * delta_x;
1917         start_y = org_y + random() * delta_y;
1918         start_z = org_z + random() * delta_z;
1919
1920         // rule 1: start inside world bounds, and outside
1921         // solid, and don't start from somewhere where you can
1922         // fall down to evil
1923         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1924         if (trace_fraction >= 1)
1925             continue;
1926         if (trace_startsolid)
1927             continue;
1928         if (trace_dphitcontents & badcontents)
1929             continue;
1930         if (trace_dphitq3surfaceflags & badsurfaceflags)
1931             continue;
1932
1933         // rule 2: if we are too high, lower the point
1934         if (trace_fraction * delta_z > maxaboveground)
1935             start = trace_endpos + '0 0 1' * maxaboveground;
1936         enddown = trace_endpos;
1937
1938         // rule 3: make sure we aren't outside the map. This only works
1939         // for somewhat well formed maps. A good rule of thumb is that
1940         // the map should have a convex outside hull.
1941         // these can be traceLINES as we already verified the starting box
1942         mstart = start + 0.5 * (e.mins + e.maxs);
1943         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1944         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1945             continue;
1946         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1947         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1948             continue;
1949         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1950         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1951             continue;
1952         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1953         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1954             continue;
1955         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1956         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1957             continue;
1958
1959         // rule 4: we must "see" some spawnpoint or item
1960         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1961                 if(checkpvs(mstart, sp))
1962                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1963                                 break;
1964         if(!sp)
1965         {
1966                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1967                         if(checkpvs(mstart, sp))
1968                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1969                                         break;
1970                 if(!sp)
1971                         continue;
1972         }
1973
1974         // find a random vector to "look at"
1975         end_x = org_x + random() * delta_x;
1976         end_y = org_y + random() * delta_y;
1977         end_z = org_z + random() * delta_z;
1978         end = start + normalize(end - start) * vlen(delta);
1979
1980         // rule 4: start TO end must not be too short
1981         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1982         if (trace_startsolid)
1983             continue;
1984         if (trace_fraction < minviewdistance / vlen(delta))
1985             continue;
1986
1987         // rule 5: don't want to look at sky
1988         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1989             continue;
1990
1991         // rule 6: we must not end up in trigger_hurt
1992         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1993             continue;
1994
1995         break;
1996     }
1997
1998     e.dphitcontentsmask = m;
1999
2000     if (i < attempts)
2001     {
2002         setorigin(e, start);
2003         e.angles = vectoangles(end - start);
2004         dprint("Needed ", ftos(i + 1), " attempts\n");
2005         return TRUE;
2006     }
2007     else
2008         return FALSE;
2009 }
2010
2011 void write_recordmarker(entity pl, float tstart, float dt)
2012 {
2013     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2014
2015     // also write a marker into demo files for demotc-race-record-extractor to find
2016     stuffcmd(pl,
2017              strcat(
2018                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2019                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2020 }
2021
2022 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2023 {
2024         switch(algn)
2025         {
2026                 default:
2027                 case 3: // right
2028                         break;
2029
2030                 case 4: // left
2031                         vecs_y = -vecs_y;
2032                         break;
2033
2034                 case 1:
2035                         if(allowcenter) // 2: allow center handedness
2036                         {
2037                                 // center
2038                                 vecs_y = 0;
2039                                 vecs_z -= 2;
2040                         }
2041                         else
2042                         {
2043                                 // right
2044                         }
2045                         break;
2046
2047                 case 2:
2048                         if(allowcenter) // 2: allow center handedness
2049                         {
2050                                 // center
2051                                 vecs_y = 0;
2052                                 vecs_z -= 2;
2053                         }
2054                         else
2055                         {
2056                                 // left
2057                                 vecs_y = -vecs_y;
2058                         }
2059                         break;
2060         }
2061         return vecs;
2062 }
2063
2064 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2065 {
2066         string s;
2067         vector v;
2068
2069         if (autocvar_g_shootfromeye)
2070         {
2071                 if (visual)
2072                 {
2073                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2074                         else { vecs_y = 0; vecs_z -= 2; }
2075                 }
2076                 else
2077                 {
2078                         vecs_y = 0;
2079                         vecs_z = 0;
2080                 }
2081         }
2082         else if (autocvar_g_shootfromcenter)
2083         {
2084                 vecs_y = 0;
2085                 vecs_z -= 2;
2086         }
2087         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2088         {
2089                 v = stov(s);
2090                 if (y_is_right)
2091                         v_y = -v_y;
2092                 if (v_x != 0)
2093                         vecs_x = v_x;
2094                 vecs_y = v_y;
2095                 vecs_z = v_z;
2096         }
2097         else if (autocvar_g_shootfromclient)
2098         {
2099                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2100         }
2101         return vecs;
2102 }
2103
2104 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2105 {
2106         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2107 }
2108
2109
2110 void attach_sameorigin(entity e, entity to, string tag)
2111 {
2112     vector org, t_forward, t_left, t_up, e_forward, e_up;
2113     float tagscale;
2114
2115     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2116     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2117     t_forward = v_forward * tagscale;
2118     t_left = v_right * -tagscale;
2119     t_up = v_up * tagscale;
2120
2121     e.origin_x = org * t_forward;
2122     e.origin_y = org * t_left;
2123     e.origin_z = org * t_up;
2124
2125     // current forward and up directions
2126     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2127                 e.angles = AnglesTransform_FromVAngles(e.angles);
2128         else
2129                 e.angles = AnglesTransform_FromAngles(e.angles);
2130     fixedmakevectors(e.angles);
2131
2132     // untransform forward, up!
2133     e_forward_x = v_forward * t_forward;
2134     e_forward_y = v_forward * t_left;
2135     e_forward_z = v_forward * t_up;
2136     e_up_x = v_up * t_forward;
2137     e_up_y = v_up * t_left;
2138     e_up_z = v_up * t_up;
2139
2140     e.angles = fixedvectoangles2(e_forward, e_up);
2141     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2142                 e.angles = AnglesTransform_ToVAngles(e.angles);
2143         else
2144                 e.angles = AnglesTransform_ToAngles(e.angles);
2145
2146     setattachment(e, to, tag);
2147     setorigin(e, e.origin);
2148 }
2149
2150 void detach_sameorigin(entity e)
2151 {
2152     vector org;
2153     org = gettaginfo(e, 0);
2154     e.angles = fixedvectoangles2(v_forward, v_up);
2155     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2156                 e.angles = AnglesTransform_ToVAngles(e.angles);
2157         else
2158                 e.angles = AnglesTransform_ToAngles(e.angles);
2159     setorigin(e, org);
2160     setattachment(e, world, "");
2161     setorigin(e, e.origin);
2162 }
2163
2164 void follow_sameorigin(entity e, entity to)
2165 {
2166     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2167     e.aiment = to; // make the hole follow bmodel
2168     e.punchangle = to.angles; // the original angles of bmodel
2169     e.view_ofs = e.origin - to.origin; // relative origin
2170     e.v_angle = e.angles - to.angles; // relative angles
2171 }
2172
2173 void unfollow_sameorigin(entity e)
2174 {
2175     e.movetype = MOVETYPE_NONE;
2176 }
2177
2178 entity gettaginfo_relative_ent;
2179 vector gettaginfo_relative(entity e, float tag)
2180 {
2181     if (!gettaginfo_relative_ent)
2182     {
2183         gettaginfo_relative_ent = spawn();
2184         gettaginfo_relative_ent.effects = EF_NODRAW;
2185     }
2186     gettaginfo_relative_ent.model = e.model;
2187     gettaginfo_relative_ent.modelindex = e.modelindex;
2188     gettaginfo_relative_ent.frame = e.frame;
2189     return gettaginfo(gettaginfo_relative_ent, tag);
2190 }
2191
2192 .float scale2;
2193
2194 float modeleffect_SendEntity(entity to, float sf)
2195 {
2196         float f;
2197         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2198
2199         f = 0;
2200         if(self.velocity != '0 0 0')
2201                 f |= 1;
2202         if(self.angles != '0 0 0')
2203                 f |= 2;
2204         if(self.avelocity != '0 0 0')
2205                 f |= 4;
2206
2207         WriteByte(MSG_ENTITY, f);
2208         WriteShort(MSG_ENTITY, self.modelindex);
2209         WriteByte(MSG_ENTITY, self.skin);
2210         WriteByte(MSG_ENTITY, self.frame);
2211         WriteCoord(MSG_ENTITY, self.origin_x);
2212         WriteCoord(MSG_ENTITY, self.origin_y);
2213         WriteCoord(MSG_ENTITY, self.origin_z);
2214         if(f & 1)
2215         {
2216                 WriteCoord(MSG_ENTITY, self.velocity_x);
2217                 WriteCoord(MSG_ENTITY, self.velocity_y);
2218                 WriteCoord(MSG_ENTITY, self.velocity_z);
2219         }
2220         if(f & 2)
2221         {
2222                 WriteCoord(MSG_ENTITY, self.angles_x);
2223                 WriteCoord(MSG_ENTITY, self.angles_y);
2224                 WriteCoord(MSG_ENTITY, self.angles_z);
2225         }
2226         if(f & 4)
2227         {
2228                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2229                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2230                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2231         }
2232         WriteShort(MSG_ENTITY, self.scale * 256.0);
2233         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2234         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2235         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2236         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2237
2238         return TRUE;
2239 }
2240
2241 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2242 {
2243         entity e;
2244         float sz;
2245         e = spawn();
2246         e.classname = "modeleffect";
2247         setmodel(e, m);
2248         e.frame = f;
2249         setorigin(e, o);
2250         e.velocity = v;
2251         e.angles = ang;
2252         e.avelocity = angv;
2253         e.alpha = a;
2254         e.teleport_time = t1;
2255         e.fade_time = t2;
2256         e.skin = s;
2257         if(s0 >= 0)
2258                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2259         else
2260                 e.scale = -s0;
2261         if(s2 >= 0)
2262                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2263         else
2264                 e.scale2 = -s2;
2265         sz = max(e.scale, e.scale2);
2266         setsize(e, e.mins * sz, e.maxs * sz);
2267         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2268 }
2269
2270 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2271 {
2272         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2273 }
2274
2275 float randombit(float bits)
2276 {
2277         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2278                 return bits;
2279
2280         float n, f, b, r;
2281
2282         r = random();
2283         b = 0;
2284         n = 0;
2285
2286         for(f = 1; f <= bits; f *= 2)
2287         {
2288                 if(bits & f)
2289                 {
2290                         ++n;
2291                         r *= n;
2292                         if(r <= 1)
2293                                 b = f;
2294                         else
2295                                 r = (r - 1) / (n - 1);
2296                 }
2297         }
2298
2299         return b;
2300 }
2301
2302 float randombits(float bits, float k, float error_return)
2303 {
2304         float r;
2305         r = 0;
2306         while(k > 0 && bits != r)
2307         {
2308                 r += randombit(bits - r);
2309                 --k;
2310         }
2311         if(error_return)
2312                 if(k > 0)
2313                         return -1; // all
2314         return r;
2315 }
2316
2317 void randombit_test(float bits, float iter)
2318 {
2319         while(iter > 0)
2320         {
2321                 print(ftos(randombit(bits)), "\n");
2322                 --iter;
2323         }
2324 }
2325
2326 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2327 {
2328         if(halflifedist > 0)
2329                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2330         else if(halflifedist < 0)
2331                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2332         else
2333                 return 1;
2334 }
2335
2336
2337
2338
2339 #ifdef RELEASE
2340 #define cvar_string_normal builtin_cvar_string
2341 #define cvar_normal builtin_cvar
2342 #else
2343 string cvar_string_normal(string n)
2344 {
2345         if (!(cvar_type(n) & 1))
2346                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2347         return builtin_cvar_string(n);
2348 }
2349
2350 float cvar_normal(string n)
2351 {
2352         return stof(cvar_string_normal(n));
2353 }
2354 #endif
2355 #define cvar_set_normal builtin_cvar_set
2356
2357 void defer_think()
2358 {
2359     entity oself;
2360
2361     oself           = self;
2362     self            = self.owner;
2363     oself.think     = SUB_Remove;
2364     oself.nextthink = time;
2365
2366     oself.use();
2367 }
2368
2369 /*
2370     Execute func() after time + fdelay.
2371     self when func is executed = self when defer is called
2372 */
2373 void defer(float fdelay, void() func)
2374 {
2375     entity e;
2376
2377     e           = spawn();
2378     e.owner     = self;
2379     e.use       = func;
2380     e.think     = defer_think;
2381     e.nextthink = time + fdelay;
2382 }
2383
2384 .string aiment_classname;
2385 .float aiment_deadflag;
2386 void SetMovetypeFollow(entity ent, entity e)
2387 {
2388         // FIXME this may not be warpzone aware
2389         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2390         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2391         ent.aiment = e; // make the hole follow bmodel
2392         ent.punchangle = e.angles; // the original angles of bmodel
2393         ent.view_ofs = ent.origin - e.origin; // relative origin
2394         ent.v_angle = ent.angles - e.angles; // relative angles
2395         ent.aiment_classname = strzone(e.classname);
2396         ent.aiment_deadflag = e.deadflag;
2397 }
2398 void UnsetMovetypeFollow(entity ent)
2399 {
2400         ent.movetype = MOVETYPE_FLY;
2401         PROJECTILE_MAKETRIGGER(ent);
2402         ent.aiment = world;
2403 }
2404 float LostMovetypeFollow(entity ent)
2405 {
2406 /*
2407         if(ent.movetype != MOVETYPE_FOLLOW)
2408                 if(ent.aiment)
2409                         error("???");
2410 */
2411         if(ent.aiment)
2412         {
2413                 if(ent.aiment.classname != ent.aiment_classname)
2414                         return 1;
2415                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2416                         return 1;
2417         }
2418         return 0;
2419 }
2420
2421 float isPushable(entity e)
2422 {
2423         if(e.iscreature)
2424                 return TRUE;
2425         if(e.pushable)
2426                 return TRUE;
2427         switch(e.classname)
2428         {
2429                 case "body":
2430                 case "droppedweapon":
2431                 case "keepawayball":
2432                 case "nexball_basketball":
2433                 case "nexball_football":
2434                         return TRUE;
2435                 case "bullet": // antilagged bullets can't hit this either
2436                         return FALSE;
2437         }
2438         if (e.projectiledeathtype)
2439                 return TRUE;
2440         return FALSE;
2441 }