qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = W_Name(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else replacement = "batteries"; // ;)
 363                 } else if (escape == "x") {
 364                         replacement = cursor_ent.netname;
 365                         if (replacement == "" || !cursor_ent)
 366                                 replacement = "nothing";
 367                 } else if (escape == "s")
 368                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 369                 else if (escape == "S")
 370                         replacement = ftos(vlen(self.velocity));
 371
 372                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 373                 p = p + strlen(replacement);
 374         }
 375         return msg;
 376 }
 377
 378 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 379         return (value == 0) ? FALSE : TRUE;
 380 }
 381
 382 /*
 383 =============
 384 GetCvars
 385 =============
 386 Called with:
 387   0:  sends the request
 388   >0: receives a cvar from name=argv(f) value=argv(f+1)
 389 */
 390 void GetCvars_handleString(string thisname, float f, .string field, string name)
 391 {
 392         if (f < 0)
 393         {
 394                 if (self.field)
 395                         strunzone(self.field);
 396                 self.field = string_null;
 397         }
 398         else if (f > 0)
 399         {
 400                 if (thisname == name)
 401                 {
 402                         if (self.field)
 403                                 strunzone(self.field);
 404                         self.field = strzone(argv(f + 1));
 405                 }
 406         }
 407         else
 408                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 409 }
 410 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 411 {
 412         GetCvars_handleString(thisname, f, field, name);
 413         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 414                 if (thisname == name)
 415                 {
 416                         string s;
 417                         s = func(strcat1(self.field));
 418                         if (s != self.field)
 419                         {
 420                                 strunzone(self.field);
 421                                 self.field = strzone(s);
 422                         }
 423                 }
 424 }
 425 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 426 {
 427         if (f < 0)
 428         {
 429         }
 430         else if (f > 0)
 431         {
 432                 if (thisname == name)
 433                         self.field = stof(argv(f + 1));
 434         }
 435         else
 436                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 437 }
 438 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 439 {
 440         if (f < 0)
 441         {
 442         }
 443         else if (f > 0)
 444         {
 445                 if (thisname == name)
 446                 {
 447                         if(!self.field)
 448                         {
 449                                 self.field = stof(argv(f + 1));
 450                                 if(!self.field)
 451                                         self.field = -1;
 452                         }
 453                 }
 454         }
 455         else
 456         {
 457                 if(!self.field)
 458                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 459         }
 460 }
 461 float w_getbestweapon(entity e);
 462 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 463 {
 464         string o;
 465         o = W_FixWeaponOrder_ForceComplete(wo);
 466         if(self.weaponorder_byimpulse)
 467         {
 468                 strunzone(self.weaponorder_byimpulse);
 469                 self.weaponorder_byimpulse = string_null;
 470         }
 471         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 472         return o;
 473 }
 474 void GetCvars(float f)
 475 {
 476         string s = string_null;
 477
 478         if (f > 0)
 479                 s = strcat1(argv(f));
 480
 481         get_cvars_f = f;
 482         get_cvars_s = s;
 483
 484         MUTATOR_CALLHOOK(GetCvars);
 485
 486         Notification_GetCvars();
 487
 488         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 489         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 490         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 491         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 492         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 493         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 505         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 506         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 507         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 508         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 509         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 510         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 511
 512         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 513         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 514
 515         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 516         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 517         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 518         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 519         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 520
 521         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 522         if (f > 0)
 523         {
 524                 if (s == "cl_weaponpriority")
 525                         self.switchweapon = w_getbestweapon(self);
 526                 if (s == "cl_allow_uidtracking")
 527                         PlayerStats_AddPlayer(self);
 528         }
 529 }
 530
 531 // decolorizes and team colors the player name when needed
 532 string playername(entity p)
 533 {
 534     string t;
 535     if (teamplay && !intermission_running && p.classname == "player")
 536     {
 537         t = Team_ColorCode(p.team);
 538         return strcat(t, strdecolorize(p.netname));
 539     }
 540     else
 541         return p.netname;
 542 }
 543
 544 vector randompos(vector m1, vector m2)
 545 {
 546     vector v;
 547     m2 = m2 - m1;
 548     v_x = m2_x * random() + m1_x;
 549     v_y = m2_y * random() + m1_y;
 550     v_z = m2_z * random() + m1_z;
 551     return  v;
 552 }
 553
 554 //#NO AUTOCVARS START
 555
 556 float g_pickup_shells;
 557 float g_pickup_shells_max;
 558 float g_pickup_nails;
 559 float g_pickup_nails_max;
 560 float g_pickup_rockets;
 561 float g_pickup_rockets_max;
 562 float g_pickup_cells;
 563 float g_pickup_cells_max;
 564 float g_pickup_fuel;
 565 float g_pickup_fuel_jetpack;
 566 float g_pickup_fuel_max;
 567 float g_pickup_armorsmall;
 568 float g_pickup_armorsmall_max;
 569 float g_pickup_armorsmall_anyway;
 570 float g_pickup_armormedium;
 571 float g_pickup_armormedium_max;
 572 float g_pickup_armormedium_anyway;
 573 float g_pickup_armorbig;
 574 float g_pickup_armorbig_max;
 575 float g_pickup_armorbig_anyway;
 576 float g_pickup_armorlarge;
 577 float g_pickup_armorlarge_max;
 578 float g_pickup_armorlarge_anyway;
 579 float g_pickup_healthsmall;
 580 float g_pickup_healthsmall_max;
 581 float g_pickup_healthsmall_anyway;
 582 float g_pickup_healthmedium;
 583 float g_pickup_healthmedium_max;
 584 float g_pickup_healthmedium_anyway;
 585 float g_pickup_healthlarge;
 586 float g_pickup_healthlarge_max;
 587 float g_pickup_healthlarge_anyway;
 588 float g_pickup_healthmega;
 589 float g_pickup_healthmega_max;
 590 float g_pickup_healthmega_anyway;
 591 float g_pickup_ammo_anyway;
 592 float g_pickup_weapons_anyway;
 593 float g_weaponarena;
 594 WEPSET_DECLARE_A(g_weaponarena_weapons);
 595 float g_weaponarena_random;
 596 float g_weaponarena_random_with_laser;
 597 string g_weaponarena_list;
 598 float g_weaponspeedfactor;
 599 float g_weaponratefactor;
 600 float g_weapondamagefactor;
 601 float g_weaponforcefactor;
 602 float g_weaponspreadfactor;
 603
 604 WEPSET_DECLARE_A(start_weapons);
 605 WEPSET_DECLARE_A(start_weapons_default);
 606 WEPSET_DECLARE_A(start_weapons_defaultmask);
 607 float start_items;
 608 float start_ammo_shells;
 609 float start_ammo_nails;
 610 float start_ammo_rockets;
 611 float start_ammo_cells;
 612 float start_ammo_fuel;
 613 float start_health;
 614 float start_armorvalue;
 615 WEPSET_DECLARE_A(warmup_start_weapons);
 616 WEPSET_DECLARE_A(warmup_start_weapons_default);
 617 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 618 float warmup_start_ammo_shells;
 619 float warmup_start_ammo_nails;
 620 float warmup_start_ammo_rockets;
 621 float warmup_start_ammo_cells;
 622 float warmup_start_ammo_fuel;
 623 float warmup_start_health;
 624 float warmup_start_armorvalue;
 625 float g_weapon_stay;
 626
 627 entity get_weaponinfo(float w);
 628
 629 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 630 {
 631         var float i = weaponinfo.weapon;
 632         var float d = 0;
 633
 634         if (!i)
 635                 return 0;
 636
 637         if (g_lms || g_ca || allguns)
 638         {
 639                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 640                         d = TRUE;
 641                 else
 642                         d = FALSE;
 643         }
 644         else if (g_cts)
 645                 d = (i == WEP_SHOTGUN);
 646         else if (g_nexball)
 647                 d = 0; // weapon is set a few lines later
 648         else
 649                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 650
 651         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 652                 d |= (i == WEP_HOOK);
 653         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 654                 d = 0;
 655
 656         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 657
 658         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 659
 660         // bit order in t:
 661         // 1: want or not
 662         // 2: is default?
 663         // 4: is set by default?
 664         if(t < 0)
 665                 t = 4 | (3 * d);
 666         else
 667                 t |= (2 * d);
 668
 669         return t;
 670 }
 671
 672 void readplayerstartcvars()
 673 {
 674         entity e;
 675         float i, j, t;
 676         string s;
 677
 678         // initialize starting values for players
 679         WEPSET_CLEAR_A(start_weapons);
 680         WEPSET_CLEAR_A(start_weapons_default);
 681         WEPSET_CLEAR_A(start_weapons_defaultmask);
 682         start_items = 0;
 683         start_ammo_shells = 0;
 684         start_ammo_nails = 0;
 685         start_ammo_rockets = 0;
 686         start_ammo_cells = 0;
 687         start_health = cvar("g_balance_health_start");
 688         start_armorvalue = cvar("g_balance_armor_start");
 689
 690         g_weaponarena = 0;
 691         WEPSET_CLEAR_A(g_weaponarena_weapons);
 692
 693         s = cvar_string("g_weaponarena");
 694         if (s == "0" || s == "")
 695         {
 696                 if(g_ca)
 697                         s = "most";
 698         }
 699
 700         if (s == "0" || s == "")
 701         {
 702                 // no arena
 703         }
 704         else if (s == "off")
 705         {
 706                 // forcibly turn off weaponarena
 707         }
 708         else if (s == "all")
 709         {
 710                 g_weaponarena = 1;
 711                 g_weaponarena_list = "All Weapons";
 712                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 713                 {
 714                         e = get_weaponinfo(j);
 715                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 716                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 717                 }
 718         }
 719         else if (s == "most")
 720         {
 721                 g_weaponarena = 1;
 722                 g_weaponarena_list = "Most Weapons";
 723                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 724                 {
 725                         e = get_weaponinfo(j);
 726                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 727                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 728                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 729                 }
 730         }
 731         else if (s == "none")
 732         {
 733                 g_weaponarena = 1;
 734                 g_weaponarena_list = "No Weapons";
 735         }
 736         else
 737         {
 738                 g_weaponarena = 1;
 739                 t = tokenize_console(s);
 740                 g_weaponarena_list = "";
 741                 for (i = 0; i < t; ++i)
 742                 {
 743                         s = argv(i);
 744                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 745                         {
 746                                 e = get_weaponinfo(j);
 747                                 if (e.netname == s)
 748                                 {
 749                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 750                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 751                                         break;
 752                                 }
 753                         }
 754                         if (j > WEP_LAST)
 755                         {
 756                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 757                         }
 758                 }
 759                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 760         }
 761
 762         if(g_weaponarena)
 763                 g_weaponarena_random = cvar("g_weaponarena_random");
 764         else
 765                 g_weaponarena_random = 0;
 766         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 767
 768         if (g_weaponarena)
 769         {
 770                 g_minstagib = 0; // incompatible
 771                 g_pinata = 0; // incompatible
 772                 g_weapon_stay = 0; // incompatible
 773                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 774                 start_items |= IT_UNLIMITED_AMMO;
 775         }
 776         else if (g_minstagib)
 777         {
 778                 g_pinata = 0; // incompatible
 779                 g_weapon_stay = 0; // incompatible
 780                 g_bloodloss = 0; // incompatible
 781                 start_health = 100;
 782                 start_armorvalue = 0;
 783                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 784                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 785                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 786
 787                 if (g_minstagib_invis_alpha <= 0)
 788                         g_minstagib_invis_alpha = -1;
 789         }
 790         else
 791         {
 792                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 793                 {
 794                         e = get_weaponinfo(i);
 795                         float w = want_weapon("g_start_weapon_", e, FALSE);
 796                         if(w & 1)
 797                                 WEPSET_OR_AW(start_weapons, i);
 798                         if(w & 2)
 799                                 WEPSET_OR_AW(start_weapons_default, i);
 800                         if(w & 4)
 801                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 802                 }
 803         }
 804
 805         if(!cvar("g_use_ammunition"))
 806                 start_items |= IT_UNLIMITED_AMMO;
 807
 808         if(cvar("g_nexball"))
 809                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 810
 811         if(g_minstagib)
 812         {
 813                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 814                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 815         }
 816         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 817         {
 818                 start_ammo_rockets = 999;
 819                 start_ammo_shells = 999;
 820                 start_ammo_cells = 999;
 821                 start_ammo_nails = 999;
 822                 start_ammo_fuel = 999;
 823         }
 824         else
 825         {
 826                 start_ammo_shells = cvar("g_start_ammo_shells");
 827                 start_ammo_nails = cvar("g_start_ammo_nails");
 828                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 829                 start_ammo_cells = cvar("g_start_ammo_cells");
 830                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 831         }
 832
 833         if (inWarmupStage)
 834         {
 835                 warmup_start_ammo_shells = start_ammo_shells;
 836                 warmup_start_ammo_nails = start_ammo_nails;
 837                 warmup_start_ammo_rockets = start_ammo_rockets;
 838                 warmup_start_ammo_cells = start_ammo_cells;
 839                 warmup_start_ammo_fuel = start_ammo_fuel;
 840                 warmup_start_health = start_health;
 841                 warmup_start_armorvalue = start_armorvalue;
 842                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 843                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 844                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 845
 846                 if (!g_weaponarena && !g_minstagib && !g_ca)
 847                 {
 848                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 849                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 850                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 851                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 852                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 853                         warmup_start_health = cvar("g_warmup_start_health");
 854                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 855                         WEPSET_CLEAR_A(warmup_start_weapons);
 856                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 857                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 858                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 859                         {
 860                                 e = get_weaponinfo(i);
 861                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 862                                 if(w & 1)
 863                                         WEPSET_OR_AW(warmup_start_weapons, i);
 864                                 if(w & 2)
 865                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 866                                 if(w & 4)
 867                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 868                         }
 869                 }
 870         }
 871
 872         if (g_jetpack)
 873                 start_items |= IT_JETPACK;
 874
 875         MUTATOR_CALLHOOK(SetStartItems);
 876
 877         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 878         {
 879                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 880                 start_items |= IT_FUEL_REGEN;
 881                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 882                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 883         }
 884
 885         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 886         {
 887                 e = get_weaponinfo(i);
 888                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 889                         weapon_action(i, WR_PRECACHE);
 890         }
 891
 892         start_ammo_shells = max(0, start_ammo_shells);
 893         start_ammo_nails = max(0, start_ammo_nails);
 894         start_ammo_cells = max(0, start_ammo_cells);
 895         start_ammo_rockets = max(0, start_ammo_rockets);
 896         start_ammo_fuel = max(0, start_ammo_fuel);
 897
 898         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 899         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 900         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 901         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 902         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 903 }
 904
 905 float g_bugrigs;
 906 float g_bugrigs_planar_movement;
 907 float g_bugrigs_planar_movement_car_jumping;
 908 float g_bugrigs_reverse_spinning;
 909 float g_bugrigs_reverse_speeding;
 910 float g_bugrigs_reverse_stopping;
 911 float g_bugrigs_air_steering;
 912 float g_bugrigs_angle_smoothing;
 913 float g_bugrigs_friction_floor;
 914 float g_bugrigs_friction_brake;
 915 float g_bugrigs_friction_air;
 916 float g_bugrigs_accel;
 917 float g_bugrigs_speed_ref;
 918 float g_bugrigs_speed_pow;
 919 float g_bugrigs_steer;
 920
 921 float sv_autotaunt;
 922 float sv_taunt;
 923
 924 string GetGametype(); // g_world.qc
 925 void readlevelcvars(void)
 926 {
 927         g_minstagib = cvar("g_minstagib");
 928
 929         // load ALL the mutators
 930         if(cvar("g_dodging"))
 931                 MUTATOR_ADD(mutator_dodging);
 932         if(cvar("g_spawn_near_teammate"))
 933                 MUTATOR_ADD(mutator_spawn_near_teammate);
 934         if(cvar("g_physical_items"))
 935                 MUTATOR_ADD(mutator_physical_items);
 936         if(cvar("g_touchexplode"))
 937                 MUTATOR_ADD(mutator_touchexplode);
 938         if(!g_minstagib)
 939         {
 940                 if(cvar("g_invincible_projectiles"))
 941                         MUTATOR_ADD(mutator_invincibleprojectiles);
 942                 if(cvar("g_new_toys"))
 943                         MUTATOR_ADD(mutator_new_toys);
 944                 if(cvar("g_nix"))
 945                         MUTATOR_ADD(mutator_nix);
 946                 if(cvar("g_rocket_flying"))
 947                         MUTATOR_ADD(mutator_rocketflying);
 948                 if(cvar("g_vampire"))
 949                         MUTATOR_ADD(mutator_vampire);
 950                 if(cvar("g_superspectate"))
 951                         MUTATOR_ADD(mutator_superspec);
 952         }
 953
 954         // is this a mutator? is this a mode?
 955         if(cvar("g_sandbox"))
 956                 MUTATOR_ADD(sandbox);
 957
 958         if(cvar("sv_allow_fullbright"))
 959                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 960
 961     g_bugrigs = cvar("g_bugrigs");
 962     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 963     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 964     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 965     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 966     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 967     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 968     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 969     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 970     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 971     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 972     g_bugrigs_accel = cvar("g_bugrigs_accel");
 973     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 974     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 975     g_bugrigs_steer = cvar("g_bugrigs_steer");
 976
 977         sv_clones = cvar("sv_clones");
 978         sv_foginterval = cvar("sv_foginterval");
 979         g_cloaked = cvar("g_cloaked");
 980     if(g_cts)
 981         g_cloaked = 1; // always enable cloak in CTS
 982         g_jump_grunt = cvar("g_jump_grunt");
 983         g_footsteps = cvar("g_footsteps");
 984         g_grappling_hook = cvar("g_grappling_hook");
 985         g_jetpack = cvar("g_jetpack");
 986         g_midair = cvar("g_midair");
 987         g_norecoil = cvar("g_norecoil");
 988         g_bloodloss = cvar("g_bloodloss");
 989         sv_maxidle = cvar("sv_maxidle");
 990         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 991         sv_autotaunt = cvar("sv_autotaunt");
 992         sv_taunt = cvar("sv_taunt");
 993
 994         inWarmupStage = cvar("g_warmup");
 995         g_warmup_limit = cvar("g_warmup_limit");
 996         g_warmup_allguns = cvar("g_warmup_allguns");
 997         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 998
 999         if ((g_race && g_race_qualifying == 2) || g_arena || g_assault || cvar("g_campaign"))
1000                 inWarmupStage = 0; // these modes cannot work together, sorry
1001
1002         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1003         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1004         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1005         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1006         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1007         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1008         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1009         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1010         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1011         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1012         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1013         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1014         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1015         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1016
1017         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1018         g_weaponratefactor = cvar("g_weaponratefactor");
1019         g_weapondamagefactor = cvar("g_weapondamagefactor");
1020         g_weaponforcefactor = cvar("g_weaponforcefactor");
1021         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1022
1023         g_pickup_shells = cvar("g_pickup_shells");
1024         g_pickup_shells_max = cvar("g_pickup_shells_max");
1025         g_pickup_nails = cvar("g_pickup_nails");
1026         g_pickup_nails_max = cvar("g_pickup_nails_max");
1027         g_pickup_rockets = cvar("g_pickup_rockets");
1028         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1029         g_pickup_cells = cvar("g_pickup_cells");
1030         g_pickup_cells_max = cvar("g_pickup_cells_max");
1031         g_pickup_fuel = cvar("g_pickup_fuel");
1032         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1033         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1034         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1035         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1036         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1037         g_pickup_armormedium = cvar("g_pickup_armormedium");
1038         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1039         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1040         g_pickup_armorbig = cvar("g_pickup_armorbig");
1041         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1042         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1043         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1044         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1045         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1046         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1047         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1048         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1049         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1050         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1051         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1052         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1053         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1054         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1055         g_pickup_healthmega = cvar("g_pickup_healthmega");
1056         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1057         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1058
1059         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1060         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1061
1062         g_pinata = cvar("g_pinata");
1063
1064     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1065     if(!g_weapon_stay)
1066         g_weapon_stay = cvar("g_weapon_stay");
1067
1068         if not(inWarmupStage)
1069                 game_starttime = time + cvar("g_start_delay");
1070
1071         readplayerstartcvars();
1072 }
1073
1074 //#NO AUTOCVARS END
1075
1076 // Sound functions
1077 string precache_sound (string s) = #19;
1078 float precache_sound_index (string s) = #19;
1079
1080 #define SND_VOLUME      1
1081 #define SND_ATTENUATION 2
1082 #define SND_LARGEENTITY 8
1083 #define SND_LARGESOUND  16
1084
1085 float sound_allowed(float dest, entity e)
1086 {
1087     // sounds from world may always pass
1088     for (;;)
1089     {
1090         if (e.classname == "body")
1091             e = e.enemy;
1092         else if (e.realowner && e.realowner != e)
1093             e = e.realowner;
1094         else if (e.owner && e.owner != e)
1095             e = e.owner;
1096         else
1097             break;
1098     }
1099     // sounds to self may always pass
1100     if (dest == MSG_ONE)
1101         if (e == msg_entity)
1102             return TRUE;
1103     // sounds by players can be removed
1104     if (autocvar_bot_sound_monopoly)
1105         if (clienttype(e) == CLIENTTYPE_REAL)
1106             return FALSE;
1107     // anything else may pass
1108     return TRUE;
1109 }
1110
1111 #ifdef COMPAT_XON010_CHANNELS
1112 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1113 void sound(entity e, float chan, string samp, float vol, float atten)
1114 {
1115     if (!sound_allowed(MSG_BROADCAST, e))
1116         return;
1117     builtin_sound(e, chan, samp, vol, atten);
1118 }
1119 #else
1120 #undef sound
1121 void sound(entity e, float chan, string samp, float vol, float atten)
1122 {
1123     if (!sound_allowed(MSG_BROADCAST, e))
1124         return;
1125     sound7(e, chan, samp, vol, atten, 0, 0);
1126 }
1127 #endif
1128
1129 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1130 {
1131     float entno, idx;
1132
1133     if (!sound_allowed(dest, e))
1134         return;
1135
1136     entno = num_for_edict(e);
1137     idx = precache_sound_index(samp);
1138
1139     float sflags;
1140     sflags = 0;
1141
1142     atten = floor(atten * 64);
1143     vol = floor(vol * 255);
1144
1145     if (vol != 255)
1146         sflags |= SND_VOLUME;
1147     if (atten != 64)
1148         sflags |= SND_ATTENUATION;
1149     if (entno >= 8192 || chan < 0 || chan > 7)
1150         sflags |= SND_LARGEENTITY;
1151     if (idx >= 256)
1152         sflags |= SND_LARGESOUND;
1153
1154     WriteByte(dest, SVC_SOUND);
1155     WriteByte(dest, sflags);
1156     if (sflags & SND_VOLUME)
1157         WriteByte(dest, vol);
1158     if (sflags & SND_ATTENUATION)
1159         WriteByte(dest, atten);
1160     if (sflags & SND_LARGEENTITY)
1161     {
1162         WriteShort(dest, entno);
1163         WriteByte(dest, chan);
1164     }
1165     else
1166     {
1167         WriteShort(dest, entno * 8 + chan);
1168     }
1169     if (sflags & SND_LARGESOUND)
1170         WriteShort(dest, idx);
1171     else
1172         WriteByte(dest, idx);
1173
1174     WriteCoord(dest, o_x);
1175     WriteCoord(dest, o_y);
1176     WriteCoord(dest, o_z);
1177 }
1178 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1179 {
1180     vector o;
1181
1182     if (!sound_allowed(dest, e))
1183         return;
1184
1185     o = e.origin + 0.5 * (e.mins + e.maxs);
1186     soundtoat(dest, e, o, chan, samp, vol, atten);
1187 }
1188 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1189 {
1190     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1191 }
1192 void stopsoundto(float dest, entity e, float chan)
1193 {
1194     float entno;
1195
1196     if (!sound_allowed(dest, e))
1197         return;
1198
1199     entno = num_for_edict(e);
1200
1201     if (entno >= 8192 || chan < 0 || chan > 7)
1202     {
1203         float idx, sflags;
1204         idx = precache_sound_index("misc/null.wav");
1205         sflags = SND_LARGEENTITY;
1206         if (idx >= 256)
1207             sflags |= SND_LARGESOUND;
1208         WriteByte(dest, SVC_SOUND);
1209         WriteByte(dest, sflags);
1210         WriteShort(dest, entno);
1211         WriteByte(dest, chan);
1212         if (sflags & SND_LARGESOUND)
1213             WriteShort(dest, idx);
1214         else
1215             WriteByte(dest, idx);
1216         WriteCoord(dest, e.origin_x);
1217         WriteCoord(dest, e.origin_y);
1218         WriteCoord(dest, e.origin_z);
1219     }
1220     else
1221     {
1222         WriteByte(dest, SVC_STOPSOUND);
1223         WriteShort(dest, entno * 8 + chan);
1224     }
1225 }
1226 void stopsound(entity e, float chan)
1227 {
1228     if (!sound_allowed(MSG_BROADCAST, e))
1229         return;
1230
1231     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1232     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1233 }
1234
1235 void play2(entity e, string filename)
1236 {
1237     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1238     msg_entity = e;
1239     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1240 }
1241
1242 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1243 .float spamtime;
1244 float spamsound(entity e, float chan, string samp, float vol, float atten)
1245 {
1246     if (!sound_allowed(MSG_BROADCAST, e))
1247         return FALSE;
1248
1249     if (time > e.spamtime)
1250     {
1251         e.spamtime = time;
1252         sound(e, chan, samp, vol, atten);
1253         return TRUE;
1254     }
1255     return FALSE;
1256 }
1257
1258 void play2team(float t, string filename)
1259 {
1260     entity head;
1261
1262     if (autocvar_bot_sound_monopoly)
1263         return;
1264
1265     FOR_EACH_REALPLAYER(head)
1266     {
1267         if (head.team == t)
1268             play2(head, filename);
1269     }
1270 }
1271
1272 void play2all(string samp)
1273 {
1274     if (autocvar_bot_sound_monopoly)
1275         return;
1276
1277     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1278 }
1279
1280 void PrecachePlayerSounds(string f);
1281 void precache_playermodel(string m)
1282 {
1283         float globhandle, i, n;
1284         string f;
1285
1286         if(substring(m, -9,5) == "_lod1")
1287                 return;
1288         if(substring(m, -9,5) == "_lod2")
1289                 return;
1290         precache_model(m);
1291         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1292         if(fexists(f))
1293                 precache_model(f);
1294         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1295         if(fexists(f))
1296                 precache_model(f);
1297
1298         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1299         if (globhandle < 0)
1300                 return;
1301         n = search_getsize(globhandle);
1302         for (i = 0; i < n; ++i)
1303         {
1304                 //print(search_getfilename(globhandle, i), "\n");
1305                 f = search_getfilename(globhandle, i);
1306                 PrecachePlayerSounds(f);
1307         }
1308         search_end(globhandle);
1309 }
1310 void precache_all_playermodels(string pattern)
1311 {
1312         float globhandle, i, n;
1313         string f;
1314
1315         globhandle = search_begin(pattern, TRUE, FALSE);
1316         if (globhandle < 0)
1317                 return;
1318         n = search_getsize(globhandle);
1319         for (i = 0; i < n; ++i)
1320         {
1321                 //print(search_getfilename(globhandle, i), "\n");
1322                 f = search_getfilename(globhandle, i);
1323                 precache_playermodel(f);
1324         }
1325         search_end(globhandle);
1326 }
1327
1328 void precache()
1329 {
1330     // gamemode related things
1331     precache_model ("models/misc/chatbubble.spr");
1332
1333 #ifdef TTURRETS_ENABLED
1334     if (autocvar_g_turrets)
1335         turrets_precash();
1336 #endif
1337
1338     // Precache all player models if desired
1339     if (autocvar_sv_precacheplayermodels)
1340     {
1341         PrecachePlayerSounds("sound/player/default.sounds");
1342         precache_all_playermodels("models/player/*.zym");
1343         precache_all_playermodels("models/player/*.dpm");
1344         precache_all_playermodels("models/player/*.md3");
1345         precache_all_playermodels("models/player/*.psk");
1346         precache_all_playermodels("models/player/*.iqm");
1347     }
1348
1349     if (autocvar_sv_defaultcharacter)
1350     {
1351         string s;
1352         s = autocvar_sv_defaultplayermodel_red;
1353         if (s != "")
1354             precache_playermodel(s);
1355         s = autocvar_sv_defaultplayermodel_blue;
1356         if (s != "")
1357             precache_playermodel(s);
1358         s = autocvar_sv_defaultplayermodel_yellow;
1359         if (s != "")
1360             precache_playermodel(s);
1361         s = autocvar_sv_defaultplayermodel_pink;
1362         if (s != "")
1363             precache_playermodel(s);
1364         s = autocvar_sv_defaultplayermodel;
1365         if (s != "")
1366             precache_playermodel(s);
1367     }
1368
1369     if (g_footsteps)
1370     {
1371         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1372         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1373     }
1374
1375     // gore and miscellaneous sounds
1376     //precache_sound ("misc/h2ohit.wav");
1377     precache_model ("models/hook.md3");
1378     precache_sound ("misc/armorimpact.wav");
1379     precache_sound ("misc/bodyimpact1.wav");
1380     precache_sound ("misc/bodyimpact2.wav");
1381     precache_sound ("misc/gib.wav");
1382     precache_sound ("misc/gib_splat01.wav");
1383     precache_sound ("misc/gib_splat02.wav");
1384     precache_sound ("misc/gib_splat03.wav");
1385     precache_sound ("misc/gib_splat04.wav");
1386     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1387     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1388     precache_sound ("misc/null.wav");
1389     precache_sound ("misc/spawn.wav");
1390     precache_sound ("misc/talk.wav");
1391     precache_sound ("misc/teleport.wav");
1392     precache_sound ("misc/poweroff.wav");
1393     precache_sound ("player/lava.wav");
1394     precache_sound ("player/slime.wav");
1395
1396     precache_model ("models/sprites/0.spr32");
1397     precache_model ("models/sprites/1.spr32");
1398     precache_model ("models/sprites/2.spr32");
1399     precache_model ("models/sprites/3.spr32");
1400     precache_model ("models/sprites/4.spr32");
1401     precache_model ("models/sprites/5.spr32");
1402     precache_model ("models/sprites/6.spr32");
1403     precache_model ("models/sprites/7.spr32");
1404     precache_model ("models/sprites/8.spr32");
1405     precache_model ("models/sprites/9.spr32");
1406     precache_model ("models/sprites/10.spr32");
1407
1408     // common weapon precaches
1409         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1410     precache_sound ("weapons/weapon_switch.wav");
1411     precache_sound ("weapons/weaponpickup.wav");
1412     precache_sound ("weapons/unavailable.wav");
1413     precache_sound ("weapons/dryfire.wav");
1414     if (g_grappling_hook)
1415     {
1416         precache_sound ("weapons/hook_fire.wav"); // hook
1417         precache_sound ("weapons/hook_impact.wav"); // hook
1418     }
1419
1420     if(autocvar_sv_precacheweapons)
1421     {
1422         //precache weapon models/sounds
1423         float wep;
1424         wep = WEP_FIRST;
1425         while (wep <= WEP_LAST)
1426         {
1427             weapon_action(wep, WR_PRECACHE);
1428             wep = wep + 1;
1429         }
1430     }
1431
1432     precache_model("models/elaser.mdl");
1433     precache_model("models/laser.mdl");
1434     precache_model("models/ebomb.mdl");
1435
1436 #if 0
1437     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1438
1439     if (!self.noise && self.music) // quake 3 uses the music field
1440         self.noise = self.music;
1441
1442     // plays music for the level if there is any
1443     if (self.noise)
1444     {
1445         precache_sound (self.noise);
1446         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1447     }
1448 #endif
1449 }
1450
1451 // WARNING: this kills the trace globals
1452 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1453 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1454
1455 #define INITPRIO_FIRST              0
1456 #define INITPRIO_GAMETYPE           0
1457 #define INITPRIO_GAMETYPE_FALLBACK  1
1458 #define INITPRIO_FINDTARGET        10
1459 #define INITPRIO_DROPTOFLOOR       20
1460 #define INITPRIO_SETLOCATION       90
1461 #define INITPRIO_LINKDOORS         91
1462 #define INITPRIO_LAST              99
1463
1464 .void(void) initialize_entity;
1465 .float initialize_entity_order;
1466 .entity initialize_entity_next;
1467 entity initialize_entity_first;
1468
1469 void make_safe_for_remove(entity e)
1470 {
1471     if (e.initialize_entity)
1472     {
1473         entity ent, prev = world;
1474         for (ent = initialize_entity_first; ent; )
1475         {
1476             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1477             {
1478                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1479                 // skip it in linked list
1480                 if (prev)
1481                 {
1482                     prev.initialize_entity_next = ent.initialize_entity_next;
1483                     ent = prev.initialize_entity_next;
1484                 }
1485                 else
1486                 {
1487                     initialize_entity_first = ent.initialize_entity_next;
1488                     ent = initialize_entity_first;
1489                 }
1490             }
1491             else
1492             {
1493                 prev = ent;
1494                 ent = ent.initialize_entity_next;
1495             }
1496         }
1497     }
1498 }
1499
1500 void objerror(string s)
1501 {
1502     make_safe_for_remove(self);
1503     builtin_objerror(s);
1504 }
1505
1506 .float remove_except_protected_forbidden;
1507 void remove_except_protected(entity e)
1508 {
1509         if(e.remove_except_protected_forbidden)
1510                 error("not allowed to remove this at this point");
1511         builtin_remove(e);
1512 }
1513
1514 void remove_unsafely(entity e)
1515 {
1516     if(e.classname == "spike")
1517         error("Removing spikes is forbidden (crylink bug), please report");
1518     builtin_remove(e);
1519 }
1520
1521 void remove_safely(entity e)
1522 {
1523     make_safe_for_remove(e);
1524     builtin_remove(e);
1525 }
1526
1527 void InitializeEntity(entity e, void(void) func, float order)
1528 {
1529     entity prev, cur;
1530
1531     if (!e || e.initialize_entity)
1532     {
1533         // make a proxy initializer entity
1534         entity e_old;
1535         e_old = e;
1536         e = spawn();
1537         e.classname = "initialize_entity";
1538         e.enemy = e_old;
1539     }
1540
1541     e.initialize_entity = func;
1542     e.initialize_entity_order = order;
1543
1544     cur = initialize_entity_first;
1545     prev = world;
1546     for (;;)
1547     {
1548         if (!cur || cur.initialize_entity_order > order)
1549         {
1550             // insert between prev and cur
1551             if (prev)
1552                 prev.initialize_entity_next = e;
1553             else
1554                 initialize_entity_first = e;
1555             e.initialize_entity_next = cur;
1556             return;
1557         }
1558         prev = cur;
1559         cur = cur.initialize_entity_next;
1560     }
1561 }
1562 void InitializeEntitiesRun()
1563 {
1564     entity startoflist;
1565     startoflist = initialize_entity_first;
1566     initialize_entity_first = world;
1567     remove = remove_except_protected;
1568     for (self = startoflist; self; self = self.initialize_entity_next)
1569     {
1570         self.remove_except_protected_forbidden = 1;
1571     }
1572     for (self = startoflist; self; )
1573     {
1574         entity e;
1575         var void(void) func;
1576         e = self.initialize_entity_next;
1577         func = self.initialize_entity;
1578         self.initialize_entity_order = 0;
1579         self.initialize_entity = func_null;
1580         self.initialize_entity_next = world;
1581         self.remove_except_protected_forbidden = 0;
1582         if (self.classname == "initialize_entity")
1583         {
1584             entity e_old;
1585             e_old = self.enemy;
1586             builtin_remove(self);
1587             self = e_old;
1588         }
1589         //dprint("Delayed initialization: ", self.classname, "\n");
1590         if(func)
1591             func();
1592         else
1593         {
1594             eprint(self);
1595             backtrace(strcat("Null function in: ", self.classname, "\n"));
1596         }
1597         self = e;
1598     }
1599     remove = remove_unsafely;
1600 }
1601
1602 .float uncustomizeentityforclient_set;
1603 .void(void) uncustomizeentityforclient;
1604 void UncustomizeEntitiesRun()
1605 {
1606     entity oldself;
1607     oldself = self;
1608     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1609         self.uncustomizeentityforclient();
1610     self = oldself;
1611 }
1612 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1613 {
1614     e.customizeentityforclient = customizer;
1615     e.uncustomizeentityforclient = uncustomizer;
1616     e.uncustomizeentityforclient_set = !!uncustomizer;
1617 }
1618
1619 .float nottargeted;
1620 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1621
1622 void() SUB_Remove;
1623 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1624 {
1625     vector mi, ma;
1626
1627     if (e.classname == "")
1628         e.classname = "net_linked";
1629
1630     if (e.model == "" || self.modelindex == 0)
1631     {
1632         mi = e.mins;
1633         ma = e.maxs;
1634         setmodel(e, "null");
1635         setsize(e, mi, ma);
1636     }
1637
1638     e.SendEntity = sendfunc;
1639     e.SendFlags = 0xFFFFFF;
1640
1641     if (!docull)
1642         e.effects |= EF_NODEPTHTEST;
1643
1644     if (dt)
1645     {
1646         e.nextthink = time + dt;
1647         e.think = SUB_Remove;
1648     }
1649 }
1650
1651 void adaptor_think2touch()
1652 {
1653     entity o;
1654     o = other;
1655     other = world;
1656     self.touch();
1657     other = o;
1658 }
1659
1660 void adaptor_think2use()
1661 {
1662     entity o, a;
1663     o = other;
1664     a = activator;
1665     activator = world;
1666     other = world;
1667     self.use();
1668     other = o;
1669     activator = a;
1670 }
1671
1672 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1673 {
1674         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1675                 self.projectiledeathtype |= HITTYPE_SPLASH;
1676         adaptor_think2use();
1677 }
1678
1679 // deferred dropping
1680 void DropToFloor_Handler()
1681 {
1682     builtin_droptofloor();
1683     self.dropped_origin = self.origin;
1684 }
1685
1686 void droptofloor()
1687 {
1688     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1689 }
1690
1691
1692
1693 float trace_hits_box_a0, trace_hits_box_a1;
1694
1695 float trace_hits_box_1d(float end, float thmi, float thma)
1696 {
1697     if (end == 0)
1698     {
1699         // just check if x is in range
1700         if (0 < thmi)
1701             return FALSE;
1702         if (0 > thma)
1703             return FALSE;
1704     }
1705     else
1706     {
1707         // do the trace with respect to x
1708         // 0 -> end has to stay in thmi -> thma
1709         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1710         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1711         if (trace_hits_box_a0 > trace_hits_box_a1)
1712             return FALSE;
1713     }
1714     return TRUE;
1715 }
1716
1717 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1718 {
1719     end -= start;
1720     thmi -= start;
1721     thma -= start;
1722     // now it is a trace from 0 to end
1723
1724     trace_hits_box_a0 = 0;
1725     trace_hits_box_a1 = 1;
1726
1727     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1728         return FALSE;
1729     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1730         return FALSE;
1731     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1732         return FALSE;
1733
1734     return TRUE;
1735 }
1736
1737 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1738 {
1739     return trace_hits_box(start, end, thmi - ma, thma - mi);
1740 }
1741
1742 float SUB_NoImpactCheck()
1743 {
1744         // zero hitcontents = this is not the real impact, but either the
1745         // mirror-impact of something hitting the projectile instead of the
1746         // projectile hitting the something, or a touchareagrid one. Neither of
1747         // these stop the projectile from moving, so...
1748         if(trace_dphitcontents == 0)
1749         {
1750                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1751                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1752                 checkclient();
1753         }
1754     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1755         return 1;
1756     if (other == world && self.size != '0 0 0')
1757     {
1758         vector tic;
1759         tic = self.velocity * sys_frametime;
1760         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1761         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1762         if (trace_fraction >= 1)
1763         {
1764             dprint("Odd... did not hit...?\n");
1765         }
1766         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1767         {
1768             dprint("Detected and prevented the sky-grapple bug.\n");
1769             return 1;
1770         }
1771     }
1772
1773     return 0;
1774 }
1775
1776 #define SUB_OwnerCheck() (other && (other == self.owner))
1777
1778 void RemoveGrapplingHook(entity pl);
1779 void W_Crylink_Dequeue(entity e);
1780 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1781 {
1782         if(SUB_OwnerCheck())
1783                 return TRUE;
1784         if(SUB_NoImpactCheck())
1785         {
1786                 if(self.classname == "grapplinghook")
1787                         RemoveGrapplingHook(self.realowner);
1788                 else if(self.classname == "spike")
1789                 {
1790                         W_Crylink_Dequeue(self);
1791                         remove(self);
1792                 }
1793                 else
1794                         remove(self);
1795                 return TRUE;
1796         }
1797         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1798                 UpdateCSQCProjectile(self);
1799         return FALSE;
1800 }
1801 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1802
1803 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1804 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1805
1806 void URI_Get_Callback(float id, float status, string data)
1807 {
1808         if(url_URI_Get_Callback(id, status, data))
1809         {
1810                 // handled
1811         }
1812         else if (id == URI_GET_DISCARD)
1813         {
1814                 // discard
1815         }
1816         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1817         {
1818                 // sv_cmd curl
1819                 Curl_URI_Get_Callback(id, status, data);
1820         }
1821         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1822         {
1823                 // online ban list
1824                 OnlineBanList_URI_Get_Callback(id, status, data);
1825         }
1826         else
1827         {
1828                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1829         }
1830 }
1831
1832 string uid2name(string myuid) {
1833         string s;
1834         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1835
1836         // FIXME remove this later after 0.6 release
1837         // convert old style broken records to correct style
1838         if(s == "")
1839         {
1840                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1841                 if(s != "")
1842                 {
1843                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1844                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1845                 }
1846         }
1847
1848         if(s == "")
1849                 s = "^1Unregistered Player";
1850         return s;
1851 }
1852
1853 float race_readTime(string map, float pos)
1854 {
1855         string rr;
1856         if(g_cts)
1857                 rr = CTS_RECORD;
1858         else
1859                 rr = RACE_RECORD;
1860
1861         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1862 }
1863
1864 string race_readUID(string map, float pos)
1865 {
1866         string rr;
1867         if(g_cts)
1868                 rr = CTS_RECORD;
1869         else
1870                 rr = RACE_RECORD;
1871
1872         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1873 }
1874
1875 float race_readPos(string map, float t) {
1876         float i;
1877         for (i = 1; i <= RANKINGS_CNT; ++i)
1878                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1879                         return i;
1880
1881         return 0; // pos is zero if unranked
1882 }
1883
1884 void race_writeTime(string map, float t, string myuid)
1885 {
1886         string rr;
1887         if(g_cts)
1888                 rr = CTS_RECORD;
1889         else
1890                 rr = RACE_RECORD;
1891
1892         float newpos;
1893         newpos = race_readPos(map, t);
1894
1895         float i, prevpos = 0;
1896         for(i = 1; i <= RANKINGS_CNT; ++i)
1897         {
1898                 if(race_readUID(map, i) == myuid)
1899                         prevpos = i;
1900         }
1901         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1902                 for (i = prevpos; i > newpos; --i) {
1903                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1904                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1905                 }
1906         } else { // player has no ranked record yet
1907                 for (i = RANKINGS_CNT; i > newpos; --i) {
1908                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1909                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1910                 }
1911         }
1912
1913         // store new time itself
1914         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1915         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1916 }
1917
1918 string race_readName(string map, float pos)
1919 {
1920         string rr;
1921         if(g_cts)
1922                 rr = CTS_RECORD;
1923         else
1924                 rr = RACE_RECORD;
1925
1926         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1927 }
1928
1929 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1930 {
1931     float m, i;
1932     vector start, org, delta, end, enddown, mstart;
1933     entity sp;
1934
1935     m = e.dphitcontentsmask;
1936     e.dphitcontentsmask = goodcontents | badcontents;
1937
1938     org = world.mins;
1939     delta = world.maxs - world.mins;
1940
1941     start = end = org;
1942
1943     for (i = 0; i < attempts; ++i)
1944     {
1945         start_x = org_x + random() * delta_x;
1946         start_y = org_y + random() * delta_y;
1947         start_z = org_z + random() * delta_z;
1948
1949         // rule 1: start inside world bounds, and outside
1950         // solid, and don't start from somewhere where you can
1951         // fall down to evil
1952         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1953         if (trace_fraction >= 1)
1954             continue;
1955         if (trace_startsolid)
1956             continue;
1957         if (trace_dphitcontents & badcontents)
1958             continue;
1959         if (trace_dphitq3surfaceflags & badsurfaceflags)
1960             continue;
1961
1962         // rule 2: if we are too high, lower the point
1963         if (trace_fraction * delta_z > maxaboveground)
1964             start = trace_endpos + '0 0 1' * maxaboveground;
1965         enddown = trace_endpos;
1966
1967         // rule 3: make sure we aren't outside the map. This only works
1968         // for somewhat well formed maps. A good rule of thumb is that
1969         // the map should have a convex outside hull.
1970         // these can be traceLINES as we already verified the starting box
1971         mstart = start + 0.5 * (e.mins + e.maxs);
1972         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1973         if (trace_fraction >= 1)
1974             continue;
1975         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1976         if (trace_fraction >= 1)
1977             continue;
1978         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1979         if (trace_fraction >= 1)
1980             continue;
1981         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1982         if (trace_fraction >= 1)
1983             continue;
1984         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1985         if (trace_fraction >= 1)
1986             continue;
1987
1988         // rule 4: we must "see" some spawnpoint
1989         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1990                 if(checkpvs(mstart, sp))
1991                         break;
1992         if(!sp)
1993         {
1994                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1995                         if(checkpvs(mstart, sp))
1996                                 break;
1997                 if(!sp)
1998                         continue;
1999         }
2000
2001         // find a random vector to "look at"
2002         end_x = org_x + random() * delta_x;
2003         end_y = org_y + random() * delta_y;
2004         end_z = org_z + random() * delta_z;
2005         end = start + normalize(end - start) * vlen(delta);
2006
2007         // rule 4: start TO end must not be too short
2008         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2009         if (trace_startsolid)
2010             continue;
2011         if (trace_fraction < minviewdistance / vlen(delta))
2012             continue;
2013
2014         // rule 5: don't want to look at sky
2015         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2016             continue;
2017
2018         // rule 6: we must not end up in trigger_hurt
2019         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2020             continue;
2021
2022         break;
2023     }
2024
2025     e.dphitcontentsmask = m;
2026
2027     if (i < attempts)
2028     {
2029         setorigin(e, start);
2030         e.angles = vectoangles(end - start);
2031         dprint("Needed ", ftos(i + 1), " attempts\n");
2032         return TRUE;
2033     }
2034     else
2035         return FALSE;
2036 }
2037
2038 float zcurveparticles_effectno;
2039 vector zcurveparticles_start;
2040 float zcurveparticles_spd;
2041
2042 void endzcurveparticles()
2043 {
2044         if(zcurveparticles_effectno)
2045         {
2046                 // terminator
2047                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2048         }
2049         zcurveparticles_effectno = 0;
2050 }
2051
2052 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2053 {
2054         spd = bound(0, floor(spd / 16), 32767);
2055         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2056         {
2057                 endzcurveparticles();
2058                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2059                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2060                 WriteShort(MSG_BROADCAST, effectno);
2061                 WriteCoord(MSG_BROADCAST, start_x);
2062                 WriteCoord(MSG_BROADCAST, start_y);
2063                 WriteCoord(MSG_BROADCAST, start_z);
2064                 zcurveparticles_effectno = effectno;
2065                 zcurveparticles_start = start;
2066         }
2067         else
2068                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2069         WriteCoord(MSG_BROADCAST, end_x);
2070         WriteCoord(MSG_BROADCAST, end_y);
2071         WriteCoord(MSG_BROADCAST, end_z);
2072         WriteCoord(MSG_BROADCAST, end_dz);
2073         zcurveparticles_spd = spd;
2074 }
2075
2076 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2077 {
2078         float end_dz;
2079         vector vecxy, velxy;
2080
2081         vecxy = end - start;
2082         vecxy_z = 0;
2083         velxy = vel;
2084         velxy_z = 0;
2085
2086         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2087         {
2088                 endzcurveparticles();
2089                 trailparticles(world, effectno, start, end);
2090                 return;
2091         }
2092
2093         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2094         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2095 }
2096
2097 void write_recordmarker(entity pl, float tstart, float dt)
2098 {
2099     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2100
2101     // also write a marker into demo files for demotc-race-record-extractor to find
2102     stuffcmd(pl,
2103              strcat(
2104                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2105                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2106 }
2107
2108 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2109 {
2110         switch(algn)
2111         {
2112                 default:
2113                 case 3: // right
2114                         break;
2115
2116                 case 4: // left
2117                         vecs_y = -vecs_y;
2118                         break;
2119
2120                 case 1:
2121                         if(allowcenter) // 2: allow center handedness
2122                         {
2123                                 // center
2124                                 vecs_y = 0;
2125                                 vecs_z -= 2;
2126                         }
2127                         else
2128                         {
2129                                 // right
2130                         }
2131                         break;
2132
2133                 case 2:
2134                         if(allowcenter) // 2: allow center handedness
2135                         {
2136                                 // center
2137                                 vecs_y = 0;
2138                                 vecs_z -= 2;
2139                         }
2140                         else
2141                         {
2142                                 // left
2143                                 vecs_y = -vecs_y;
2144                         }
2145                         break;
2146         }
2147         return vecs;
2148 }
2149
2150 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2151 {
2152         string s;
2153         vector v;
2154
2155         if (autocvar_g_shootfromeye)
2156         {
2157                 if (visual)
2158                 {
2159                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2160                         else { vecs_y = 0; vecs_z -= 2; }
2161                 }
2162                 else
2163                 {
2164                         vecs_y = 0;
2165                         vecs_z = 0;
2166                 }
2167         }
2168         else if (autocvar_g_shootfromcenter)
2169         {
2170                 vecs_y = 0;
2171                 vecs_z -= 2;
2172         }
2173         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2174         {
2175                 v = stov(s);
2176                 if (y_is_right)
2177                         v_y = -v_y;
2178                 if (v_x != 0)
2179                         vecs_x = v_x;
2180                 vecs_y = v_y;
2181                 vecs_z = v_z;
2182         }
2183         else if (autocvar_g_shootfromclient)
2184         {
2185                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2186         }
2187         return vecs;
2188 }
2189
2190 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2191 {
2192         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2193 }
2194
2195
2196 void attach_sameorigin(entity e, entity to, string tag)
2197 {
2198     vector org, t_forward, t_left, t_up, e_forward, e_up;
2199     float tagscale;
2200
2201     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2202     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2203     t_forward = v_forward * tagscale;
2204     t_left = v_right * -tagscale;
2205     t_up = v_up * tagscale;
2206
2207     e.origin_x = org * t_forward;
2208     e.origin_y = org * t_left;
2209     e.origin_z = org * t_up;
2210
2211     // current forward and up directions
2212     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2213                 e.angles = AnglesTransform_FromVAngles(e.angles);
2214         else
2215                 e.angles = AnglesTransform_FromAngles(e.angles);
2216     fixedmakevectors(e.angles);
2217
2218     // untransform forward, up!
2219     e_forward_x = v_forward * t_forward;
2220     e_forward_y = v_forward * t_left;
2221     e_forward_z = v_forward * t_up;
2222     e_up_x = v_up * t_forward;
2223     e_up_y = v_up * t_left;
2224     e_up_z = v_up * t_up;
2225
2226     e.angles = fixedvectoangles2(e_forward, e_up);
2227     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2228                 e.angles = AnglesTransform_ToVAngles(e.angles);
2229         else
2230                 e.angles = AnglesTransform_ToAngles(e.angles);
2231
2232     setattachment(e, to, tag);
2233     setorigin(e, e.origin);
2234 }
2235
2236 void detach_sameorigin(entity e)
2237 {
2238     vector org;
2239     org = gettaginfo(e, 0);
2240     e.angles = fixedvectoangles2(v_forward, v_up);
2241     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2242                 e.angles = AnglesTransform_ToVAngles(e.angles);
2243         else
2244                 e.angles = AnglesTransform_ToAngles(e.angles);
2245     setorigin(e, org);
2246     setattachment(e, world, "");
2247     setorigin(e, e.origin);
2248 }
2249
2250 void follow_sameorigin(entity e, entity to)
2251 {
2252     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2253     e.aiment = to; // make the hole follow bmodel
2254     e.punchangle = to.angles; // the original angles of bmodel
2255     e.view_ofs = e.origin - to.origin; // relative origin
2256     e.v_angle = e.angles - to.angles; // relative angles
2257 }
2258
2259 void unfollow_sameorigin(entity e)
2260 {
2261     e.movetype = MOVETYPE_NONE;
2262 }
2263
2264 entity gettaginfo_relative_ent;
2265 vector gettaginfo_relative(entity e, float tag)
2266 {
2267     if (!gettaginfo_relative_ent)
2268     {
2269         gettaginfo_relative_ent = spawn();
2270         gettaginfo_relative_ent.effects = EF_NODRAW;
2271     }
2272     gettaginfo_relative_ent.model = e.model;
2273     gettaginfo_relative_ent.modelindex = e.modelindex;
2274     gettaginfo_relative_ent.frame = e.frame;
2275     return gettaginfo(gettaginfo_relative_ent, tag);
2276 }
2277
2278 .float scale2;
2279
2280 float modeleffect_SendEntity(entity to, float sf)
2281 {
2282         float f;
2283         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2284
2285         f = 0;
2286         if(self.velocity != '0 0 0')
2287                 f |= 1;
2288         if(self.angles != '0 0 0')
2289                 f |= 2;
2290         if(self.avelocity != '0 0 0')
2291                 f |= 4;
2292
2293         WriteByte(MSG_ENTITY, f);
2294         WriteShort(MSG_ENTITY, self.modelindex);
2295         WriteByte(MSG_ENTITY, self.skin);
2296         WriteByte(MSG_ENTITY, self.frame);
2297         WriteCoord(MSG_ENTITY, self.origin_x);
2298         WriteCoord(MSG_ENTITY, self.origin_y);
2299         WriteCoord(MSG_ENTITY, self.origin_z);
2300         if(f & 1)
2301         {
2302                 WriteCoord(MSG_ENTITY, self.velocity_x);
2303                 WriteCoord(MSG_ENTITY, self.velocity_y);
2304                 WriteCoord(MSG_ENTITY, self.velocity_z);
2305         }
2306         if(f & 2)
2307         {
2308                 WriteCoord(MSG_ENTITY, self.angles_x);
2309                 WriteCoord(MSG_ENTITY, self.angles_y);
2310                 WriteCoord(MSG_ENTITY, self.angles_z);
2311         }
2312         if(f & 4)
2313         {
2314                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2315                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2316                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2317         }
2318         WriteShort(MSG_ENTITY, self.scale * 256.0);
2319         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2320         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2321         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2322         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2323
2324         return TRUE;
2325 }
2326
2327 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2328 {
2329         entity e;
2330         float sz;
2331         e = spawn();
2332         e.classname = "modeleffect";
2333         setmodel(e, m);
2334         e.frame = f;
2335         setorigin(e, o);
2336         e.velocity = v;
2337         e.angles = ang;
2338         e.avelocity = angv;
2339         e.alpha = a;
2340         e.teleport_time = t1;
2341         e.fade_time = t2;
2342         e.skin = s;
2343         if(s0 >= 0)
2344                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2345         else
2346                 e.scale = -s0;
2347         if(s2 >= 0)
2348                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2349         else
2350                 e.scale2 = -s2;
2351         sz = max(e.scale, e.scale2);
2352         setsize(e, e.mins * sz, e.maxs * sz);
2353         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2354 }
2355
2356 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2357 {
2358         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2359 }
2360
2361 float randombit(float bits)
2362 {
2363         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2364                 return bits;
2365
2366         float n, f, b, r;
2367
2368         r = random();
2369         b = 0;
2370         n = 0;
2371
2372         for(f = 1; f <= bits; f *= 2)
2373         {
2374                 if(bits & f)
2375                 {
2376                         ++n;
2377                         r *= n;
2378                         if(r <= 1)
2379                                 b = f;
2380                         else
2381                                 r = (r - 1) / (n - 1);
2382                 }
2383         }
2384
2385         return b;
2386 }
2387
2388 float randombits(float bits, float k, float error_return)
2389 {
2390         float r;
2391         r = 0;
2392         while(k > 0 && bits != r)
2393         {
2394                 r += randombit(bits - r);
2395                 --k;
2396         }
2397         if(error_return)
2398                 if(k > 0)
2399                         return -1; // all
2400         return r;
2401 }
2402
2403 void randombit_test(float bits, float iter)
2404 {
2405         while(iter > 0)
2406         {
2407                 print(ftos(randombit(bits)), "\n");
2408                 --iter;
2409         }
2410 }
2411
2412 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2413 {
2414         if(halflifedist > 0)
2415                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2416         else if(halflifedist < 0)
2417                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2418         else
2419                 return 1;
2420 }
2421
2422
2423
2424
2425 #ifdef RELEASE
2426 #define cvar_string_normal builtin_cvar_string
2427 #define cvar_normal builtin_cvar
2428 #else
2429 string cvar_string_normal(string n)
2430 {
2431         if not(cvar_type(n) & 1)
2432                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2433         return builtin_cvar_string(n);
2434 }
2435
2436 float cvar_normal(string n)
2437 {
2438         return stof(cvar_string_normal(n));
2439 }
2440 #endif
2441 #define cvar_set_normal builtin_cvar_set
2442
2443 void defer_think()
2444 {
2445     entity oself;
2446
2447     oself           = self;
2448     self            = self.owner;
2449     oself.think     = SUB_Remove;
2450     oself.nextthink = time;
2451
2452     oself.use();
2453 }
2454
2455 /*
2456     Execute func() after time + fdelay.
2457     self when func is executed = self when defer is called
2458 */
2459 void defer(float fdelay, void() func)
2460 {
2461     entity e;
2462
2463     e           = spawn();
2464     e.owner     = self;
2465     e.use       = func;
2466     e.think     = defer_think;
2467     e.nextthink = time + fdelay;
2468 }
2469
2470 .string aiment_classname;
2471 .float aiment_deadflag;
2472 void SetMovetypeFollow(entity ent, entity e)
2473 {
2474         // FIXME this may not be warpzone aware
2475         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2476         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2477         ent.aiment = e; // make the hole follow bmodel
2478         ent.punchangle = e.angles; // the original angles of bmodel
2479         ent.view_ofs = ent.origin - e.origin; // relative origin
2480         ent.v_angle = ent.angles - e.angles; // relative angles
2481         ent.aiment_classname = strzone(e.classname);
2482         ent.aiment_deadflag = e.deadflag;
2483 }
2484 void UnsetMovetypeFollow(entity ent)
2485 {
2486         ent.movetype = MOVETYPE_FLY;
2487         PROJECTILE_MAKETRIGGER(ent);
2488         ent.aiment = world;
2489 }
2490 float LostMovetypeFollow(entity ent)
2491 {
2492 /*
2493         if(ent.movetype != MOVETYPE_FOLLOW)
2494                 if(ent.aiment)
2495                         error("???");
2496 */
2497         if(ent.aiment)
2498         {
2499                 if(ent.aiment.classname != ent.aiment_classname)
2500                         return 1;
2501                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2502                         return 1;
2503         }
2504         return 0;
2505 }
2506
2507 float isPushable(entity e)
2508 {
2509         if(e.iscreature)
2510                 return TRUE;
2511         if(e.pushable)
2512                 return TRUE;
2513         switch(e.classname)
2514         {
2515                 case "body":
2516                 case "droppedweapon":
2517                 case "keepawayball":
2518                 case "nexball_basketball":
2519                 case "nexball_football":
2520                         return TRUE;
2521                 case "bullet": // antilagged bullets can't hit this either
2522                         return FALSE;
2523         }
2524         if (e.projectiledeathtype)
2525                 return TRUE;
2526         return FALSE;
2527 }