qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  12 void WarpZone_crosshair_trace(entity pl)
  13 {
  14         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  15 }
  16
  17 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  18 void() spawnpoint_use;
  19 string GetMapname();
  20 string ColoredTeamName(float t);
  21
  22 string admin_name(void)
  23 {
  24         if(autocvar_sv_adminnick != "")
  25                 return autocvar_sv_adminnick;
  26         else
  27                 return "SERVER ADMIN";
  28 }
  29
  30 float DistributeEvenly_amount;
  31 float DistributeEvenly_totalweight;
  32 void DistributeEvenly_Init(float amount, float totalweight)
  33 {
  34     if (DistributeEvenly_amount)
  35     {
  36         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  37         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  38     }
  39     if (totalweight == 0)
  40         DistributeEvenly_amount = 0;
  41     else
  42         DistributeEvenly_amount = amount;
  43     DistributeEvenly_totalweight = totalweight;
  44 }
  45 float DistributeEvenly_Get(float weight)
  46 {
  47     float f;
  48     if (weight <= 0)
  49         return 0;
  50     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  51     DistributeEvenly_totalweight -= weight;
  52     DistributeEvenly_amount -= f;
  53     return f;
  54 }
  55
  56 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  57
  58
  59 string STR_PLAYER = "player";
  60 string STR_SPECTATOR = "spectator";
  61 string STR_OBSERVER = "observer";
  62
  63 #if 0
  64 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  65 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  66 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  67 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  68 #else
  69 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  70 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  71 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  72 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  73 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  74 #endif
  75
  76 // copies a string to a tempstring (so one can strunzone it)
  77 string strcat1(string s) = #115; // FRIK_FILE
  78
  79 float logfile_open;
  80 float logfile;
  81
  82 void bcenterprint(string s)
  83 {
  84     // TODO replace by MSG_ALL (would show it to spectators too, though)?
  85     entity head;
  86     FOR_EACH_PLAYER(head)
  87     if (clienttype(head) == CLIENTTYPE_REAL)
  88         centerprint(head, s);
  89 }
  90
  91 void GameLogEcho(string s)
  92 {
  93     string fn;
  94     float matches;
  95
  96     if (autocvar_sv_eventlog_files)
  97     {
  98         if (!logfile_open)
  99         {
 100             logfile_open = TRUE;
 101             matches = autocvar_sv_eventlog_files_counter + 1;
 102             cvar_set("sv_eventlog_files_counter", ftos(matches));
 103             fn = ftos(matches);
 104             if (strlen(fn) < 8)
 105                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 106             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 107             logfile = fopen(fn, FILE_APPEND);
 108             fputs(logfile, ":logversion:3\n");
 109         }
 110         if (logfile >= 0)
 111         {
 112             if (autocvar_sv_eventlog_files_timestamps)
 113                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 114             else
 115                 fputs(logfile, strcat(s, "\n"));
 116         }
 117     }
 118     if (autocvar_sv_eventlog_console)
 119     {
 120         print(s, "\n");
 121     }
 122 }
 123
 124 void GameLogInit()
 125 {
 126     logfile_open = 0;
 127     // will be opened later
 128 }
 129
 130 void GameLogClose()
 131 {
 132     if (logfile_open && logfile >= 0)
 133     {
 134         fclose(logfile);
 135         logfile = -1;
 136     }
 137 }
 138
 139 vector PL_VIEW_OFS;
 140 vector PL_MIN;
 141 vector PL_MAX;
 142 vector PL_HEAD;
 143 vector PL_CROUCH_VIEW_OFS;
 144 vector PL_CROUCH_MIN;
 145 vector PL_CROUCH_MAX;
 146
 147 float spawnpoint_nag;
 148 void relocate_spawnpoint()
 149 {
 150     PL_VIEW_OFS                             = stov(autocvar_sv_player_viewoffset);
 151     PL_MIN                                  = stov(autocvar_sv_player_mins);
 152     PL_MAX                                  = stov(autocvar_sv_player_maxs);
 153     PL_HEAD                                 = stov(autocvar_sv_player_headsize);
 154     PL_CROUCH_VIEW_OFS                      = stov(autocvar_sv_player_crouch_viewoffset);
 155     PL_CROUCH_MIN                           = stov(autocvar_sv_player_crouch_mins);
 156     PL_CROUCH_MAX                           = stov(autocvar_sv_player_crouch_maxs);
 157
 158     // nudge off the floor
 159     setorigin(self, self.origin + '0 0 1');
 160
 161     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 162     if (trace_startsolid)
 163     {
 164         vector o;
 165         o = self.origin;
 166         self.mins = PL_MIN;
 167         self.maxs = PL_MAX;
 168         if (!move_out_of_solid(self))
 169             objerror("could not get out of solid at all!");
 170         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 171         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 172         print(" ", ftos(self.origin_y - o_y));
 173         print(" ", ftos(self.origin_z - o_z), "'\n");
 174         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 175         {
 176             if (!spawnpoint_nag)
 177                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 178             spawnpoint_nag = 1;
 179         }
 180         else
 181         {
 182             setorigin(self, o);
 183             self.mins = self.maxs = '0 0 0';
 184             objerror("player spawn point in solid, mapper sucks!\n");
 185             return;
 186         }
 187     }
 188
 189     self.use = spawnpoint_use;
 190     self.team_saved = self.team;
 191     if (!self.cnt)
 192         self.cnt = 1;
 193
 194     if (have_team_spawns != 0)
 195         if (self.team)
 196             have_team_spawns = 1;
 197     have_team_spawns_forteam[self.team] = 1;
 198
 199     if (autocvar_r_showbboxes)
 200     {
 201         // show where spawnpoints point at too
 202         makevectors(self.angles);
 203         entity e;
 204         e = spawn();
 205         e.classname = "info_player_foo";
 206         setorigin(e, self.origin + v_forward * 24);
 207         setsize(e, '-8 -8 -8', '8 8 8');
 208         e.solid = SOLID_TRIGGER;
 209     }
 210 }
 211
 212 #define strstr strstrofs
 213 /*
 214 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 215 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 216 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 217 // BE CONSTANT OR strzoneD!
 218 float strstr(string haystack, string needle, float offset)
 219 {
 220         float len, endpos;
 221         string found;
 222         len = strlen(needle);
 223         endpos = strlen(haystack) - len;
 224         while(offset <= endpos)
 225         {
 226                 found = substring(haystack, offset, len);
 227                 if(found == needle)
 228                         return offset;
 229                 offset = offset + 1;
 230         }
 231         return -1;
 232 }
 233 */
 234
 235 float NUM_NEAREST_ENTITIES = 4;
 236 entity nearest_entity[NUM_NEAREST_ENTITIES];
 237 float nearest_length[NUM_NEAREST_ENTITIES];
 238 entity findnearest(vector point, .string field, string value, vector axismod)
 239 {
 240     entity localhead;
 241     float i;
 242     float j;
 243     float len;
 244     vector dist;
 245
 246     float num_nearest;
 247     num_nearest = 0;
 248
 249     localhead = find(world, field, value);
 250     while (localhead)
 251     {
 252         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 253             dist = localhead.oldorigin;
 254         else
 255             dist = localhead.origin;
 256         dist = dist - point;
 257         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 258         len = vlen(dist);
 259
 260         for (i = 0; i < num_nearest; ++i)
 261         {
 262             if (len < nearest_length[i])
 263                 break;
 264         }
 265
 266         // now i tells us where to insert at
 267         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 268         if (i < NUM_NEAREST_ENTITIES)
 269         {
 270             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 271             {
 272                 nearest_length[j + 1] = nearest_length[j];
 273                 nearest_entity[j + 1] = nearest_entity[j];
 274             }
 275             nearest_length[i] = len;
 276             nearest_entity[i] = localhead;
 277             if (num_nearest < NUM_NEAREST_ENTITIES)
 278                 num_nearest = num_nearest + 1;
 279         }
 280
 281         localhead = find(localhead, field, value);
 282     }
 283
 284     // now use the first one from our list that we can see
 285     for (i = 0; i < num_nearest; ++i)
 286     {
 287         traceline(point, nearest_entity[i].origin, TRUE, world);
 288         if (trace_fraction == 1)
 289         {
 290             if (i != 0)
 291             {
 292                 dprint("Nearest point (");
 293                 dprint(nearest_entity[0].netname);
 294                 dprint(") is not visible, using a visible one.\n");
 295             }
 296             return nearest_entity[i];
 297         }
 298     }
 299
 300     if (num_nearest == 0)
 301         return world;
 302
 303     dprint("Not seeing any location point, using nearest as fallback.\n");
 304     /* DEBUGGING CODE:
 305     dprint("Candidates were: ");
 306     for(j = 0; j < num_nearest; ++j)
 307     {
 308         if(j != 0)
 309                 dprint(", ");
 310         dprint(nearest_entity[j].netname);
 311     }
 312     dprint("\n");
 313     */
 314
 315     return nearest_entity[0];
 316 }
 317
 318 void spawnfunc_target_location()
 319 {
 320     self.classname = "target_location";
 321     // location name in netname
 322     // eventually support: count, teamgame selectors, line of sight?
 323 }
 324
 325 void spawnfunc_info_location()
 326 {
 327     self.classname = "target_location";
 328     self.message = self.netname;
 329 }
 330
 331 string NearestLocation(vector p)
 332 {
 333     entity loc;
 334     string ret;
 335     ret = "somewhere";
 336     loc = findnearest(p, classname, "target_location", '1 1 1');
 337     if (loc)
 338     {
 339         ret = loc.message;
 340     }
 341     else
 342     {
 343         loc = findnearest(p, target, "###item###", '1 1 4');
 344         if (loc)
 345             ret = loc.netname;
 346     }
 347     return ret;
 348 }
 349
 350 string formatmessage(string msg)
 351 {
 352         float p, p1, p2;
 353         float n;
 354         vector cursor;
 355         entity cursor_ent;
 356         string escape;
 357         string replacement;
 358         p = 0;
 359         n = 7;
 360
 361         WarpZone_crosshair_trace(self);
 362         cursor = trace_endpos;
 363         cursor_ent = trace_ent;
 364
 365         while (1) {
 366                 if (n < 1)
 367                         break; // too many replacements
 368
 369                 n = n - 1;
 370                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 371                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 372
 373                 if (p1 < 0)
 374                         p1 = p2;
 375
 376                 if (p2 < 0)
 377                         p2 = p1;
 378
 379                 p = min(p1, p2);
 380
 381                 if (p < 0)
 382                         break;
 383
 384                 replacement = substring(msg, p, 2);
 385                 escape = substring(msg, p + 1, 1);
 386
 387                 if (escape == "%")
 388                         replacement = "%";
 389                 else if (escape == "\\")
 390                         replacement = "\\";
 391                 else if (escape == "n")
 392                         replacement = "\n";
 393                 else if (escape == "a")
 394                         replacement = ftos(floor(self.armorvalue));
 395                 else if (escape == "h")
 396                         replacement = ftos(floor(self.health));
 397                 else if (escape == "l")
 398                         replacement = NearestLocation(self.origin);
 399                 else if (escape == "y")
 400                         replacement = NearestLocation(cursor);
 401                 else if (escape == "d")
 402                         replacement = NearestLocation(self.death_origin);
 403                 else if (escape == "w") {
 404                         float wep;
 405                         wep = self.weapon;
 406                         if (!wep)
 407                                 wep = self.switchweapon;
 408                         if (!wep)
 409                                 wep = self.cnt;
 410                         replacement = W_Name(wep);
 411                 } else if (escape == "W") {
 412                         if (self.items & IT_SHELLS) replacement = "shells";
 413                         else if (self.items & IT_NAILS) replacement = "bullets";
 414                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 415                         else if (self.items & IT_CELLS) replacement = "cells";
 416                         else replacement = "batteries"; // ;)
 417                 } else if (escape == "x") {
 418                         replacement = cursor_ent.netname;
 419                         if (!replacement || !cursor_ent)
 420                                 replacement = "nothing";
 421                 } else if (escape == "s")
 422                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 423                 else if (escape == "S")
 424                         replacement = ftos(vlen(self.velocity));
 425
 426                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 427                 p = p + strlen(replacement);
 428         }
 429         return msg;
 430 }
 431
 432 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 433         return (value == 0) ? FALSE : TRUE;
 434 }
 435
 436 /*
 437 =============
 438 GetCvars
 439 =============
 440 Called with:
 441   0:  sends the request
 442   >0: receives a cvar from name=argv(f) value=argv(f+1)
 443 */
 444 void GetCvars_handleString(string thisname, float f, .string field, string name)
 445 {
 446         if (f < 0)
 447         {
 448                 if (self.field)
 449                         strunzone(self.field);
 450                 self.field = string_null;
 451         }
 452         else if (f > 0)
 453         {
 454                 if (thisname == name)
 455                 {
 456                         if (self.field)
 457                                 strunzone(self.field);
 458                         self.field = strzone(argv(f + 1));
 459                 }
 460         }
 461         else
 462                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 463 }
 464 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 465 {
 466         GetCvars_handleString(thisname, f, field, name);
 467         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 468                 if (thisname == name)
 469                 {
 470                         string s;
 471                         s = func(strcat1(self.field));
 472                         if (s != self.field)
 473                         {
 474                                 strunzone(self.field);
 475                                 self.field = strzone(s);
 476                         }
 477                 }
 478 }
 479 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 480 {
 481         if (f < 0)
 482         {
 483         }
 484         else if (f > 0)
 485         {
 486                 if (thisname == name)
 487                         self.field = stof(argv(f + 1));
 488         }
 489         else
 490                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 491 }
 492 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 493 {
 494         if (f < 0)
 495         {
 496         }
 497         else if (f > 0)
 498         {
 499                 if (thisname == name)
 500                 {
 501                         if(!self.field)
 502                         {
 503                                 self.field = stof(argv(f + 1));
 504                                 if(!self.field)
 505                                         self.field = -1;
 506                         }
 507                 }
 508         }
 509         else
 510         {
 511                 if(!self.field)
 512                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 513         }
 514 }
 515 float w_getbestweapon(entity e);
 516 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 517 {
 518         string o;
 519         o = W_FixWeaponOrder_ForceComplete(wo);
 520         if(self.weaponorder_byimpulse)
 521         {
 522                 strunzone(self.weaponorder_byimpulse);
 523                 self.weaponorder_byimpulse = string_null;
 524         }
 525         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 526         return o;
 527 }
 528 void GetCvars(float f)
 529 {
 530         string s;
 531
 532         if (f > 0)
 533                 s = strcat1(argv(f));
 534
 535         get_cvars_f = f;
 536         get_cvars_s = s;
 537         MUTATOR_CALLHOOK(GetCvars);
 538         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 539         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 540         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 541         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 542         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 543         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 556         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 557         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 558         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 559         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 560         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 561         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 562
 563         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 564         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 565
 566 #ifdef ALLOW_FORCEMODELS
 567         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 568         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 569 #endif
 570         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 571         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 572         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 573         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 574         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 575
 576         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 577         if (f > 0)
 578         {
 579                 if (s == "cl_weaponpriority")
 580                         self.switchweapon = w_getbestweapon(self);
 581                 if (s == "cl_allow_uidtracking")
 582                         PlayerStats_AddPlayer(self);
 583         }
 584 }
 585
 586 void backtrace(string msg)
 587 {
 588     float dev, war;
 589     dev = autocvar_developer;
 590     war = autocvar_prvm_backtraceforwarnings;
 591     cvar_set("developer", "1");
 592     cvar_set("prvm_backtraceforwarnings", "1");
 593     print("\n");
 594     print("--- CUT HERE ---\nWARNING: ");
 595     print(msg);
 596     print("\n");
 597     remove(world); // isn't there any better way to cause a backtrace?
 598     print("\n--- CUT UNTIL HERE ---\n");
 599     cvar_set("developer", ftos(dev));
 600     cvar_set("prvm_backtraceforwarnings", ftos(war));
 601 }
 602
 603 string Team_ColorCode(float teamid)
 604 {
 605     if (teamid == COLOR_TEAM1)
 606         return "^1";
 607     else if (teamid == COLOR_TEAM2)
 608         return "^4";
 609     else if (teamid == COLOR_TEAM3)
 610         return "^3";
 611     else if (teamid == COLOR_TEAM4)
 612         return "^6";
 613     else
 614         return "^7";
 615 }
 616
 617 string Team_ColorName(float t)
 618 {
 619     // fixme: Search for team entities and get their .netname's!
 620     if (t == COLOR_TEAM1)
 621         return "Red";
 622     if (t == COLOR_TEAM2)
 623         return "Blue";
 624     if (t == COLOR_TEAM3)
 625         return "Yellow";
 626     if (t == COLOR_TEAM4)
 627         return "Pink";
 628     return "Neutral";
 629 }
 630
 631 string Team_ColorNameLowerCase(float t)
 632 {
 633     // fixme: Search for team entities and get their .netname's!
 634     if (t == COLOR_TEAM1)
 635         return "red";
 636     if (t == COLOR_TEAM2)
 637         return "blue";
 638     if (t == COLOR_TEAM3)
 639         return "yellow";
 640     if (t == COLOR_TEAM4)
 641         return "pink";
 642     return "neutral";
 643 }
 644
 645 float ColourToNumber(string team_colour)
 646 {
 647         if (team_colour == "red")
 648                 return COLOR_TEAM1;
 649
 650         if (team_colour == "blue")
 651                 return COLOR_TEAM2;
 652
 653         if (team_colour == "yellow")
 654                 return COLOR_TEAM3;
 655
 656         if (team_colour == "pink")
 657                 return COLOR_TEAM4;
 658
 659         if (team_colour == "auto")
 660                 return 0;
 661
 662         return -1;
 663 }
 664
 665 float NumberToTeamNumber(float number)
 666 {
 667         if (number == 1)
 668                 return COLOR_TEAM1;
 669
 670         if (number == 2)
 671                 return COLOR_TEAM2;
 672
 673         if (number == 3)
 674                 return COLOR_TEAM3;
 675
 676         if (number == 4)
 677                 return COLOR_TEAM4;
 678
 679         return -1;
 680 }
 681
 682 // decolorizes and team colors the player name when needed
 683 string playername(entity p)
 684 {
 685     string t;
 686     if (teamplay && !intermission_running && p.classname == "player")
 687     {
 688         t = Team_ColorCode(p.team);
 689         return strcat(t, strdecolorize(p.netname));
 690     }
 691     else
 692         return p.netname;
 693 }
 694
 695 vector randompos(vector m1, vector m2)
 696 {
 697     vector v;
 698     m2 = m2 - m1;
 699     v_x = m2_x * random() + m1_x;
 700     v_y = m2_y * random() + m1_y;
 701     v_z = m2_z * random() + m1_z;
 702     return  v;
 703 }
 704
 705 //#NO AUTOCVARS START
 706
 707 float g_pickup_shells;
 708 float g_pickup_shells_max;
 709 float g_pickup_nails;
 710 float g_pickup_nails_max;
 711 float g_pickup_rockets;
 712 float g_pickup_rockets_max;
 713 float g_pickup_cells;
 714 float g_pickup_cells_max;
 715 float g_pickup_fuel;
 716 float g_pickup_fuel_jetpack;
 717 float g_pickup_fuel_max;
 718 float g_pickup_armorsmall;
 719 float g_pickup_armorsmall_max;
 720 float g_pickup_armorsmall_anyway;
 721 float g_pickup_armormedium;
 722 float g_pickup_armormedium_max;
 723 float g_pickup_armormedium_anyway;
 724 float g_pickup_armorbig;
 725 float g_pickup_armorbig_max;
 726 float g_pickup_armorbig_anyway;
 727 float g_pickup_armorlarge;
 728 float g_pickup_armorlarge_max;
 729 float g_pickup_armorlarge_anyway;
 730 float g_pickup_healthsmall;
 731 float g_pickup_healthsmall_max;
 732 float g_pickup_healthsmall_anyway;
 733 float g_pickup_healthmedium;
 734 float g_pickup_healthmedium_max;
 735 float g_pickup_healthmedium_anyway;
 736 float g_pickup_healthlarge;
 737 float g_pickup_healthlarge_max;
 738 float g_pickup_healthlarge_anyway;
 739 float g_pickup_healthmega;
 740 float g_pickup_healthmega_max;
 741 float g_pickup_healthmega_anyway;
 742 float g_pickup_ammo_anyway;
 743 float g_pickup_weapons_anyway;
 744 float g_weaponarena;
 745 float g_weaponarena_random;
 746 float g_weaponarena_random_with_laser;
 747 string g_weaponarena_list;
 748 float g_weaponspeedfactor;
 749 float g_weaponratefactor;
 750 float g_weapondamagefactor;
 751 float g_weaponforcefactor;
 752 float g_weaponspreadfactor;
 753
 754 float start_weapons;
 755 float start_items;
 756 float start_ammo_shells;
 757 float start_ammo_nails;
 758 float start_ammo_rockets;
 759 float start_ammo_cells;
 760 float start_ammo_fuel;
 761 float start_health;
 762 float start_armorvalue;
 763 float warmup_start_weapons;
 764 float warmup_start_ammo_shells;
 765 float warmup_start_ammo_nails;
 766 float warmup_start_ammo_rockets;
 767 float warmup_start_ammo_cells;
 768 float warmup_start_ammo_fuel;
 769 float warmup_start_health;
 770 float warmup_start_armorvalue;
 771 float g_weapon_stay;
 772 float g_ghost_items;
 773
 774 entity get_weaponinfo(float w);
 775
 776 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 777 {
 778         var float i = weaponinfo.weapon;
 779
 780         if (!i)
 781                 return 0;
 782
 783         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 784
 785         if (t < 0) // "default" weapon selection
 786         {
 787                 if (g_lms || g_ca || allguns)
 788                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 789                 else if(t < -1)
 790                         t = 0;
 791                 else if (g_cts)
 792                         t = (i == WEP_SHOTGUN);
 793                 else if (g_nexball)
 794                         t = 0; // weapon is set a few lines later
 795                 else
 796                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 797                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 798                         t |= (i == WEP_HOOK);
 799         }
 800
 801         // we cannot disable porto in Nexball, we must force it
 802         if(g_nexball && i == WEP_PORTO)
 803                 t = 1;
 804
 805         return t;
 806 }
 807
 808 void readplayerstartcvars()
 809 {
 810         entity e;
 811         float i, j, t;
 812         string s;
 813
 814         // initialize starting values for players
 815         start_weapons = 0;
 816         start_items = 0;
 817         start_ammo_shells = 0;
 818         start_ammo_nails = 0;
 819         start_ammo_rockets = 0;
 820         start_ammo_cells = 0;
 821         start_health = cvar("g_balance_health_start");
 822         start_armorvalue = cvar("g_balance_armor_start");
 823
 824         g_weaponarena = 0;
 825         s = cvar_string("g_weaponarena");
 826         if (s == "0" || s == "")
 827         {
 828                 if(g_lms || g_ca)
 829                         s = "most";
 830         }
 831
 832         if (s == "0" || s == "")
 833         {
 834                 // no arena
 835         }
 836         else if (s == "off")
 837         {
 838                 // forcibly turn off weaponarena
 839         }
 840         else if (s == "all")
 841         {
 842                 g_weaponarena_list = "All Weapons";
 843                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 844                 {
 845                         e = get_weaponinfo(j);
 846                         g_weaponarena |= e.weapons;
 847                         weapon_action(e.weapon, WR_PRECACHE);
 848                 }
 849         }
 850         else if (s == "most")
 851         {
 852                 g_weaponarena_list = "Most Weapons";
 853                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 854                 {
 855                         e = get_weaponinfo(j);
 856                         if (e.spawnflags & WEP_FLAG_NORMAL)
 857                         {
 858                                 g_weaponarena |= e.weapons;
 859                                 weapon_action(e.weapon, WR_PRECACHE);
 860                         }
 861                 }
 862         }
 863         else if (s == "none")
 864         {
 865                 g_weaponarena_list = "No Weapons";
 866                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 867         }
 868         else
 869         {
 870                 t = tokenize_console(s);
 871                 g_weaponarena_list = "";
 872                 for (i = 0; i < t; ++i)
 873                 {
 874                         s = argv(i);
 875                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 876                         {
 877                                 e = get_weaponinfo(j);
 878                                 if (e.netname == s)
 879                                 {
 880                                         g_weaponarena |= e.weapons;
 881                                         weapon_action(e.weapon, WR_PRECACHE);
 882                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 883                                         break;
 884                                 }
 885                         }
 886                         if (j > WEP_LAST)
 887                         {
 888                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 889                         }
 890                 }
 891                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 892         }
 893
 894         if(g_weaponarena)
 895                 g_weaponarena_random = cvar("g_weaponarena_random");
 896         else
 897                 g_weaponarena_random = 0;
 898         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 899
 900         if (g_weaponarena)
 901         {
 902                 start_weapons = g_weaponarena;
 903                 if(!(g_lms || g_ca))
 904                         start_items |= IT_UNLIMITED_AMMO;
 905         }
 906         else if (g_minstagib)
 907         {
 908                 start_health = 100;
 909                 start_armorvalue = 0;
 910                 start_weapons = WEPBIT_MINSTANEX;
 911                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 912                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 913
 914                 if (g_minstagib_invis_alpha <= 0)
 915                         g_minstagib_invis_alpha = -1;
 916         }
 917         else
 918         {
 919                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 920                 {
 921                         e = get_weaponinfo(i);
 922                         if(want_weapon("g_start_weapon_", e, FALSE))
 923                                 start_weapons |= e.weapons;
 924                 }
 925         }
 926
 927         if(!cvar("g_use_ammunition"))
 928                 start_items |= IT_UNLIMITED_AMMO;
 929
 930         if(g_minstagib)
 931         {
 932                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 933                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 934         }
 935         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 936         {
 937                 start_ammo_rockets = 999;
 938                 start_ammo_shells = 999;
 939                 start_ammo_cells = 999;
 940                 start_ammo_nails = 999;
 941                 start_ammo_fuel = 999;
 942         }
 943         else
 944         {
 945                 if(g_lms || g_ca)
 946                 {
 947                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 948                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 949                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 950                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 951                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 952                 }
 953                 else
 954                 {
 955                         start_ammo_shells = cvar("g_start_ammo_shells");
 956                         start_ammo_nails = cvar("g_start_ammo_nails");
 957                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 958                         start_ammo_cells = cvar("g_start_ammo_cells");
 959                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 960                 }
 961         }
 962
 963         if (g_lms || g_ca)
 964         {
 965                 start_health = cvar("g_lms_start_health");
 966                 start_armorvalue = cvar("g_lms_start_armor");
 967         }
 968
 969         if (inWarmupStage)
 970         {
 971                 warmup_start_ammo_shells = start_ammo_shells;
 972                 warmup_start_ammo_nails = start_ammo_nails;
 973                 warmup_start_ammo_rockets = start_ammo_rockets;
 974                 warmup_start_ammo_cells = start_ammo_cells;
 975                 warmup_start_ammo_fuel = start_ammo_fuel;
 976                 warmup_start_health = start_health;
 977                 warmup_start_armorvalue = start_armorvalue;
 978                 warmup_start_weapons = start_weapons;
 979
 980                 if (!g_weaponarena && !g_minstagib && !g_ca)
 981                 {
 982                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 983                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 984                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 985                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 986                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 987                         warmup_start_health = cvar("g_warmup_start_health");
 988                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 989                         warmup_start_weapons = 0;
 990                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 991                         {
 992                                 e = get_weaponinfo(i);
 993                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
 994                                         warmup_start_weapons |= e.weapons;
 995                         }
 996                 }
 997         }
 998
 999         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
1000         {
1001                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
1002                 start_items |= IT_FUEL_REGEN;
1003                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1004                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1005         }
1006
1007         if (g_jetpack)
1008                 start_items |= IT_JETPACK;
1009
1010         if (g_weapon_stay == 2)
1011         {
1012                 if (!start_ammo_shells) start_ammo_shells = g_pickup_shells;
1013                 if (!start_ammo_nails) start_ammo_nails = g_pickup_nails;
1014                 if (!start_ammo_cells) start_ammo_cells = g_pickup_cells;
1015                 if (!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
1016                 if (!start_ammo_fuel) start_ammo_fuel = g_pickup_fuel;
1017                 if (!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
1018                 if (!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
1019                 if (!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
1020                 if (!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
1021                 if (!warmup_start_ammo_fuel) warmup_start_ammo_fuel = g_pickup_fuel;
1022         }
1023
1024         MUTATOR_CALLHOOK(SetStartItems);
1025
1026         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1027         {
1028                 e = get_weaponinfo(i);
1029                 if(e.weapons & (start_weapons | warmup_start_weapons))
1030                         weapon_action(e.weapon, WR_PRECACHE);
1031         }
1032
1033         start_ammo_shells = max(0, start_ammo_shells);
1034         start_ammo_nails = max(0, start_ammo_nails);
1035         start_ammo_cells = max(0, start_ammo_cells);
1036         start_ammo_rockets = max(0, start_ammo_rockets);
1037         start_ammo_fuel = max(0, start_ammo_fuel);
1038
1039         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1040         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1041         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1042         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1043         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1044 }
1045
1046 float g_bugrigs;
1047 float g_bugrigs_planar_movement;
1048 float g_bugrigs_planar_movement_car_jumping;
1049 float g_bugrigs_reverse_spinning;
1050 float g_bugrigs_reverse_speeding;
1051 float g_bugrigs_reverse_stopping;
1052 float g_bugrigs_air_steering;
1053 float g_bugrigs_angle_smoothing;
1054 float g_bugrigs_friction_floor;
1055 float g_bugrigs_friction_brake;
1056 float g_bugrigs_friction_air;
1057 float g_bugrigs_accel;
1058 float g_bugrigs_speed_ref;
1059 float g_bugrigs_speed_pow;
1060 float g_bugrigs_steer;
1061
1062 float g_touchexplode;
1063 float g_touchexplode_radius;
1064 float g_touchexplode_damage;
1065 float g_touchexplode_edgedamage;
1066 float g_touchexplode_force;
1067
1068 float sv_autotaunt;
1069 float sv_taunt;
1070
1071 float sv_pitch_min;
1072 float sv_pitch_max;
1073 float sv_pitch_fixyaw;
1074
1075 string GetGametype(); // g_world.qc
1076 void readlevelcvars(void)
1077 {
1078         // first load all the mutators
1079         if(cvar("g_invincible_projectiles"))
1080                 MUTATOR_ADD(mutator_invincibleprojectiles);
1081         if(cvar("g_nix"))
1082                 MUTATOR_ADD(mutator_nix);
1083         if(cvar("g_dodging"))
1084                 MUTATOR_ADD(mutator_dodging);
1085         if(cvar("g_rocket_flying"))
1086                 MUTATOR_ADD(mutator_rocketflying);
1087         if(cvar("g_vampire"))
1088                 MUTATOR_ADD(mutator_vampire);
1089
1090         if(cvar("sv_allow_fullbright"))
1091                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1092
1093     g_bugrigs = cvar("g_bugrigs");
1094     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1095     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1096     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1097     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1098     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1099     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1100     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1101     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1102     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1103     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1104     g_bugrigs_accel = cvar("g_bugrigs_accel");
1105     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1106     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1107     g_bugrigs_steer = cvar("g_bugrigs_steer");
1108
1109     g_touchexplode = cvar("g_touchexplode");
1110     g_touchexplode_radius = cvar("g_touchexplode_radius");
1111     g_touchexplode_damage = cvar("g_touchexplode_damage");
1112     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1113     g_touchexplode_force = cvar("g_touchexplode_force");
1114
1115 #ifdef ALLOW_FORCEMODELS
1116         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1117 #endif
1118         sv_loddistance1 = cvar("sv_loddistance1");
1119         sv_loddistance2 = cvar("sv_loddistance2");
1120
1121         if(sv_loddistance2 <= sv_loddistance1)
1122                 sv_loddistance2 = 1073741824; // enough to turn off LOD 2 reliably
1123
1124         sv_clones = cvar("sv_clones");
1125         sv_gentle = cvar("sv_gentle");
1126         sv_foginterval = cvar("sv_foginterval");
1127         g_cloaked = cvar("g_cloaked");
1128     if(g_cts)
1129         g_cloaked = 1; // always enable cloak in CTS
1130         g_jump_grunt = cvar("g_jump_grunt");
1131         g_footsteps = cvar("g_footsteps");
1132         g_grappling_hook = cvar("g_grappling_hook");
1133         g_jetpack = cvar("g_jetpack");
1134         g_midair = cvar("g_midair");
1135         g_minstagib = cvar("g_minstagib");
1136         g_norecoil = cvar("g_norecoil");
1137         g_bloodloss = cvar("g_bloodloss");
1138         sv_maxidle = cvar("sv_maxidle");
1139         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1140         g_ctf_reverse = cvar("g_ctf_reverse");
1141         sv_autotaunt = cvar("sv_autotaunt");
1142         sv_taunt = cvar("sv_taunt");
1143
1144         inWarmupStage = cvar("g_warmup");
1145         g_warmup_limit = cvar("g_warmup_limit");
1146         g_warmup_allguns = cvar("g_warmup_allguns");
1147         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1148
1149         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1150                 inWarmupStage = 0; // these modes cannot work together, sorry
1151
1152         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1153         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1154         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1155         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1156         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1157         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1158         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1159         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1160         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1161         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1162         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1163         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1164
1165         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1166         g_weaponratefactor = cvar("g_weaponratefactor");
1167         g_weapondamagefactor = cvar("g_weapondamagefactor");
1168         g_weaponforcefactor = cvar("g_weaponforcefactor");
1169         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1170
1171         g_pickup_shells = cvar("g_pickup_shells");
1172         g_pickup_shells_max = cvar("g_pickup_shells_max");
1173         g_pickup_nails = cvar("g_pickup_nails");
1174         g_pickup_nails_max = cvar("g_pickup_nails_max");
1175         g_pickup_rockets = cvar("g_pickup_rockets");
1176         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1177         g_pickup_cells = cvar("g_pickup_cells");
1178         g_pickup_cells_max = cvar("g_pickup_cells_max");
1179         g_pickup_fuel = cvar("g_pickup_fuel");
1180         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1181         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1182         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1183         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1184         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1185         g_pickup_armormedium = cvar("g_pickup_armormedium");
1186         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1187         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1188         g_pickup_armorbig = cvar("g_pickup_armorbig");
1189         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1190         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1191         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1192         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1193         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1194         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1195         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1196         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1197         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1198         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1199         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1200         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1201         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1202         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1203         g_pickup_healthmega = cvar("g_pickup_healthmega");
1204         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1205         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1206
1207         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1208         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1209
1210         g_pinata = cvar("g_pinata");
1211
1212     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1213     if(!g_weapon_stay)
1214         g_weapon_stay = cvar("g_weapon_stay");
1215
1216         g_ghost_items = cvar("g_ghost_items");
1217
1218         if(g_ghost_items >= 1)
1219                 g_ghost_items = 0.25; // default alpha value
1220
1221         if not(inWarmupStage && !g_ca)
1222                 game_starttime = cvar("g_start_delay");
1223
1224         sv_pitch_min = cvar("sv_pitch_min");
1225         sv_pitch_max = cvar("sv_pitch_max");
1226         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1227
1228         readplayerstartcvars();
1229 }
1230
1231 //#NO AUTOCVARS END
1232
1233 // Sound functions
1234 string precache_sound (string s) = #19;
1235 float precache_sound_index (string s) = #19;
1236
1237 #define SND_VOLUME      1
1238 #define SND_ATTENUATION 2
1239 #define SND_LARGEENTITY 8
1240 #define SND_LARGESOUND  16
1241
1242 float sound_allowed(float dest, entity e)
1243 {
1244     // sounds from world may always pass
1245     for (;;)
1246     {
1247         if (e.classname == "body")
1248             e = e.enemy;
1249         else if (e.realowner && e.realowner != e)
1250             e = e.realowner;
1251         else if (e.owner && e.owner != e)
1252             e = e.owner;
1253         else
1254             break;
1255     }
1256     // sounds to self may always pass
1257     if (dest == MSG_ONE)
1258         if (e == msg_entity)
1259             return TRUE;
1260     // sounds by players can be removed
1261     if (autocvar_bot_sound_monopoly)
1262         if (clienttype(e) == CLIENTTYPE_REAL)
1263             return FALSE;
1264     // anything else may pass
1265     return TRUE;
1266 }
1267
1268 #ifdef COMPAT_XON010_CHANNELS
1269 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1270 void sound(entity e, float chan, string samp, float vol, float atten)
1271 {
1272     if (!sound_allowed(MSG_BROADCAST, e))
1273         return;
1274     sound_builtin(e, chan, samp, vol, atten);
1275 }
1276 #else
1277 #undef sound
1278 void sound(entity e, float chan, string samp, float vol, float atten)
1279 {
1280     if (!sound_allowed(MSG_BROADCAST, e))
1281         return;
1282     sound7(e, chan, samp, vol, atten, 0, 0);
1283 }
1284 #endif
1285
1286 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1287 {
1288     float entno, idx;
1289
1290     if (!sound_allowed(dest, e))
1291         return;
1292
1293     entno = num_for_edict(e);
1294     idx = precache_sound_index(samp);
1295
1296     float sflags;
1297     sflags = 0;
1298
1299     atten = floor(atten * 64);
1300     vol = floor(vol * 255);
1301
1302     if (vol != 255)
1303         sflags |= SND_VOLUME;
1304     if (atten != 64)
1305         sflags |= SND_ATTENUATION;
1306     if (entno >= 8192 || chan < 0 || chan > 7)
1307         sflags |= SND_LARGEENTITY;
1308     if (idx >= 256)
1309         sflags |= SND_LARGESOUND;
1310
1311     WriteByte(dest, SVC_SOUND);
1312     WriteByte(dest, sflags);
1313     if (sflags & SND_VOLUME)
1314         WriteByte(dest, vol);
1315     if (sflags & SND_ATTENUATION)
1316         WriteByte(dest, atten);
1317     if (sflags & SND_LARGEENTITY)
1318     {
1319         WriteShort(dest, entno);
1320         WriteByte(dest, chan);
1321     }
1322     else
1323     {
1324         WriteShort(dest, entno * 8 + chan);
1325     }
1326     if (sflags & SND_LARGESOUND)
1327         WriteShort(dest, idx);
1328     else
1329         WriteByte(dest, idx);
1330
1331     WriteCoord(dest, o_x);
1332     WriteCoord(dest, o_y);
1333     WriteCoord(dest, o_z);
1334 }
1335 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1336 {
1337     vector o;
1338
1339     if (!sound_allowed(dest, e))
1340         return;
1341
1342     o = e.origin + 0.5 * (e.mins + e.maxs);
1343     soundtoat(dest, e, o, chan, samp, vol, atten);
1344 }
1345 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1346 {
1347     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1348 }
1349 void stopsoundto(float dest, entity e, float chan)
1350 {
1351     float entno;
1352
1353     if (!sound_allowed(dest, e))
1354         return;
1355
1356     entno = num_for_edict(e);
1357
1358     if (entno >= 8192 || chan < 0 || chan > 7)
1359     {
1360         float idx, sflags;
1361         idx = precache_sound_index("misc/null.wav");
1362         sflags = SND_LARGEENTITY;
1363         if (idx >= 256)
1364             sflags |= SND_LARGESOUND;
1365         WriteByte(dest, SVC_SOUND);
1366         WriteByte(dest, sflags);
1367         WriteShort(dest, entno);
1368         WriteByte(dest, chan);
1369         if (sflags & SND_LARGESOUND)
1370             WriteShort(dest, idx);
1371         else
1372             WriteByte(dest, idx);
1373         WriteCoord(dest, e.origin_x);
1374         WriteCoord(dest, e.origin_y);
1375         WriteCoord(dest, e.origin_z);
1376     }
1377     else
1378     {
1379         WriteByte(dest, SVC_STOPSOUND);
1380         WriteShort(dest, entno * 8 + chan);
1381     }
1382 }
1383 void stopsound(entity e, float chan)
1384 {
1385     if (!sound_allowed(MSG_BROADCAST, e))
1386         return;
1387
1388     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1389     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1390 }
1391
1392 void play2(entity e, string filename)
1393 {
1394     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1395     msg_entity = e;
1396     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1397 }
1398
1399 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1400 .float spamtime;
1401 float spamsound(entity e, float chan, string samp, float vol, float atten)
1402 {
1403     if (!sound_allowed(MSG_BROADCAST, e))
1404         return FALSE;
1405
1406     if (time > e.spamtime)
1407     {
1408         e.spamtime = time;
1409         sound(e, chan, samp, vol, atten);
1410         return TRUE;
1411     }
1412     return FALSE;
1413 }
1414
1415 void play2team(float t, string filename)
1416 {
1417     entity head;
1418
1419     if (autocvar_bot_sound_monopoly)
1420         return;
1421
1422     FOR_EACH_REALPLAYER(head)
1423     {
1424         if (head.team == t)
1425             play2(head, filename);
1426     }
1427 }
1428
1429 void play2all(string samp)
1430 {
1431     if (autocvar_bot_sound_monopoly)
1432         return;
1433
1434     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1435 }
1436
1437 void PrecachePlayerSounds(string f);
1438 void precache_playermodel(string m)
1439 {
1440         float globhandle, i, n;
1441         string f;
1442
1443         if(substring(m, -9,5) == "_lod1")
1444                 return;
1445         if(substring(m, -9,5) == "_lod2")
1446                 return;
1447         precache_model(m);
1448         if(sv_loddistance1)
1449         {
1450                 f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1451                 if(fexists(f))
1452                         precache_model(f);
1453                 f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1454                 if(fexists(f))
1455                         precache_model(f);
1456         }
1457
1458         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1459         if (globhandle < 0)
1460                 return;
1461         n = search_getsize(globhandle);
1462         for (i = 0; i < n; ++i)
1463         {
1464                 //print(search_getfilename(globhandle, i), "\n");
1465                 f = search_getfilename(globhandle, i);
1466                 PrecachePlayerSounds(f);
1467         }
1468         search_end(globhandle);
1469 }
1470 void precache_all_playermodels(string pattern)
1471 {
1472         float globhandle, i, n;
1473         string f;
1474
1475         globhandle = search_begin(pattern, TRUE, FALSE);
1476         if (globhandle < 0)
1477                 return;
1478         n = search_getsize(globhandle);
1479         for (i = 0; i < n; ++i)
1480         {
1481                 //print(search_getfilename(globhandle, i), "\n");
1482                 f = search_getfilename(globhandle, i);
1483                 precache_playermodel(f);
1484         }
1485         search_end(globhandle);
1486 }
1487
1488 void precache()
1489 {
1490     // gamemode related things
1491     precache_model ("models/misc/chatbubble.spr");
1492     if (g_runematch)
1493     {
1494         precache_model ("models/runematch/curse.mdl");
1495         precache_model ("models/runematch/rune.mdl");
1496     }
1497
1498 #ifdef TTURRETS_ENABLED
1499     if (autocvar_g_turrets)
1500         turrets_precash();
1501 #endif
1502
1503     // Precache all player models if desired
1504     if (autocvar_sv_precacheplayermodels)
1505     {
1506         PrecachePlayerSounds("sound/player/default.sounds");
1507         precache_all_playermodels("models/player/*.zym");
1508         precache_all_playermodels("models/player/*.dpm");
1509         precache_all_playermodels("models/player/*.md3");
1510         precache_all_playermodels("models/player/*.psk");
1511         precache_all_playermodels("models/player/*.iqm");
1512     }
1513
1514     if (autocvar_sv_defaultcharacter)
1515     {
1516         string s;
1517         s = autocvar_sv_defaultplayermodel_red;
1518         if (s != "")
1519             precache_playermodel(s);
1520         s = autocvar_sv_defaultplayermodel_blue;
1521         if (s != "")
1522             precache_playermodel(s);
1523         s = autocvar_sv_defaultplayermodel_yellow;
1524         if (s != "")
1525             precache_playermodel(s);
1526         s = autocvar_sv_defaultplayermodel_pink;
1527         if (s != "")
1528             precache_playermodel(s);
1529         s = autocvar_sv_defaultplayermodel;
1530         if (s != "")
1531             precache_playermodel(s);
1532     }
1533
1534     if (g_footsteps)
1535     {
1536         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1537         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1538     }
1539
1540     // gore and miscellaneous sounds
1541     //precache_sound ("misc/h2ohit.wav");
1542     precache_model ("models/hook.md3");
1543     precache_sound ("misc/armorimpact.wav");
1544     precache_sound ("misc/bodyimpact1.wav");
1545     precache_sound ("misc/bodyimpact2.wav");
1546     precache_sound ("misc/gib.wav");
1547     precache_sound ("misc/gib_splat01.wav");
1548     precache_sound ("misc/gib_splat02.wav");
1549     precache_sound ("misc/gib_splat03.wav");
1550     precache_sound ("misc/gib_splat04.wav");
1551     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1552     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1553     precache_sound ("misc/null.wav");
1554     precache_sound ("misc/spawn.wav");
1555     precache_sound ("misc/talk.wav");
1556     precache_sound ("misc/teleport.wav");
1557     precache_sound ("misc/poweroff.wav");
1558     precache_sound ("player/lava.wav");
1559     precache_sound ("player/slime.wav");
1560
1561     if (g_jetpack)
1562         precache_sound ("misc/jetpack_fly.wav");
1563
1564     precache_model ("models/sprites/0.spr32");
1565     precache_model ("models/sprites/1.spr32");
1566     precache_model ("models/sprites/2.spr32");
1567     precache_model ("models/sprites/3.spr32");
1568     precache_model ("models/sprites/4.spr32");
1569     precache_model ("models/sprites/5.spr32");
1570     precache_model ("models/sprites/6.spr32");
1571     precache_model ("models/sprites/7.spr32");
1572     precache_model ("models/sprites/8.spr32");
1573     precache_model ("models/sprites/9.spr32");
1574     precache_model ("models/sprites/10.spr32");
1575
1576     // common weapon precaches
1577         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1578     precache_sound ("weapons/weapon_switch.wav");
1579     precache_sound ("weapons/weaponpickup.wav");
1580     precache_sound ("weapons/unavailable.wav");
1581     precache_sound ("weapons/dryfire.wav");
1582     if (g_grappling_hook)
1583     {
1584         precache_sound ("weapons/hook_fire.wav"); // hook
1585         precache_sound ("weapons/hook_impact.wav"); // hook
1586     }
1587
1588     if(autocvar_sv_precacheweapons)
1589     {
1590         //precache weapon models/sounds
1591         float wep;
1592         wep = WEP_FIRST;
1593         while (wep <= WEP_LAST)
1594         {
1595             weapon_action(wep, WR_PRECACHE);
1596             wep = wep + 1;
1597         }
1598     }
1599
1600     precache_model("models/elaser.mdl");
1601     precache_model("models/laser.mdl");
1602     precache_model("models/ebomb.mdl");
1603
1604 #if 0
1605     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1606
1607     if (!self.noise && self.music) // quake 3 uses the music field
1608         self.noise = self.music;
1609
1610     // plays music for the level if there is any
1611     if (self.noise)
1612     {
1613         precache_sound (self.noise);
1614         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1615     }
1616 #endif
1617 }
1618
1619 // sorry, but using \ in macros breaks line numbers
1620 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1621 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1622 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1623
1624
1625 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1626 {
1627         if (clienttype(e) == CLIENTTYPE_REAL)
1628         {
1629                 msg_entity = e;
1630                 WRITESPECTATABLE_MSG_ONE({
1631                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1632                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1633                         WriteByte(MSG_ONE, id);
1634                         WriteString(MSG_ONE, s);
1635                         if (id != 0 && s != "")
1636                         {
1637                                 WriteByte(MSG_ONE, duration);
1638                                 WriteByte(MSG_ONE, countdown_num);
1639                         }
1640                 });
1641         }
1642 }
1643 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1644 {
1645         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1646 }
1647 // WARNING: this kills the trace globals
1648 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1649 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1650
1651 #define INITPRIO_FIRST              0
1652 #define INITPRIO_GAMETYPE           0
1653 #define INITPRIO_GAMETYPE_FALLBACK  1
1654 #define INITPRIO_FINDTARGET        10
1655 #define INITPRIO_DROPTOFLOOR       20
1656 #define INITPRIO_SETLOCATION       90
1657 #define INITPRIO_LINKDOORS         91
1658 #define INITPRIO_LAST              99
1659
1660 .void(void) initialize_entity;
1661 .float initialize_entity_order;
1662 .entity initialize_entity_next;
1663 entity initialize_entity_first;
1664
1665 void make_safe_for_remove(entity e)
1666 {
1667     if (e.initialize_entity)
1668     {
1669         entity ent, prev;
1670         for (ent = initialize_entity_first; ent; )
1671         {
1672             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1673             {
1674                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1675                 // skip it in linked list
1676                 if (prev)
1677                 {
1678                     prev.initialize_entity_next = ent.initialize_entity_next;
1679                     ent = prev.initialize_entity_next;
1680                 }
1681                 else
1682                 {
1683                     initialize_entity_first = ent.initialize_entity_next;
1684                     ent = initialize_entity_first;
1685                 }
1686             }
1687             else
1688             {
1689                 prev = ent;
1690                 ent = ent.initialize_entity_next;
1691             }
1692         }
1693     }
1694 }
1695
1696 void objerror(string s)
1697 {
1698     make_safe_for_remove(self);
1699     objerror_builtin(s);
1700 }
1701
1702 .float remove_except_protected_forbidden;
1703 void remove_except_protected(entity e)
1704 {
1705         if(e.remove_except_protected_forbidden)
1706                 error("not allowed to remove this at this point");
1707         remove_builtin(e);
1708 }
1709
1710 void remove_unsafely(entity e)
1711 {
1712     if(e.classname == "spike")
1713         error("Removing spikes is forbidden (crylink bug), please report");
1714     remove_builtin(e);
1715 }
1716
1717 void remove_safely(entity e)
1718 {
1719     make_safe_for_remove(e);
1720     remove_builtin(e);
1721 }
1722
1723 void InitializeEntity(entity e, void(void) func, float order)
1724 {
1725     entity prev, cur;
1726
1727     if (!e || e.initialize_entity)
1728     {
1729         // make a proxy initializer entity
1730         entity e_old;
1731         e_old = e;
1732         e = spawn();
1733         e.classname = "initialize_entity";
1734         e.enemy = e_old;
1735     }
1736
1737     e.initialize_entity = func;
1738     e.initialize_entity_order = order;
1739
1740     cur = initialize_entity_first;
1741     for (;;)
1742     {
1743         if (!cur || cur.initialize_entity_order > order)
1744         {
1745             // insert between prev and cur
1746             if (prev)
1747                 prev.initialize_entity_next = e;
1748             else
1749                 initialize_entity_first = e;
1750             e.initialize_entity_next = cur;
1751             return;
1752         }
1753         prev = cur;
1754         cur = cur.initialize_entity_next;
1755     }
1756 }
1757 void InitializeEntitiesRun()
1758 {
1759     entity startoflist;
1760     startoflist = initialize_entity_first;
1761     initialize_entity_first = world;
1762     remove = remove_except_protected;
1763     for (self = startoflist; self; self = self.initialize_entity_next)
1764     {
1765         self.remove_except_protected_forbidden = 1;
1766     }
1767     for (self = startoflist; self; )
1768     {
1769         entity e;
1770         var void(void) func;
1771         e = self.initialize_entity_next;
1772         func = self.initialize_entity;
1773         self.initialize_entity_order = 0;
1774         self.initialize_entity = func_null;
1775         self.initialize_entity_next = world;
1776         self.remove_except_protected_forbidden = 0;
1777         if (self.classname == "initialize_entity")
1778         {
1779             entity e_old;
1780             e_old = self.enemy;
1781             remove_builtin(self);
1782             self = e_old;
1783         }
1784         //dprint("Delayed initialization: ", self.classname, "\n");
1785         if(func != func_null)
1786             func();
1787         else
1788         {
1789             eprint(self);
1790             backtrace(strcat("Null function in: ", self.classname, "\n"));
1791         }
1792         self = e;
1793     }
1794     remove = remove_unsafely;
1795 }
1796
1797 .float uncustomizeentityforclient_set;
1798 .void(void) uncustomizeentityforclient;
1799 void(void) SUB_Nullpointer = #0;
1800 void UncustomizeEntitiesRun()
1801 {
1802     entity oldself;
1803     oldself = self;
1804     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1805         self.uncustomizeentityforclient();
1806     self = oldself;
1807 }
1808 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1809 {
1810     e.customizeentityforclient = customizer;
1811     e.uncustomizeentityforclient = uncustomizer;
1812     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1813 }
1814
1815 .float nottargeted;
1816 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1817
1818 void() SUB_Remove;
1819 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1820 {
1821     vector mi, ma;
1822
1823     if (e.classname == "")
1824         e.classname = "net_linked";
1825
1826     if (e.model == "" || self.modelindex == 0)
1827     {
1828         mi = e.mins;
1829         ma = e.maxs;
1830         setmodel(e, "null");
1831         setsize(e, mi, ma);
1832     }
1833
1834     e.SendEntity = sendfunc;
1835     e.SendFlags = 0xFFFFFF;
1836
1837     if (!docull)
1838         e.effects |= EF_NODEPTHTEST;
1839
1840     if (dt)
1841     {
1842         e.nextthink = time + dt;
1843         e.think = SUB_Remove;
1844     }
1845 }
1846
1847 void adaptor_think2touch()
1848 {
1849     entity o;
1850     o = other;
1851     other = world;
1852     self.touch();
1853     other = o;
1854 }
1855
1856 void adaptor_think2use()
1857 {
1858     entity o, a;
1859     o = other;
1860     a = activator;
1861     activator = world;
1862     other = world;
1863     self.use();
1864     other = o;
1865     activator = a;
1866 }
1867
1868 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1869 {
1870         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1871                 self.projectiledeathtype |= HITTYPE_SPLASH;
1872         adaptor_think2use();
1873 }
1874
1875 // deferred dropping
1876 void DropToFloor_Handler()
1877 {
1878     droptofloor_builtin();
1879     self.dropped_origin = self.origin;
1880 }
1881
1882 void droptofloor()
1883 {
1884     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1885 }
1886
1887
1888
1889 float trace_hits_box_a0, trace_hits_box_a1;
1890
1891 float trace_hits_box_1d(float end, float thmi, float thma)
1892 {
1893     if (end == 0)
1894     {
1895         // just check if x is in range
1896         if (0 < thmi)
1897             return FALSE;
1898         if (0 > thma)
1899             return FALSE;
1900     }
1901     else
1902     {
1903         // do the trace with respect to x
1904         // 0 -> end has to stay in thmi -> thma
1905         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1906         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1907         if (trace_hits_box_a0 > trace_hits_box_a1)
1908             return FALSE;
1909     }
1910     return TRUE;
1911 }
1912
1913 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1914 {
1915     end -= start;
1916     thmi -= start;
1917     thma -= start;
1918     // now it is a trace from 0 to end
1919
1920     trace_hits_box_a0 = 0;
1921     trace_hits_box_a1 = 1;
1922
1923     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1924         return FALSE;
1925     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1926         return FALSE;
1927     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1928         return FALSE;
1929
1930     return TRUE;
1931 }
1932
1933 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1934 {
1935     return trace_hits_box(start, end, thmi - ma, thma - mi);
1936 }
1937
1938 float SUB_NoImpactCheck()
1939 {
1940         // zero hitcontents = this is not the real impact, but either the
1941         // mirror-impact of something hitting the projectile instead of the
1942         // projectile hitting the something, or a touchareagrid one. Neither of
1943         // these stop the projectile from moving, so...
1944         if(trace_dphitcontents == 0)
1945         {
1946                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1947                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1948                 checkclient();
1949         }
1950     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1951         return 1;
1952     if (other == world && self.size != '0 0 0')
1953     {
1954         vector tic;
1955         tic = self.velocity * sys_frametime;
1956         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1957         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1958         if (trace_fraction >= 1)
1959         {
1960             dprint("Odd... did not hit...?\n");
1961         }
1962         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1963         {
1964             dprint("Detected and prevented the sky-grapple bug.\n");
1965             return 1;
1966         }
1967     }
1968
1969     return 0;
1970 }
1971
1972 #define SUB_OwnerCheck() (other && (other == self.owner))
1973
1974 void RemoveGrapplingHook(entity pl);
1975 void W_Crylink_Dequeue(entity e);
1976 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1977 {
1978         if(SUB_OwnerCheck())
1979                 return TRUE;
1980         if(SUB_NoImpactCheck())
1981         {
1982                 if(self.classname == "grapplinghook")
1983                         RemoveGrapplingHook(self.realowner);
1984                 else if(self.classname == "spike")
1985                 {
1986                         W_Crylink_Dequeue(self);
1987                         remove(self);
1988                 }
1989                 else
1990                         remove(self);
1991                 return TRUE;
1992         }
1993         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1994                 UpdateCSQCProjectile(self);
1995         return FALSE;
1996 }
1997 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1998
1999 float MAX_IPBAN_URIS           = 16;
2000
2001 float URI_GET_DISCARD          = 0;
2002 float URI_GET_IPBAN            = 1;
2003 float URI_GET_IPBAN_END        = 16;
2004
2005 void URI_Get_Callback(float id, float status, string data)
2006 {
2007     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
2008     dprint(data);
2009     dprint("\nEnd of data.\n");
2010
2011     if(url_URI_Get_Callback(id, status, data))
2012     {
2013         // handled
2014     }
2015     else if (id == URI_GET_DISCARD)
2016     {
2017         // discard
2018     }
2019     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2020     {
2021         // online ban list
2022         OnlineBanList_URI_Get_Callback(id, status, data);
2023     }
2024     else
2025     {
2026         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2027     }
2028 }
2029
2030 void print_to(entity e, string s)
2031 {
2032     if (e)
2033         sprint(e, strcat(s, "\n"));
2034     else
2035         print(s, "\n");
2036 }
2037
2038 string uid2name(string myuid) {
2039         string s;
2040         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2041
2042         // FIXME remove this later after 0.6 release
2043         // convert old style broken records to correct style
2044         if(s == "")
2045         {
2046                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2047                 if(s != "")
2048                 {
2049                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2050                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2051                 }
2052         }
2053
2054         if(s == "")
2055                 s = "^1Unregistered Player";
2056         return s;
2057 }
2058
2059 float race_readTime(string map, float pos)
2060 {
2061         string rr;
2062         if(g_cts)
2063                 rr = CTS_RECORD;
2064         else
2065                 rr = RACE_RECORD;
2066
2067         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2068 }
2069
2070 string race_readUID(string map, float pos)
2071 {
2072         string rr;
2073         if(g_cts)
2074                 rr = CTS_RECORD;
2075         else
2076                 rr = RACE_RECORD;
2077
2078         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2079 }
2080
2081 float race_readPos(string map, float t) {
2082         float i;
2083         for (i = 1; i <= RANKINGS_CNT; ++i)
2084                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2085                         return i;
2086
2087         return 0; // pos is zero if unranked
2088 }
2089
2090 void race_writeTime(string map, float t, string myuid)
2091 {
2092         string rr;
2093         if(g_cts)
2094                 rr = CTS_RECORD;
2095         else
2096                 rr = RACE_RECORD;
2097
2098         float newpos;
2099         newpos = race_readPos(map, t);
2100
2101         float i, prevpos;
2102         for(i = 1; i <= RANKINGS_CNT; ++i)
2103         {
2104                 if(race_readUID(map, i) == myuid)
2105                         prevpos = i;
2106         }
2107         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2108                 for (i = prevpos; i > newpos; --i) {
2109                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2110                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2111                 }
2112         } else { // player has no ranked record yet
2113                 for (i = RANKINGS_CNT; i > newpos; --i) {
2114                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2115                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2116                 }
2117         }
2118
2119         // store new time itself
2120         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2121         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2122 }
2123
2124 string race_readName(string map, float pos)
2125 {
2126         string rr;
2127         if(g_cts)
2128                 rr = CTS_RECORD;
2129         else
2130                 rr = RACE_RECORD;
2131
2132         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2133 }
2134
2135 string race_placeName(float pos) {
2136         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2137         {
2138                 if(mod(pos, 10) == 1)
2139                         return strcat(ftos(pos), "st");
2140                 else if(mod(pos, 10) == 2)
2141                         return strcat(ftos(pos), "nd");
2142                 else if(mod(pos, 10) == 3)
2143                         return strcat(ftos(pos), "rd");
2144                 else
2145                         return strcat(ftos(pos), "th");
2146         }
2147         else
2148                 return strcat(ftos(pos), "th");
2149 }
2150 string getrecords(float page) // 50 records per page
2151 {
2152     float rec;
2153     string h;
2154     float r;
2155     float i;
2156     string s;
2157
2158     rec = 0;
2159
2160     s = "";
2161
2162     if (g_ctf)
2163     {
2164         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2165         {
2166             if (MapInfo_Get_ByID(i))
2167             {
2168                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
2169                 if (r == 0)
2170                     continue;
2171                 // TODO: uid2name
2172                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
2173                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
2174                 ++rec;
2175             }
2176         }
2177     }
2178
2179     if (g_race)
2180     {
2181         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2182         {
2183             if (MapInfo_Get_ByID(i))
2184             {
2185                 r = race_readTime(MapInfo_Map_bspname, 1);
2186                 if (r == 0)
2187                     continue;
2188                 h = race_readName(MapInfo_Map_bspname, 1);
2189                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2190                 ++rec;
2191             }
2192         }
2193     }
2194
2195     if (g_cts)
2196     {
2197         for (i = page * 200; i < MapInfo_count && i < page * 200 + 200; ++i)
2198         {
2199             if (MapInfo_Get_ByID(i))
2200             {
2201                 r = race_readTime(MapInfo_Map_bspname, 1);
2202                 if (r == 0)
2203                     continue;
2204                 h = race_readName(MapInfo_Map_bspname, 1);
2205                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
2206                 ++rec;
2207             }
2208         }
2209     }
2210
2211     MapInfo_ClearTemps();
2212
2213     if (s == "" && page == 0)
2214         return "No records are available on this server.\n";
2215     else
2216         return s;
2217 }
2218
2219 string getrankings()
2220 {
2221     string n;
2222     float t;
2223     float i;
2224     string s;
2225     string p;
2226     string map;
2227
2228     s = "";
2229
2230     map = GetMapname();
2231
2232     for (i = 1; i <= RANKINGS_CNT; ++i)
2233     {
2234         t = race_readTime(map, i);
2235         if (t == 0)
2236             continue;
2237         n = race_readName(map, i);
2238         p = race_placeName(i);
2239         s = strcat(s, strpad(8, p), " ", strpad(-8, TIME_ENCODED_TOSTRING(t)), " ", n, "\n");
2240     }
2241
2242     MapInfo_ClearTemps();
2243
2244     if (s == "")
2245         return strcat("No records are available for the map: ", map, "\n");
2246     else
2247         return strcat("Records for ", map, ":\n", s);
2248 }
2249
2250 #define LADDER_FIRSTPOINT 100
2251 #define LADDER_CNT 10
2252         // position X still gives LADDER_FIRSTPOINT/X points
2253 #define LADDER_SIZE 30
2254         // ladder shows the top X players
2255 string top_uids[LADDER_SIZE];
2256 float top_scores[LADDER_SIZE];
2257 string getladder()
2258 {
2259     float i, j, k, uidcnt;
2260     string s, temp_s;
2261
2262     s = "";
2263     temp_s = "";
2264
2265     string rr;
2266     if(g_cts)
2267         rr = CTS_RECORD;
2268     else
2269         rr = RACE_RECORD;
2270
2271     string myuid;
2272
2273     for (k = 0; k < MapInfo_count; ++k)
2274     {
2275         if (MapInfo_Get_ByID(k))
2276         {
2277                 for (i = 0; i <= LADDER_CNT; ++i) { // i = 0 because it is the speed award
2278                         if(i == 0) // speed award
2279                         {
2280                                 if(stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/speed"))) == 0)
2281                                         continue;
2282
2283                                 myuid = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, rr, "speed/crypto_idfp"));
2284                         }
2285                         else // normal record, if it exists (else break)
2286                         {
2287                                 if(race_readTime(MapInfo_Map_bspname, i) == 0)
2288                                         continue;
2289
2290                                 myuid = race_readUID(MapInfo_Map_bspname, i);
2291                         }
2292
2293                         // string s contains:
2294                         // arg 0 = # of speed recs
2295                         // arg 1 = # of 1st place recs
2296                         // arg 2 = # of 2nd place recs
2297                         // ... etc
2298                         // LADDER_CNT+1 = total points
2299
2300                         temp_s = db_get(TemporaryDB, strcat("ladder", myuid));
2301                         if (temp_s == "")
2302                         {
2303                             db_put(TemporaryDB, strcat("uid", ftos(uidcnt)), myuid);
2304                             ++uidcnt;
2305                             for (j = 0; j <= LADDER_CNT + 1; ++j)
2306                             {
2307                                 if(j != LADDER_CNT + 1)
2308                                     temp_s = strcat(temp_s, "0 ");
2309                                 else
2310                                     temp_s = strcat(temp_s, "0");
2311                             }
2312                         }
2313
2314                         tokenize_console(temp_s);
2315                         s = "";
2316
2317                         if(i == 0) // speed award
2318                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2319                             {
2320                                 if(j == 0) // speed award
2321                                     s = strcat(s, ftos(stof(argv(j)) +1)); // add 1 to speed rec count and write
2322                                 else
2323                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2324                             }
2325                         else // record
2326                             for (j = 0; j <= LADDER_CNT; ++j) // loop over each arg in the string
2327                             {
2328                                 if(j == 0)
2329                                     s = strcat(s, argv(j)); // speed award, dont prefix with " "
2330                                 else if(j == i) // wanted rec!
2331                                     s = strcat(s, " ", ftos(stof(argv(j)) +1)); // update argv(j)
2332                                 else
2333                                     s = strcat(s, " ", argv(j)); // just copy over everything else
2334                             }
2335
2336                         // total points are (by default) calculated like this:
2337                         // speedrec = floor(100 / 10) = 10 points
2338                         // 1st place = floor(100 / 1) = 100 points
2339                         // 2nd place = floor(100 / 2) = 50 points
2340                         // 3rd place = floor(100 / 3) = 33 points
2341                         // 4th place = floor(100 / 4) = 25 points
2342                         // 5th place = floor(100 / 5) = 20 points
2343                         // ... etc
2344
2345                         if(i == 0)
2346                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + LADDER_FIRSTPOINT / 10)); // speed award, add LADDER_FIRSTPOINT / 10 points
2347                         else
2348                             s = strcat(s, " ", ftos(stof(argv(LADDER_CNT+1)) + floor(LADDER_FIRSTPOINT / i))); // record, add LADDER_FIRSTPOINT / i points
2349
2350                         db_put(TemporaryDB, strcat("ladder", myuid), s);
2351                 }
2352         }
2353     }
2354
2355     float thiscnt;
2356     string thisuid;
2357     for (i = 0; i <= uidcnt; ++i) // for each known uid
2358     {
2359         thisuid = db_get(TemporaryDB, strcat("uid", ftos(i)));
2360         temp_s = db_get(TemporaryDB, strcat("ladder", thisuid));
2361         tokenize_console(temp_s);
2362         thiscnt = stof(argv(LADDER_CNT+1));
2363
2364         if(thiscnt > top_scores[LADDER_SIZE-1])
2365         for (j = 0; j < LADDER_SIZE; ++j) // for each place in ladder
2366         {
2367             if(thiscnt > top_scores[j])
2368             {
2369                 for (k = LADDER_SIZE-1; k >= j; --k)
2370                 {
2371                     top_uids[k] = top_uids[k-1];
2372                     top_scores[k] = top_scores[k-1];
2373                 }
2374                 top_uids[j] = thisuid;
2375                 top_scores[j] = thiscnt;
2376                 break;
2377             }
2378         }
2379     }
2380
2381     s = "^3-----------------------\n\n";
2382
2383     s = strcat(s, "Pos ^3|");
2384     s = strcat(s, " ^7Total  ^3|");
2385     for (i = 1; i <= LADDER_CNT; ++i)
2386     {
2387         s = strcat(s, " ^7", race_placeName(i), " ^3|");
2388     }
2389     s = strcat(s, " ^7Speed awards ^3| ^7Name");
2390
2391     s = strcat(s, "\n^3----+--------");
2392     for (i = 1; i <= min(9, LADDER_CNT); ++i)
2393     {
2394         s = strcat(s, "+-----");
2395     }
2396 #if LADDER_CNT > 9
2397     for (i = 1; i <= LADDER_CNT - 9; ++i)
2398     {
2399         s = strcat(s, "+------");
2400     }
2401 #endif
2402
2403     s = strcat(s, "+--------------+--------------------\n");
2404
2405     for (i = 0; i < LADDER_SIZE; ++i)
2406     {
2407         temp_s = db_get(TemporaryDB, strcat("ladder", top_uids[i]));
2408         tokenize_console(temp_s);
2409         if (argv(LADDER_CNT+1) == "") // total is 0, skip
2410             continue;
2411         s = strcat(s, strpad(4, race_placeName(i+1)), "^3| ^7"); // pos
2412         s = strcat(s, strpad(7, argv(LADDER_CNT+1)), "^3| ^7"); // total
2413         for (j = 1; j <= min(9, LADDER_CNT); ++j)
2414         {
2415             s = strcat(s, strpad(4, argv(j)), "^3| ^7"); // 1st, 2nd, 3rd etc cnt
2416         }
2417 #if LADDER_CNT > 9
2418         for (j = 10; j <= LADDER_CNT; ++j)
2419         {
2420             s = strcat(s, strpad(4, argv(j)), " ^3| ^7"); // 1st, 2nd, 3rd etc cnt
2421         }
2422 #endif
2423
2424         s = strcat(s, strpad(13, argv(0)), "^3| ^7"); // speed award cnt
2425         s = strcat(s, uid2name(top_uids[i]), "\n"); // name
2426     }
2427
2428     MapInfo_ClearTemps();
2429
2430     if (s == "")
2431         return "No ladder on this server!\n";
2432     else
2433         return strcat("Top ", ftos(LADDER_SIZE), " ladder rankings:\n", s);
2434 }
2435
2436
2437 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2438 {
2439     float m, i;
2440     vector start, org, delta, end, enddown, mstart;
2441     entity sp;
2442
2443     m = e.dphitcontentsmask;
2444     e.dphitcontentsmask = goodcontents | badcontents;
2445
2446     org = world.mins;
2447     delta = world.maxs - world.mins;
2448
2449     for (i = 0; i < attempts; ++i)
2450     {
2451         start_x = org_x + random() * delta_x;
2452         start_y = org_y + random() * delta_y;
2453         start_z = org_z + random() * delta_z;
2454
2455         // rule 1: start inside world bounds, and outside
2456         // solid, and don't start from somewhere where you can
2457         // fall down to evil
2458         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2459         if (trace_fraction >= 1)
2460             continue;
2461         if (trace_startsolid)
2462             continue;
2463         if (trace_dphitcontents & badcontents)
2464             continue;
2465         if (trace_dphitq3surfaceflags & badsurfaceflags)
2466             continue;
2467
2468         // rule 2: if we are too high, lower the point
2469         if (trace_fraction * delta_z > maxaboveground)
2470             start = trace_endpos + '0 0 1' * maxaboveground;
2471         enddown = trace_endpos;
2472
2473         // rule 3: make sure we aren't outside the map. This only works
2474         // for somewhat well formed maps. A good rule of thumb is that
2475         // the map should have a convex outside hull.
2476         // these can be traceLINES as we already verified the starting box
2477         mstart = start + 0.5 * (e.mins + e.maxs);
2478         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2479         if (trace_fraction >= 1)
2480             continue;
2481         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2482         if (trace_fraction >= 1)
2483             continue;
2484         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2485         if (trace_fraction >= 1)
2486             continue;
2487         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2488         if (trace_fraction >= 1)
2489             continue;
2490         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2491         if (trace_fraction >= 1)
2492             continue;
2493
2494         // rule 4: we must "see" some spawnpoint
2495         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2496                 if(checkpvs(mstart, sp))
2497                         break;
2498         if(!sp)
2499         {
2500                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2501                         if(checkpvs(mstart, sp))
2502                                 break;
2503                 if(!sp)
2504                         continue;
2505         }
2506
2507         // find a random vector to "look at"
2508         end_x = org_x + random() * delta_x;
2509         end_y = org_y + random() * delta_y;
2510         end_z = org_z + random() * delta_z;
2511         end = start + normalize(end - start) * vlen(delta);
2512
2513         // rule 4: start TO end must not be too short
2514         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2515         if (trace_startsolid)
2516             continue;
2517         if (trace_fraction < minviewdistance / vlen(delta))
2518             continue;
2519
2520         // rule 5: don't want to look at sky
2521         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2522             continue;
2523
2524         // rule 6: we must not end up in trigger_hurt
2525         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2526             continue;
2527
2528         break;
2529     }
2530
2531     e.dphitcontentsmask = m;
2532
2533     if (i < attempts)
2534     {
2535         setorigin(e, start);
2536         e.angles = vectoangles(end - start);
2537         dprint("Needed ", ftos(i + 1), " attempts\n");
2538         return TRUE;
2539     }
2540     else
2541         return FALSE;
2542 }
2543
2544 float zcurveparticles_effectno;
2545 vector zcurveparticles_start;
2546 float zcurveparticles_spd;
2547
2548 void endzcurveparticles()
2549 {
2550         if(zcurveparticles_effectno)
2551         {
2552                 // terminator
2553                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2554         }
2555         zcurveparticles_effectno = 0;
2556 }
2557
2558 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2559 {
2560         spd = bound(0, floor(spd / 16), 32767);
2561         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2562         {
2563                 endzcurveparticles();
2564                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2565                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2566                 WriteShort(MSG_BROADCAST, effectno);
2567                 WriteCoord(MSG_BROADCAST, start_x);
2568                 WriteCoord(MSG_BROADCAST, start_y);
2569                 WriteCoord(MSG_BROADCAST, start_z);
2570                 zcurveparticles_effectno = effectno;
2571                 zcurveparticles_start = start;
2572         }
2573         else
2574                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2575         WriteCoord(MSG_BROADCAST, end_x);
2576         WriteCoord(MSG_BROADCAST, end_y);
2577         WriteCoord(MSG_BROADCAST, end_z);
2578         WriteCoord(MSG_BROADCAST, end_dz);
2579         zcurveparticles_spd = spd;
2580 }
2581
2582 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2583 {
2584         float end_dz;
2585         vector vecxy, velxy;
2586
2587         vecxy = end - start;
2588         vecxy_z = 0;
2589         velxy = vel;
2590         velxy_z = 0;
2591
2592         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2593         {
2594                 endzcurveparticles();
2595                 trailparticles(world, effectno, start, end);
2596                 return;
2597         }
2598
2599         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2600         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2601 }
2602
2603 void write_recordmarker(entity pl, float tstart, float dt)
2604 {
2605     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2606
2607     // also write a marker into demo files for demotc-race-record-extractor to find
2608     stuffcmd(pl,
2609              strcat(
2610                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2611                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2612 }
2613
2614 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2615 {
2616         switch(algn)
2617         {
2618                 default:
2619                 case 3: // right
2620                         break;
2621
2622                 case 4: // left
2623                         vecs_y = -vecs_y;
2624                         break;
2625
2626                 case 1:
2627                         if(allowcenter) // 2: allow center handedness
2628                         {
2629                                 // center
2630                                 vecs_y = 0;
2631                                 vecs_z -= 2;
2632                         }
2633                         else
2634                         {
2635                                 // right
2636                         }
2637                         break;
2638
2639                 case 2:
2640                         if(allowcenter) // 2: allow center handedness
2641                         {
2642                                 // center
2643                                 vecs_y = 0;
2644                                 vecs_z -= 2;
2645                         }
2646                         else
2647                         {
2648                                 // left
2649                                 vecs_y = -vecs_y;
2650                         }
2651                         break;
2652         }
2653         return vecs;
2654 }
2655
2656 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2657 {
2658         string s;
2659         vector v;
2660
2661         if (autocvar_g_shootfromeye)
2662         {
2663                 if (visual)
2664                 {
2665                         vecs_y = 0;
2666                         vecs_z -= 2;
2667                 }
2668                 else
2669                 {
2670                         vecs_y = 0;
2671                         vecs_z = 0;
2672                 }
2673         }
2674         else if (autocvar_g_shootfromcenter)
2675         {
2676                 vecs_y = 0;
2677                 vecs_z -= 2;
2678         }
2679         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2680         {
2681                 v = stov(s);
2682                 if (y_is_right)
2683                         v_y = -v_y;
2684                 if (v_x != 0)
2685                         vecs_x = v_x;
2686                 vecs_y = v_y;
2687                 vecs_z = v_z;
2688         }
2689         else if (autocvar_g_shootfromclient)
2690         {
2691                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2692         }
2693         return vecs;
2694 }
2695
2696 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2697 {
2698         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2699 }
2700
2701
2702 void attach_sameorigin(entity e, entity to, string tag)
2703 {
2704     vector org, t_forward, t_left, t_up, e_forward, e_up;
2705     vector org0, ang0;
2706     float tagscale;
2707
2708     ang0 = e.angles;
2709     org0 = e.origin;
2710
2711     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2712     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2713     t_forward = v_forward * tagscale;
2714     t_left = v_right * -tagscale;
2715     t_up = v_up * tagscale;
2716
2717     e.origin_x = org * t_forward;
2718     e.origin_y = org * t_left;
2719     e.origin_z = org * t_up;
2720
2721     // current forward and up directions
2722     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2723                 e.angles = AnglesTransform_FromVAngles(e.angles);
2724         else
2725                 e.angles = AnglesTransform_FromAngles(e.angles);
2726     fixedmakevectors(e.angles);
2727
2728     // untransform forward, up!
2729     e_forward_x = v_forward * t_forward;
2730     e_forward_y = v_forward * t_left;
2731     e_forward_z = v_forward * t_up;
2732     e_up_x = v_up * t_forward;
2733     e_up_y = v_up * t_left;
2734     e_up_z = v_up * t_up;
2735
2736     e.angles = fixedvectoangles2(e_forward, e_up);
2737     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2738                 e.angles = AnglesTransform_ToVAngles(e.angles);
2739         else
2740                 e.angles = AnglesTransform_ToAngles(e.angles);
2741
2742     setattachment(e, to, tag);
2743     setorigin(e, e.origin);
2744 }
2745
2746 void detach_sameorigin(entity e)
2747 {
2748     vector org;
2749     org = gettaginfo(e, 0);
2750     e.angles = fixedvectoangles2(v_forward, v_up);
2751     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2752                 e.angles = AnglesTransform_ToVAngles(e.angles);
2753         else
2754                 e.angles = AnglesTransform_ToAngles(e.angles);
2755     setorigin(e, org);
2756     setattachment(e, world, "");
2757     setorigin(e, e.origin);
2758 }
2759
2760 void follow_sameorigin(entity e, entity to)
2761 {
2762     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2763     e.aiment = to; // make the hole follow bmodel
2764     e.punchangle = to.angles; // the original angles of bmodel
2765     e.view_ofs = e.origin - to.origin; // relative origin
2766     e.v_angle = e.angles - to.angles; // relative angles
2767 }
2768
2769 void unfollow_sameorigin(entity e)
2770 {
2771     e.movetype = MOVETYPE_NONE;
2772 }
2773
2774 entity gettaginfo_relative_ent;
2775 vector gettaginfo_relative(entity e, float tag)
2776 {
2777     if (!gettaginfo_relative_ent)
2778     {
2779         gettaginfo_relative_ent = spawn();
2780         gettaginfo_relative_ent.effects = EF_NODRAW;
2781     }
2782     gettaginfo_relative_ent.model = e.model;
2783     gettaginfo_relative_ent.modelindex = e.modelindex;
2784     gettaginfo_relative_ent.frame = e.frame;
2785     return gettaginfo(gettaginfo_relative_ent, tag);
2786 }
2787
2788 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2789 {
2790     float p;
2791     p = pow(2, chan);
2792     if (pl.soundentity.cnt & p)
2793         return;
2794     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2795     pl.soundentity.cnt |= p;
2796 }
2797
2798 void SoundEntity_StopSound(entity pl, float chan)
2799 {
2800     float p;
2801     p = pow(2, chan);
2802     if (pl.soundentity.cnt & p)
2803     {
2804         stopsoundto(MSG_ALL, pl.soundentity, chan);
2805         pl.soundentity.cnt &~= p;
2806     }
2807 }
2808
2809 void SoundEntity_Attach(entity pl)
2810 {
2811     pl.soundentity = spawn();
2812     pl.soundentity.classname = "soundentity";
2813     pl.soundentity.owner = pl;
2814     setattachment(pl.soundentity, pl, "");
2815     setmodel(pl.soundentity, "null");
2816 }
2817
2818 void SoundEntity_Detach(entity pl)
2819 {
2820     float i;
2821     for (i = 0; i <= 7; ++i)
2822         SoundEntity_StopSound(pl, i);
2823 }
2824
2825
2826 float ParseCommandPlayerSlotTarget_firsttoken;
2827 entity GetCommandPlayerSlotTargetFromTokenizedCommand(float tokens, float idx) // idx = start index
2828 {
2829         string s;
2830         entity e, head;
2831         float n;
2832
2833         s = string_null;
2834
2835         ParseCommandPlayerSlotTarget_firsttoken = -1;
2836
2837         if (tokens > idx)
2838         {
2839                 if (substring(argv(idx), 0, 1) == "#")
2840                 {
2841                         s = substring(argv(idx), 1, -1);
2842                         ++idx;
2843                         if (s == "") if (tokens > idx)
2844                         {
2845                                 s = argv(idx);
2846                                 ++idx;
2847                         }
2848                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2849                         n = stof(s);
2850                         if (s == ftos(n) && n > 0 && n <= maxclients)
2851                         {
2852                                 e = edict_num(n);
2853                                 if (e.flags & FL_CLIENT)
2854                                         return e;
2855                         }
2856                 }
2857                 else
2858                 {
2859                         // it must be a nick name
2860                         s = argv(idx);
2861                         ++idx;
2862                         ParseCommandPlayerSlotTarget_firsttoken = idx;
2863
2864                         n = 0;
2865                         FOR_EACH_CLIENT(head)
2866                                 if (head.netname == s)
2867                                 {
2868                                         e = head;
2869                                         ++n;
2870                                 }
2871                         if (n == 1)
2872                                 return e;
2873
2874                         s = strdecolorize(s);
2875                         n = 0;
2876                         FOR_EACH_CLIENT(head)
2877                                 if (strdecolorize(head.netname) == s)
2878                                 {
2879                                         e = head;
2880                                         ++n;
2881                                 }
2882                         if (n == 1)
2883                                 return e;
2884                 }
2885         }
2886
2887         return world;
2888 }
2889
2890 .float scale2;
2891
2892 float modeleffect_SendEntity(entity to, float sf)
2893 {
2894         float f;
2895         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2896
2897         f = 0;
2898         if(self.velocity != '0 0 0')
2899                 f |= 1;
2900         if(self.angles != '0 0 0')
2901                 f |= 2;
2902         if(self.avelocity != '0 0 0')
2903                 f |= 4;
2904
2905         WriteByte(MSG_ENTITY, f);
2906         WriteShort(MSG_ENTITY, self.modelindex);
2907         WriteByte(MSG_ENTITY, self.skin);
2908         WriteByte(MSG_ENTITY, self.frame);
2909         WriteCoord(MSG_ENTITY, self.origin_x);
2910         WriteCoord(MSG_ENTITY, self.origin_y);
2911         WriteCoord(MSG_ENTITY, self.origin_z);
2912         if(f & 1)
2913         {
2914                 WriteCoord(MSG_ENTITY, self.velocity_x);
2915                 WriteCoord(MSG_ENTITY, self.velocity_y);
2916                 WriteCoord(MSG_ENTITY, self.velocity_z);
2917         }
2918         if(f & 2)
2919         {
2920                 WriteCoord(MSG_ENTITY, self.angles_x);
2921                 WriteCoord(MSG_ENTITY, self.angles_y);
2922                 WriteCoord(MSG_ENTITY, self.angles_z);
2923         }
2924         if(f & 4)
2925         {
2926                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2927                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2928                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2929         }
2930         WriteShort(MSG_ENTITY, self.scale * 256.0);
2931         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2932         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2933         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2934         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2935
2936         return TRUE;
2937 }
2938
2939 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2940 {
2941         entity e;
2942         float sz;
2943         e = spawn();
2944         e.classname = "modeleffect";
2945         setmodel(e, m);
2946         e.frame = f;
2947         setorigin(e, o);
2948         e.velocity = v;
2949         e.angles = ang;
2950         e.avelocity = angv;
2951         e.alpha = a;
2952         e.teleport_time = t1;
2953         e.fade_time = t2;
2954         e.skin = s;
2955         if(s0 >= 0)
2956                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2957         else
2958                 e.scale = -s0;
2959         if(s2 >= 0)
2960                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2961         else
2962                 e.scale2 = -s2;
2963         sz = max(e.scale, e.scale2);
2964         setsize(e, e.mins * sz, e.maxs * sz);
2965         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2966 }
2967
2968 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2969 {
2970         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2971 }
2972
2973 float randombit(float bits)
2974 {
2975         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2976                 return bits;
2977
2978         float n, f, b, r;
2979
2980         r = random();
2981         b = 0;
2982         n = 0;
2983
2984         for(f = 1; f <= bits; f *= 2)
2985         {
2986                 if(bits & f)
2987                 {
2988                         ++n;
2989                         r *= n;
2990                         if(r <= 1)
2991                                 b = f;
2992                         else
2993                                 r = (r - 1) / (n - 1);
2994                 }
2995         }
2996
2997         return b;
2998 }
2999
3000 float randombits(float bits, float k, float error_return)
3001 {
3002         float r;
3003         r = 0;
3004         while(k > 0 && bits != r)
3005         {
3006                 r += randombit(bits - r);
3007                 --k;
3008         }
3009         if(error_return)
3010                 if(k > 0)
3011                         return -1; // all
3012         return r;
3013 }
3014
3015 void randombit_test(float bits, float iter)
3016 {
3017         while(iter > 0)
3018         {
3019                 print(ftos(randombit(bits)), "\n");
3020                 --iter;
3021         }
3022 }
3023
3024 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
3025 {
3026         if(halflifedist > 0)
3027                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
3028         else if(halflifedist < 0)
3029                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
3030         else
3031                 return 1;
3032 }
3033
3034
3035
3036
3037 #ifdef RELEASE
3038 #define cvar_string_normal cvar_string_builtin
3039 #define cvar_normal cvar_builtin
3040 #else
3041 string cvar_string_normal(string n)
3042 {
3043         if not(cvar_type(n) & 1)
3044                 backtrace(strcat("Attempt to access undefined cvar: ", n));
3045         return cvar_string_builtin(n);
3046 }
3047
3048 float cvar_normal(string n)
3049 {
3050         return stof(cvar_string_normal(n));
3051 }
3052 #endif
3053 #define cvar_set_normal cvar_set_builtin
3054
3055 void defer_think()
3056 {
3057     entity oself;
3058
3059     oself           = self;
3060     self            = self.owner;
3061     oself.think     = SUB_Remove;
3062     oself.nextthink = time;
3063
3064     oself.use();
3065 }
3066
3067 /*
3068     Execute func() after time + fdelay.
3069     self when func is executed = self when defer is called
3070 */
3071 void defer(float fdelay, void() func)
3072 {
3073     entity e;
3074
3075     e           = spawn();
3076     e.owner     = self;
3077     e.use       = func;
3078     e.think     = defer_think;
3079     e.nextthink = time + fdelay;
3080 }
3081
3082 .string aiment_classname;
3083 .float aiment_deadflag;
3084 void SetMovetypeFollow(entity ent, entity e)
3085 {
3086         // FIXME this may not be warpzone aware
3087         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
3088         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
3089         ent.aiment = e; // make the hole follow bmodel
3090         ent.punchangle = e.angles; // the original angles of bmodel
3091         ent.view_ofs = ent.origin - e.origin; // relative origin
3092         ent.v_angle = ent.angles - e.angles; // relative angles
3093         ent.aiment_classname = strzone(e.classname);
3094         ent.aiment_deadflag = e.deadflag;
3095 }
3096 void UnsetMovetypeFollow(entity ent)
3097 {
3098         ent.movetype = MOVETYPE_FLY;
3099         PROJECTILE_MAKETRIGGER(ent);
3100         ent.aiment = world;
3101 }
3102 float LostMovetypeFollow(entity ent)
3103 {
3104 /*
3105         if(ent.movetype != MOVETYPE_FOLLOW)
3106                 if(ent.aiment)
3107                         error("???");
3108 */
3109         if(ent.aiment)
3110         {
3111                 if(ent.aiment.classname != ent.aiment_classname)
3112                         return 1;
3113                 if(ent.aiment.deadflag != ent.aiment_deadflag)
3114                         return 1;
3115         }
3116         return 0;
3117 }
3118
3119 float isPushable(entity e)
3120 {
3121         if(e.iscreature)
3122                 return TRUE;
3123         switch(e.classname)
3124         {
3125                 case "body":
3126                 case "droppedweapon":
3127                 case "keepawayball":
3128                 case "nexball_basketball":
3129                 case "nexball_football":
3130                         return TRUE;
3131                 case "bullet": // antilagged bullets can't hit this either
3132                         return FALSE;
3133         }
3134         if (e.projectiledeathtype)
3135                 return TRUE;
3136         return FALSE;
3137 }