qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 const string STR_PLAYER = "player";
  81 const string STR_SPECTATOR = "spectator";
  82 const string STR_OBSERVER = "observer";
  83
  84 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  85 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  86 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  87 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  88 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  89 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  90 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  91
  92 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  93 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  94 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  95
  96 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  97 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
  98 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
  99
 100 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 const float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = WEP_NAME(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else if (self.items & IT_PLASMA) replacement = "plasma";
 363                         else replacement = "batteries"; // ;)
 364                 } else if (escape == "x") {
 365                         replacement = cursor_ent.netname;
 366                         if (replacement == "" || !cursor_ent)
 367                                 replacement = "nothing";
 368                 } else if (escape == "s")
 369                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 370                 else if (escape == "S")
 371                         replacement = ftos(vlen(self.velocity));
 372
 373                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 374                 p = p + strlen(replacement);
 375         }
 376         return msg;
 377 }
 378
 379 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 380         return (value == 0) ? FALSE : TRUE;
 381 }
 382
 383 /*
 384 =============
 385 GetCvars
 386 =============
 387 Called with:
 388   0:  sends the request
 389   >0: receives a cvar from name=argv(f) value=argv(f+1)
 390 */
 391 void GetCvars_handleString(string thisname, float f, .string field, string name)
 392 {
 393         if (f < 0)
 394         {
 395                 if (self.field)
 396                         strunzone(self.field);
 397                 self.field = string_null;
 398         }
 399         else if (f > 0)
 400         {
 401                 if (thisname == name)
 402                 {
 403                         if (self.field)
 404                                 strunzone(self.field);
 405                         self.field = strzone(argv(f + 1));
 406                 }
 407         }
 408         else
 409                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 410 }
 411 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 412 {
 413         GetCvars_handleString(thisname, f, field, name);
 414         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 415                 if (thisname == name)
 416                 {
 417                         string s;
 418                         s = func(strcat1(self.field));
 419                         if (s != self.field)
 420                         {
 421                                 strunzone(self.field);
 422                                 self.field = strzone(s);
 423                         }
 424                 }
 425 }
 426 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 427 {
 428         if (f < 0)
 429         {
 430         }
 431         else if (f > 0)
 432         {
 433                 if (thisname == name)
 434                         self.field = stof(argv(f + 1));
 435         }
 436         else
 437                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 438 }
 439 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 440 {
 441         if (f < 0)
 442         {
 443         }
 444         else if (f > 0)
 445         {
 446                 if (thisname == name)
 447                 {
 448                         if(!self.field)
 449                         {
 450                                 self.field = stof(argv(f + 1));
 451                                 if(!self.field)
 452                                         self.field = -1;
 453                         }
 454                 }
 455         }
 456         else
 457         {
 458                 if(!self.field)
 459                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 460         }
 461 }
 462 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 463 {
 464         string o;
 465         o = W_FixWeaponOrder_ForceComplete(wo);
 466         if(self.weaponorder_byimpulse)
 467         {
 468                 strunzone(self.weaponorder_byimpulse);
 469                 self.weaponorder_byimpulse = string_null;
 470         }
 471         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 472         return o;
 473 }
 474 void GetCvars(float f)
 475 {
 476         string s = string_null;
 477
 478         if (f > 0)
 479                 s = strcat1(argv(f));
 480
 481         get_cvars_f = f;
 482         get_cvars_s = s;
 483
 484         MUTATOR_CALLHOOK(GetCvars);
 485
 486         Notification_GetCvars();
 487
 488         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 489         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 490         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 491         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 492         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 493         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 506         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 507         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 508         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 510         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 512
 513         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 514         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 515
 516         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 517         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 519         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 520         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 521
 522         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 523         if (f > 0)
 524         {
 525                 if (s == "cl_weaponpriority")
 526                         self.switchweapon = w_getbestweapon(self);
 527                 if (s == "cl_allow_uidtracking")
 528                         PlayerStats_GameReport_AddPlayer(self);
 529         }
 530 }
 531
 532 // decolorizes and team colors the player name when needed
 533 string playername(entity p)
 534 {
 535     string t;
 536     if (teamplay && !intermission_running && IS_PLAYER(p))
 537     {
 538         t = Team_ColorCode(p.team);
 539         return strcat(t, strdecolorize(p.netname));
 540     }
 541     else
 542         return p.netname;
 543 }
 544
 545 vector randompos(vector m1, vector m2)
 546 {
 547     vector v;
 548     m2 = m2 - m1;
 549     v_x = m2_x * random() + m1_x;
 550     v_y = m2_y * random() + m1_y;
 551     v_z = m2_z * random() + m1_z;
 552     return  v;
 553 }
 554
 555 //#NO AUTOCVARS START
 556
 557 float g_pickup_shells;
 558 float g_pickup_shells_max;
 559 float g_pickup_nails;
 560 float g_pickup_nails_max;
 561 float g_pickup_rockets;
 562 float g_pickup_rockets_max;
 563 float g_pickup_cells;
 564 float g_pickup_cells_max;
 565 float g_pickup_plasma;
 566 float g_pickup_plasma_max;
 567 float g_pickup_fuel;
 568 float g_pickup_fuel_jetpack;
 569 float g_pickup_fuel_max;
 570 float g_pickup_armorsmall;
 571 float g_pickup_armorsmall_max;
 572 float g_pickup_armorsmall_anyway;
 573 float g_pickup_armormedium;
 574 float g_pickup_armormedium_max;
 575 float g_pickup_armormedium_anyway;
 576 float g_pickup_armorbig;
 577 float g_pickup_armorbig_max;
 578 float g_pickup_armorbig_anyway;
 579 float g_pickup_armorlarge;
 580 float g_pickup_armorlarge_max;
 581 float g_pickup_armorlarge_anyway;
 582 float g_pickup_healthsmall;
 583 float g_pickup_healthsmall_max;
 584 float g_pickup_healthsmall_anyway;
 585 float g_pickup_healthmedium;
 586 float g_pickup_healthmedium_max;
 587 float g_pickup_healthmedium_anyway;
 588 float g_pickup_healthlarge;
 589 float g_pickup_healthlarge_max;
 590 float g_pickup_healthlarge_anyway;
 591 float g_pickup_healthmega;
 592 float g_pickup_healthmega_max;
 593 float g_pickup_healthmega_anyway;
 594 float g_pickup_ammo_anyway;
 595 float g_pickup_weapons_anyway;
 596 float g_weaponarena;
 597 WepSet g_weaponarena_weapons;
 598 float g_weaponarena_random;
 599 float g_weaponarena_random_with_blaster;
 600 string g_weaponarena_list;
 601 float g_weaponspeedfactor;
 602 float g_weaponratefactor;
 603 float g_weapondamagefactor;
 604 float g_weaponforcefactor;
 605 float g_weaponspreadfactor;
 606
 607 WepSet start_weapons;
 608 WepSet start_weapons_default;
 609 WepSet start_weapons_defaultmask;
 610 float start_items;
 611 float start_ammo_shells;
 612 float start_ammo_nails;
 613 float start_ammo_rockets;
 614 float start_ammo_cells;
 615 float start_ammo_plasma;
 616 float start_ammo_fuel;
 617 float start_health;
 618 float start_armorvalue;
 619 WepSet warmup_start_weapons;
 620 WepSet warmup_start_weapons_default;
 621 WepSet warmup_start_weapons_defaultmask;
 622 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 623 float warmup_start_ammo_shells;
 624 float warmup_start_ammo_nails;
 625 float warmup_start_ammo_rockets;
 626 float warmup_start_ammo_cells;
 627 float warmup_start_ammo_plasma;
 628 float warmup_start_ammo_fuel;
 629 float warmup_start_health;
 630 float warmup_start_armorvalue;
 631 float g_weapon_stay;
 632
 633 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 634 {
 635         var float i = weaponinfo.weapon;
 636         var float d = 0;
 637
 638         if (!i)
 639                 return 0;
 640
 641         if (g_lms || g_ca || allguns)
 642         {
 643                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 644                         d = TRUE;
 645                 else
 646                         d = FALSE;
 647         }
 648         else if (g_cts)
 649                 d = (i == WEP_SHOTGUN);
 650         else if (g_nexball)
 651                 d = 0; // weapon is set a few lines later
 652         else
 653                 d = !(!weaponinfo.weaponstart);
 654
 655         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 656                 d |= (i == WEP_HOOK);
 657         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 658                 d = 0;
 659
 660         var float t = weaponinfo.weaponstartoverride;
 661
 662         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 663
 664         // bit order in t:
 665         // 1: want or not
 666         // 2: is default?
 667         // 4: is set by default?
 668         if(t < 0)
 669                 t = 4 | (3 * d);
 670         else
 671                 t |= (2 * d);
 672
 673         return t;
 674 }
 675
 676 void readplayerstartcvars()
 677 {
 678         entity e;
 679         float i, j, t;
 680         string s;
 681
 682         // initialize starting values for players
 683         start_weapons = '0 0 0';
 684         start_weapons_default = '0 0 0';
 685         start_weapons_defaultmask = '0 0 0';
 686         start_items = 0;
 687         start_ammo_shells = 0;
 688         start_ammo_nails = 0;
 689         start_ammo_rockets = 0;
 690         start_ammo_cells = 0;
 691         start_ammo_plasma = 0;
 692         start_health = cvar("g_balance_health_start");
 693         start_armorvalue = cvar("g_balance_armor_start");
 694
 695         g_weaponarena = 0;
 696         g_weaponarena_weapons = '0 0 0';
 697
 698         s = cvar_string("g_weaponarena");
 699         if (s == "0" || s == "")
 700         {
 701                 if(g_ca)
 702                         s = "most";
 703         }
 704
 705         if (s == "0" || s == "")
 706         {
 707                 // no arena
 708         }
 709         else if (s == "off")
 710         {
 711                 // forcibly turn off weaponarena
 712         }
 713         else if (s == "all" || s == "1")
 714         {
 715                 g_weaponarena = 1;
 716                 g_weaponarena_list = "All Weapons";
 717                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 718                 {
 719                         e = get_weaponinfo(j);
 720                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 721                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 722                 }
 723         }
 724         else if (s == "most")
 725         {
 726                 g_weaponarena = 1;
 727                 g_weaponarena_list = "Most Weapons";
 728                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 729                 {
 730                         e = get_weaponinfo(j);
 731                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 732                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 733                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 734                 }
 735         }
 736         else if (s == "none")
 737         {
 738                 g_weaponarena = 1;
 739                 g_weaponarena_list = "No Weapons";
 740         }
 741         else
 742         {
 743                 g_weaponarena = 1;
 744                 t = tokenize_console(s);
 745                 g_weaponarena_list = "";
 746                 for (i = 0; i < t; ++i)
 747                 {
 748                         s = argv(i);
 749                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 750                         {
 751                                 e = get_weaponinfo(j);
 752                                 if (e.netname == s)
 753                                 {
 754                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 755                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 756                                         break;
 757                                 }
 758                         }
 759                         if (j > WEP_LAST)
 760                         {
 761                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 762                         }
 763                 }
 764                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 765         }
 766
 767         if(g_weaponarena)
 768                 g_weaponarena_random = cvar("g_weaponarena_random");
 769         else
 770                 g_weaponarena_random = 0;
 771         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 772
 773         if (g_weaponarena)
 774         {
 775                 g_weapon_stay = 0; // incompatible
 776                 start_weapons = g_weaponarena_weapons;
 777                 start_items |= IT_UNLIMITED_AMMO;
 778         }
 779         else
 780         {
 781                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 782                 {
 783                         e = get_weaponinfo(i);
 784                         float w = want_weapon(e, FALSE);
 785                         if(w & 1)
 786                                 start_weapons |= WepSet_FromWeapon(i);
 787                         if(w & 2)
 788                                 start_weapons_default |= WepSet_FromWeapon(i);
 789                         if(w & 4)
 790                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 791                 }
 792         }
 793
 794         if(!cvar("g_use_ammunition"))
 795                 start_items |= IT_UNLIMITED_AMMO;
 796
 797         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 798         {
 799                 start_ammo_shells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_rockets = 999;
 802                 start_ammo_cells = 999;
 803                 start_ammo_plasma = 999;
 804                 start_ammo_fuel = 999;
 805         }
 806         else
 807         {
 808                 start_ammo_shells = cvar("g_start_ammo_shells");
 809                 start_ammo_nails = cvar("g_start_ammo_nails");
 810                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 811                 start_ammo_cells = cvar("g_start_ammo_cells");
 812                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 813                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 814         }
 815
 816         if (warmup_stage)
 817         {
 818                 warmup_start_ammo_shells = start_ammo_shells;
 819                 warmup_start_ammo_nails = start_ammo_nails;
 820                 warmup_start_ammo_rockets = start_ammo_rockets;
 821                 warmup_start_ammo_cells = start_ammo_cells;
 822                 warmup_start_ammo_plasma = start_ammo_plasma;
 823                 warmup_start_ammo_fuel = start_ammo_fuel;
 824                 warmup_start_health = start_health;
 825                 warmup_start_armorvalue = start_armorvalue;
 826                 warmup_start_weapons = start_weapons;
 827                 warmup_start_weapons_default = start_weapons_default;
 828                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 829
 830                 if (!g_weaponarena && !g_ca)
 831                 {
 832                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 833                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 834                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 835                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 836                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 837                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 838                         warmup_start_health = cvar("g_warmup_start_health");
 839                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 840                         warmup_start_weapons = '0 0 0';
 841                         warmup_start_weapons_default = '0 0 0';
 842                         warmup_start_weapons_defaultmask = '0 0 0';
 843                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 844                         {
 845                                 e = get_weaponinfo(i);
 846                                 float w = want_weapon(e, g_warmup_allguns);
 847                                 if(w & 1)
 848                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 849                                 if(w & 2)
 850                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 851                                 if(w & 4)
 852                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 853                         }
 854                 }
 855         }
 856
 857         if (g_jetpack)
 858                 start_items |= IT_JETPACK;
 859
 860         MUTATOR_CALLHOOK(SetStartItems);
 861
 862         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 863         {
 864                 start_items |= IT_FUEL_REGEN;
 865                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 866                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 867         }
 868
 869         WepSet precache_weapons = start_weapons;
 870         if (g_warmup_allguns != 1)
 871                 precache_weapons |= warmup_start_weapons;
 872         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 873         {
 874                 e = get_weaponinfo(i);
 875                 if(precache_weapons & WepSet_FromWeapon(i))
 876                         WEP_ACTION(i, WR_INIT);
 877         }
 878
 879         start_ammo_shells = max(0, start_ammo_shells);
 880         start_ammo_nails = max(0, start_ammo_nails);
 881         start_ammo_rockets = max(0, start_ammo_rockets);
 882         start_ammo_cells = max(0, start_ammo_cells);
 883         start_ammo_plasma = max(0, start_ammo_plasma);
 884         start_ammo_fuel = max(0, start_ammo_fuel);
 885
 886         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 887         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 888         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 889         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 890         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 891         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 892 }
 893
 894 float g_bugrigs;
 895 float g_bugrigs_planar_movement;
 896 float g_bugrigs_planar_movement_car_jumping;
 897 float g_bugrigs_reverse_spinning;
 898 float g_bugrigs_reverse_speeding;
 899 float g_bugrigs_reverse_stopping;
 900 float g_bugrigs_air_steering;
 901 float g_bugrigs_angle_smoothing;
 902 float g_bugrigs_friction_floor;
 903 float g_bugrigs_friction_brake;
 904 float g_bugrigs_friction_air;
 905 float g_bugrigs_accel;
 906 float g_bugrigs_speed_ref;
 907 float g_bugrigs_speed_pow;
 908 float g_bugrigs_steer;
 909
 910 float sv_autotaunt;
 911 float sv_taunt;
 912
 913 string GetGametype(); // g_world.qc
 914 void mutators_add(); // mutators.qc
 915 void readlevelcvars(void)
 916 {
 917         // load mutators
 918         mutators_add();
 919
 920         if(cvar("sv_allow_fullbright"))
 921                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 922
 923     g_bugrigs = cvar("g_bugrigs");
 924     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 925     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 926     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 927     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 928     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 929     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 930     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 931     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 932     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 933     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 934     g_bugrigs_accel = cvar("g_bugrigs_accel");
 935     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 936     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 937     g_bugrigs_steer = cvar("g_bugrigs_steer");
 938
 939         g_instagib = cvar("g_instagib");
 940
 941         sv_clones = cvar("sv_clones");
 942         sv_foginterval = cvar("sv_foginterval");
 943         g_cloaked = cvar("g_cloaked");
 944         g_footsteps = cvar("g_footsteps");
 945         g_grappling_hook = cvar("g_grappling_hook");
 946         g_jetpack = cvar("g_jetpack");
 947         sv_maxidle = cvar("sv_maxidle");
 948         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 949         sv_autotaunt = cvar("sv_autotaunt");
 950         sv_taunt = cvar("sv_taunt");
 951
 952         warmup_stage = cvar("g_warmup");
 953         g_warmup_limit = cvar("g_warmup_limit");
 954         g_warmup_allguns = cvar("g_warmup_allguns");
 955         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 956
 957         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 958                 warmup_stage = 0; // these modes cannot work together, sorry
 959
 960         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 961         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 962         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 963         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 964         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 965         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 966         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 967         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 968         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 969         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 970         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 971         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 972         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 973         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 974
 975         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 976         g_weaponratefactor = cvar("g_weaponratefactor");
 977         g_weapondamagefactor = cvar("g_weapondamagefactor");
 978         g_weaponforcefactor = cvar("g_weaponforcefactor");
 979         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 980
 981         g_pickup_shells = cvar("g_pickup_shells");
 982         g_pickup_shells_max = cvar("g_pickup_shells_max");
 983         g_pickup_nails = cvar("g_pickup_nails");
 984         g_pickup_nails_max = cvar("g_pickup_nails_max");
 985         g_pickup_rockets = cvar("g_pickup_rockets");
 986         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 987         g_pickup_cells = cvar("g_pickup_cells");
 988         g_pickup_cells_max = cvar("g_pickup_cells_max");
 989         g_pickup_plasma = cvar("g_pickup_plasma");
 990         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
 991         g_pickup_fuel = cvar("g_pickup_fuel");
 992         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 993         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
 994         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
 995         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
 996         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
 997         g_pickup_armormedium = cvar("g_pickup_armormedium");
 998         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
 999         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1000         g_pickup_armorbig = cvar("g_pickup_armorbig");
1001         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1002         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1003         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1004         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1005         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1006         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1007         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1008         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1009         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1010         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1011         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1012         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1013         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1014         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1015         g_pickup_healthmega = cvar("g_pickup_healthmega");
1016         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1017         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1018
1019         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1020         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1021
1022     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1023     if(!g_weapon_stay)
1024         g_weapon_stay = cvar("g_weapon_stay");
1025
1026         if (!warmup_stage)
1027                 game_starttime = time + cvar("g_start_delay");
1028
1029         float i;
1030         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1031                 WEP_ACTION(i, WR_INIT);
1032
1033         readplayerstartcvars();
1034 }
1035
1036 //#NO AUTOCVARS END
1037
1038 // Sound functions
1039 string precache_sound (string s) = #19;
1040 float precache_sound_index (string s) = #19;
1041
1042 #define SND_VOLUME      1
1043 #define SND_ATTENUATION 2
1044 #define SND_LARGEENTITY 8
1045 #define SND_LARGESOUND  16
1046
1047 float sound_allowed(float dest, entity e)
1048 {
1049     // sounds from world may always pass
1050     for (;;)
1051     {
1052         if (e.classname == "body")
1053             e = e.enemy;
1054         else if (e.realowner && e.realowner != e)
1055             e = e.realowner;
1056         else if (e.owner && e.owner != e)
1057             e = e.owner;
1058         else
1059             break;
1060     }
1061     // sounds to self may always pass
1062     if (dest == MSG_ONE)
1063         if (e == msg_entity)
1064             return TRUE;
1065     // sounds by players can be removed
1066     if (autocvar_bot_sound_monopoly)
1067         if (IS_REAL_CLIENT(e))
1068             return FALSE;
1069     // anything else may pass
1070     return TRUE;
1071 }
1072
1073 #undef sound
1074 void sound(entity e, float chan, string samp, float vol, float atten)
1075 {
1076     if (!sound_allowed(MSG_BROADCAST, e))
1077         return;
1078     sound7(e, chan, samp, vol, atten, 0, 0);
1079 }
1080
1081 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1082 {
1083     float entno, idx;
1084
1085     if (!sound_allowed(dest, e))
1086         return;
1087
1088     entno = num_for_edict(e);
1089     idx = precache_sound_index(samp);
1090
1091     float sflags;
1092     sflags = 0;
1093
1094     atten = floor(atten * 64);
1095     vol = floor(vol * 255);
1096
1097     if (vol != 255)
1098         sflags |= SND_VOLUME;
1099     if (atten != 64)
1100         sflags |= SND_ATTENUATION;
1101     if (entno >= 8192 || chan < 0 || chan > 7)
1102         sflags |= SND_LARGEENTITY;
1103     if (idx >= 256)
1104         sflags |= SND_LARGESOUND;
1105
1106     WriteByte(dest, SVC_SOUND);
1107     WriteByte(dest, sflags);
1108     if (sflags & SND_VOLUME)
1109         WriteByte(dest, vol);
1110     if (sflags & SND_ATTENUATION)
1111         WriteByte(dest, atten);
1112     if (sflags & SND_LARGEENTITY)
1113     {
1114         WriteShort(dest, entno);
1115         WriteByte(dest, chan);
1116     }
1117     else
1118     {
1119         WriteShort(dest, entno * 8 + chan);
1120     }
1121     if (sflags & SND_LARGESOUND)
1122         WriteShort(dest, idx);
1123     else
1124         WriteByte(dest, idx);
1125
1126     WriteCoord(dest, o_x);
1127     WriteCoord(dest, o_y);
1128     WriteCoord(dest, o_z);
1129 }
1130 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1131 {
1132     vector o;
1133
1134     if (!sound_allowed(dest, e))
1135         return;
1136
1137     o = e.origin + 0.5 * (e.mins + e.maxs);
1138     soundtoat(dest, e, o, chan, samp, vol, atten);
1139 }
1140 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1141 {
1142     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1143 }
1144 void stopsoundto(float dest, entity e, float chan)
1145 {
1146     float entno;
1147
1148     if (!sound_allowed(dest, e))
1149         return;
1150
1151     entno = num_for_edict(e);
1152
1153     if (entno >= 8192 || chan < 0 || chan > 7)
1154     {
1155         float idx, sflags;
1156         idx = precache_sound_index("misc/null.wav");
1157         sflags = SND_LARGEENTITY;
1158         if (idx >= 256)
1159             sflags |= SND_LARGESOUND;
1160         WriteByte(dest, SVC_SOUND);
1161         WriteByte(dest, sflags);
1162         WriteShort(dest, entno);
1163         WriteByte(dest, chan);
1164         if (sflags & SND_LARGESOUND)
1165             WriteShort(dest, idx);
1166         else
1167             WriteByte(dest, idx);
1168         WriteCoord(dest, e.origin_x);
1169         WriteCoord(dest, e.origin_y);
1170         WriteCoord(dest, e.origin_z);
1171     }
1172     else
1173     {
1174         WriteByte(dest, SVC_STOPSOUND);
1175         WriteShort(dest, entno * 8 + chan);
1176     }
1177 }
1178 void stopsound(entity e, float chan)
1179 {
1180     if (!sound_allowed(MSG_BROADCAST, e))
1181         return;
1182
1183     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1184     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1185 }
1186
1187 void play2(entity e, string filename)
1188 {
1189     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1190     msg_entity = e;
1191     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1192 }
1193
1194 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1195 .float spamtime;
1196 float spamsound(entity e, float chan, string samp, float vol, float atten)
1197 {
1198     if (!sound_allowed(MSG_BROADCAST, e))
1199         return FALSE;
1200
1201     if (time > e.spamtime)
1202     {
1203         e.spamtime = time;
1204         sound(e, chan, samp, vol, atten);
1205         return TRUE;
1206     }
1207     return FALSE;
1208 }
1209
1210 void play2team(float t, string filename)
1211 {
1212     entity head;
1213
1214     if (autocvar_bot_sound_monopoly)
1215         return;
1216
1217     FOR_EACH_REALPLAYER(head)
1218     {
1219         if (head.team == t)
1220             play2(head, filename);
1221     }
1222 }
1223
1224 void play2all(string samp)
1225 {
1226     if (autocvar_bot_sound_monopoly)
1227         return;
1228
1229     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1230 }
1231
1232 void PrecachePlayerSounds(string f);
1233 void precache_playermodel(string m)
1234 {
1235         float globhandle, i, n;
1236         string f;
1237
1238         if(substring(m, -9,5) == "_lod1")
1239                 return;
1240         if(substring(m, -9,5) == "_lod2")
1241                 return;
1242         precache_model(m);
1243         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1244         if(fexists(f))
1245                 precache_model(f);
1246         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1247         if(fexists(f))
1248                 precache_model(f);
1249
1250         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1251         if (globhandle < 0)
1252                 return;
1253         n = search_getsize(globhandle);
1254         for (i = 0; i < n; ++i)
1255         {
1256                 //print(search_getfilename(globhandle, i), "\n");
1257                 f = search_getfilename(globhandle, i);
1258                 PrecachePlayerSounds(f);
1259         }
1260         search_end(globhandle);
1261 }
1262 void precache_all_playermodels(string pattern)
1263 {
1264         float globhandle, i, n;
1265         string f;
1266
1267         globhandle = search_begin(pattern, TRUE, FALSE);
1268         if (globhandle < 0)
1269                 return;
1270         n = search_getsize(globhandle);
1271         for (i = 0; i < n; ++i)
1272         {
1273                 //print(search_getfilename(globhandle, i), "\n");
1274                 f = search_getfilename(globhandle, i);
1275                 precache_playermodel(f);
1276         }
1277         search_end(globhandle);
1278 }
1279
1280 void precache()
1281 {
1282     // gamemode related things
1283     precache_model ("models/misc/chatbubble.spr");
1284         precache_model("models/ice/ice.md3");
1285
1286 #ifdef TTURRETS_ENABLED
1287     if (autocvar_g_turrets)
1288         turrets_precash();
1289 #endif
1290
1291     // Precache all player models if desired
1292     if (autocvar_sv_precacheplayermodels)
1293     {
1294         PrecachePlayerSounds("sound/player/default.sounds");
1295         precache_all_playermodels("models/player/*.zym");
1296         precache_all_playermodels("models/player/*.dpm");
1297         precache_all_playermodels("models/player/*.md3");
1298         precache_all_playermodels("models/player/*.psk");
1299         precache_all_playermodels("models/player/*.iqm");
1300     }
1301
1302     if (autocvar_sv_defaultcharacter)
1303     {
1304         string s;
1305         s = autocvar_sv_defaultplayermodel_red;
1306         if (s != "")
1307             precache_playermodel(s);
1308         s = autocvar_sv_defaultplayermodel_blue;
1309         if (s != "")
1310             precache_playermodel(s);
1311         s = autocvar_sv_defaultplayermodel_yellow;
1312         if (s != "")
1313             precache_playermodel(s);
1314         s = autocvar_sv_defaultplayermodel_pink;
1315         if (s != "")
1316             precache_playermodel(s);
1317         s = autocvar_sv_defaultplayermodel;
1318         if (s != "")
1319             precache_playermodel(s);
1320     }
1321
1322     if (g_footsteps)
1323     {
1324         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1325         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1326     }
1327
1328     // gore and miscellaneous sounds
1329     //precache_sound ("misc/h2ohit.wav");
1330     precache_model ("models/hook.md3");
1331     precache_sound ("misc/armorimpact.wav");
1332     precache_sound ("misc/bodyimpact1.wav");
1333     precache_sound ("misc/bodyimpact2.wav");
1334     precache_sound ("misc/gib.wav");
1335     precache_sound ("misc/gib_splat01.wav");
1336     precache_sound ("misc/gib_splat02.wav");
1337     precache_sound ("misc/gib_splat03.wav");
1338     precache_sound ("misc/gib_splat04.wav");
1339     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1340     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1341     precache_sound ("misc/null.wav");
1342     precache_sound ("misc/spawn.wav");
1343     precache_sound ("misc/talk.wav");
1344     precache_sound ("misc/teleport.wav");
1345     precache_sound ("misc/poweroff.wav");
1346     precache_sound ("player/lava.wav");
1347     precache_sound ("player/slime.wav");
1348
1349     precache_model ("models/sprites/0.spr32");
1350     precache_model ("models/sprites/1.spr32");
1351     precache_model ("models/sprites/2.spr32");
1352     precache_model ("models/sprites/3.spr32");
1353     precache_model ("models/sprites/4.spr32");
1354     precache_model ("models/sprites/5.spr32");
1355     precache_model ("models/sprites/6.spr32");
1356     precache_model ("models/sprites/7.spr32");
1357     precache_model ("models/sprites/8.spr32");
1358     precache_model ("models/sprites/9.spr32");
1359     precache_model ("models/sprites/10.spr32");
1360
1361     // common weapon precaches
1362         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1363     precache_sound ("weapons/weapon_switch.wav");
1364     precache_sound ("weapons/weaponpickup.wav");
1365     precache_sound ("weapons/unavailable.wav");
1366     precache_sound ("weapons/dryfire.wav");
1367     if (g_grappling_hook)
1368     {
1369         precache_sound ("weapons/hook_fire.wav"); // hook
1370         precache_sound ("weapons/hook_impact.wav"); // hook
1371     }
1372
1373     precache_model("models/elaser.mdl");
1374     precache_model("models/laser.mdl");
1375     precache_model("models/ebomb.mdl");
1376
1377 #if 0
1378     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1379
1380     if (!self.noise && self.music) // quake 3 uses the music field
1381         self.noise = self.music;
1382
1383     // plays music for the level if there is any
1384     if (self.noise)
1385     {
1386         precache_sound (self.noise);
1387         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1388     }
1389 #endif
1390
1391 #include "precache-for-csqc.inc"
1392 }
1393
1394 // WARNING: this kills the trace globals
1395 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1396 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1397
1398 #define INITPRIO_FIRST              0
1399 #define INITPRIO_GAMETYPE           0
1400 #define INITPRIO_GAMETYPE_FALLBACK  1
1401 #define INITPRIO_FINDTARGET        10
1402 #define INITPRIO_DROPTOFLOOR       20
1403 #define INITPRIO_SETLOCATION       90
1404 #define INITPRIO_LINKDOORS         91
1405 #define INITPRIO_LAST              99
1406
1407 .void(void) initialize_entity;
1408 .float initialize_entity_order;
1409 .entity initialize_entity_next;
1410 entity initialize_entity_first;
1411
1412 void make_safe_for_remove(entity e)
1413 {
1414     if (e.initialize_entity)
1415     {
1416         entity ent, prev = world;
1417         for (ent = initialize_entity_first; ent; )
1418         {
1419             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1420             {
1421                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1422                 // skip it in linked list
1423                 if (prev)
1424                 {
1425                     prev.initialize_entity_next = ent.initialize_entity_next;
1426                     ent = prev.initialize_entity_next;
1427                 }
1428                 else
1429                 {
1430                     initialize_entity_first = ent.initialize_entity_next;
1431                     ent = initialize_entity_first;
1432                 }
1433             }
1434             else
1435             {
1436                 prev = ent;
1437                 ent = ent.initialize_entity_next;
1438             }
1439         }
1440     }
1441 }
1442
1443 void objerror(string s)
1444 {
1445     make_safe_for_remove(self);
1446     builtin_objerror(s);
1447 }
1448
1449 .float remove_except_protected_forbidden;
1450 void remove_except_protected(entity e)
1451 {
1452         if(e.remove_except_protected_forbidden)
1453                 error("not allowed to remove this at this point");
1454         builtin_remove(e);
1455 }
1456
1457 void remove_unsafely(entity e)
1458 {
1459     if(e.classname == "spike")
1460         error("Removing spikes is forbidden (crylink bug), please report");
1461     builtin_remove(e);
1462 }
1463
1464 void remove_safely(entity e)
1465 {
1466     make_safe_for_remove(e);
1467     builtin_remove(e);
1468 }
1469
1470 void InitializeEntity(entity e, void(void) func, float order)
1471 {
1472     entity prev, cur;
1473
1474     if (!e || e.initialize_entity)
1475     {
1476         // make a proxy initializer entity
1477         entity e_old;
1478         e_old = e;
1479         e = spawn();
1480         e.classname = "initialize_entity";
1481         e.enemy = e_old;
1482     }
1483
1484     e.initialize_entity = func;
1485     e.initialize_entity_order = order;
1486
1487     cur = initialize_entity_first;
1488     prev = world;
1489     for (;;)
1490     {
1491         if (!cur || cur.initialize_entity_order > order)
1492         {
1493             // insert between prev and cur
1494             if (prev)
1495                 prev.initialize_entity_next = e;
1496             else
1497                 initialize_entity_first = e;
1498             e.initialize_entity_next = cur;
1499             return;
1500         }
1501         prev = cur;
1502         cur = cur.initialize_entity_next;
1503     }
1504 }
1505 void InitializeEntitiesRun()
1506 {
1507     entity startoflist;
1508     startoflist = initialize_entity_first;
1509     initialize_entity_first = world;
1510     remove = remove_except_protected;
1511     for (self = startoflist; self; self = self.initialize_entity_next)
1512     {
1513         self.remove_except_protected_forbidden = 1;
1514     }
1515     for (self = startoflist; self; )
1516     {
1517         entity e;
1518         var void(void) func;
1519         e = self.initialize_entity_next;
1520         func = self.initialize_entity;
1521         self.initialize_entity_order = 0;
1522         self.initialize_entity = func_null;
1523         self.initialize_entity_next = world;
1524         self.remove_except_protected_forbidden = 0;
1525         if (self.classname == "initialize_entity")
1526         {
1527             entity e_old;
1528             e_old = self.enemy;
1529             builtin_remove(self);
1530             self = e_old;
1531         }
1532         //dprint("Delayed initialization: ", self.classname, "\n");
1533         if(func)
1534             func();
1535         else
1536         {
1537             eprint(self);
1538             backtrace(strcat("Null function in: ", self.classname, "\n"));
1539         }
1540         self = e;
1541     }
1542     remove = remove_unsafely;
1543 }
1544
1545 .float uncustomizeentityforclient_set;
1546 .void(void) uncustomizeentityforclient;
1547 void UncustomizeEntitiesRun()
1548 {
1549     entity oldself;
1550     oldself = self;
1551     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1552         self.uncustomizeentityforclient();
1553     self = oldself;
1554 }
1555 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1556 {
1557     e.customizeentityforclient = customizer;
1558     e.uncustomizeentityforclient = uncustomizer;
1559     e.uncustomizeentityforclient_set = !!uncustomizer;
1560 }
1561
1562 .float nottargeted;
1563 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1564
1565 void() SUB_Remove;
1566 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1567 {
1568     vector mi, ma;
1569
1570     if (e.classname == "")
1571         e.classname = "net_linked";
1572
1573     if (e.model == "" || self.modelindex == 0)
1574     {
1575         mi = e.mins;
1576         ma = e.maxs;
1577         setmodel(e, "null");
1578         setsize(e, mi, ma);
1579     }
1580
1581     e.SendEntity = sendfunc;
1582     e.SendFlags = 0xFFFFFF;
1583
1584     if (!docull)
1585         e.effects |= EF_NODEPTHTEST;
1586
1587     if (dt)
1588     {
1589         e.nextthink = time + dt;
1590         e.think = SUB_Remove;
1591     }
1592 }
1593
1594
1595 entity eliminatedPlayers;
1596 .float(entity) isEliminated;
1597 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1598 {
1599         float i, f, b;
1600         entity e;
1601         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1602         WriteByte(MSG_ENTITY, sendflags);
1603
1604         if(sendflags & 1)
1605         {
1606                 for(i = 1; i <= maxclients; i += 8)
1607                 {
1608                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1609                         {
1610                                 if(eliminatedPlayers.isEliminated(e))
1611                                         f |= b;
1612                         }
1613                         WriteByte(MSG_ENTITY, f);
1614                 }
1615         }
1616
1617         return TRUE;
1618 }
1619
1620 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1621 {
1622         if(eliminatedPlayers)
1623         {
1624                 backtrace("Can't spawn eliminatedPlayers again!");
1625                 return;
1626         }
1627         Net_LinkEntity(eliminatedPlayers = spawn(), FALSE, 0, EliminatedPlayers_SendEntity);
1628         eliminatedPlayers.isEliminated = isEliminated_func;
1629 }
1630
1631
1632 void adaptor_think2touch()
1633 {
1634     entity o;
1635     o = other;
1636     other = world;
1637     self.touch();
1638     other = o;
1639 }
1640
1641 void adaptor_think2use()
1642 {
1643     entity o, a;
1644     o = other;
1645     a = activator;
1646     activator = world;
1647     other = world;
1648     self.use();
1649     other = o;
1650     activator = a;
1651 }
1652
1653 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1654 {
1655         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1656                 self.projectiledeathtype |= HITTYPE_SPLASH;
1657         adaptor_think2use();
1658 }
1659
1660 // deferred dropping
1661 void DropToFloor_Handler()
1662 {
1663     builtin_droptofloor();
1664     self.dropped_origin = self.origin;
1665 }
1666
1667 void droptofloor()
1668 {
1669     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1670 }
1671
1672
1673
1674 float trace_hits_box_a0, trace_hits_box_a1;
1675
1676 float trace_hits_box_1d(float end, float thmi, float thma)
1677 {
1678     if (end == 0)
1679     {
1680         // just check if x is in range
1681         if (0 < thmi)
1682             return FALSE;
1683         if (0 > thma)
1684             return FALSE;
1685     }
1686     else
1687     {
1688         // do the trace with respect to x
1689         // 0 -> end has to stay in thmi -> thma
1690         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1691         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1692         if (trace_hits_box_a0 > trace_hits_box_a1)
1693             return FALSE;
1694     }
1695     return TRUE;
1696 }
1697
1698 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1699 {
1700     end -= start;
1701     thmi -= start;
1702     thma -= start;
1703     // now it is a trace from 0 to end
1704
1705     trace_hits_box_a0 = 0;
1706     trace_hits_box_a1 = 1;
1707
1708     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1709         return FALSE;
1710     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1711         return FALSE;
1712     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1713         return FALSE;
1714
1715     return TRUE;
1716 }
1717
1718 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1719 {
1720     return trace_hits_box(start, end, thmi - ma, thma - mi);
1721 }
1722
1723 float SUB_NoImpactCheck()
1724 {
1725         // zero hitcontents = this is not the real impact, but either the
1726         // mirror-impact of something hitting the projectile instead of the
1727         // projectile hitting the something, or a touchareagrid one. Neither of
1728         // these stop the projectile from moving, so...
1729         if(trace_dphitcontents == 0)
1730         {
1731                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1732                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1733                 checkclient();
1734         }
1735     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1736         return 1;
1737     if (other == world && self.size != '0 0 0')
1738     {
1739         vector tic;
1740         tic = self.velocity * sys_frametime;
1741         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1742         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1743         if (trace_fraction >= 1)
1744         {
1745             dprint("Odd... did not hit...?\n");
1746         }
1747         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1748         {
1749             dprint("Detected and prevented the sky-grapple bug.\n");
1750             return 1;
1751         }
1752     }
1753
1754     return 0;
1755 }
1756
1757 #define SUB_OwnerCheck() (other && (other == self.owner))
1758
1759 void RemoveGrapplingHook(entity pl);
1760 void W_Crylink_Dequeue(entity e);
1761 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1762 {
1763         if(SUB_OwnerCheck())
1764                 return TRUE;
1765         if(SUB_NoImpactCheck())
1766         {
1767                 if(self.classname == "nade")
1768                         return FALSE; // no checks here
1769                 else if(self.classname == "grapplinghook")
1770                         RemoveGrapplingHook(self.realowner);
1771                 else if(self.classname == "spike")
1772                 {
1773                         W_Crylink_Dequeue(self);
1774                         remove(self);
1775                 }
1776                 else
1777                         remove(self);
1778                 return TRUE;
1779         }
1780         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1781                 UpdateCSQCProjectile(self);
1782         return FALSE;
1783 }
1784 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1785
1786 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1787 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1788
1789 void URI_Get_Callback(float id, float status, string data)
1790 {
1791         if(url_URI_Get_Callback(id, status, data))
1792         {
1793                 // handled
1794         }
1795         else if (id == URI_GET_DISCARD)
1796         {
1797                 // discard
1798         }
1799         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1800         {
1801                 // sv_cmd curl
1802                 Curl_URI_Get_Callback(id, status, data);
1803         }
1804         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1805         {
1806                 // online ban list
1807                 OnlineBanList_URI_Get_Callback(id, status, data);
1808         }
1809         else
1810         {
1811                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1812         }
1813 }
1814
1815 string uid2name(string myuid) {
1816         string s;
1817         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1818
1819         // FIXME remove this later after 0.6 release
1820         // convert old style broken records to correct style
1821         if(s == "")
1822         {
1823                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1824                 if(s != "")
1825                 {
1826                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1827                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1828                 }
1829         }
1830
1831         if(s == "")
1832                 s = "^1Unregistered Player";
1833         return s;
1834 }
1835
1836 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1837 {
1838     float m, i;
1839     vector start, org, delta, end, enddown, mstart;
1840     entity sp;
1841
1842     m = e.dphitcontentsmask;
1843     e.dphitcontentsmask = goodcontents | badcontents;
1844
1845     org = world.mins;
1846     delta = world.maxs - world.mins;
1847
1848     start = end = org;
1849
1850     for (i = 0; i < attempts; ++i)
1851     {
1852         start_x = org_x + random() * delta_x;
1853         start_y = org_y + random() * delta_y;
1854         start_z = org_z + random() * delta_z;
1855
1856         // rule 1: start inside world bounds, and outside
1857         // solid, and don't start from somewhere where you can
1858         // fall down to evil
1859         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1860         if (trace_fraction >= 1)
1861             continue;
1862         if (trace_startsolid)
1863             continue;
1864         if (trace_dphitcontents & badcontents)
1865             continue;
1866         if (trace_dphitq3surfaceflags & badsurfaceflags)
1867             continue;
1868
1869         // rule 2: if we are too high, lower the point
1870         if (trace_fraction * delta_z > maxaboveground)
1871             start = trace_endpos + '0 0 1' * maxaboveground;
1872         enddown = trace_endpos;
1873
1874         // rule 3: make sure we aren't outside the map. This only works
1875         // for somewhat well formed maps. A good rule of thumb is that
1876         // the map should have a convex outside hull.
1877         // these can be traceLINES as we already verified the starting box
1878         mstart = start + 0.5 * (e.mins + e.maxs);
1879         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1880         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1881             continue;
1882         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1883         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1884             continue;
1885         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1886         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1887             continue;
1888         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1889         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1890             continue;
1891         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1892         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1893             continue;
1894
1895         // rule 4: we must "see" some spawnpoint or item
1896         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1897                 if(checkpvs(mstart, sp))
1898                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1899                                 break;
1900         if(!sp)
1901         {
1902                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1903                         if(checkpvs(mstart, sp))
1904                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1905                                         break;
1906                 if(!sp)
1907                         continue;
1908         }
1909
1910         // find a random vector to "look at"
1911         end_x = org_x + random() * delta_x;
1912         end_y = org_y + random() * delta_y;
1913         end_z = org_z + random() * delta_z;
1914         end = start + normalize(end - start) * vlen(delta);
1915
1916         // rule 4: start TO end must not be too short
1917         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1918         if (trace_startsolid)
1919             continue;
1920         if (trace_fraction < minviewdistance / vlen(delta))
1921             continue;
1922
1923         // rule 5: don't want to look at sky
1924         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1925             continue;
1926
1927         // rule 6: we must not end up in trigger_hurt
1928         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1929             continue;
1930
1931         break;
1932     }
1933
1934     e.dphitcontentsmask = m;
1935
1936     if (i < attempts)
1937     {
1938         setorigin(e, start);
1939         e.angles = vectoangles(end - start);
1940         dprint("Needed ", ftos(i + 1), " attempts\n");
1941         return TRUE;
1942     }
1943     else
1944         return FALSE;
1945 }
1946
1947 void write_recordmarker(entity pl, float tstart, float dt)
1948 {
1949     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1950
1951     // also write a marker into demo files for demotc-race-record-extractor to find
1952     stuffcmd(pl,
1953              strcat(
1954                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1955                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1956 }
1957
1958 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1959 {
1960         switch(algn)
1961         {
1962                 default:
1963                 case 3: // right
1964                         break;
1965
1966                 case 4: // left
1967                         vecs_y = -vecs_y;
1968                         break;
1969
1970                 case 1:
1971                         if(allowcenter) // 2: allow center handedness
1972                         {
1973                                 // center
1974                                 vecs_y = 0;
1975                                 vecs_z -= 2;
1976                         }
1977                         else
1978                         {
1979                                 // right
1980                         }
1981                         break;
1982
1983                 case 2:
1984                         if(allowcenter) // 2: allow center handedness
1985                         {
1986                                 // center
1987                                 vecs_y = 0;
1988                                 vecs_z -= 2;
1989                         }
1990                         else
1991                         {
1992                                 // left
1993                                 vecs_y = -vecs_y;
1994                         }
1995                         break;
1996         }
1997         return vecs;
1998 }
1999
2000 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2001 {
2002         string s;
2003         vector v;
2004
2005         if (autocvar_g_shootfromeye)
2006         {
2007                 if (visual)
2008                 {
2009                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2010                         else { vecs_y = 0; vecs_z -= 2; }
2011                 }
2012                 else
2013                 {
2014                         vecs_y = 0;
2015                         vecs_z = 0;
2016                 }
2017         }
2018         else if (autocvar_g_shootfromcenter)
2019         {
2020                 vecs_y = 0;
2021                 vecs_z -= 2;
2022         }
2023         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2024         {
2025                 v = stov(s);
2026                 if (y_is_right)
2027                         v_y = -v_y;
2028                 if (v_x != 0)
2029                         vecs_x = v_x;
2030                 vecs_y = v_y;
2031                 vecs_z = v_z;
2032         }
2033         else if (autocvar_g_shootfromclient)
2034         {
2035                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2036         }
2037         return vecs;
2038 }
2039
2040 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2041 {
2042         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2043 }
2044
2045
2046 void attach_sameorigin(entity e, entity to, string tag)
2047 {
2048     vector org, t_forward, t_left, t_up, e_forward, e_up;
2049     float tagscale;
2050
2051     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2052     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2053     t_forward = v_forward * tagscale;
2054     t_left = v_right * -tagscale;
2055     t_up = v_up * tagscale;
2056
2057     e.origin_x = org * t_forward;
2058     e.origin_y = org * t_left;
2059     e.origin_z = org * t_up;
2060
2061     // current forward and up directions
2062     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2063                 e.angles = AnglesTransform_FromVAngles(e.angles);
2064         else
2065                 e.angles = AnglesTransform_FromAngles(e.angles);
2066     fixedmakevectors(e.angles);
2067
2068     // untransform forward, up!
2069     e_forward_x = v_forward * t_forward;
2070     e_forward_y = v_forward * t_left;
2071     e_forward_z = v_forward * t_up;
2072     e_up_x = v_up * t_forward;
2073     e_up_y = v_up * t_left;
2074     e_up_z = v_up * t_up;
2075
2076     e.angles = fixedvectoangles2(e_forward, e_up);
2077     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2078                 e.angles = AnglesTransform_ToVAngles(e.angles);
2079         else
2080                 e.angles = AnglesTransform_ToAngles(e.angles);
2081
2082     setattachment(e, to, tag);
2083     setorigin(e, e.origin);
2084 }
2085
2086 void detach_sameorigin(entity e)
2087 {
2088     vector org;
2089     org = gettaginfo(e, 0);
2090     e.angles = fixedvectoangles2(v_forward, v_up);
2091     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2092                 e.angles = AnglesTransform_ToVAngles(e.angles);
2093         else
2094                 e.angles = AnglesTransform_ToAngles(e.angles);
2095     setorigin(e, org);
2096     setattachment(e, world, "");
2097     setorigin(e, e.origin);
2098 }
2099
2100 void follow_sameorigin(entity e, entity to)
2101 {
2102     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2103     e.aiment = to; // make the hole follow bmodel
2104     e.punchangle = to.angles; // the original angles of bmodel
2105     e.view_ofs = e.origin - to.origin; // relative origin
2106     e.v_angle = e.angles - to.angles; // relative angles
2107 }
2108
2109 void unfollow_sameorigin(entity e)
2110 {
2111     e.movetype = MOVETYPE_NONE;
2112 }
2113
2114 entity gettaginfo_relative_ent;
2115 vector gettaginfo_relative(entity e, float tag)
2116 {
2117     if (!gettaginfo_relative_ent)
2118     {
2119         gettaginfo_relative_ent = spawn();
2120         gettaginfo_relative_ent.effects = EF_NODRAW;
2121     }
2122     gettaginfo_relative_ent.model = e.model;
2123     gettaginfo_relative_ent.modelindex = e.modelindex;
2124     gettaginfo_relative_ent.frame = e.frame;
2125     return gettaginfo(gettaginfo_relative_ent, tag);
2126 }
2127
2128 .float scale2;
2129
2130 float modeleffect_SendEntity(entity to, float sf)
2131 {
2132         float f;
2133         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2134
2135         f = 0;
2136         if(self.velocity != '0 0 0')
2137                 f |= 1;
2138         if(self.angles != '0 0 0')
2139                 f |= 2;
2140         if(self.avelocity != '0 0 0')
2141                 f |= 4;
2142
2143         WriteByte(MSG_ENTITY, f);
2144         WriteShort(MSG_ENTITY, self.modelindex);
2145         WriteByte(MSG_ENTITY, self.skin);
2146         WriteByte(MSG_ENTITY, self.frame);
2147         WriteCoord(MSG_ENTITY, self.origin_x);
2148         WriteCoord(MSG_ENTITY, self.origin_y);
2149         WriteCoord(MSG_ENTITY, self.origin_z);
2150         if(f & 1)
2151         {
2152                 WriteCoord(MSG_ENTITY, self.velocity_x);
2153                 WriteCoord(MSG_ENTITY, self.velocity_y);
2154                 WriteCoord(MSG_ENTITY, self.velocity_z);
2155         }
2156         if(f & 2)
2157         {
2158                 WriteCoord(MSG_ENTITY, self.angles_x);
2159                 WriteCoord(MSG_ENTITY, self.angles_y);
2160                 WriteCoord(MSG_ENTITY, self.angles_z);
2161         }
2162         if(f & 4)
2163         {
2164                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2165                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2166                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2167         }
2168         WriteShort(MSG_ENTITY, self.scale * 256.0);
2169         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2170         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2171         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2172         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2173
2174         return TRUE;
2175 }
2176
2177 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2178 {
2179         entity e;
2180         float sz;
2181         e = spawn();
2182         e.classname = "modeleffect";
2183         setmodel(e, m);
2184         e.frame = f;
2185         setorigin(e, o);
2186         e.velocity = v;
2187         e.angles = ang;
2188         e.avelocity = angv;
2189         e.alpha = a;
2190         e.teleport_time = t1;
2191         e.fade_time = t2;
2192         e.skin = s;
2193         if(s0 >= 0)
2194                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2195         else
2196                 e.scale = -s0;
2197         if(s2 >= 0)
2198                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2199         else
2200                 e.scale2 = -s2;
2201         sz = max(e.scale, e.scale2);
2202         setsize(e, e.mins * sz, e.maxs * sz);
2203         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2204 }
2205
2206 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2207 {
2208         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2209 }
2210
2211 float randombit(float bits)
2212 {
2213         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2214                 return bits;
2215
2216         float n, f, b, r;
2217
2218         r = random();
2219         b = 0;
2220         n = 0;
2221
2222         for(f = 1; f <= bits; f *= 2)
2223         {
2224                 if(bits & f)
2225                 {
2226                         ++n;
2227                         r *= n;
2228                         if(r <= 1)
2229                                 b = f;
2230                         else
2231                                 r = (r - 1) / (n - 1);
2232                 }
2233         }
2234
2235         return b;
2236 }
2237
2238 float randombits(float bits, float k, float error_return)
2239 {
2240         float r;
2241         r = 0;
2242         while(k > 0 && bits != r)
2243         {
2244                 r += randombit(bits - r);
2245                 --k;
2246         }
2247         if(error_return)
2248                 if(k > 0)
2249                         return -1; // all
2250         return r;
2251 }
2252
2253 void randombit_test(float bits, float iter)
2254 {
2255         while(iter > 0)
2256         {
2257                 print(ftos(randombit(bits)), "\n");
2258                 --iter;
2259         }
2260 }
2261
2262 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2263 {
2264         if(halflifedist > 0)
2265                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2266         else if(halflifedist < 0)
2267                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2268         else
2269                 return 1;
2270 }
2271
2272
2273
2274
2275 #ifdef RELEASE
2276 #define cvar_string_normal builtin_cvar_string
2277 #define cvar_normal builtin_cvar
2278 #else
2279 string cvar_string_normal(string n)
2280 {
2281         if (!(cvar_type(n) & 1))
2282                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2283         return builtin_cvar_string(n);
2284 }
2285
2286 float cvar_normal(string n)
2287 {
2288         return stof(cvar_string_normal(n));
2289 }
2290 #endif
2291 #define cvar_set_normal builtin_cvar_set
2292
2293 void defer_think()
2294 {
2295     entity oself;
2296
2297     oself           = self;
2298     self            = self.owner;
2299     oself.think     = SUB_Remove;
2300     oself.nextthink = time;
2301
2302     oself.use();
2303 }
2304
2305 /*
2306     Execute func() after time + fdelay.
2307     self when func is executed = self when defer is called
2308 */
2309 void defer(float fdelay, void() func)
2310 {
2311     entity e;
2312
2313     e           = spawn();
2314     e.owner     = self;
2315     e.use       = func;
2316     e.think     = defer_think;
2317     e.nextthink = time + fdelay;
2318 }
2319
2320 .string aiment_classname;
2321 .float aiment_deadflag;
2322 void SetMovetypeFollow(entity ent, entity e)
2323 {
2324         // FIXME this may not be warpzone aware
2325         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2326         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2327         ent.aiment = e; // make the hole follow bmodel
2328         ent.punchangle = e.angles; // the original angles of bmodel
2329         ent.view_ofs = ent.origin - e.origin; // relative origin
2330         ent.v_angle = ent.angles - e.angles; // relative angles
2331         ent.aiment_classname = strzone(e.classname);
2332         ent.aiment_deadflag = e.deadflag;
2333 }
2334 void UnsetMovetypeFollow(entity ent)
2335 {
2336         ent.movetype = MOVETYPE_FLY;
2337         PROJECTILE_MAKETRIGGER(ent);
2338         ent.aiment = world;
2339 }
2340 float LostMovetypeFollow(entity ent)
2341 {
2342 /*
2343         if(ent.movetype != MOVETYPE_FOLLOW)
2344                 if(ent.aiment)
2345                         error("???");
2346 */
2347         if(ent.aiment)
2348         {
2349                 if(ent.aiment.classname != ent.aiment_classname)
2350                         return 1;
2351                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2352                         return 1;
2353         }
2354         return 0;
2355 }
2356
2357 float isPushable(entity e)
2358 {
2359         if(e.iscreature)
2360                 return TRUE;
2361         if(e.pushable)
2362                 return TRUE;
2363         switch(e.classname)
2364         {
2365                 case "body":
2366                 case "droppedweapon":
2367                 case "keepawayball":
2368                 case "nexball_basketball":
2369                 case "nexball_football":
2370                         return TRUE;
2371                 case "bullet": // antilagged bullets can't hit this either
2372                         return FALSE;
2373         }
2374         if (e.projectiledeathtype)
2375                 return TRUE;
2376         return FALSE;
2377 }