qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 #define strstr strstrofs
 161 /*
 162 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 163 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 164 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 165 // BE CONSTANT OR strzoneD!
 166 float strstr(string haystack, string needle, float offset)
 167 {
 168         float len, endpos;
 169         string found;
 170         len = strlen(needle);
 171         endpos = strlen(haystack) - len;
 172         while(offset <= endpos)
 173         {
 174                 found = substring(haystack, offset, len);
 175                 if(found == needle)
 176                         return offset;
 177                 offset = offset + 1;
 178         }
 179         return -1;
 180 }
 181 */
 182
 183 const float NUM_NEAREST_ENTITIES = 4;
 184 entity nearest_entity[NUM_NEAREST_ENTITIES];
 185 float nearest_length[NUM_NEAREST_ENTITIES];
 186 entity findnearest(vector point, .string field, string value, vector axismod)
 187 {
 188     entity localhead;
 189     float i;
 190     float j;
 191     float len;
 192     vector dist;
 193
 194     float num_nearest;
 195     num_nearest = 0;
 196
 197     localhead = find(world, field, value);
 198     while (localhead)
 199     {
 200         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 201             dist = localhead.oldorigin;
 202         else
 203             dist = localhead.origin;
 204         dist = dist - point;
 205         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 206         len = vlen(dist);
 207
 208         for (i = 0; i < num_nearest; ++i)
 209         {
 210             if (len < nearest_length[i])
 211                 break;
 212         }
 213
 214         // now i tells us where to insert at
 215         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 216         if (i < NUM_NEAREST_ENTITIES)
 217         {
 218             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 219             {
 220                 nearest_length[j + 1] = nearest_length[j];
 221                 nearest_entity[j + 1] = nearest_entity[j];
 222             }
 223             nearest_length[i] = len;
 224             nearest_entity[i] = localhead;
 225             if (num_nearest < NUM_NEAREST_ENTITIES)
 226                 num_nearest = num_nearest + 1;
 227         }
 228
 229         localhead = find(localhead, field, value);
 230     }
 231
 232     // now use the first one from our list that we can see
 233     for (i = 0; i < num_nearest; ++i)
 234     {
 235         traceline(point, nearest_entity[i].origin, TRUE, world);
 236         if (trace_fraction == 1)
 237         {
 238             if (i != 0)
 239             {
 240                 dprint("Nearest point (");
 241                 dprint(nearest_entity[0].netname);
 242                 dprint(") is not visible, using a visible one.\n");
 243             }
 244             return nearest_entity[i];
 245         }
 246     }
 247
 248     if (num_nearest == 0)
 249         return world;
 250
 251     dprint("Not seeing any location point, using nearest as fallback.\n");
 252     /* DEBUGGING CODE:
 253     dprint("Candidates were: ");
 254     for(j = 0; j < num_nearest; ++j)
 255     {
 256         if(j != 0)
 257                 dprint(", ");
 258         dprint(nearest_entity[j].netname);
 259     }
 260     dprint("\n");
 261     */
 262
 263     return nearest_entity[0];
 264 }
 265
 266 void spawnfunc_target_location()
 267 {
 268     self.classname = "target_location";
 269     // location name in netname
 270     // eventually support: count, teamgame selectors, line of sight?
 271 }
 272
 273 void spawnfunc_info_location()
 274 {
 275     self.classname = "target_location";
 276     self.message = self.netname;
 277 }
 278
 279 string NearestLocation(vector p)
 280 {
 281     entity loc;
 282     string ret;
 283     ret = "somewhere";
 284     loc = findnearest(p, classname, "target_location", '1 1 1');
 285     if (loc)
 286     {
 287         ret = loc.message;
 288     }
 289     else
 290     {
 291         loc = findnearest(p, target, "###item###", '1 1 4');
 292         if (loc)
 293             ret = loc.netname;
 294     }
 295     return ret;
 296 }
 297
 298 string formatmessage(string msg)
 299 {
 300         float p, p1, p2;
 301         float n;
 302         vector cursor;
 303         entity cursor_ent;
 304         string escape;
 305         string replacement;
 306         p = 0;
 307         n = 7;
 308
 309         WarpZone_crosshair_trace(self);
 310         cursor = trace_endpos;
 311         cursor_ent = trace_ent;
 312
 313         while (1) {
 314                 if (n < 1)
 315                         break; // too many replacements
 316
 317                 n = n - 1;
 318                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 319                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 320
 321                 if (p1 < 0)
 322                         p1 = p2;
 323
 324                 if (p2 < 0)
 325                         p2 = p1;
 326
 327                 p = min(p1, p2);
 328
 329                 if (p < 0)
 330                         break;
 331
 332                 replacement = substring(msg, p, 2);
 333                 escape = substring(msg, p + 1, 1);
 334
 335                 if (escape == "%")
 336                         replacement = "%";
 337                 else if (escape == "\\")
 338                         replacement = "\\";
 339                 else if (escape == "n")
 340                         replacement = "\n";
 341                 else if (escape == "a")
 342                         replacement = ftos(floor(self.armorvalue));
 343                 else if (escape == "h")
 344                         replacement = ftos(floor(self.health));
 345                 else if (escape == "l")
 346                         replacement = NearestLocation(self.origin);
 347                 else if (escape == "y")
 348                         replacement = NearestLocation(cursor);
 349                 else if (escape == "d")
 350                         replacement = NearestLocation(self.death_origin);
 351                 else if (escape == "w") {
 352                         float wep;
 353                         wep = self.weapon;
 354                         if (!wep)
 355                                 wep = self.switchweapon;
 356                         if (!wep)
 357                                 wep = self.cnt;
 358                         replacement = W_Name(wep);
 359                 } else if (escape == "W") {
 360                         if (self.items & IT_SHELLS) replacement = "shells";
 361                         else if (self.items & IT_NAILS) replacement = "bullets";
 362                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 363                         else if (self.items & IT_CELLS) replacement = "cells";
 364                         else replacement = "batteries"; // ;)
 365                 } else if (escape == "x") {
 366                         replacement = cursor_ent.netname;
 367                         if (replacement == "" || !cursor_ent)
 368                                 replacement = "nothing";
 369                 } else if (escape == "s")
 370                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 371                 else if (escape == "S")
 372                         replacement = ftos(vlen(self.velocity));
 373
 374                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 375                 p = p + strlen(replacement);
 376         }
 377         return msg;
 378 }
 379
 380 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 381         return (value == 0) ? FALSE : TRUE;
 382 }
 383
 384 /*
 385 =============
 386 GetCvars
 387 =============
 388 Called with:
 389   0:  sends the request
 390   >0: receives a cvar from name=argv(f) value=argv(f+1)
 391 */
 392 void GetCvars_handleString(string thisname, float f, .string field, string name)
 393 {
 394         if (f < 0)
 395         {
 396                 if (self.field)
 397                         strunzone(self.field);
 398                 self.field = string_null;
 399         }
 400         else if (f > 0)
 401         {
 402                 if (thisname == name)
 403                 {
 404                         if (self.field)
 405                                 strunzone(self.field);
 406                         self.field = strzone(argv(f + 1));
 407                 }
 408         }
 409         else
 410                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 411 }
 412 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 413 {
 414         GetCvars_handleString(thisname, f, field, name);
 415         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 416                 if (thisname == name)
 417                 {
 418                         string s;
 419                         s = func(strcat1(self.field));
 420                         if (s != self.field)
 421                         {
 422                                 strunzone(self.field);
 423                                 self.field = strzone(s);
 424                         }
 425                 }
 426 }
 427 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 428 {
 429         if (f < 0)
 430         {
 431         }
 432         else if (f > 0)
 433         {
 434                 if (thisname == name)
 435                         self.field = stof(argv(f + 1));
 436         }
 437         else
 438                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 439 }
 440 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 441 {
 442         if (f < 0)
 443         {
 444         }
 445         else if (f > 0)
 446         {
 447                 if (thisname == name)
 448                 {
 449                         if(!self.field)
 450                         {
 451                                 self.field = stof(argv(f + 1));
 452                                 if(!self.field)
 453                                         self.field = -1;
 454                         }
 455                 }
 456         }
 457         else
 458         {
 459                 if(!self.field)
 460                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 461         }
 462 }
 463 float w_getbestweapon(entity e);
 464 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 465 {
 466         string o;
 467         o = W_FixWeaponOrder_ForceComplete(wo);
 468         if(self.weaponorder_byimpulse)
 469         {
 470                 strunzone(self.weaponorder_byimpulse);
 471                 self.weaponorder_byimpulse = string_null;
 472         }
 473         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 474         return o;
 475 }
 476 void GetCvars(float f)
 477 {
 478         string s = string_null;
 479
 480         if (f > 0)
 481                 s = strcat1(argv(f));
 482
 483         get_cvars_f = f;
 484         get_cvars_s = s;
 485
 486         MUTATOR_CALLHOOK(GetCvars);
 487
 488         Notification_GetCvars();
 489
 490         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 491         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 492         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 493         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 494         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 506         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 507         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 508         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 510         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 512         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 513
 514         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 515         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 516
 517         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 519         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 520         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 521         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 522
 523         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 524         if (f > 0)
 525         {
 526                 if (s == "cl_weaponpriority")
 527                         self.switchweapon = w_getbestweapon(self);
 528                 if (s == "cl_allow_uidtracking")
 529                         PlayerStats_AddPlayer(self);
 530         }
 531 }
 532
 533 // decolorizes and team colors the player name when needed
 534 string playername(entity p)
 535 {
 536     string t;
 537     if (teamplay && !intermission_running && IS_PLAYER(p))
 538     {
 539         t = Team_ColorCode(p.team);
 540         return strcat(t, strdecolorize(p.netname));
 541     }
 542     else
 543         return p.netname;
 544 }
 545
 546 vector randompos(vector m1, vector m2)
 547 {
 548     vector v;
 549     m2 = m2 - m1;
 550     v_x = m2_x * random() + m1_x;
 551     v_y = m2_y * random() + m1_y;
 552     v_z = m2_z * random() + m1_z;
 553     return  v;
 554 }
 555
 556 //#NO AUTOCVARS START
 557
 558 float g_pickup_shells;
 559 float g_pickup_shells_max;
 560 float g_pickup_nails;
 561 float g_pickup_nails_max;
 562 float g_pickup_rockets;
 563 float g_pickup_rockets_max;
 564 float g_pickup_cells;
 565 float g_pickup_cells_max;
 566 float g_pickup_fuel;
 567 float g_pickup_fuel_jetpack;
 568 float g_pickup_fuel_max;
 569 float g_pickup_armorsmall;
 570 float g_pickup_armorsmall_max;
 571 float g_pickup_armorsmall_anyway;
 572 float g_pickup_armormedium;
 573 float g_pickup_armormedium_max;
 574 float g_pickup_armormedium_anyway;
 575 float g_pickup_armorbig;
 576 float g_pickup_armorbig_max;
 577 float g_pickup_armorbig_anyway;
 578 float g_pickup_armorlarge;
 579 float g_pickup_armorlarge_max;
 580 float g_pickup_armorlarge_anyway;
 581 float g_pickup_healthsmall;
 582 float g_pickup_healthsmall_max;
 583 float g_pickup_healthsmall_anyway;
 584 float g_pickup_healthmedium;
 585 float g_pickup_healthmedium_max;
 586 float g_pickup_healthmedium_anyway;
 587 float g_pickup_healthlarge;
 588 float g_pickup_healthlarge_max;
 589 float g_pickup_healthlarge_anyway;
 590 float g_pickup_healthmega;
 591 float g_pickup_healthmega_max;
 592 float g_pickup_healthmega_anyway;
 593 float g_pickup_ammo_anyway;
 594 float g_pickup_weapons_anyway;
 595 float g_weaponarena;
 596 WepSet g_weaponarena_weapons;
 597 float g_weaponarena_random;
 598 float g_weaponarena_random_with_laser;
 599 string g_weaponarena_list;
 600 float g_weaponspeedfactor;
 601 float g_weaponratefactor;
 602 float g_weapondamagefactor;
 603 float g_weaponforcefactor;
 604 float g_weaponspreadfactor;
 605
 606 WepSet start_weapons;
 607 WepSet start_weapons_default;
 608 WepSet start_weapons_defaultmask;
 609 float start_items;
 610 float start_ammo_shells;
 611 float start_ammo_nails;
 612 float start_ammo_rockets;
 613 float start_ammo_cells;
 614 float start_ammo_fuel;
 615 float start_health;
 616 float start_armorvalue;
 617 WepSet warmup_start_weapons;
 618 WepSet warmup_start_weapons_default;
 619 WepSet warmup_start_weapons_defaultmask;
 620 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 621 float warmup_start_ammo_shells;
 622 float warmup_start_ammo_nails;
 623 float warmup_start_ammo_rockets;
 624 float warmup_start_ammo_cells;
 625 float warmup_start_ammo_fuel;
 626 float warmup_start_health;
 627 float warmup_start_armorvalue;
 628 float g_weapon_stay;
 629
 630 entity get_weaponinfo(float w);
 631
 632 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 633 {
 634         var float i = weaponinfo.weapon;
 635         var float d = 0;
 636
 637         if (!i)
 638                 return 0;
 639
 640         if (g_lms || g_ca || allguns)
 641         {
 642                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 643                         d = TRUE;
 644                 else
 645                         d = FALSE;
 646         }
 647         else if (g_cts)
 648                 d = (i == WEP_SHOTGUN);
 649         else if (g_nexball)
 650                 d = 0; // weapon is set a few lines later
 651         else
 652                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 653
 654         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 655                 d |= (i == WEP_HOOK);
 656         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 657                 d = 0;
 658
 659         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 660
 661         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 662
 663         // bit order in t:
 664         // 1: want or not
 665         // 2: is default?
 666         // 4: is set by default?
 667         if(t < 0)
 668                 t = 4 | (3 * d);
 669         else
 670                 t |= (2 * d);
 671
 672         return t;
 673 }
 674
 675 void readplayerstartcvars()
 676 {
 677         entity e;
 678         float i, j, t;
 679         string s;
 680
 681         // initialize starting values for players
 682         start_weapons = '0 0 0';
 683         start_weapons_default = '0 0 0';
 684         start_weapons_defaultmask = '0 0 0';
 685         start_items = 0;
 686         start_ammo_shells = 0;
 687         start_ammo_nails = 0;
 688         start_ammo_rockets = 0;
 689         start_ammo_cells = 0;
 690         start_health = cvar("g_balance_health_start");
 691         start_armorvalue = cvar("g_balance_armor_start");
 692
 693         g_weaponarena = 0;
 694         g_weaponarena_weapons = '0 0 0';
 695
 696         s = cvar_string("g_weaponarena");
 697         if (s == "0" || s == "")
 698         {
 699                 if(g_ca)
 700                         s = "most";
 701         }
 702
 703         if (s == "0" || s == "")
 704         {
 705                 // no arena
 706         }
 707         else if (s == "off")
 708         {
 709                 // forcibly turn off weaponarena
 710         }
 711         else if (s == "all")
 712         {
 713                 g_weaponarena = 1;
 714                 g_weaponarena_list = "All Weapons";
 715                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 716                 {
 717                         e = get_weaponinfo(j);
 718                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 719                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 720                 }
 721         }
 722         else if (s == "most")
 723         {
 724                 g_weaponarena = 1;
 725                 g_weaponarena_list = "Most Weapons";
 726                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 727                 {
 728                         e = get_weaponinfo(j);
 729                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 730                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 731                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 732                 }
 733         }
 734         else if (s == "none")
 735         {
 736                 g_weaponarena = 1;
 737                 g_weaponarena_list = "No Weapons";
 738         }
 739         else
 740         {
 741                 g_weaponarena = 1;
 742                 t = tokenize_console(s);
 743                 g_weaponarena_list = "";
 744                 for (i = 0; i < t; ++i)
 745                 {
 746                         s = argv(i);
 747                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 748                         {
 749                                 e = get_weaponinfo(j);
 750                                 if (e.netname == s)
 751                                 {
 752                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 753                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 754                                         break;
 755                                 }
 756                         }
 757                         if (j > WEP_LAST)
 758                         {
 759                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 760                         }
 761                 }
 762                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 763         }
 764
 765         if(g_weaponarena)
 766                 g_weaponarena_random = cvar("g_weaponarena_random");
 767         else
 768                 g_weaponarena_random = 0;
 769         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 770
 771         if (g_weaponarena)
 772         {
 773                 g_weapon_stay = 0; // incompatible
 774                 start_weapons = g_weaponarena_weapons;
 775                 start_items |= IT_UNLIMITED_AMMO;
 776         }
 777         else
 778         {
 779                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 780                 {
 781                         e = get_weaponinfo(i);
 782                         float w = want_weapon("g_start_weapon_", e, FALSE);
 783                         if(w & 1)
 784                                 start_weapons |= WepSet_FromWeapon(i);
 785                         if(w & 2)
 786                                 start_weapons_default |= WepSet_FromWeapon(i);
 787                         if(w & 4)
 788                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 789                 }
 790         }
 791
 792         if(!cvar("g_use_ammunition"))
 793                 start_items |= IT_UNLIMITED_AMMO;
 794
 795         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 796         {
 797                 start_ammo_rockets = 999;
 798                 start_ammo_shells = 999;
 799                 start_ammo_cells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_fuel = 999;
 802         }
 803         else
 804         {
 805                 start_ammo_shells = cvar("g_start_ammo_shells");
 806                 start_ammo_nails = cvar("g_start_ammo_nails");
 807                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 808                 start_ammo_cells = cvar("g_start_ammo_cells");
 809                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 810         }
 811
 812         if (warmup_stage)
 813         {
 814                 warmup_start_ammo_shells = start_ammo_shells;
 815                 warmup_start_ammo_nails = start_ammo_nails;
 816                 warmup_start_ammo_rockets = start_ammo_rockets;
 817                 warmup_start_ammo_cells = start_ammo_cells;
 818                 warmup_start_ammo_fuel = start_ammo_fuel;
 819                 warmup_start_health = start_health;
 820                 warmup_start_armorvalue = start_armorvalue;
 821                 warmup_start_weapons = start_weapons;
 822                 warmup_start_weapons_default = start_weapons_default;
 823                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 824
 825                 if (!g_weaponarena && !g_ca)
 826                 {
 827                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 828                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 829                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 830                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 831                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 832                         warmup_start_health = cvar("g_warmup_start_health");
 833                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 834                         warmup_start_weapons = '0 0 0';
 835                         warmup_start_weapons_default = '0 0 0';
 836                         warmup_start_weapons_defaultmask = '0 0 0';
 837                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 838                         {
 839                                 e = get_weaponinfo(i);
 840                                 float w = want_weapon("g_start_weapon_", e, g_warmup_allguns);
 841                                 if(w & 1)
 842                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 843                                 if(w & 2)
 844                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 845                                 if(w & 4)
 846                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 847                         }
 848                 }
 849         }
 850
 851         if (g_jetpack)
 852                 start_items |= IT_JETPACK;
 853
 854         MUTATOR_CALLHOOK(SetStartItems);
 855
 856         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 857         {
 858                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 859                 start_items |= IT_FUEL_REGEN;
 860                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 861                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 862         }
 863
 864         WepSet precache_weapons = start_weapons;
 865         if (g_warmup_allguns != 1)
 866                 precache_weapons |= warmup_start_weapons;
 867         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 868         {
 869                 e = get_weaponinfo(i);
 870                 if(precache_weapons & WepSet_FromWeapon(i))
 871                         weapon_action(i, WR_PRECACHE);
 872         }
 873
 874         start_ammo_shells = max(0, start_ammo_shells);
 875         start_ammo_nails = max(0, start_ammo_nails);
 876         start_ammo_cells = max(0, start_ammo_cells);
 877         start_ammo_rockets = max(0, start_ammo_rockets);
 878         start_ammo_fuel = max(0, start_ammo_fuel);
 879
 880         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 881         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 882         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 883         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 884         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 885 }
 886
 887 float g_bugrigs;
 888 float g_bugrigs_planar_movement;
 889 float g_bugrigs_planar_movement_car_jumping;
 890 float g_bugrigs_reverse_spinning;
 891 float g_bugrigs_reverse_speeding;
 892 float g_bugrigs_reverse_stopping;
 893 float g_bugrigs_air_steering;
 894 float g_bugrigs_angle_smoothing;
 895 float g_bugrigs_friction_floor;
 896 float g_bugrigs_friction_brake;
 897 float g_bugrigs_friction_air;
 898 float g_bugrigs_accel;
 899 float g_bugrigs_speed_ref;
 900 float g_bugrigs_speed_pow;
 901 float g_bugrigs_steer;
 902
 903 float sv_autotaunt;
 904 float sv_taunt;
 905
 906 string GetGametype(); // g_world.qc
 907 void readlevelcvars(void)
 908 {
 909         // load mutators
 910         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 911                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 912
 913         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 914         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, teamplay);
 915         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 916         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 917         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 918         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 919         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 921         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 922         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 923         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 924         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 925         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
 926         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
 927         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
 928         CHECK_MUTATOR_ADD("g_multijump", mutator_multijump, 1);
 929         CHECK_MUTATOR_ADD("g_melee_only", mutator_melee_only, !cvar("g_minstagib"));
 930         CHECK_MUTATOR_ADD("g_nades", mutator_nades, 1);
 931         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 932         CHECK_MUTATOR_ADD("g_campcheck", mutator_campcheck, 1);
 933
 934         #undef CHECK_MUTATOR_ADD
 935
 936         if(cvar("sv_allow_fullbright"))
 937                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 938
 939     g_bugrigs = cvar("g_bugrigs");
 940     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 941     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 942     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 943     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 944     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 945     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 946     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 947     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 948     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 949     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 950     g_bugrigs_accel = cvar("g_bugrigs_accel");
 951     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 952     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 953     g_bugrigs_steer = cvar("g_bugrigs_steer");
 954
 955         g_minstagib = cvar("g_minstagib");
 956
 957         sv_clones = cvar("sv_clones");
 958         sv_foginterval = cvar("sv_foginterval");
 959         g_cloaked = cvar("g_cloaked");
 960         g_footsteps = cvar("g_footsteps");
 961         g_grappling_hook = cvar("g_grappling_hook");
 962         g_jetpack = cvar("g_jetpack");
 963         sv_maxidle = cvar("sv_maxidle");
 964         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 965         sv_autotaunt = cvar("sv_autotaunt");
 966         sv_taunt = cvar("sv_taunt");
 967
 968         warmup_stage = cvar("g_warmup");
 969         g_warmup_limit = cvar("g_warmup_limit");
 970         g_warmup_allguns = cvar("g_warmup_allguns");
 971         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 972
 973         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 974                 warmup_stage = 0; // these modes cannot work together, sorry
 975
 976         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 977         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 978         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 979         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 980         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 981         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 982         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 983         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 984         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 985         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 986         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 987         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 988         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 989         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 990
 991         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 992         g_weaponratefactor = cvar("g_weaponratefactor");
 993         g_weapondamagefactor = cvar("g_weapondamagefactor");
 994         g_weaponforcefactor = cvar("g_weaponforcefactor");
 995         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 996
 997         g_pickup_shells = cvar("g_pickup_shells");
 998         g_pickup_shells_max = cvar("g_pickup_shells_max");
 999         g_pickup_nails = cvar("g_pickup_nails");
1000         g_pickup_nails_max = cvar("g_pickup_nails_max");
1001         g_pickup_rockets = cvar("g_pickup_rockets");
1002         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1003         g_pickup_cells = cvar("g_pickup_cells");
1004         g_pickup_cells_max = cvar("g_pickup_cells_max");
1005         g_pickup_fuel = cvar("g_pickup_fuel");
1006         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1007         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1008         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1009         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1010         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1011         g_pickup_armormedium = cvar("g_pickup_armormedium");
1012         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1013         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1014         g_pickup_armorbig = cvar("g_pickup_armorbig");
1015         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1016         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1017         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1018         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1019         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1020         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1021         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1022         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1023         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1024         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1025         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1026         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1027         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1028         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1029         g_pickup_healthmega = cvar("g_pickup_healthmega");
1030         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1031         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1032
1033         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1034         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1035
1036     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1037     if(!g_weapon_stay)
1038         g_weapon_stay = cvar("g_weapon_stay");
1039
1040         if (!warmup_stage)
1041                 game_starttime = time + cvar("g_start_delay");
1042
1043         readplayerstartcvars();
1044 }
1045
1046 //#NO AUTOCVARS END
1047
1048 // Sound functions
1049 string precache_sound (string s) = #19;
1050 float precache_sound_index (string s) = #19;
1051
1052 #define SND_VOLUME      1
1053 #define SND_ATTENUATION 2
1054 #define SND_LARGEENTITY 8
1055 #define SND_LARGESOUND  16
1056
1057 float sound_allowed(float dest, entity e)
1058 {
1059     // sounds from world may always pass
1060     for (;;)
1061     {
1062         if (e.classname == "body")
1063             e = e.enemy;
1064         else if (e.realowner && e.realowner != e)
1065             e = e.realowner;
1066         else if (e.owner && e.owner != e)
1067             e = e.owner;
1068         else
1069             break;
1070     }
1071     // sounds to self may always pass
1072     if (dest == MSG_ONE)
1073         if (e == msg_entity)
1074             return TRUE;
1075     // sounds by players can be removed
1076     if (autocvar_bot_sound_monopoly)
1077         if (IS_REAL_CLIENT(e))
1078             return FALSE;
1079     // anything else may pass
1080     return TRUE;
1081 }
1082
1083 #ifdef COMPAT_XON010_CHANNELS
1084 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1085 void sound(entity e, float chan, string samp, float vol, float atten)
1086 {
1087     if (!sound_allowed(MSG_BROADCAST, e))
1088         return;
1089     builtin_sound(e, chan, samp, vol, atten);
1090 }
1091 #else
1092 #undef sound
1093 void sound(entity e, float chan, string samp, float vol, float atten)
1094 {
1095     if (!sound_allowed(MSG_BROADCAST, e))
1096         return;
1097     sound7(e, chan, samp, vol, atten, 0, 0);
1098 }
1099 #endif
1100
1101 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1102 {
1103     float entno, idx;
1104
1105     if (!sound_allowed(dest, e))
1106         return;
1107
1108     entno = num_for_edict(e);
1109     idx = precache_sound_index(samp);
1110
1111     float sflags;
1112     sflags = 0;
1113
1114     atten = floor(atten * 64);
1115     vol = floor(vol * 255);
1116
1117     if (vol != 255)
1118         sflags |= SND_VOLUME;
1119     if (atten != 64)
1120         sflags |= SND_ATTENUATION;
1121     if (entno >= 8192 || chan < 0 || chan > 7)
1122         sflags |= SND_LARGEENTITY;
1123     if (idx >= 256)
1124         sflags |= SND_LARGESOUND;
1125
1126     WriteByte(dest, SVC_SOUND);
1127     WriteByte(dest, sflags);
1128     if (sflags & SND_VOLUME)
1129         WriteByte(dest, vol);
1130     if (sflags & SND_ATTENUATION)
1131         WriteByte(dest, atten);
1132     if (sflags & SND_LARGEENTITY)
1133     {
1134         WriteShort(dest, entno);
1135         WriteByte(dest, chan);
1136     }
1137     else
1138     {
1139         WriteShort(dest, entno * 8 + chan);
1140     }
1141     if (sflags & SND_LARGESOUND)
1142         WriteShort(dest, idx);
1143     else
1144         WriteByte(dest, idx);
1145
1146     WriteCoord(dest, o_x);
1147     WriteCoord(dest, o_y);
1148     WriteCoord(dest, o_z);
1149 }
1150 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1151 {
1152     vector o;
1153
1154     if (!sound_allowed(dest, e))
1155         return;
1156
1157     o = e.origin + 0.5 * (e.mins + e.maxs);
1158     soundtoat(dest, e, o, chan, samp, vol, atten);
1159 }
1160 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1161 {
1162     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1163 }
1164 void stopsoundto(float dest, entity e, float chan)
1165 {
1166     float entno;
1167
1168     if (!sound_allowed(dest, e))
1169         return;
1170
1171     entno = num_for_edict(e);
1172
1173     if (entno >= 8192 || chan < 0 || chan > 7)
1174     {
1175         float idx, sflags;
1176         idx = precache_sound_index("misc/null.wav");
1177         sflags = SND_LARGEENTITY;
1178         if (idx >= 256)
1179             sflags |= SND_LARGESOUND;
1180         WriteByte(dest, SVC_SOUND);
1181         WriteByte(dest, sflags);
1182         WriteShort(dest, entno);
1183         WriteByte(dest, chan);
1184         if (sflags & SND_LARGESOUND)
1185             WriteShort(dest, idx);
1186         else
1187             WriteByte(dest, idx);
1188         WriteCoord(dest, e.origin_x);
1189         WriteCoord(dest, e.origin_y);
1190         WriteCoord(dest, e.origin_z);
1191     }
1192     else
1193     {
1194         WriteByte(dest, SVC_STOPSOUND);
1195         WriteShort(dest, entno * 8 + chan);
1196     }
1197 }
1198 void stopsound(entity e, float chan)
1199 {
1200     if (!sound_allowed(MSG_BROADCAST, e))
1201         return;
1202
1203     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1204     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1205 }
1206
1207 void play2(entity e, string filename)
1208 {
1209     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1210     msg_entity = e;
1211     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1212 }
1213
1214 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1215 .float spamtime;
1216 float spamsound(entity e, float chan, string samp, float vol, float atten)
1217 {
1218     if (!sound_allowed(MSG_BROADCAST, e))
1219         return FALSE;
1220
1221     if (time > e.spamtime)
1222     {
1223         e.spamtime = time;
1224         sound(e, chan, samp, vol, atten);
1225         return TRUE;
1226     }
1227     return FALSE;
1228 }
1229
1230 void play2team(float t, string filename)
1231 {
1232     entity head;
1233
1234     if (autocvar_bot_sound_monopoly)
1235         return;
1236
1237     FOR_EACH_REALPLAYER(head)
1238     {
1239         if (head.team == t)
1240             play2(head, filename);
1241     }
1242 }
1243
1244 void play2all(string samp)
1245 {
1246     if (autocvar_bot_sound_monopoly)
1247         return;
1248
1249     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1250 }
1251
1252 void PrecachePlayerSounds(string f);
1253 void precache_playermodel(string m)
1254 {
1255         float globhandle, i, n;
1256         string f;
1257
1258         if(substring(m, -9,5) == "_lod1")
1259                 return;
1260         if(substring(m, -9,5) == "_lod2")
1261                 return;
1262         precache_model(m);
1263         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1264         if(fexists(f))
1265                 precache_model(f);
1266         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1267         if(fexists(f))
1268                 precache_model(f);
1269
1270         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1271         if (globhandle < 0)
1272                 return;
1273         n = search_getsize(globhandle);
1274         for (i = 0; i < n; ++i)
1275         {
1276                 //print(search_getfilename(globhandle, i), "\n");
1277                 f = search_getfilename(globhandle, i);
1278                 PrecachePlayerSounds(f);
1279         }
1280         search_end(globhandle);
1281 }
1282 void precache_all_playermodels(string pattern)
1283 {
1284         float globhandle, i, n;
1285         string f;
1286
1287         globhandle = search_begin(pattern, TRUE, FALSE);
1288         if (globhandle < 0)
1289                 return;
1290         n = search_getsize(globhandle);
1291         for (i = 0; i < n; ++i)
1292         {
1293                 //print(search_getfilename(globhandle, i), "\n");
1294                 f = search_getfilename(globhandle, i);
1295                 precache_playermodel(f);
1296         }
1297         search_end(globhandle);
1298 }
1299
1300 void precache()
1301 {
1302     // gamemode related things
1303     precache_model ("models/misc/chatbubble.spr");
1304
1305 #ifdef TTURRETS_ENABLED
1306     if (autocvar_g_turrets)
1307         turrets_precash();
1308 #endif
1309
1310     // Precache all player models if desired
1311     if (autocvar_sv_precacheplayermodels)
1312     {
1313         PrecachePlayerSounds("sound/player/default.sounds");
1314         precache_all_playermodels("models/player/*.zym");
1315         precache_all_playermodels("models/player/*.dpm");
1316         precache_all_playermodels("models/player/*.md3");
1317         precache_all_playermodels("models/player/*.psk");
1318         precache_all_playermodels("models/player/*.iqm");
1319     }
1320
1321     if (autocvar_sv_defaultcharacter)
1322     {
1323         string s;
1324         s = autocvar_sv_defaultplayermodel_red;
1325         if (s != "")
1326             precache_playermodel(s);
1327         s = autocvar_sv_defaultplayermodel_blue;
1328         if (s != "")
1329             precache_playermodel(s);
1330         s = autocvar_sv_defaultplayermodel_yellow;
1331         if (s != "")
1332             precache_playermodel(s);
1333         s = autocvar_sv_defaultplayermodel_pink;
1334         if (s != "")
1335             precache_playermodel(s);
1336         s = autocvar_sv_defaultplayermodel;
1337         if (s != "")
1338             precache_playermodel(s);
1339     }
1340
1341     if (g_footsteps)
1342     {
1343         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1344         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1345     }
1346
1347     // gore and miscellaneous sounds
1348     //precache_sound ("misc/h2ohit.wav");
1349     precache_model ("models/hook.md3");
1350     precache_sound ("misc/armorimpact.wav");
1351     precache_sound ("misc/bodyimpact1.wav");
1352     precache_sound ("misc/bodyimpact2.wav");
1353     precache_sound ("misc/gib.wav");
1354     precache_sound ("misc/gib_splat01.wav");
1355     precache_sound ("misc/gib_splat02.wav");
1356     precache_sound ("misc/gib_splat03.wav");
1357     precache_sound ("misc/gib_splat04.wav");
1358     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1359     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1360     precache_sound ("misc/null.wav");
1361     precache_sound ("misc/spawn.wav");
1362     precache_sound ("misc/talk.wav");
1363     precache_sound ("misc/teleport.wav");
1364     precache_sound ("misc/poweroff.wav");
1365     precache_sound ("player/lava.wav");
1366     precache_sound ("player/slime.wav");
1367
1368     precache_model ("models/sprites/0.spr32");
1369     precache_model ("models/sprites/1.spr32");
1370     precache_model ("models/sprites/2.spr32");
1371     precache_model ("models/sprites/3.spr32");
1372     precache_model ("models/sprites/4.spr32");
1373     precache_model ("models/sprites/5.spr32");
1374     precache_model ("models/sprites/6.spr32");
1375     precache_model ("models/sprites/7.spr32");
1376     precache_model ("models/sprites/8.spr32");
1377     precache_model ("models/sprites/9.spr32");
1378     precache_model ("models/sprites/10.spr32");
1379
1380     // common weapon precaches
1381         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1382     precache_sound ("weapons/weapon_switch.wav");
1383     precache_sound ("weapons/weaponpickup.wav");
1384     precache_sound ("weapons/unavailable.wav");
1385     precache_sound ("weapons/dryfire.wav");
1386     if (g_grappling_hook)
1387     {
1388         precache_sound ("weapons/hook_fire.wav"); // hook
1389         precache_sound ("weapons/hook_impact.wav"); // hook
1390     }
1391
1392     if(autocvar_sv_precacheweapons)
1393     {
1394         //precache weapon models/sounds
1395         float wep;
1396         wep = WEP_FIRST;
1397         while (wep <= WEP_LAST)
1398         {
1399             weapon_action(wep, WR_PRECACHE);
1400             wep = wep + 1;
1401         }
1402     }
1403
1404     precache_model("models/elaser.mdl");
1405     precache_model("models/laser.mdl");
1406     precache_model("models/ebomb.mdl");
1407
1408 #if 0
1409     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1410
1411     if (!self.noise && self.music) // quake 3 uses the music field
1412         self.noise = self.music;
1413
1414     // plays music for the level if there is any
1415     if (self.noise)
1416     {
1417         precache_sound (self.noise);
1418         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1419     }
1420 #endif
1421
1422 #include "precache-for-csqc.inc"
1423 }
1424
1425 // WARNING: this kills the trace globals
1426 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1427 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1428
1429 #define INITPRIO_FIRST              0
1430 #define INITPRIO_GAMETYPE           0
1431 #define INITPRIO_GAMETYPE_FALLBACK  1
1432 #define INITPRIO_FINDTARGET        10
1433 #define INITPRIO_DROPTOFLOOR       20
1434 #define INITPRIO_SETLOCATION       90
1435 #define INITPRIO_LINKDOORS         91
1436 #define INITPRIO_LAST              99
1437
1438 .void(void) initialize_entity;
1439 .float initialize_entity_order;
1440 .entity initialize_entity_next;
1441 entity initialize_entity_first;
1442
1443 void make_safe_for_remove(entity e)
1444 {
1445     if (e.initialize_entity)
1446     {
1447         entity ent, prev = world;
1448         for (ent = initialize_entity_first; ent; )
1449         {
1450             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1451             {
1452                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1453                 // skip it in linked list
1454                 if (prev)
1455                 {
1456                     prev.initialize_entity_next = ent.initialize_entity_next;
1457                     ent = prev.initialize_entity_next;
1458                 }
1459                 else
1460                 {
1461                     initialize_entity_first = ent.initialize_entity_next;
1462                     ent = initialize_entity_first;
1463                 }
1464             }
1465             else
1466             {
1467                 prev = ent;
1468                 ent = ent.initialize_entity_next;
1469             }
1470         }
1471     }
1472 }
1473
1474 void objerror(string s)
1475 {
1476     make_safe_for_remove(self);
1477     builtin_objerror(s);
1478 }
1479
1480 .float remove_except_protected_forbidden;
1481 void remove_except_protected(entity e)
1482 {
1483         if(e.remove_except_protected_forbidden)
1484                 error("not allowed to remove this at this point");
1485         builtin_remove(e);
1486 }
1487
1488 void remove_unsafely(entity e)
1489 {
1490     if(e.classname == "spike")
1491         error("Removing spikes is forbidden (crylink bug), please report");
1492     builtin_remove(e);
1493 }
1494
1495 void remove_safely(entity e)
1496 {
1497     make_safe_for_remove(e);
1498     builtin_remove(e);
1499 }
1500
1501 void InitializeEntity(entity e, void(void) func, float order)
1502 {
1503     entity prev, cur;
1504
1505     if (!e || e.initialize_entity)
1506     {
1507         // make a proxy initializer entity
1508         entity e_old;
1509         e_old = e;
1510         e = spawn();
1511         e.classname = "initialize_entity";
1512         e.enemy = e_old;
1513     }
1514
1515     e.initialize_entity = func;
1516     e.initialize_entity_order = order;
1517
1518     cur = initialize_entity_first;
1519     prev = world;
1520     for (;;)
1521     {
1522         if (!cur || cur.initialize_entity_order > order)
1523         {
1524             // insert between prev and cur
1525             if (prev)
1526                 prev.initialize_entity_next = e;
1527             else
1528                 initialize_entity_first = e;
1529             e.initialize_entity_next = cur;
1530             return;
1531         }
1532         prev = cur;
1533         cur = cur.initialize_entity_next;
1534     }
1535 }
1536 void InitializeEntitiesRun()
1537 {
1538     entity startoflist;
1539     startoflist = initialize_entity_first;
1540     initialize_entity_first = world;
1541     remove = remove_except_protected;
1542     for (self = startoflist; self; self = self.initialize_entity_next)
1543     {
1544         self.remove_except_protected_forbidden = 1;
1545     }
1546     for (self = startoflist; self; )
1547     {
1548         entity e;
1549         var void(void) func;
1550         e = self.initialize_entity_next;
1551         func = self.initialize_entity;
1552         self.initialize_entity_order = 0;
1553         self.initialize_entity = func_null;
1554         self.initialize_entity_next = world;
1555         self.remove_except_protected_forbidden = 0;
1556         if (self.classname == "initialize_entity")
1557         {
1558             entity e_old;
1559             e_old = self.enemy;
1560             builtin_remove(self);
1561             self = e_old;
1562         }
1563         //dprint("Delayed initialization: ", self.classname, "\n");
1564         if(func)
1565             func();
1566         else
1567         {
1568             eprint(self);
1569             backtrace(strcat("Null function in: ", self.classname, "\n"));
1570         }
1571         self = e;
1572     }
1573     remove = remove_unsafely;
1574 }
1575
1576 .float uncustomizeentityforclient_set;
1577 .void(void) uncustomizeentityforclient;
1578 void UncustomizeEntitiesRun()
1579 {
1580     entity oldself;
1581     oldself = self;
1582     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1583         self.uncustomizeentityforclient();
1584     self = oldself;
1585 }
1586 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1587 {
1588     e.customizeentityforclient = customizer;
1589     e.uncustomizeentityforclient = uncustomizer;
1590     e.uncustomizeentityforclient_set = !!uncustomizer;
1591 }
1592
1593 .float nottargeted;
1594 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1595
1596 void() SUB_Remove;
1597 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1598 {
1599     vector mi, ma;
1600
1601     if (e.classname == "")
1602         e.classname = "net_linked";
1603
1604     if (e.model == "" || self.modelindex == 0)
1605     {
1606         mi = e.mins;
1607         ma = e.maxs;
1608         setmodel(e, "null");
1609         setsize(e, mi, ma);
1610     }
1611
1612     e.SendEntity = sendfunc;
1613     e.SendFlags = 0xFFFFFF;
1614
1615     if (!docull)
1616         e.effects |= EF_NODEPTHTEST;
1617
1618     if (dt)
1619     {
1620         e.nextthink = time + dt;
1621         e.think = SUB_Remove;
1622     }
1623 }
1624
1625 void adaptor_think2touch()
1626 {
1627     entity o;
1628     o = other;
1629     other = world;
1630     self.touch();
1631     other = o;
1632 }
1633
1634 void adaptor_think2use()
1635 {
1636     entity o, a;
1637     o = other;
1638     a = activator;
1639     activator = world;
1640     other = world;
1641     self.use();
1642     other = o;
1643     activator = a;
1644 }
1645
1646 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1647 {
1648         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1649                 self.projectiledeathtype |= HITTYPE_SPLASH;
1650         adaptor_think2use();
1651 }
1652
1653 // deferred dropping
1654 void DropToFloor_Handler()
1655 {
1656     builtin_droptofloor();
1657     self.dropped_origin = self.origin;
1658 }
1659
1660 void droptofloor()
1661 {
1662     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1663 }
1664
1665
1666
1667 float trace_hits_box_a0, trace_hits_box_a1;
1668
1669 float trace_hits_box_1d(float end, float thmi, float thma)
1670 {
1671     if (end == 0)
1672     {
1673         // just check if x is in range
1674         if (0 < thmi)
1675             return FALSE;
1676         if (0 > thma)
1677             return FALSE;
1678     }
1679     else
1680     {
1681         // do the trace with respect to x
1682         // 0 -> end has to stay in thmi -> thma
1683         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1684         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1685         if (trace_hits_box_a0 > trace_hits_box_a1)
1686             return FALSE;
1687     }
1688     return TRUE;
1689 }
1690
1691 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1692 {
1693     end -= start;
1694     thmi -= start;
1695     thma -= start;
1696     // now it is a trace from 0 to end
1697
1698     trace_hits_box_a0 = 0;
1699     trace_hits_box_a1 = 1;
1700
1701     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1702         return FALSE;
1703     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1704         return FALSE;
1705     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1706         return FALSE;
1707
1708     return TRUE;
1709 }
1710
1711 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1712 {
1713     return trace_hits_box(start, end, thmi - ma, thma - mi);
1714 }
1715
1716 float SUB_NoImpactCheck()
1717 {
1718         // zero hitcontents = this is not the real impact, but either the
1719         // mirror-impact of something hitting the projectile instead of the
1720         // projectile hitting the something, or a touchareagrid one. Neither of
1721         // these stop the projectile from moving, so...
1722         if(trace_dphitcontents == 0)
1723         {
1724                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1725                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1726                 checkclient();
1727         }
1728     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1729         return 1;
1730     if (other == world && self.size != '0 0 0')
1731     {
1732         vector tic;
1733         tic = self.velocity * sys_frametime;
1734         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1735         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1736         if (trace_fraction >= 1)
1737         {
1738             dprint("Odd... did not hit...?\n");
1739         }
1740         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1741         {
1742             dprint("Detected and prevented the sky-grapple bug.\n");
1743             return 1;
1744         }
1745     }
1746
1747     return 0;
1748 }
1749
1750 #define SUB_OwnerCheck() (other && (other == self.owner))
1751
1752 void RemoveGrapplingHook(entity pl);
1753 void W_Crylink_Dequeue(entity e);
1754 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1755 {
1756         if(SUB_OwnerCheck())
1757                 return TRUE;
1758         if(SUB_NoImpactCheck())
1759         {
1760                 if(self.classname == "grapplinghook")
1761                         RemoveGrapplingHook(self.realowner);
1762                 else if(self.classname == "spike")
1763                 {
1764                         W_Crylink_Dequeue(self);
1765                         remove(self);
1766                 }
1767                 else
1768                         remove(self);
1769                 return TRUE;
1770         }
1771         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1772                 UpdateCSQCProjectile(self);
1773         return FALSE;
1774 }
1775 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1776
1777 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1778 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1779
1780 void URI_Get_Callback(float id, float status, string data)
1781 {
1782         if(url_URI_Get_Callback(id, status, data))
1783         {
1784                 // handled
1785         }
1786         else if (id == URI_GET_DISCARD)
1787         {
1788                 // discard
1789         }
1790         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1791         {
1792                 // sv_cmd curl
1793                 Curl_URI_Get_Callback(id, status, data);
1794         }
1795         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1796         {
1797                 // online ban list
1798                 OnlineBanList_URI_Get_Callback(id, status, data);
1799         }
1800         else
1801         {
1802                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1803         }
1804 }
1805
1806 string uid2name(string myuid) {
1807         string s;
1808         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1809
1810         // FIXME remove this later after 0.6 release
1811         // convert old style broken records to correct style
1812         if(s == "")
1813         {
1814                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1815                 if(s != "")
1816                 {
1817                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1818                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1819                 }
1820         }
1821
1822         if(s == "")
1823                 s = "^1Unregistered Player";
1824         return s;
1825 }
1826
1827 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1828 {
1829     float m, i;
1830     vector start, org, delta, end, enddown, mstart;
1831     entity sp;
1832
1833     m = e.dphitcontentsmask;
1834     e.dphitcontentsmask = goodcontents | badcontents;
1835
1836     org = world.mins;
1837     delta = world.maxs - world.mins;
1838
1839     start = end = org;
1840
1841     for (i = 0; i < attempts; ++i)
1842     {
1843         start_x = org_x + random() * delta_x;
1844         start_y = org_y + random() * delta_y;
1845         start_z = org_z + random() * delta_z;
1846
1847         // rule 1: start inside world bounds, and outside
1848         // solid, and don't start from somewhere where you can
1849         // fall down to evil
1850         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1851         if (trace_fraction >= 1)
1852             continue;
1853         if (trace_startsolid)
1854             continue;
1855         if (trace_dphitcontents & badcontents)
1856             continue;
1857         if (trace_dphitq3surfaceflags & badsurfaceflags)
1858             continue;
1859
1860         // rule 2: if we are too high, lower the point
1861         if (trace_fraction * delta_z > maxaboveground)
1862             start = trace_endpos + '0 0 1' * maxaboveground;
1863         enddown = trace_endpos;
1864
1865         // rule 3: make sure we aren't outside the map. This only works
1866         // for somewhat well formed maps. A good rule of thumb is that
1867         // the map should have a convex outside hull.
1868         // these can be traceLINES as we already verified the starting box
1869         mstart = start + 0.5 * (e.mins + e.maxs);
1870         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1871         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1872             continue;
1873         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1874         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1875             continue;
1876         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1877         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1878             continue;
1879         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1880         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1881             continue;
1882         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1883         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1884             continue;
1885
1886         // rule 4: we must "see" some spawnpoint or item
1887         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1888                 if(checkpvs(mstart, sp))
1889                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1890                                 break;
1891         if(!sp)
1892         {
1893                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1894                         if(checkpvs(mstart, sp))
1895                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1896                                         break;
1897                 if(!sp)
1898                         continue;
1899         }
1900
1901         // find a random vector to "look at"
1902         end_x = org_x + random() * delta_x;
1903         end_y = org_y + random() * delta_y;
1904         end_z = org_z + random() * delta_z;
1905         end = start + normalize(end - start) * vlen(delta);
1906
1907         // rule 4: start TO end must not be too short
1908         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1909         if (trace_startsolid)
1910             continue;
1911         if (trace_fraction < minviewdistance / vlen(delta))
1912             continue;
1913
1914         // rule 5: don't want to look at sky
1915         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1916             continue;
1917
1918         // rule 6: we must not end up in trigger_hurt
1919         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1920             continue;
1921
1922         break;
1923     }
1924
1925     e.dphitcontentsmask = m;
1926
1927     if (i < attempts)
1928     {
1929         setorigin(e, start);
1930         e.angles = vectoangles(end - start);
1931         dprint("Needed ", ftos(i + 1), " attempts\n");
1932         return TRUE;
1933     }
1934     else
1935         return FALSE;
1936 }
1937
1938 void write_recordmarker(entity pl, float tstart, float dt)
1939 {
1940     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1941
1942     // also write a marker into demo files for demotc-race-record-extractor to find
1943     stuffcmd(pl,
1944              strcat(
1945                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1946                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1947 }
1948
1949 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1950 {
1951         switch(algn)
1952         {
1953                 default:
1954                 case 3: // right
1955                         break;
1956
1957                 case 4: // left
1958                         vecs_y = -vecs_y;
1959                         break;
1960
1961                 case 1:
1962                         if(allowcenter) // 2: allow center handedness
1963                         {
1964                                 // center
1965                                 vecs_y = 0;
1966                                 vecs_z -= 2;
1967                         }
1968                         else
1969                         {
1970                                 // right
1971                         }
1972                         break;
1973
1974                 case 2:
1975                         if(allowcenter) // 2: allow center handedness
1976                         {
1977                                 // center
1978                                 vecs_y = 0;
1979                                 vecs_z -= 2;
1980                         }
1981                         else
1982                         {
1983                                 // left
1984                                 vecs_y = -vecs_y;
1985                         }
1986                         break;
1987         }
1988         return vecs;
1989 }
1990
1991 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1992 {
1993         string s;
1994         vector v;
1995
1996         if (autocvar_g_shootfromeye)
1997         {
1998                 if (visual)
1999                 {
2000                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2001                         else { vecs_y = 0; vecs_z -= 2; }
2002                 }
2003                 else
2004                 {
2005                         vecs_y = 0;
2006                         vecs_z = 0;
2007                 }
2008         }
2009         else if (autocvar_g_shootfromcenter)
2010         {
2011                 vecs_y = 0;
2012                 vecs_z -= 2;
2013         }
2014         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2015         {
2016                 v = stov(s);
2017                 if (y_is_right)
2018                         v_y = -v_y;
2019                 if (v_x != 0)
2020                         vecs_x = v_x;
2021                 vecs_y = v_y;
2022                 vecs_z = v_z;
2023         }
2024         else if (autocvar_g_shootfromclient)
2025         {
2026                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2027         }
2028         return vecs;
2029 }
2030
2031 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2032 {
2033         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2034 }
2035
2036
2037 void attach_sameorigin(entity e, entity to, string tag)
2038 {
2039     vector org, t_forward, t_left, t_up, e_forward, e_up;
2040     float tagscale;
2041
2042     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2043     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2044     t_forward = v_forward * tagscale;
2045     t_left = v_right * -tagscale;
2046     t_up = v_up * tagscale;
2047
2048     e.origin_x = org * t_forward;
2049     e.origin_y = org * t_left;
2050     e.origin_z = org * t_up;
2051
2052     // current forward and up directions
2053     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2054                 e.angles = AnglesTransform_FromVAngles(e.angles);
2055         else
2056                 e.angles = AnglesTransform_FromAngles(e.angles);
2057     fixedmakevectors(e.angles);
2058
2059     // untransform forward, up!
2060     e_forward_x = v_forward * t_forward;
2061     e_forward_y = v_forward * t_left;
2062     e_forward_z = v_forward * t_up;
2063     e_up_x = v_up * t_forward;
2064     e_up_y = v_up * t_left;
2065     e_up_z = v_up * t_up;
2066
2067     e.angles = fixedvectoangles2(e_forward, e_up);
2068     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2069                 e.angles = AnglesTransform_ToVAngles(e.angles);
2070         else
2071                 e.angles = AnglesTransform_ToAngles(e.angles);
2072
2073     setattachment(e, to, tag);
2074     setorigin(e, e.origin);
2075 }
2076
2077 void detach_sameorigin(entity e)
2078 {
2079     vector org;
2080     org = gettaginfo(e, 0);
2081     e.angles = fixedvectoangles2(v_forward, v_up);
2082     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2083                 e.angles = AnglesTransform_ToVAngles(e.angles);
2084         else
2085                 e.angles = AnglesTransform_ToAngles(e.angles);
2086     setorigin(e, org);
2087     setattachment(e, world, "");
2088     setorigin(e, e.origin);
2089 }
2090
2091 void follow_sameorigin(entity e, entity to)
2092 {
2093     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2094     e.aiment = to; // make the hole follow bmodel
2095     e.punchangle = to.angles; // the original angles of bmodel
2096     e.view_ofs = e.origin - to.origin; // relative origin
2097     e.v_angle = e.angles - to.angles; // relative angles
2098 }
2099
2100 void unfollow_sameorigin(entity e)
2101 {
2102     e.movetype = MOVETYPE_NONE;
2103 }
2104
2105 entity gettaginfo_relative_ent;
2106 vector gettaginfo_relative(entity e, float tag)
2107 {
2108     if (!gettaginfo_relative_ent)
2109     {
2110         gettaginfo_relative_ent = spawn();
2111         gettaginfo_relative_ent.effects = EF_NODRAW;
2112     }
2113     gettaginfo_relative_ent.model = e.model;
2114     gettaginfo_relative_ent.modelindex = e.modelindex;
2115     gettaginfo_relative_ent.frame = e.frame;
2116     return gettaginfo(gettaginfo_relative_ent, tag);
2117 }
2118
2119 .float scale2;
2120
2121 float modeleffect_SendEntity(entity to, float sf)
2122 {
2123         float f;
2124         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2125
2126         f = 0;
2127         if(self.velocity != '0 0 0')
2128                 f |= 1;
2129         if(self.angles != '0 0 0')
2130                 f |= 2;
2131         if(self.avelocity != '0 0 0')
2132                 f |= 4;
2133
2134         WriteByte(MSG_ENTITY, f);
2135         WriteShort(MSG_ENTITY, self.modelindex);
2136         WriteByte(MSG_ENTITY, self.skin);
2137         WriteByte(MSG_ENTITY, self.frame);
2138         WriteCoord(MSG_ENTITY, self.origin_x);
2139         WriteCoord(MSG_ENTITY, self.origin_y);
2140         WriteCoord(MSG_ENTITY, self.origin_z);
2141         if(f & 1)
2142         {
2143                 WriteCoord(MSG_ENTITY, self.velocity_x);
2144                 WriteCoord(MSG_ENTITY, self.velocity_y);
2145                 WriteCoord(MSG_ENTITY, self.velocity_z);
2146         }
2147         if(f & 2)
2148         {
2149                 WriteCoord(MSG_ENTITY, self.angles_x);
2150                 WriteCoord(MSG_ENTITY, self.angles_y);
2151                 WriteCoord(MSG_ENTITY, self.angles_z);
2152         }
2153         if(f & 4)
2154         {
2155                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2156                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2157                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2158         }
2159         WriteShort(MSG_ENTITY, self.scale * 256.0);
2160         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2161         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2162         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2163         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2164
2165         return TRUE;
2166 }
2167
2168 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2169 {
2170         entity e;
2171         float sz;
2172         e = spawn();
2173         e.classname = "modeleffect";
2174         setmodel(e, m);
2175         e.frame = f;
2176         setorigin(e, o);
2177         e.velocity = v;
2178         e.angles = ang;
2179         e.avelocity = angv;
2180         e.alpha = a;
2181         e.teleport_time = t1;
2182         e.fade_time = t2;
2183         e.skin = s;
2184         if(s0 >= 0)
2185                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2186         else
2187                 e.scale = -s0;
2188         if(s2 >= 0)
2189                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2190         else
2191                 e.scale2 = -s2;
2192         sz = max(e.scale, e.scale2);
2193         setsize(e, e.mins * sz, e.maxs * sz);
2194         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2195 }
2196
2197 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2198 {
2199         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2200 }
2201
2202 float randombit(float bits)
2203 {
2204         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2205                 return bits;
2206
2207         float n, f, b, r;
2208
2209         r = random();
2210         b = 0;
2211         n = 0;
2212
2213         for(f = 1; f <= bits; f *= 2)
2214         {
2215                 if(bits & f)
2216                 {
2217                         ++n;
2218                         r *= n;
2219                         if(r <= 1)
2220                                 b = f;
2221                         else
2222                                 r = (r - 1) / (n - 1);
2223                 }
2224         }
2225
2226         return b;
2227 }
2228
2229 float randombits(float bits, float k, float error_return)
2230 {
2231         float r;
2232         r = 0;
2233         while(k > 0 && bits != r)
2234         {
2235                 r += randombit(bits - r);
2236                 --k;
2237         }
2238         if(error_return)
2239                 if(k > 0)
2240                         return -1; // all
2241         return r;
2242 }
2243
2244 void randombit_test(float bits, float iter)
2245 {
2246         while(iter > 0)
2247         {
2248                 print(ftos(randombit(bits)), "\n");
2249                 --iter;
2250         }
2251 }
2252
2253 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2254 {
2255         if(halflifedist > 0)
2256                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2257         else if(halflifedist < 0)
2258                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2259         else
2260                 return 1;
2261 }
2262
2263
2264
2265
2266 #ifdef RELEASE
2267 #define cvar_string_normal builtin_cvar_string
2268 #define cvar_normal builtin_cvar
2269 #else
2270 string cvar_string_normal(string n)
2271 {
2272         if (!(cvar_type(n) & 1))
2273                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2274         return builtin_cvar_string(n);
2275 }
2276
2277 float cvar_normal(string n)
2278 {
2279         return stof(cvar_string_normal(n));
2280 }
2281 #endif
2282 #define cvar_set_normal builtin_cvar_set
2283
2284 void defer_think()
2285 {
2286     entity oself;
2287
2288     oself           = self;
2289     self            = self.owner;
2290     oself.think     = SUB_Remove;
2291     oself.nextthink = time;
2292
2293     oself.use();
2294 }
2295
2296 /*
2297     Execute func() after time + fdelay.
2298     self when func is executed = self when defer is called
2299 */
2300 void defer(float fdelay, void() func)
2301 {
2302     entity e;
2303
2304     e           = spawn();
2305     e.owner     = self;
2306     e.use       = func;
2307     e.think     = defer_think;
2308     e.nextthink = time + fdelay;
2309 }
2310
2311 .string aiment_classname;
2312 .float aiment_deadflag;
2313 void SetMovetypeFollow(entity ent, entity e)
2314 {
2315         // FIXME this may not be warpzone aware
2316         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2317         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2318         ent.aiment = e; // make the hole follow bmodel
2319         ent.punchangle = e.angles; // the original angles of bmodel
2320         ent.view_ofs = ent.origin - e.origin; // relative origin
2321         ent.v_angle = ent.angles - e.angles; // relative angles
2322         ent.aiment_classname = strzone(e.classname);
2323         ent.aiment_deadflag = e.deadflag;
2324 }
2325 void UnsetMovetypeFollow(entity ent)
2326 {
2327         ent.movetype = MOVETYPE_FLY;
2328         PROJECTILE_MAKETRIGGER(ent);
2329         ent.aiment = world;
2330 }
2331 float LostMovetypeFollow(entity ent)
2332 {
2333 /*
2334         if(ent.movetype != MOVETYPE_FOLLOW)
2335                 if(ent.aiment)
2336                         error("???");
2337 */
2338         if(ent.aiment)
2339         {
2340                 if(ent.aiment.classname != ent.aiment_classname)
2341                         return 1;
2342                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2343                         return 1;
2344         }
2345         return 0;
2346 }
2347
2348 float isPushable(entity e)
2349 {
2350         if(e.iscreature)
2351                 return TRUE;
2352         if(e.pushable)
2353                 return TRUE;
2354         switch(e.classname)
2355         {
2356                 case "body":
2357                 case "droppedweapon":
2358                 case "keepawayball":
2359                 case "nexball_basketball":
2360                 case "nexball_football":
2361                         return TRUE;
2362                 case "bullet": // antilagged bullets can't hit this either
2363                         return FALSE;
2364         }
2365         if (e.projectiledeathtype)
2366                 return TRUE;
2367         return FALSE;
2368 }