qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 void bcenterprint(string s)
  83 {
  84     // TODO replace by MSG_ALL (would show it to spectators too, though)?
  85     entity head;
  86     FOR_EACH_PLAYER(head)
  87     if (clienttype(head) == CLIENTTYPE_REAL)
  88         centerprint(head, s);
  89 }
  90
  91 void GameLogEcho(string s)
  92 {
  93     string fn;
  94     float matches;
  95
  96     if (autocvar_sv_eventlog_files)
  97     {
  98         if (!logfile_open)
  99         {
 100             logfile_open = TRUE;
 101             matches = autocvar_sv_eventlog_files_counter + 1;
 102             cvar_set("sv_eventlog_files_counter", ftos(matches));
 103             fn = ftos(matches);
 104             if (strlen(fn) < 8)
 105                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 106             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 107             logfile = fopen(fn, FILE_APPEND);
 108             fputs(logfile, ":logversion:3\n");
 109         }
 110         if (logfile >= 0)
 111         {
 112             if (autocvar_sv_eventlog_files_timestamps)
 113                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 114             else
 115                 fputs(logfile, strcat(s, "\n"));
 116         }
 117     }
 118     if (autocvar_sv_eventlog_console)
 119     {
 120         print(s, "\n");
 121     }
 122 }
 123
 124 void GameLogInit()
 125 {
 126     logfile_open = 0;
 127     // will be opened later
 128 }
 129
 130 void GameLogClose()
 131 {
 132     if (logfile_open && logfile >= 0)
 133     {
 134         fclose(logfile);
 135         logfile = -1;
 136     }
 137 }
 138
 139 vector PL_VIEW_OFS;
 140 vector PL_MIN;
 141 vector PL_MAX;
 142 vector PL_HEAD;
 143 vector PL_CROUCH_VIEW_OFS;
 144 vector PL_CROUCH_MIN;
 145 vector PL_CROUCH_MAX;
 146
 147 float spawnpoint_nag;
 148 void relocate_spawnpoint()
 149 {
 150     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 151     PL_MIN                                  = stov(autocvar_sv_player_mins);
 152     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 153     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 154     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 155     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 156     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 157
 158     // nudge off the floor
 159     setorigin(self, self.origin + '0 0 1');
 160
 161     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 162     if (trace_startsolid)
 163     {
 164         vector o;
 165         o = self.origin;
 166         self.mins = PL_MIN;
 167         self.maxs = PL_MAX;
 168         if (!move_out_of_solid(self))
 169             objerror("could not get out of solid at all!");
 170         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 171         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 172         print(" ", ftos(self.origin_y - o_y));
 173         print(" ", ftos(self.origin_z - o_z), "'\n");
 174         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 175         {
 176             if (!spawnpoint_nag)
 177                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 178             spawnpoint_nag = 1;
 179         }
 180         else
 181         {
 182             setorigin(self, o);
 183             self.mins = self.maxs = '0 0 0';
 184             objerror("player spawn point in solid, mapper sucks!\n");
 185             return;
 186         }
 187     }
 188
 189     self.use = spawnpoint_use;
 190     self.team_saved = self.team;
 191     if (!self.cnt)
 192         self.cnt = 1;
 193
 194     if (have_team_spawns != 0)
 195         if (self.team)
 196             have_team_spawns = 1;
 197     have_team_spawns_forteam[self.team] = 1;
 198
 199     if (autocvar_r_showbboxes)
 200     {
 201         // show where spawnpoints point at too
 202         makevectors(self.angles);
 203         entity e;
 204         e = spawn();
 205         e.classname = "info_player_foo";
 206         setorigin(e, self.origin + v_forward * 24);
 207         setsize(e, '-8 -8 -8', '8 8 8');
 208         e.solid = SOLID_TRIGGER;
 209     }
 210 }
 211
 212 #define strstr strstrofs
 213 /*
 214 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 215 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 216 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 217 // BE CONSTANT OR strzoneD!
 218 float strstr(string haystack, string needle, float offset)
 219 {
 220         float len, endpos;
 221         string found;
 222         len = strlen(needle);
 223         endpos = strlen(haystack) - len;
 224         while(offset <= endpos)
 225         {
 226                 found = substring(haystack, offset, len);
 227                 if(found == needle)
 228                         return offset;
 229                 offset = offset + 1;
 230         }
 231         return -1;
 232 }
 233 */
 234
 235 float NUM_NEAREST_ENTITIES = 4;
 236 entity nearest_entity[NUM_NEAREST_ENTITIES];
 237 float nearest_length[NUM_NEAREST_ENTITIES];
 238 entity findnearest(vector point, .string field, string value, vector axismod)
 239 {
 240     entity localhead;
 241     float i;
 242     float j;
 243     float len;
 244     vector dist;
 245
 246     float num_nearest;
 247     num_nearest = 0;
 248
 249     localhead = find(world, field, value);
 250     while (localhead)
 251     {
 252         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 253             dist = localhead.oldorigin;
 254         else
 255             dist = localhead.origin;
 256         dist = dist - point;
 257         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 258         len = vlen(dist);
 259
 260         for (i = 0; i < num_nearest; ++i)
 261         {
 262             if (len < nearest_length[i])
 263                 break;
 264         }
 265
 266         // now i tells us where to insert at
 267         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 268         if (i < NUM_NEAREST_ENTITIES)
 269         {
 270             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 271             {
 272                 nearest_length[j + 1] = nearest_length[j];
 273                 nearest_entity[j + 1] = nearest_entity[j];
 274             }
 275             nearest_length[i] = len;
 276             nearest_entity[i] = localhead;
 277             if (num_nearest < NUM_NEAREST_ENTITIES)
 278                 num_nearest = num_nearest + 1;
 279         }
 280
 281         localhead = find(localhead, field, value);
 282     }
 283
 284     // now use the first one from our list that we can see
 285     for (i = 0; i < num_nearest; ++i)
 286     {
 287         traceline(point, nearest_entity[i].origin, TRUE, world);
 288         if (trace_fraction == 1)
 289         {
 290             if (i != 0)
 291             {
 292                 dprint("Nearest point (");
 293                 dprint(nearest_entity[0].netname);
 294                 dprint(") is not visible, using a visible one.\n");
 295             }
 296             return nearest_entity[i];
 297         }
 298     }
 299
 300     if (num_nearest == 0)
 301         return world;
 302
 303     dprint("Not seeing any location point, using nearest as fallback.\n");
 304     /* DEBUGGING CODE:
 305     dprint("Candidates were: ");
 306     for(j = 0; j < num_nearest; ++j)
 307     {
 308         if(j != 0)
 309                 dprint(", ");
 310         dprint(nearest_entity[j].netname);
 311     }
 312     dprint("\n");
 313     */
 314
 315     return nearest_entity[0];
 316 }
 317
 318 void spawnfunc_target_location()
 319 {
 320     self.classname = "target_location";
 321     // location name in netname
 322     // eventually support: count, teamgame selectors, line of sight?
 323 }
 324
 325 void spawnfunc_info_location()
 326 {
 327     self.classname = "target_location";
 328     self.message = self.netname;
 329 }
 330
 331 string NearestLocation(vector p)
 332 {
 333     entity loc;
 334     string ret;
 335     ret = "somewhere";
 336     loc = findnearest(p, classname, "target_location", '1 1 1');
 337     if (loc)
 338     {
 339         ret = loc.message;
 340     }
 341     else
 342     {
 343         loc = findnearest(p, target, "###item###", '1 1 4');
 344         if (loc)
 345             ret = loc.netname;
 346     }
 347     return ret;
 348 }
 349
 350 string formatmessage(string msg)
 351 {
 352         float p, p1, p2;
 353         float n;
 354         vector cursor;
 355         entity cursor_ent;
 356         string escape;
 357         string replacement;
 358         p = 0;
 359         n = 7;
 360
 361         WarpZone_crosshair_trace(self);
 362         cursor = trace_endpos;
 363         cursor_ent = trace_ent;
 364
 365         while (1) {
 366                 if (n < 1)
 367                         break; // too many replacements
 368
 369                 n = n - 1;
 370                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 371                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 372
 373                 if (p1 < 0)
 374                         p1 = p2;
 375
 376                 if (p2 < 0)
 377                         p2 = p1;
 378
 379                 p = min(p1, p2);
 380
 381                 if (p < 0)
 382                         break;
 383
 384                 replacement = substring(msg, p, 2);
 385                 escape = substring(msg, p + 1, 1);
 386
 387                 if (escape == "%")
 388                         replacement = "%";
 389                 else if (escape == "\\")
 390                         replacement = "\\";
 391                 else if (escape == "n")
 392                         replacement = "\n";
 393                 else if (escape == "a")
 394                         replacement = ftos(floor(self.armorvalue));
 395                 else if (escape == "h")
 396                         replacement = ftos(floor(self.health));
 397                 else if (escape == "l")
 398                         replacement = NearestLocation(self.origin);
 399                 else if (escape == "y")
 400                         replacement = NearestLocation(cursor);
 401                 else if (escape == "d")
 402                         replacement = NearestLocation(self.death_origin);
 403                 else if (escape == "w") {
 404                         float wep;
 405                         wep = self.weapon;
 406                         if (!wep)
 407                                 wep = self.switchweapon;
 408                         if (!wep)
 409                                 wep = self.cnt;
 410                         replacement = W_Name(wep);
 411                 } else if (escape == "W") {
 412                         if (self.items & IT_SHELLS) replacement = "shells";
 413                         else if (self.items & IT_NAILS) replacement = "bullets";
 414                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 415                         else if (self.items & IT_CELLS) replacement = "cells";
 416                         else replacement = "batteries"; // ;)
 417                 } else if (escape == "x") {
 418                         replacement = cursor_ent.netname;
 419                         if (!replacement || !cursor_ent)
 420                                 replacement = "nothing";
 421                 } else if (escape == "s")
 422                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 423                 else if (escape == "S")
 424                         replacement = ftos(vlen(self.velocity));
 425
 426                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 427                 p = p + strlen(replacement);
 428         }
 429         return msg;
 430 }
 431
 432 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 433         return (value == 0) ? FALSE : TRUE;
 434 }
 435
 436 /*
 437 =============
 438 GetCvars
 439 =============
 440 Called with:
 441   0:  sends the request
 442   >0: receives a cvar from name=argv(f) value=argv(f+1)
 443 */
 444 void GetCvars_handleString(string thisname, float f, .string field, string name)
 445 {
 446         if (f < 0)
 447         {
 448                 if (self.field)
 449                         strunzone(self.field);
 450                 self.field = string_null;
 451         }
 452         else if (f > 0)
 453         {
 454                 if (thisname == name)
 455                 {
 456                         if (self.field)
 457                                 strunzone(self.field);
 458                         self.field = strzone(argv(f + 1));
 459                 }
 460         }
 461         else
 462                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 463 }
 464 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 465 {
 466         GetCvars_handleString(thisname, f, field, name);
 467         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 468                 if (thisname == name)
 469                 {
 470                         string s;
 471                         s = func(strcat1(self.field));
 472                         if (s != self.field)
 473                         {
 474                                 strunzone(self.field);
 475                                 self.field = strzone(s);
 476                         }
 477                 }
 478 }
 479 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 480 {
 481         if (f < 0)
 482         {
 483         }
 484         else if (f > 0)
 485         {
 486                 if (thisname == name)
 487                         self.field = stof(argv(f + 1));
 488         }
 489         else
 490                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 491 }
 492 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 493 {
 494         if (f < 0)
 495         {
 496         }
 497         else if (f > 0)
 498         {
 499                 if (thisname == name)
 500                 {
 501                         if(!self.field)
 502                         {
 503                                 self.field = stof(argv(f + 1));
 504                                 if(!self.field)
 505                                         self.field = -1;
 506                         }
 507                 }
 508         }
 509         else
 510         {
 511                 if(!self.field)
 512                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 513         }
 514 }
 515 float w_getbestweapon(entity e);
 516 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 517 {
 518         string o;
 519         o = W_FixWeaponOrder_ForceComplete(wo);
 520         if(self.weaponorder_byimpulse)
 521         {
 522                 strunzone(self.weaponorder_byimpulse);
 523                 self.weaponorder_byimpulse = string_null;
 524         }
 525         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 526         return o;
 527 }
 528 void GetCvars(float f)
 529 {
 530         string s;
 531
 532         if (f > 0)
 533                 s = strcat1(argv(f));
 534
 535         get_cvars_f = f;
 536         get_cvars_s = s;
 537         MUTATOR_CALLHOOK(GetCvars);
 538         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 539         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 540         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 541         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 542         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 543         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 556         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 557         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 558         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 559         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 560         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 561         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 562
 563         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 564         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 565
 566 #ifdef ALLOW_FORCEMODELS
 567         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 568         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 569 #endif
 570         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 571         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 572         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 573         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 574         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 575
 576         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 577         if (f > 0)
 578         {
 579                 if (s == "cl_weaponpriority")
 580                         self.switchweapon = w_getbestweapon(self);
 581                 if (s == "cl_allow_uidtracking")
 582                         PlayerStats_AddPlayer(self);
 583         }
 584 }
 585
 586 void backtrace(string msg)
 587 {
 588     float dev, war;
 589     dev = autocvar_developer;
 590     war = autocvar_prvm_backtraceforwarnings;
 591     cvar_set("developer", "1");
 592     cvar_set("prvm_backtraceforwarnings", "1");
 593     print("\n");
 594     print("--- CUT HERE ---\nWARNING: ");
 595     print(msg);
 596     print("\n");
 597     remove(world); // isn't there any better way to cause a backtrace?
 598     print("\n--- CUT UNTIL HERE ---\n");
 599     cvar_set("developer", ftos(dev));
 600     cvar_set("prvm_backtraceforwarnings", ftos(war));
 601 }
 602
 603 string Team_ColorCode(float teamid)
 604 {
 605     if (teamid == COLOR_TEAM1)
 606         return "^1";
 607     else if (teamid == COLOR_TEAM2)
 608         return "^4";
 609     else if (teamid == COLOR_TEAM3)
 610         return "^3";
 611     else if (teamid == COLOR_TEAM4)
 612         return "^6";
 613     else
 614         return "^7";
 615 }
 616
 617 string Team_ColorName(float t)
 618 {
 619     // fixme: Search for team entities and get their .netname's!
 620     if (t == COLOR_TEAM1)
 621         return "Red";
 622     if (t == COLOR_TEAM2)
 623         return "Blue";
 624     if (t == COLOR_TEAM3)
 625         return "Yellow";
 626     if (t == COLOR_TEAM4)
 627         return "Pink";
 628     return "Neutral";
 629 }
 630
 631 string Team_ColorNameLowerCase(float t)
 632 {
 633     // fixme: Search for team entities and get their .netname's!
 634     if (t == COLOR_TEAM1)
 635         return "red";
 636     if (t == COLOR_TEAM2)
 637         return "blue";
 638     if (t == COLOR_TEAM3)
 639         return "yellow";
 640     if (t == COLOR_TEAM4)
 641         return "pink";
 642     return "neutral";
 643 }
 644
 645 float ColourToNumber(string team_colour)
 646 {
 647         if (team_colour == "red")
 648                 return COLOR_TEAM1;
 649
 650         if (team_colour == "blue")
 651                 return COLOR_TEAM2;
 652
 653         if (team_colour == "yellow")
 654                 return COLOR_TEAM3;
 655
 656         if (team_colour == "pink")
 657                 return COLOR_TEAM4;
 658
 659         if (team_colour == "auto")
 660                 return 0;
 661
 662         return -1;
 663 }
 664
 665 float NumberToTeamNumber(float number)
 666 {
 667         if (number == 1)
 668                 return COLOR_TEAM1;
 669
 670         if (number == 2)
 671                 return COLOR_TEAM2;
 672
 673         if (number == 3)
 674                 return COLOR_TEAM3;
 675
 676         if (number == 4)
 677                 return COLOR_TEAM4;
 678
 679         return -1;
 680 }
 681
 682 // decolorizes and team colors the player name when needed
 683 string playername(entity p)
 684 {
 685     string t;
 686     if (teamplay && !intermission_running && p.classname == "player")
 687     {
 688         t = Team_ColorCode(p.team);
 689         return strcat(t, strdecolorize(p.netname));
 690     }
 691     else
 692         return p.netname;
 693 }
 694
 695 vector randompos(vector m1, vector m2)
 696 {
 697     vector v;
 698     m2 = m2 - m1;
 699     v_x = m2_x * random() + m1_x;
 700     v_y = m2_y * random() + m1_y;
 701     v_z = m2_z * random() + m1_z;
 702     return  v;
 703 }
 704
 705 //#NO AUTOCVARS START
 706
 707 float g_pickup_shells;
 708 float g_pickup_shells_max;
 709 float g_pickup_nails;
 710 float g_pickup_nails_max;
 711 float g_pickup_rockets;
 712 float g_pickup_rockets_max;
 713 float g_pickup_cells;
 714 float g_pickup_cells_max;
 715 float g_pickup_fuel;
 716 float g_pickup_fuel_jetpack;
 717 float g_pickup_fuel_max;
 718 float g_pickup_armorsmall;
 719 float g_pickup_armorsmall_max;
 720 float g_pickup_armorsmall_anyway;
 721 float g_pickup_armormedium;
 722 float g_pickup_armormedium_max;
 723 float g_pickup_armormedium_anyway;
 724 float g_pickup_armorbig;
 725 float g_pickup_armorbig_max;
 726 float g_pickup_armorbig_anyway;
 727 float g_pickup_armorlarge;
 728 float g_pickup_armorlarge_max;
 729 float g_pickup_armorlarge_anyway;
 730 float g_pickup_healthsmall;
 731 float g_pickup_healthsmall_max;
 732 float g_pickup_healthsmall_anyway;
 733 float g_pickup_healthmedium;
 734 float g_pickup_healthmedium_max;
 735 float g_pickup_healthmedium_anyway;
 736 float g_pickup_healthlarge;
 737 float g_pickup_healthlarge_max;
 738 float g_pickup_healthlarge_anyway;
 739 float g_pickup_healthmega;
 740 float g_pickup_healthmega_max;
 741 float g_pickup_healthmega_anyway;
 742 float g_pickup_ammo_anyway;
 743 float g_pickup_weapons_anyway;
 744 float g_weaponarena;
 745 float g_weaponarena_random;
 746 float g_weaponarena_random_with_laser;
 747 string g_weaponarena_list;
 748 float g_weaponspeedfactor;
 749 float g_weaponratefactor;
 750 float g_weapondamagefactor;
 751 float g_weaponforcefactor;
 752 float g_weaponspreadfactor;
 753
 754 float start_weapons;
 755 float start_items;
 756 float start_ammo_shells;
 757 float start_ammo_nails;
 758 float start_ammo_rockets;
 759 float start_ammo_cells;
 760 float start_ammo_fuel;
 761 float start_health;
 762 float start_armorvalue;
 763 float warmup_start_weapons;
 764 float warmup_start_ammo_shells;
 765 float warmup_start_ammo_nails;
 766 float warmup_start_ammo_rockets;
 767 float warmup_start_ammo_cells;
 768 float warmup_start_ammo_fuel;
 769 float warmup_start_health;
 770 float warmup_start_armorvalue;
 771 float g_weapon_stay;
 772 float g_ghost_items;
 773
 774 entity get_weaponinfo(float w);
 775
 776 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 777 {
 778         var float i = weaponinfo.weapon;
 779
 780         if (!i)
 781                 return 0;
 782
 783         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 784
 785         if (t < 0) // "default" weapon selection
 786         {
 787                 if (g_lms || g_ca || allguns)
 788                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 789                 else if(t < -1)
 790                         t = 0;
 791                 else if (g_cts)
 792                         t = (i == WEP_SHOTGUN);
 793                 else if (g_nexball)
 794                         t = 0; // weapon is set a few lines later
 795                 else
 796                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 797                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 798                         t |= (i == WEP_HOOK);
 799         }
 800
 801         // we cannot disable porto in Nexball, we must force it
 802         if(g_nexball && i == WEP_PORTO)
 803                 t = 1;
 804
 805         return t;
 806 }
 807
 808 void readplayerstartcvars()
 809 {
 810         entity e;
 811         float i, j, t;
 812         string s;
 813
 814         // initialize starting values for players
 815         start_weapons = 0;
 816         start_items = 0;
 817         start_ammo_shells = 0;
 818         start_ammo_nails = 0;
 819         start_ammo_rockets = 0;
 820         start_ammo_cells = 0;
 821         start_health = cvar("g_balance_health_start");
 822         start_armorvalue = cvar("g_balance_armor_start");
 823
 824         g_weaponarena = 0;
 825         s = cvar_string("g_weaponarena");
 826         if (s == "0" || s == "")
 827         {
 828                 if(g_lms || g_ca)
 829                         s = "most";
 830         }
 831
 832         if (s == "0" || s == "")
 833         {
 834                 // no arena
 835         }
 836         else if (s == "off")
 837         {
 838                 // forcibly turn off weaponarena
 839         }
 840         else if (s == "all")
 841         {
 842                 g_weaponarena_list = "All Weapons";
 843                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 844                 {
 845                         e = get_weaponinfo(j);
 846                         g_weaponarena |= e.weapons;
 847                         weapon_action(e.weapon, WR_PRECACHE);
 848                 }
 849         }
 850         else if (s == "most")
 851         {
 852                 g_weaponarena_list = "Most Weapons";
 853                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 854                 {
 855                         e = get_weaponinfo(j);
 856                         if (e.spawnflags & WEP_FLAG_NORMAL)
 857                         {
 858                                 g_weaponarena |= e.weapons;
 859                                 weapon_action(e.weapon, WR_PRECACHE);
 860                         }
 861                 }
 862         }
 863         else if (s == "none")
 864         {
 865                 g_weaponarena_list = "No Weapons";
 866                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 867         }
 868         else
 869         {
 870                 t = tokenize_console(s);
 871                 g_weaponarena_list = "";
 872                 for (i = 0; i < t; ++i)
 873                 {
 874                         s = argv(i);
 875                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 876                         {
 877                                 e = get_weaponinfo(j);
 878                                 if (e.netname == s)
 879                                 {
 880                                         g_weaponarena |= e.weapons;
 881                                         weapon_action(e.weapon, WR_PRECACHE);
 882                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 883                                         break;
 884                                 }
 885                         }
 886                         if (j > WEP_LAST)
 887                         {
 888                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 889                         }
 890                 }
 891                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 892         }
 893
 894         if(g_weaponarena)
 895                 g_weaponarena_random = cvar("g_weaponarena_random");
 896         else
 897                 g_weaponarena_random = 0;
 898         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 899
 900         if (g_weaponarena)
 901         {
 902                 start_weapons = g_weaponarena;
 903                 if(!(g_lms || g_ca))
 904                         start_items |= IT_UNLIMITED_AMMO;
 905         }
 906         else if (g_minstagib)
 907         {
 908                 start_health = 100;
 909                 start_armorvalue = 0;
 910                 start_weapons = WEPBIT_MINSTANEX;
 911                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 912                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 913
 914                 if (g_minstagib_invis_alpha <= 0)
 915                         g_minstagib_invis_alpha = -1;
 916         }
 917         else
 918         {
 919                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 920                 {
 921                         e = get_weaponinfo(i);
 922                         if(want_weapon("g_start_weapon_", e, FALSE))
 923                                 start_weapons |= e.weapons;
 924                 }
 925         }
 926
 927         if(!cvar("g_use_ammunition"))
 928                 start_items |= IT_UNLIMITED_AMMO;
 929
 930         if(g_minstagib)
 931         {
 932                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 933                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 934         }
 935         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 936         {
 937                 start_ammo_rockets = 999;
 938                 start_ammo_shells = 999;
 939                 start_ammo_cells = 999;
 940                 start_ammo_nails = 999;
 941                 start_ammo_fuel = 999;
 942         }
 943         else
 944         {
 945                 if(g_lms || g_ca)
 946                 {
 947                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 948                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 949                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 950                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 951                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 952                 }
 953                 else
 954                 {
 955                         start_ammo_shells = cvar("g_start_ammo_shells");
 956                         start_ammo_nails = cvar("g_start_ammo_nails");
 957                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 958                         start_ammo_cells = cvar("g_start_ammo_cells");
 959                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 960                 }
 961         }
 962
 963         if (g_lms || g_ca)
 964         {
 965                 start_health = cvar("g_lms_start_health");
 966                 start_armorvalue = cvar("g_lms_start_armor");
 967         }
 968
 969         if (inWarmupStage)
 970         {
 971                 warmup_start_ammo_shells = start_ammo_shells;
 972                 warmup_start_ammo_nails = start_ammo_nails;
 973                 warmup_start_ammo_rockets = start_ammo_rockets;
 974                 warmup_start_ammo_cells = start_ammo_cells;
 975                 warmup_start_ammo_fuel = start_ammo_fuel;
 976                 warmup_start_health = start_health;
 977                 warmup_start_armorvalue = start_armorvalue;
 978                 warmup_start_weapons = start_weapons;
 979
 980                 if (!g_weaponarena && !g_minstagib && !g_ca)
 981                 {
 982                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 983                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 984                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 985                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 986                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 987                         warmup_start_health = cvar("g_warmup_start_health");
 988                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 989                         warmup_start_weapons = 0;
 990                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 991                         {
 992                                 e = get_weaponinfo(i);
 993                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
 994                                         warmup_start_weapons |= e.weapons;
 995                         }
 996                 }
 997         }
 998
 999         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1000         {
1001                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1002                 start_items |= IT_FUEL_REGEN;
1003                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1004                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1005         }
1006
1007         if (g_jetpack)
1008                 start_items |= IT_JETPACK;
1009
1010         if (g_weapon_stay == 2)
1011         {
1012                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1013                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1014                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1015                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1016                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1017                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1018                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1019                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1020                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1021                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1022         }
1023
1024         MUTATOR_CALLHOOK(SetStartItems);
1025
1026         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1027         {
1028                 e = get_weaponinfo(i);
1029                 if(e.weapons & (start_weapons | warmup_start_weapons))
1030                         weapon_action(e.weapon, WR_PRECACHE);
1031         }
1032
1033         start_ammo_shells = max(0, start_ammo_shells);
1034         start_ammo_nails = max(0, start_ammo_nails);
1035         start_ammo_cells = max(0, start_ammo_cells);
1036         start_ammo_rockets = max(0, start_ammo_rockets);
1037         start_ammo_fuel = max(0, start_ammo_fuel);
1038
1039         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1040         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1041         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1042         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1043         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1044 }
1045
1046 float g_bugrigs;
1047 float g_bugrigs_planar_movement;
1048 float g_bugrigs_planar_movement_car_jumping;
1049 float g_bugrigs_reverse_spinning;
1050 float g_bugrigs_reverse_speeding;
1051 float g_bugrigs_reverse_stopping;
1052 float g_bugrigs_air_steering;
1053 float g_bugrigs_angle_smoothing;
1054 float g_bugrigs_friction_floor;
1055 float g_bugrigs_friction_brake;
1056 float g_bugrigs_friction_air;
1057 float g_bugrigs_accel;
1058 float g_bugrigs_speed_ref;
1059 float g_bugrigs_speed_pow;
1060 float g_bugrigs_steer;
1061
1062 float g_touchexplode;
1063 float g_touchexplode_radius;
1064 float g_touchexplode_damage;
1065 float g_touchexplode_edgedamage;
1066 float g_touchexplode_force;
1067
1068 float sv_autotaunt;
1069 float sv_taunt;
1070
1071 float sv_pitch_min;
1072 float sv_pitch_max;
1073 float sv_pitch_fixyaw;
1074
1075 string GetGametype(); // g_world.qc
1076 void readlevelcvars(void)
1077 {
1078         // first load all the mutators
1079         if(cvar("g_invincible_projectiles"))
1080                 MUTATOR_ADD(mutator_invincibleprojectiles);
1081         if(cvar("g_nix"))
1082                 MUTATOR_ADD(mutator_nix);
1083         if(cvar("g_dodging"))
1084                 MUTATOR_ADD(mutator_dodging);
1085         if(cvar("g_rocket_flying"))
1086                 MUTATOR_ADD(mutator_rocketflying);
1087         if(cvar("g_vampire"))
1088                 MUTATOR_ADD(mutator_vampire);
1089         if(cvar("g_spawn_near_teammate"))
1090                 MUTATOR_ADD(mutator_spawn_near_teammate);
1091
1092         if(cvar("sv_allow_fullbright"))
1093                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1094
1095     g_bugrigs = cvar("g_bugrigs");
1096     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1097     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1098     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1099     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1100     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1101     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1102     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1103     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1104     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1105     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1106     g_bugrigs_accel = cvar("g_bugrigs_accel");
1107     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1108     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1109     g_bugrigs_steer = cvar("g_bugrigs_steer");
1110
1111     g_touchexplode = cvar("g_touchexplode");
1112     g_touchexplode_radius = cvar("g_touchexplode_radius");
1113     g_touchexplode_damage = cvar("g_touchexplode_damage");
1114     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1115     g_touchexplode_force = cvar("g_touchexplode_force");
1116
1117 #ifdef ALLOW_FORCEMODELS
1118         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1119 #endif
1120         sv_loddistance1 = cvar("sv_loddistance1");
1121         sv_loddistance2 = cvar("sv_loddistance2");
1122
1123         if(sv_loddistance2 <= sv_loddistance1)
1124                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1125
1126         sv_clones = cvar("sv_clones");
1127         sv_gentle = cvar("sv_gentle");
1128         sv_foginterval = cvar("sv_foginterval");
1129         g_cloaked = cvar("g_cloaked");
1130     if(g_cts)
1131         g_cloaked = 1; // always enable cloak in CTS
1132         g_jump_grunt = cvar("g_jump_grunt");
1133         g_footsteps = cvar("g_footsteps");
1134         g_grappling_hook = cvar("g_grappling_hook");
1135         g_jetpack = cvar("g_jetpack");
1136         g_midair = cvar("g_midair");
1137         g_minstagib = cvar("g_minstagib");
1138         g_norecoil = cvar("g_norecoil");
1139         g_bloodloss = cvar("g_bloodloss");
1140         sv_maxidle = cvar("sv_maxidle");
1141         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1142         g_ctf_reverse = cvar("g_ctf_reverse");
1143         sv_autotaunt = cvar("sv_autotaunt");
1144         sv_taunt = cvar("sv_taunt");
1145
1146         inWarmupStage = cvar("g_warmup");
1147         g_warmup_limit = cvar("g_warmup_limit");
1148         g_warmup_allguns = cvar("g_warmup_allguns");
1149         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1150
1151         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1152                 inWarmupStage = 0; // these modes cannot work together, sorry
1153
1154         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1155         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1156         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1157         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1158         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1159         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1160         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1161         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1162         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1163         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1164         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1165         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1166
1167         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1168         g_weaponratefactor = cvar("g_weaponratefactor");
1169         g_weapondamagefactor = cvar("g_weapondamagefactor");
1170         g_weaponforcefactor = cvar("g_weaponforcefactor");
1171         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1172
1173         g_pickup_shells = cvar("g_pickup_shells");
1174         g_pickup_shells_max = cvar("g_pickup_shells_max");
1175         g_pickup_nails = cvar("g_pickup_nails");
1176         g_pickup_nails_max = cvar("g_pickup_nails_max");
1177         g_pickup_rockets = cvar("g_pickup_rockets");
1178         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1179         g_pickup_cells = cvar("g_pickup_cells");
1180         g_pickup_cells_max = cvar("g_pickup_cells_max");
1181         g_pickup_fuel = cvar("g_pickup_fuel");
1182         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1183         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1184         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1185         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1186         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1187         g_pickup_armormedium = cvar("g_pickup_armormedium");
1188         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1189         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1190         g_pickup_armorbig = cvar("g_pickup_armorbig");
1191         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1192         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1193         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1194         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1195         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1196         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1197         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1198         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1199         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1200         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1201         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1202         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1203         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1204         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1205         g_pickup_healthmega = cvar("g_pickup_healthmega");
1206         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1207         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1208
1209         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1210         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1211
1212         g_pinata = cvar("g_pinata");
1213
1214     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1215     if(!g_weapon_stay)
1216         g_weapon_stay = cvar("g_weapon_stay");
1217
1218         g_ghost_items = cvar("g_ghost_items");
1219
1220         if(g_ghost_items >= 1)
1221                 g_ghost_items = 0.25; // default alpha value
1222
1223         if not(inWarmupStage && !g_ca)
1224                 game_starttime = cvar("g_start_delay");
1225
1226         sv_pitch_min = cvar("sv_pitch_min");
1227         sv_pitch_max = cvar("sv_pitch_max");
1228         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1229
1230         readplayerstartcvars();
1231 }
1232
1233 //#NO AUTOCVARS END
1234
1235 // Sound functions
1236 string precache_sound (string s) = #19;
1237 float precache_sound_index (string s) = #19;
1238
1239 #define SND_VOLUME      1
1240 #define SND_ATTENUATION 2
1241 #define SND_LARGEENTITY 8
1242 #define SND_LARGESOUND  16
1243
1244 float sound_allowed(float dest, entity e)
1245 {
1246     // sounds from world may always pass
1247     for (;;)
1248     {
1249         if (e.classname == "body")
1250             e = e.enemy;
1251         else if (e.realowner && e.realowner != e)
1252             e = e.realowner;
1253         else if (e.owner && e.owner != e)
1254             e = e.owner;
1255         else
1256             break;
1257     }
1258     // sounds to self may always pass
1259     if (dest == MSG_ONE)
1260         if (e == msg_entity)
1261             return TRUE;
1262     // sounds by players can be removed
1263     if (autocvar_bot_sound_monopoly)
1264         if (clienttype(e) == CLIENTTYPE_REAL)
1265             return FALSE;
1266     // anything else may pass
1267     return TRUE;
1268 }
1269
1270 #ifdef COMPAT_XON010_CHANNELS
1271 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1272 void sound(entity e, float chan, string samp, float vol, float atten)
1273 {
1274     if (!sound_allowed(MSG_BROADCAST, e))
1275         return;
1276     builtin_sound(e, chan, samp, vol, atten);
1277 }
1278 #else
1279 #undef sound
1280 void sound(entity e, float chan, string samp, float vol, float atten)
1281 {
1282     if (!sound_allowed(MSG_BROADCAST, e))
1283         return;
1284     sound7(e, chan, samp, vol, atten, 0, 0);
1285 }
1286 #endif
1287
1288 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1289 {
1290     float entno, idx;
1291
1292     if (!sound_allowed(dest, e))
1293         return;
1294
1295     entno = num_for_edict(e);
1296     idx = precache_sound_index(samp);
1297
1298     float sflags;
1299     sflags = 0;
1300
1301     atten = floor(atten * 64);
1302     vol = floor(vol * 255);
1303
1304     if (vol != 255)
1305         sflags |= SND_VOLUME;
1306     if (atten != 64)
1307         sflags |= SND_ATTENUATION;
1308     if (entno >= 8192 || chan < 0 || chan > 7)
1309         sflags |= SND_LARGEENTITY;
1310     if (idx >= 256)
1311         sflags |= SND_LARGESOUND;
1312
1313     WriteByte(dest, SVC_SOUND);
1314     WriteByte(dest, sflags);
1315     if (sflags & SND_VOLUME)
1316         WriteByte(dest, vol);
1317     if (sflags & SND_ATTENUATION)
1318         WriteByte(dest, atten);
1319     if (sflags & SND_LARGEENTITY)
1320     {
1321         WriteShort(dest, entno);
1322         WriteByte(dest, chan);
1323     }
1324     else
1325     {
1326         WriteShort(dest, entno * 8 + chan);
1327     }
1328     if (sflags & SND_LARGESOUND)
1329         WriteShort(dest, idx);
1330     else
1331         WriteByte(dest, idx);
1332
1333     WriteCoord(dest, o_x);
1334     WriteCoord(dest, o_y);
1335     WriteCoord(dest, o_z);
1336 }
1337 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1338 {
1339     vector o;
1340
1341     if (!sound_allowed(dest, e))
1342         return;
1343
1344     o = e.origin + 0.5 * (e.mins + e.maxs);
1345     soundtoat(dest, e, o, chan, samp, vol, atten);
1346 }
1347 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1348 {
1349     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1350 }
1351 void stopsoundto(float dest, entity e, float chan)
1352 {
1353     float entno;
1354
1355     if (!sound_allowed(dest, e))
1356         return;
1357
1358     entno = num_for_edict(e);
1359
1360     if (entno >= 8192 || chan < 0 || chan > 7)
1361     {
1362         float idx, sflags;
1363         idx = precache_sound_index("misc/null.wav");
1364         sflags = SND_LARGEENTITY;
1365         if (idx >= 256)
1366             sflags |= SND_LARGESOUND;
1367         WriteByte(dest, SVC_SOUND);
1368         WriteByte(dest, sflags);
1369         WriteShort(dest, entno);
1370         WriteByte(dest, chan);
1371         if (sflags & SND_LARGESOUND)
1372             WriteShort(dest, idx);
1373         else
1374             WriteByte(dest, idx);
1375         WriteCoord(dest, e.origin_x);
1376         WriteCoord(dest, e.origin_y);
1377         WriteCoord(dest, e.origin_z);
1378     }
1379     else
1380     {
1381         WriteByte(dest, SVC_STOPSOUND);
1382         WriteShort(dest, entno * 8 + chan);
1383     }
1384 }
1385 void stopsound(entity e, float chan)
1386 {
1387     if (!sound_allowed(MSG_BROADCAST, e))
1388         return;
1389
1390     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1391     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1392 }
1393
1394 void play2(entity e, string filename)
1395 {
1396     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1397     msg_entity = e;
1398     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1399 }
1400
1401 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1402 .float spamtime;
1403 float spamsound(entity e, float chan, string samp, float vol, float atten)
1404 {
1405     if (!sound_allowed(MSG_BROADCAST, e))
1406         return FALSE;
1407
1408     if (time > e.spamtime)
1409     {
1410         e.spamtime = time;
1411         sound(e, chan, samp, vol, atten);
1412         return TRUE;
1413     }
1414     return FALSE;
1415 }
1416
1417 void play2team(float t, string filename)
1418 {
1419     entity head;
1420
1421     if (autocvar_bot_sound_monopoly)
1422         return;
1423
1424     FOR_EACH_REALPLAYER(head)
1425     {
1426         if (head.team == t)
1427             play2(head, filename);
1428     }
1429 }
1430
1431 void play2all(string samp)
1432 {
1433     if (autocvar_bot_sound_monopoly)
1434         return;
1435
1436     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1437 }
1438
1439 void PrecachePlayerSounds(string f);
1440 void precache_playermodel(string m)
1441 {
1442         float globhandle, i, n;
1443         string f;
1444
1445         if(substring(m, -9,5) == "_lod1")
1446                 return;
1447         if(substring(m, -9,5) == "_lod2")
1448                 return;
1449         precache_model(m);
1450         if(sv_loddistance1)
1451         {
1452                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1453                 if(fexists(f))
1454                         precache_model(f);
1455                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1456                 if(fexists(f))
1457                         precache_model(f);
1458         }
1459
1460         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1461         if (globhandle < 0)
1462                 return;
1463         n = search_getsize(globhandle);
1464         for (i = 0; i < n; ++i)
1465         {
1466                 //print(search_getfilename(globhandle, i), "\n");
1467                 f = search_getfilename(globhandle, i);
1468                 PrecachePlayerSounds(f);
1469         }
1470         search_end(globhandle);
1471 }
1472 void precache_all_playermodels(string pattern)
1473 {
1474         float globhandle, i, n;
1475         string f;
1476
1477         globhandle = search_begin(pattern, TRUE, FALSE);
1478         if (globhandle < 0)
1479                 return;
1480         n = search_getsize(globhandle);
1481         for (i = 0; i < n; ++i)
1482         {
1483                 //print(search_getfilename(globhandle, i), "\n");
1484                 f = search_getfilename(globhandle, i);
1485                 precache_playermodel(f);
1486         }
1487         search_end(globhandle);
1488 }
1489
1490 void precache()
1491 {
1492     // gamemode related things
1493     precache_model ("models/misc/chatbubble.spr");
1494     if (g_runematch)
1495     {
1496         precache_model ("models/runematch/curse.mdl");
1497         precache_model ("models/runematch/rune.mdl");
1498     }
1499
1500 #ifdef TTURRETS_ENABLED
1501     if (autocvar_g_turrets)
1502         turrets_precash();
1503 #endif
1504
1505     // Precache all player models if desired
1506     if (autocvar_sv_precacheplayermodels)
1507     {
1508         PrecachePlayerSounds("sound/player/default.sounds");
1509         precache_all_playermodels("models/player/*.zym");
1510         precache_all_playermodels("models/player/*.dpm");
1511         precache_all_playermodels("models/player/*.md3");
1512         precache_all_playermodels("models/player/*.psk");
1513         precache_all_playermodels("models/player/*.iqm");
1514     }
1515
1516     if (autocvar_sv_defaultcharacter)
1517     {
1518         string s;
1519         s = autocvar_sv_defaultplayermodel_red;
1520         if (s != "")
1521             precache_playermodel(s);
1522         s = autocvar_sv_defaultplayermodel_blue;
1523         if (s != "")
1524             precache_playermodel(s);
1525         s = autocvar_sv_defaultplayermodel_yellow;
1526         if (s != "")
1527             precache_playermodel(s);
1528         s = autocvar_sv_defaultplayermodel_pink;
1529         if (s != "")
1530             precache_playermodel(s);
1531         s = autocvar_sv_defaultplayermodel;
1532         if (s != "")
1533             precache_playermodel(s);
1534     }
1535
1536     if (g_footsteps)
1537     {
1538         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1539         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1540     }
1541
1542     // gore and miscellaneous sounds
1543     //precache_sound ("misc/h2ohit.wav");
1544     precache_model ("models/hook.md3");
1545     precache_sound ("misc/armorimpact.wav");
1546     precache_sound ("misc/bodyimpact1.wav");
1547     precache_sound ("misc/bodyimpact2.wav");
1548     precache_sound ("misc/gib.wav");
1549     precache_sound ("misc/gib_splat01.wav");
1550     precache_sound ("misc/gib_splat02.wav");
1551     precache_sound ("misc/gib_splat03.wav");
1552     precache_sound ("misc/gib_splat04.wav");
1553     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1554     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1555     precache_sound ("misc/null.wav");
1556     precache_sound ("misc/spawn.wav");
1557     precache_sound ("misc/talk.wav");
1558     precache_sound ("misc/teleport.wav");
1559     precache_sound ("misc/poweroff.wav");
1560     precache_sound ("player/lava.wav");
1561     precache_sound ("player/slime.wav");
1562
1563     if (g_jetpack)
1564         precache_sound ("misc/jetpack_fly.wav");
1565
1566     precache_model ("models/sprites/0.spr32");
1567     precache_model ("models/sprites/1.spr32");
1568     precache_model ("models/sprites/2.spr32");
1569     precache_model ("models/sprites/3.spr32");
1570     precache_model ("models/sprites/4.spr32");
1571     precache_model ("models/sprites/5.spr32");
1572     precache_model ("models/sprites/6.spr32");
1573     precache_model ("models/sprites/7.spr32");
1574     precache_model ("models/sprites/8.spr32");
1575     precache_model ("models/sprites/9.spr32");
1576     precache_model ("models/sprites/10.spr32");
1577
1578     // common weapon precaches
1579         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1580     precache_sound ("weapons/weapon_switch.wav");
1581     precache_sound ("weapons/weaponpickup.wav");
1582     precache_sound ("weapons/unavailable.wav");
1583     precache_sound ("weapons/dryfire.wav");
1584     if (g_grappling_hook)
1585     {
1586         precache_sound ("weapons/hook_fire.wav"); // hook
1587         precache_sound ("weapons/hook_impact.wav"); // hook
1588     }
1589
1590     if(autocvar_sv_precacheweapons)
1591     {
1592         //precache weapon models/sounds
1593         float wep;
1594         wep = WEP_FIRST;
1595         while (wep <= WEP_LAST)
1596         {
1597             weapon_action(wep, WR_PRECACHE);
1598             wep = wep + 1;
1599         }
1600     }
1601
1602     precache_model("models/elaser.mdl");
1603     precache_model("models/laser.mdl");
1604     precache_model("models/ebomb.mdl");
1605
1606 #if 0
1607     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1608
1609     if (!self.noise && self.music) // quake 3 uses the music field
1610         self.noise = self.music;
1611
1612     // plays music for the level if there is any
1613     if (self.noise)
1614     {
1615         precache_sound (self.noise);
1616         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1617     }
1618 #endif
1619 }
1620
1621 // sorry, but using \ in macros breaks line numbers
1622 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1623 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1624 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1625
1626
1627 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1628 {
1629         if (clienttype(e) == CLIENTTYPE_REAL)
1630         {
1631                 msg_entity = e;
1632                 WRITESPECTATABLE_MSG_ONE({
1633                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1634                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1635                         WriteByte(MSG_ONE, id);
1636                         WriteString(MSG_ONE, s);
1637                         if (id != 0 && s != "")
1638                         {
1639                                 WriteByte(MSG_ONE, duration);
1640                                 WriteByte(MSG_ONE, countdown_num);
1641                         }
1642                 });
1643         }
1644 }
1645 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1646 {
1647         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1648 }
1649 // WARNING: this kills the trace globals
1650 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1651 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1652
1653 #define INITPRIO_FIRST              0
1654 #define INITPRIO_GAMETYPE           0
1655 #define INITPRIO_GAMETYPE_FALLBACK  1
1656 #define INITPRIO_FINDTARGET        10
1657 #define INITPRIO_DROPTOFLOOR       20
1658 #define INITPRIO_SETLOCATION       90
1659 #define INITPRIO_LINKDOORS         91
1660 #define INITPRIO_LAST              99
1661
1662 .void(void) initialize_entity;
1663 .float initialize_entity_order;
1664 .entity initialize_entity_next;
1665 entity initialize_entity_first;
1666
1667 void make_safe_for_remove(entity e)
1668 {
1669     if (e.initialize_entity)
1670     {
1671         entity ent, prev;
1672         for (ent = initialize_entity_first; ent; )
1673         {
1674             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1675             {
1676                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1677                 // skip it in linked list
1678                 if (prev)
1679                 {
1680                     prev.initialize_entity_next = ent.initialize_entity_next;
1681                     ent = prev.initialize_entity_next;
1682                 }
1683                 else
1684                 {
1685                     initialize_entity_first = ent.initialize_entity_next;
1686                     ent = initialize_entity_first;
1687                 }
1688             }
1689             else
1690             {
1691                 prev = ent;
1692                 ent = ent.initialize_entity_next;
1693             }
1694         }
1695     }
1696 }
1697
1698 void objerror(string s)
1699 {
1700     make_safe_for_remove(self);
1701     builtin_objerror(s);
1702 }
1703
1704 .float remove_except_protected_forbidden;
1705 void remove_except_protected(entity e)
1706 {
1707         if(e.remove_except_protected_forbidden)
1708                 error("not allowed to remove this at this point");
1709         builtin_remove(e);
1710 }
1711
1712 void remove_unsafely(entity e)
1713 {
1714     if(e.classname == "spike")
1715         error("Removing spikes is forbidden (crylink bug), please report");
1716     builtin_remove(e);
1717 }
1718
1719 void remove_safely(entity e)
1720 {
1721     make_safe_for_remove(e);
1722     builtin_remove(e);
1723 }
1724
1725 void InitializeEntity(entity e, void(void) func, float order)
1726 {
1727     entity prev, cur;
1728
1729     if (!e || e.initialize_entity)
1730     {
1731         // make a proxy initializer entity
1732         entity e_old;
1733         e_old = e;
1734         e = spawn();
1735         e.classname = "initialize_entity";
1736         e.enemy = e_old;
1737     }
1738
1739     e.initialize_entity = func;
1740     e.initialize_entity_order = order;
1741
1742     cur = initialize_entity_first;
1743     for (;;)
1744     {
1745         if (!cur || cur.initialize_entity_order > order)
1746         {
1747             // insert between prev and cur
1748             if (prev)
1749                 prev.initialize_entity_next = e;
1750             else
1751                 initialize_entity_first = e;
1752             e.initialize_entity_next = cur;
1753             return;
1754         }
1755         prev = cur;
1756         cur = cur.initialize_entity_next;
1757     }
1758 }
1759 void InitializeEntitiesRun()
1760 {
1761     entity startoflist;
1762     startoflist = initialize_entity_first;
1763     initialize_entity_first = world;
1764     remove = remove_except_protected;
1765     for (self = startoflist; self; self = self.initialize_entity_next)
1766     {
1767         self.remove_except_protected_forbidden = 1;
1768     }
1769     for (self = startoflist; self; )
1770     {
1771         entity e;
1772         var void(void) func;
1773         e = self.initialize_entity_next;
1774         func = self.initialize_entity;
1775         self.initialize_entity_order = 0;
1776         self.initialize_entity = func_null;
1777         self.initialize_entity_next = world;
1778         self.remove_except_protected_forbidden = 0;
1779         if (self.classname == "initialize_entity")
1780         {
1781             entity e_old;
1782             e_old = self.enemy;
1783             builtin_remove(self);
1784             self = e_old;
1785         }
1786         //dprint("Delayed initialization: ", self.classname, "\n");
1787         if(func != func_null)
1788             func();
1789         else
1790         {
1791             eprint(self);
1792             backtrace(strcat("Null function in: ", self.classname, "\n"));
1793         }
1794         self = e;
1795     }
1796     remove = remove_unsafely;
1797 }
1798
1799 .float uncustomizeentityforclient_set;
1800 .void(void) uncustomizeentityforclient;
1801 void(void) SUB_Nullpointer = #0;
1802 void UncustomizeEntitiesRun()
1803 {
1804     entity oldself;
1805     oldself = self;
1806     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1807         self.uncustomizeentityforclient();
1808     self = oldself;
1809 }
1810 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1811 {
1812     e.customizeentityforclient = customizer;
1813     e.uncustomizeentityforclient = uncustomizer;
1814     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1815 }
1816
1817 .float nottargeted;
1818 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1819
1820 void() SUB_Remove;
1821 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1822 {
1823     vector mi, ma;
1824
1825     if (e.classname == "")
1826         e.classname = "net_linked";
1827
1828     if (e.model == "" || self.modelindex == 0)
1829     {
1830         mi = e.mins;
1831         ma = e.maxs;
1832         setmodel(e, "null");
1833         setsize(e, mi, ma);
1834     }
1835
1836     e.SendEntity = sendfunc;
1837     e.SendFlags = 0xFFFFFF;
1838
1839     if (!docull)
1840         e.effects |= EF_NODEPTHTEST;
1841
1842     if (dt)
1843     {
1844         e.nextthink = time + dt;
1845         e.think = SUB_Remove;
1846     }
1847 }
1848
1849 void adaptor_think2touch()
1850 {
1851     entity o;
1852     o = other;
1853     other = world;
1854     self.touch();
1855     other = o;
1856 }
1857
1858 void adaptor_think2use()
1859 {
1860     entity o, a;
1861     o = other;
1862     a = activator;
1863     activator = world;
1864     other = world;
1865     self.use();
1866     other = o;
1867     activator = a;
1868 }
1869
1870 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1871 {
1872         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1873                 self.projectiledeathtype |= HITTYPE_SPLASH;
1874         adaptor_think2use();
1875 }
1876
1877 // deferred dropping
1878 void DropToFloor_Handler()
1879 {
1880     builtin_droptofloor();
1881     self.dropped_origin = self.origin;
1882 }
1883
1884 void droptofloor()
1885 {
1886     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1887 }
1888
1889
1890
1891 float trace_hits_box_a0, trace_hits_box_a1;
1892
1893 float trace_hits_box_1d(float end, float thmi, float thma)
1894 {
1895     if (end == 0)
1896     {
1897         // just check if x is in range
1898         if (0 < thmi)
1899             return FALSE;
1900         if (0 > thma)
1901             return FALSE;
1902     }
1903     else
1904     {
1905         // do the trace with respect to x
1906         // 0 -> end has to stay in thmi -> thma
1907         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1908         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1909         if (trace_hits_box_a0 > trace_hits_box_a1)
1910             return FALSE;
1911     }
1912     return TRUE;
1913 }
1914
1915 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1916 {
1917     end -= start;
1918     thmi -= start;
1919     thma -= start;
1920     // now it is a trace from 0 to end
1921
1922     trace_hits_box_a0 = 0;
1923     trace_hits_box_a1 = 1;
1924
1925     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1926         return FALSE;
1927     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1928         return FALSE;
1929     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1930         return FALSE;
1931
1932     return TRUE;
1933 }
1934
1935 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1936 {
1937     return trace_hits_box(start, end, thmi - ma, thma - mi);
1938 }
1939
1940 float SUB_NoImpactCheck()
1941 {
1942         // zero hitcontents = this is not the real impact, but either the
1943         // mirror-impact of something hitting the projectile instead of the
1944         // projectile hitting the something, or a touchareagrid one. Neither of
1945         // these stop the projectile from moving, so...
1946         if(trace_dphitcontents == 0)
1947         {
1948                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1949                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1950                 checkclient();
1951         }
1952     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1953         return 1;
1954     if (other == world && self.size != '0 0 0')
1955     {
1956         vector tic;
1957         tic = self.velocity * sys_frametime;
1958         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1959         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1960         if (trace_fraction >= 1)
1961         {
1962             dprint("Odd... did not hit...?\n");
1963         }
1964         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1965         {
1966             dprint("Detected and prevented the sky-grapple bug.\n");
1967             return 1;
1968         }
1969     }
1970
1971     return 0;
1972 }
1973
1974 #define SUB_OwnerCheck() (other && (other == self.owner))
1975
1976 void RemoveGrapplingHook(entity pl);
1977 void W_Crylink_Dequeue(entity e);
1978 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1979 {
1980         if(SUB_OwnerCheck())
1981                 return TRUE;
1982         if(SUB_NoImpactCheck())
1983         {
1984                 if(self.classname == "grapplinghook")
1985                         RemoveGrapplingHook(self.realowner);
1986                 else if(self.classname == "spike")
1987                 {
1988                         W_Crylink_Dequeue(self);
1989                         remove(self);
1990                 }
1991                 else
1992                         remove(self);
1993                 return TRUE;
1994         }
1995         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1996                 UpdateCSQCProjectile(self);
1997         return FALSE;
1998 }
1999 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
2000
2001 float MAX_IPBAN_URIS           = 16;
2002
2003 float URI_GET_DISCARD          = 0;
2004 float URI_GET_IPBAN            = 1;
2005 float URI_GET_IPBAN_END        = 16;
2006
2007 void URI_Get_Callback(float id, float status, string data)
2008 {
2009     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2010     dprint(data);
2011     dprint("\nEnd of data.\n");
2012
2013     if(url_URI_Get_Callback(id, status, data))
2014     {
2015         // handled
2016     }
2017     else if (id == URI_GET_DISCARD)
2018     {
2019         // discard
2020     }
2021     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2022     {
2023         // online ban list
2024         OnlineBanList_URI_Get_Callback(id, status, data);
2025     }
2026     else
2027     {
2028         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2029     }
2030 }
2031
2032 void print_to(entity e, string s)
2033 {
2034     if (e)
2035         sprint(e, strcat(s, "\n"));
2036     else
2037         print(s, "\n");
2038 }
2039
2040 string uid2name(string myuid) {
2041         string s;
2042         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2043
2044         // FIXME remove this later after 0.6 release
2045         // convert old style broken records to correct style
2046         if(s == "")
2047         {
2048                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2049                 if(s != "")
2050                 {
2051                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2052                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2053                 }
2054         }
2055
2056         if(s == "")
2057                 s = "^1Unregistered Player";
2058         return s;
2059 }
2060
2061 float race_readTime(string map, float pos)
2062 {
2063         string rr;
2064         if(g_cts)
2065                 rr = CTS_RECORD;
2066         else
2067                 rr = RACE_RECORD;
2068
2069         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2070 }
2071
2072 string race_readUID(string map, float pos)
2073 {
2074         string rr;
2075         if(g_cts)
2076                 rr = CTS_RECORD;
2077         else
2078                 rr = RACE_RECORD;
2079
2080         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2081 }
2082
2083 float race_readPos(string map, float t) {
2084         float i;
2085         for (i = 1; i <= RANKINGS_CNT; ++i)
2086                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2087                         return i;
2088
2089         return 0; // pos is zero if unranked
2090 }
2091
2092 void race_writeTime(string map, float t, string myuid)
2093 {
2094         string rr;
2095         if(g_cts)
2096                 rr = CTS_RECORD;
2097         else
2098                 rr = RACE_RECORD;
2099
2100         float newpos;
2101         newpos = race_readPos(map, t);
2102
2103         float i, prevpos;
2104         for(i = 1; i <= RANKINGS_CNT; ++i)
2105         {
2106                 if(race_readUID(map, i) == myuid)
2107                         prevpos = i;
2108         }
2109         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2110                 for (i = prevpos; i > newpos; --i) {
2111                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2112                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2113                 }
2114         } else { // player has no ranked record yet
2115                 for (i = RANKINGS_CNT; i > newpos; --i) {
2116                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2117                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2118                 }
2119         }
2120
2121         // store new time itself
2122         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2123         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2124 }
2125
2126 string race_readName(string map, float pos)
2127 {
2128         string rr;
2129         if(g_cts)
2130                 rr = CTS_RECORD;
2131         else
2132                 rr = RACE_RECORD;
2133
2134         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2135 }
2136
2137 string race_placeName(float pos) {
2138         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2139         {
2140                 if(mod(pos, 10) == 1)
2141                         return strcat(ftos(pos), "st");
2142                 else if(mod(pos, 10) == 2)
2143                         return strcat(ftos(pos), "nd");
2144                 else if(mod(pos, 10) == 3)
2145                         return strcat(ftos(pos), "rd");
2146                 else
2147                         return strcat(ftos(pos), "th");
2148         }
2149         else
2150                 return strcat(ftos(pos), "th");
2151 }
2152 string getrecords(float page) // 50 records per page
2153 {
2154     float rec;
2155     string h;
2156     float r;
2157     float i;
2158     string s;
2159
2160     rec = 0;
2161
2162     s = "";
2163
2164     if (g_ctf)
2165     {
2166         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2167         {
2168             if (MapInfo_Get_ByID(i))
2169             {
2170                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2171                 if (r == 0)
2172                     continue;
2173                 // TODO: uid2name
2174                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2175                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2176                 ++rec;
2177             }
2178         }
2179     }
2180
2181     if (g_race)
2182     {
2183         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2184         {
2185             if (MapInfo_Get_ByID(i))
2186             {
2187                 r = race_readTime(MapInfo_Map_bspname, 1);
2188                 if (r == 0)
2189                     continue;
2190                 h = race_readName(MapInfo_Map_bspname, 1);
2191                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2192                 ++rec;
2193             }
2194         }
2195     }
2196
2197     if (g_cts)
2198     {
2199         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2200         {
2201             if (MapInfo_Get_ByID(i))
2202             {
2203                 r = race_readTime(MapInfo_Map_bspname, 1);
2204                 if (r == 0)
2205                     continue;
2206                 h = race_readName(MapInfo_Map_bspname, 1);
2207                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2208                 ++rec;
2209             }
2210         }
2211     }
2212
2213     MapInfo_ClearTemps();
2214
2215     if (s == "" && page == 0)
2216         return "No records are available on this server.\n";
2217     else
2218         return s;
2219 }
2220
2221 string getrankings()
2222 {
2223     string n;
2224     float t;
2225     float i;
2226     string s;
2227     string p;
2228     string map;
2229
2230     s = "";
2231
2232     map = GetMapname();
2233
2234     for (i = 1; i <= RANKINGS_CNT; ++i)
2235     {
2236         t = race_readTime(map, i);
2237         if (t == 0)
2238             continue;
2239         n = race_readName(map, i);
2240         p = race_placeName(i);
2241         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2242     }
2243
2244     MapInfo_ClearTemps();
2245
2246     if (s == "")
2247         return strcat("No records are available for the map: ", map, "\n");
2248     else
2249         return strcat("Records for ", map, ":\n", s);
2250 }
2251
2252 #define LADDER_FIRSTPOINT 100
2253 #define LADDER_CNT 10
2254         // position X still gives LADDER_FIRSTPOINT/X points
2255 #define LADDER_SIZE 30
2256         // ladder shows the top X players
2257 string top_uids[LADDER_SIZE];
2258 float top_scores[LADDER_SIZE];
2259 string getladder()
2260 {
2261     float i, j, k, uidcnt;
2262     string s, temp_s;
2263
2264     s = "";
2265     temp_s = "";
2266
2267     string rr;
2268     if(g_cts)
2269         rr = CTS_RECORD;
2270     else
2271         rr = RACE_RECORD;
2272
2273     string myuid;
2274
2275     for (k = 0; k < MapInfo_count; ++k)
2276     {
2277         if (MapInfo_Get_ByID(k))
2278         {
2279                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2280                         if(i == 0) // speed award
2281                         {
2282                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2283                                         continue;
2284
2285                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2286                         }
2287                         else // normal record, if it exists (else break)
2288                         {
2289                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2290                                         continue;
2291
2292                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2293                         }
2294
2295                         // string s contains:
2296                         // arg 0 = # of speed recs
2297                         // arg 1 = # of 1st place recs
2298                         // arg 2 = # of 2nd place recs
2299                         // ... etc
2300                         // LADDER_CNT+1 = total points
2301
2302                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2303                         if (temp_s == "")
2304                         {
2305                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2306                             ++uidcnt;
2307                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2308                             {
2309                                 if(j != LADDER_CNT + 1)
2310                                     temp_s = strcat(temp_s, "0 ");
2311                                 else
2312                                     temp_s = strcat(temp_s, "0");
2313                             }
2314                         }
2315
2316                         tokenize_console(temp_s);
2317                         s = "";
2318
2319                         if(i == 0) // speed award
2320                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2321                             {
2322                                 if(j == 0) // speed award
2323                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2324                                 else
2325                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2326                             }
2327                         else // record
2328                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2329                             {
2330                                 if(j == 0)
2331                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2332                                 else if(j == i) // wanted rec!
2333                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2334                                 else
2335                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2336                             }
2337
2338                         // total points are (by default) calculated like this:
2339                         // speedrec = floor(100 / 10) = 10 points
2340                         // 1st place = floor(100 / 1) = 100 points
2341                         // 2nd place = floor(100 / 2) = 50 points
2342                         // 3rd place = floor(100 / 3) = 33 points
2343                         // 4th place = floor(100 / 4) = 25 points
2344                         // 5th place = floor(100 / 5) = 20 points
2345                         // ... etc
2346
2347                         if(i == 0)
2348                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2349                         else
2350                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2351
2352                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2353                 }
2354         }
2355     }
2356
2357     float thiscnt;
2358     string thisuid;
2359     for (i = 0; i <= uidcnt; ++i) // for each known uid
2360     {
2361         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2362         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2363         tokenize_console(temp_s);
2364         thiscnt = stof(argv(LADDER_CNT+1));
2365
2366         if(thiscnt > top_scores[LADDER_SIZE-1])
2367         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2368         {
2369             if(thiscnt > top_scores[j])
2370             {
2371                 for (k = LADDER_SIZE-1; k >= j; --k)
2372                 {
2373                     top_uids[k] = top_uids[k-1];
2374                     top_scores[k] = top_scores[k-1];
2375                 }
2376                 top_uids[j] = thisuid;
2377                 top_scores[j] = thiscnt;
2378                 break;
2379             }
2380         }
2381     }
2382
2383     s = "^3-----------------------\n\n";
2384
2385     s = strcat(s, "Pos ^3|");
2386     s = strcat(s, " ^7Total  ^3|");
2387     for (i = 1; i <= LADDER_CNT; ++i)
2388     {
2389         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2390     }
2391     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2392
2393     s = strcat(s, "\n^3----+--------");
2394     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2395     {
2396         s = strcat(s, "+-----");
2397     }
2398 #if LADDER_CNT > 9
2399     for (i = 1; i <= LADDER_CNT - 9; ++i)
2400     {
2401         s = strcat(s, "+------");
2402     }
2403 #endif
2404
2405     s = strcat(s, "+--------------+--------------------\n");
2406
2407     for (i = 0; i < LADDER_SIZE; ++i)
2408     {
2409         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2410         tokenize_console(temp_s);
2411         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2412             continue;
2413         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2414         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2415         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2416         {
2417             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2418         }
2419 #if LADDER_CNT > 9
2420         for (j = 10; j <= LADDER_CNT; ++j)
2421         {
2422             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2423         }
2424 #endif
2425
2426         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2427         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2428     }
2429
2430     MapInfo_ClearTemps();
2431
2432     if (s == "")
2433         return "No ladder on this server!\n";
2434     else
2435         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2436 }
2437
2438
2439 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2440 {
2441     float m, i;
2442     vector start, org, delta, end, enddown, mstart;
2443     entity sp;
2444
2445     m = e.dphitcontentsmask;
2446     e.dphitcontentsmask = goodcontents | badcontents;
2447
2448     org = world.mins;
2449     delta = world.maxs - world.mins;
2450
2451     for (i = 0; i < attempts; ++i)
2452     {
2453         start_x = org_x + random() * delta_x;
2454         start_y = org_y + random() * delta_y;
2455         start_z = org_z + random() * delta_z;
2456
2457         // rule 1: start inside world bounds, and outside
2458         // solid, and don't start from somewhere where you can
2459         // fall down to evil
2460         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2461         if (trace_fraction >= 1)
2462             continue;
2463         if (trace_startsolid)
2464             continue;
2465         if (trace_dphitcontents & badcontents)
2466             continue;
2467         if (trace_dphitq3surfaceflags & badsurfaceflags)
2468             continue;
2469
2470         // rule 2: if we are too high, lower the point
2471         if (trace_fraction * delta_z > maxaboveground)
2472             start = trace_endpos + '0 0 1' * maxaboveground;
2473         enddown = trace_endpos;
2474
2475         // rule 3: make sure we aren't outside the map. This only works
2476         // for somewhat well formed maps. A good rule of thumb is that
2477         // the map should have a convex outside hull.
2478         // these can be traceLINES as we already verified the starting box
2479         mstart = start + 0.5 * (e.mins + e.maxs);
2480         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2481         if (trace_fraction >= 1)
2482             continue;
2483         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2484         if (trace_fraction >= 1)
2485             continue;
2486         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2487         if (trace_fraction >= 1)
2488             continue;
2489         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2490         if (trace_fraction >= 1)
2491             continue;
2492         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2493         if (trace_fraction >= 1)
2494             continue;
2495
2496         // rule 4: we must "see" some spawnpoint
2497         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2498                 if(checkpvs(mstart, sp))
2499                         break;
2500         if(!sp)
2501         {
2502                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2503                         if(checkpvs(mstart, sp))
2504                                 break;
2505                 if(!sp)
2506                         continue;
2507         }
2508
2509         // find a random vector to "look at"
2510         end_x = org_x + random() * delta_x;
2511         end_y = org_y + random() * delta_y;
2512         end_z = org_z + random() * delta_z;
2513         end = start + normalize(end - start) * vlen(delta);
2514
2515         // rule 4: start TO end must not be too short
2516         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2517         if (trace_startsolid)
2518             continue;
2519         if (trace_fraction < minviewdistance / vlen(delta))
2520             continue;
2521
2522         // rule 5: don't want to look at sky
2523         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2524             continue;
2525
2526         // rule 6: we must not end up in trigger_hurt
2527         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2528             continue;
2529
2530         break;
2531     }
2532
2533     e.dphitcontentsmask = m;
2534
2535     if (i < attempts)
2536     {
2537         setorigin(e, start);
2538         e.angles = vectoangles(end - start);
2539         dprint("Needed ", ftos(i + 1), " attempts\n");
2540         return TRUE;
2541     }
2542     else
2543         return FALSE;
2544 }
2545
2546 float zcurveparticles_effectno;
2547 vector zcurveparticles_start;
2548 float zcurveparticles_spd;
2549
2550 void endzcurveparticles()
2551 {
2552         if(zcurveparticles_effectno)
2553         {
2554                 // terminator
2555                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2556         }
2557         zcurveparticles_effectno = 0;
2558 }
2559
2560 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2561 {
2562         spd = bound(0, floor(spd / 16), 32767);
2563         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2564         {
2565                 endzcurveparticles();
2566                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2567                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2568                 WriteShort(MSG_BROADCAST, effectno);
2569                 WriteCoord(MSG_BROADCAST, start_x);
2570                 WriteCoord(MSG_BROADCAST, start_y);
2571                 WriteCoord(MSG_BROADCAST, start_z);
2572                 zcurveparticles_effectno = effectno;
2573                 zcurveparticles_start = start;
2574         }
2575         else
2576                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2577         WriteCoord(MSG_BROADCAST, end_x);
2578         WriteCoord(MSG_BROADCAST, end_y);
2579         WriteCoord(MSG_BROADCAST, end_z);
2580         WriteCoord(MSG_BROADCAST, end_dz);
2581         zcurveparticles_spd = spd;
2582 }
2583
2584 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2585 {
2586         float end_dz;
2587         vector vecxy, velxy;
2588
2589         vecxy = end - start;
2590         vecxy_z = 0;
2591         velxy = vel;
2592         velxy_z = 0;
2593
2594         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2595         {
2596                 endzcurveparticles();
2597                 trailparticles(world, effectno, start, end);
2598                 return;
2599         }
2600
2601         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2602         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2603 }
2604
2605 void write_recordmarker(entity pl, float tstart, float dt)
2606 {
2607     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2608
2609     // also write a marker into demo files for demotc-race-record-extractor to find
2610     stuffcmd(pl,
2611              strcat(
2612                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2613                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2614 }
2615
2616 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2617 {
2618         switch(algn)
2619         {
2620                 default:
2621                 case 3: // right
2622                         break;
2623
2624                 case 4: // left
2625                         vecs_y = -vecs_y;
2626                         break;
2627
2628                 case 1:
2629                         if(allowcenter) // 2: allow center handedness
2630                         {
2631                                 // center
2632                                 vecs_y = 0;
2633                                 vecs_z -= 2;
2634                         }
2635                         else
2636                         {
2637                                 // right
2638                         }
2639                         break;
2640
2641                 case 2:
2642                         if(allowcenter) // 2: allow center handedness
2643                         {
2644                                 // center
2645                                 vecs_y = 0;
2646                                 vecs_z -= 2;
2647                         }
2648                         else
2649                         {
2650                                 // left
2651                                 vecs_y = -vecs_y;
2652                         }
2653                         break;
2654         }
2655         return vecs;
2656 }
2657
2658 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2659 {
2660         string s;
2661         vector v;
2662
2663         if (autocvar_g_shootfromeye)
2664         {
2665                 if (visual)
2666                 {
2667                         vecs_y = 0;
2668                         vecs_z -= 2;
2669                 }
2670                 else
2671                 {
2672                         vecs_y = 0;
2673                         vecs_z = 0;
2674                 }
2675         }
2676         else if (autocvar_g_shootfromcenter)
2677         {
2678                 vecs_y = 0;
2679                 vecs_z -= 2;
2680         }
2681         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2682         {
2683                 v = stov(s);
2684                 if (y_is_right)
2685                         v_y = -v_y;
2686                 if (v_x != 0)
2687                         vecs_x = v_x;
2688                 vecs_y = v_y;
2689                 vecs_z = v_z;
2690         }
2691         else if (autocvar_g_shootfromclient)
2692         {
2693                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2694         }
2695         return vecs;
2696 }
2697
2698 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2699 {
2700         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2701 }
2702
2703
2704 void attach_sameorigin(entity e, entity to, string tag)
2705 {
2706     vector org, t_forward, t_left, t_up, e_forward, e_up;
2707     vector org0, ang0;
2708     float tagscale;
2709
2710     ang0 = e.angles;
2711     org0 = e.origin;
2712
2713     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2714     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2715     t_forward = v_forward * tagscale;
2716     t_left = v_right * -tagscale;
2717     t_up = v_up * tagscale;
2718
2719     e.origin_x = org * t_forward;
2720     e.origin_y = org * t_left;
2721     e.origin_z = org * t_up;
2722
2723     // current forward and up directions
2724     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2725                 e.angles = AnglesTransform_FromVAngles(e.angles);
2726         else
2727                 e.angles = AnglesTransform_FromAngles(e.angles);
2728     fixedmakevectors(e.angles);
2729
2730     // untransform forward, up!
2731     e_forward_x = v_forward * t_forward;
2732     e_forward_y = v_forward * t_left;
2733     e_forward_z = v_forward * t_up;
2734     e_up_x = v_up * t_forward;
2735     e_up_y = v_up * t_left;
2736     e_up_z = v_up * t_up;
2737
2738     e.angles = fixedvectoangles2(e_forward, e_up);
2739     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2740                 e.angles = AnglesTransform_ToVAngles(e.angles);
2741         else
2742                 e.angles = AnglesTransform_ToAngles(e.angles);
2743
2744     setattachment(e, to, tag);
2745     setorigin(e, e.origin);
2746 }
2747
2748 void detach_sameorigin(entity e)
2749 {
2750     vector org;
2751     org = gettaginfo(e, 0);
2752     e.angles = fixedvectoangles2(v_forward, v_up);
2753     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2754                 e.angles = AnglesTransform_ToVAngles(e.angles);
2755         else
2756                 e.angles = AnglesTransform_ToAngles(e.angles);
2757     setorigin(e, org);
2758     setattachment(e, world, "");
2759     setorigin(e, e.origin);
2760 }
2761
2762 void follow_sameorigin(entity e, entity to)
2763 {
2764     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2765     e.aiment = to; // make the hole follow bmodel
2766     e.punchangle = to.angles; // the original angles of bmodel
2767     e.view_ofs = e.origin - to.origin; // relative origin
2768     e.v_angle = e.angles - to.angles; // relative angles
2769 }
2770
2771 void unfollow_sameorigin(entity e)
2772 {
2773     e.movetype = MOVETYPE_NONE;
2774 }
2775
2776 entity gettaginfo_relative_ent;
2777 vector gettaginfo_relative(entity e, float tag)
2778 {
2779     if (!gettaginfo_relative_ent)
2780     {
2781         gettaginfo_relative_ent = spawn();
2782         gettaginfo_relative_ent.effects = EF_NODRAW;
2783     }
2784     gettaginfo_relative_ent.model = e.model;
2785     gettaginfo_relative_ent.modelindex = e.modelindex;
2786     gettaginfo_relative_ent.frame = e.frame;
2787     return gettaginfo(gettaginfo_relative_ent, tag);
2788 }
2789
2790 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2791 {
2792     float p;
2793     p = pow(2, chan);
2794     if (pl.soundentity.cnt & p)
2795         return;
2796     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2797     pl.soundentity.cnt |= p;
2798 }
2799
2800 void SoundEntity_StopSound(entity pl, float chan)
2801 {
2802     float p;
2803     p = pow(2, chan);
2804     if (pl.soundentity.cnt & p)
2805     {
2806         stopsoundto(MSG_ALL, pl.soundentity, chan);
2807         pl.soundentity.cnt &~= p;
2808     }
2809 }
2810
2811 void SoundEntity_Attach(entity pl)
2812 {
2813     pl.soundentity = spawn();
2814     pl.soundentity.classname = "soundentity";
2815     pl.soundentity.owner = pl;
2816     setattachment(pl.soundentity, pl, "");
2817     setmodel(pl.soundentity, "null");
2818 }
2819
2820 void SoundEntity_Detach(entity pl)
2821 {
2822     float i;
2823     for (i = 0; i <= 7; ++i)
2824         SoundEntity_StopSound(pl, i);
2825 }
2826
2827
2828 float ParseCommandPlayerSlotTarget_firsttoken;
2829 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2830 {
2831         string s;
2832         entity e, head;
2833         float n;
2834
2835         s = string_null;
2836
2837         ParseCommandPlayerSlotTarget_firsttoken = -1;
2838
2839         if (tokens > idx)
2840         {
2841                 if (substring(argv(idx), 0, 1) == "#")
2842                 {
2843                         s = substring(argv(idx), 1, -1);
2844                         ++idx;
2845                         if (s == "") if (tokens > idx)
2846                         {
2847                                 s = argv(idx);
2848                                 ++idx;
2849                         }
2850                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2851                         n = stof(s);
2852                         if (s == ftos(n) && n > 0 && n <= maxclients)
2853                         {
2854                                 e = edict_num(n);
2855                                 if (e.flags & FL_CLIENT)
2856                                         return e;
2857                         }
2858                 }
2859                 else
2860                 {
2861                         // it must be a nick name
2862                         s = argv(idx);
2863                         ++idx;
2864                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2865
2866                         n = 0;
2867                         FOR_EACH_CLIENT(head)
2868                                 if (head.netname == s)
2869                                 {
2870                                         e = head;
2871                                         ++n;
2872                                 }
2873                         if (n == 1)
2874                                 return e;
2875
2876                         s = strdecolorize(s);
2877                         n = 0;
2878                         FOR_EACH_CLIENT(head)
2879                                 if (strdecolorize(head.netname) == s)
2880                                 {
2881                                         e = head;
2882                                         ++n;
2883                                 }
2884                         if (n == 1)
2885                                 return e;
2886                 }
2887         }
2888
2889         return world;
2890 }
2891
2892 .float scale2;
2893
2894 float modeleffect_SendEntity(entity to, float sf)
2895 {
2896         float f;
2897         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2898
2899         f = 0;
2900         if(self.velocity != '0 0 0')
2901                 f |= 1;
2902         if(self.angles != '0 0 0')
2903                 f |= 2;
2904         if(self.avelocity != '0 0 0')
2905                 f |= 4;
2906
2907         WriteByte(MSG_ENTITY, f);
2908         WriteShort(MSG_ENTITY, self.modelindex);
2909         WriteByte(MSG_ENTITY, self.skin);
2910         WriteByte(MSG_ENTITY, self.frame);
2911         WriteCoord(MSG_ENTITY, self.origin_x);
2912         WriteCoord(MSG_ENTITY, self.origin_y);
2913         WriteCoord(MSG_ENTITY, self.origin_z);
2914         if(f & 1)
2915         {
2916                 WriteCoord(MSG_ENTITY, self.velocity_x);
2917                 WriteCoord(MSG_ENTITY, self.velocity_y);
2918                 WriteCoord(MSG_ENTITY, self.velocity_z);
2919         }
2920         if(f & 2)
2921         {
2922                 WriteCoord(MSG_ENTITY, self.angles_x);
2923                 WriteCoord(MSG_ENTITY, self.angles_y);
2924                 WriteCoord(MSG_ENTITY, self.angles_z);
2925         }
2926         if(f & 4)
2927         {
2928                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2929                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2930                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2931         }
2932         WriteShort(MSG_ENTITY, self.scale * 256.0);
2933         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2934         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2935         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2936         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2937
2938         return TRUE;
2939 }
2940
2941 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2942 {
2943         entity e;
2944         float sz;
2945         e = spawn();
2946         e.classname = "modeleffect";
2947         setmodel(e, m);
2948         e.frame = f;
2949         setorigin(e, o);
2950         e.velocity = v;
2951         e.angles = ang;
2952         e.avelocity = angv;
2953         e.alpha = a;
2954         e.teleport_time = t1;
2955         e.fade_time = t2;
2956         e.skin = s;
2957         if(s0 >= 0)
2958                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2959         else
2960                 e.scale = -s0;
2961         if(s2 >= 0)
2962                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2963         else
2964                 e.scale2 = -s2;
2965         sz = max(e.scale, e.scale2);
2966         setsize(e, e.mins * sz, e.maxs * sz);
2967         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2968 }
2969
2970 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2971 {
2972         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2973 }
2974
2975 float randombit(float bits)
2976 {
2977         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2978                 return bits;
2979
2980         float n, f, b, r;
2981
2982         r = random();
2983         b = 0;
2984         n = 0;
2985
2986         for(f = 1; f <= bits; f *= 2)
2987         {
2988                 if(bits & f)
2989                 {
2990                         ++n;
2991                         r *= n;
2992                         if(r <= 1)
2993                                 b = f;
2994                         else
2995                                 r = (r - 1) / (n - 1);
2996                 }
2997         }
2998
2999         return b;
3000 }
3001
3002 float randombits(float bits, float k, float error_return)
3003 {
3004         float r;
3005         r = 0;
3006         while(k > 0 && bits != r)
3007         {
3008                 r += randombit(bits - r);
3009                 --k;
3010         }
3011         if(error_return)
3012                 if(k > 0)
3013                         return -1; // all
3014         return r;
3015 }
3016
3017 void randombit_test(float bits, float iter)
3018 {
3019         while(iter > 0)
3020         {
3021                 print(ftos(randombit(bits)), "\n");
3022                 --iter;
3023         }
3024 }
3025
3026 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3027 {
3028         if(halflifedist > 0)
3029                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3030         else if(halflifedist < 0)
3031                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3032         else
3033                 return 1;
3034 }
3035
3036
3037
3038
3039 #ifdef RELEASE
3040 #define cvar_string_normal builtin_cvar_string
3041 #define cvar_normal builtin_cvar
3042 #else
3043 string cvar_string_normal(string n)
3044 {
3045         if not(cvar_type(n) & 1)
3046                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3047         return builtin_cvar_string(n);
3048 }
3049
3050 float cvar_normal(string n)
3051 {
3052         return stof(cvar_string_normal(n));
3053 }
3054 #endif
3055 #define cvar_set_normal builtin_cvar_set
3056
3057 void defer_think()
3058 {
3059     entity oself;
3060
3061     oself           = self;
3062     self            = self.owner;
3063     oself.think     = SUB_Remove;
3064     oself.nextthink = time;
3065
3066     oself.use();
3067 }
3068
3069 /*
3070     Execute func() after time + fdelay.
3071     self when func is executed = self when defer is called
3072 */
3073 void defer(float fdelay, void() func)
3074 {
3075     entity e;
3076
3077     e           = spawn();
3078     e.owner     = self;
3079     e.use       = func;
3080     e.think     = defer_think;
3081     e.nextthink = time + fdelay;
3082 }
3083
3084 .string aiment_classname;
3085 .float aiment_deadflag;
3086 void SetMovetypeFollow(entity ent, entity e)
3087 {
3088         // FIXME this may not be warpzone aware
3089         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3090         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3091         ent.aiment = e; // make the hole follow bmodel
3092         ent.punchangle = e.angles; // the original angles of bmodel
3093         ent.view_ofs = ent.origin - e.origin; // relative origin
3094         ent.v_angle = ent.angles - e.angles; // relative angles
3095         ent.aiment_classname = strzone(e.classname);
3096         ent.aiment_deadflag = e.deadflag;
3097 }
3098 void UnsetMovetypeFollow(entity ent)
3099 {
3100         ent.movetype = MOVETYPE_FLY;
3101         PROJECTILE_MAKETRIGGER(ent);
3102         ent.aiment = world;
3103 }
3104 float LostMovetypeFollow(entity ent)
3105 {
3106 /*
3107         if(ent.movetype != MOVETYPE_FOLLOW)
3108                 if(ent.aiment)
3109                         error("???");
3110 */
3111         if(ent.aiment)
3112         {
3113                 if(ent.aiment.classname != ent.aiment_classname)
3114                         return 1;
3115                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3116                         return 1;
3117         }
3118         return 0;
3119 }
3120
3121 float isPushable(entity e)
3122 {
3123         if(e.iscreature)
3124                 return TRUE;
3125         switch(e.classname)
3126         {
3127                 case "body":
3128                 case "droppedweapon":
3129                 case "keepawayball":
3130                 case "nexball_basketball":
3131                 case "nexball_football":
3132                         return TRUE;
3133                 case "bullet": // antilagged bullets can't hit this either
3134                         return FALSE;
3135         }
3136         if (e.projectiledeathtype)
3137                 return TRUE;
3138         return FALSE;
3139 }