qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 const string STR_PLAYER = "player";
  81 const string STR_SPECTATOR = "spectator";
  82 const string STR_OBSERVER = "observer";
  83
  84 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  85 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  86 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  87 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  88 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  89 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  90 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  91
  92 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  93 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  94 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  95
  96 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  97 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
  98 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
  99
 100 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 const float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = WEP_NAME(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else if (self.items & IT_PLASMA) replacement = "plasma";
 363                         else replacement = "batteries"; // ;)
 364                 } else if (escape == "x") {
 365                         replacement = cursor_ent.netname;
 366                         if (replacement == "" || !cursor_ent)
 367                                 replacement = "nothing";
 368                 } else if (escape == "s")
 369                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 370                 else if (escape == "S")
 371                         replacement = ftos(vlen(self.velocity));
 372
 373                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 374                 p = p + strlen(replacement);
 375         }
 376         return msg;
 377 }
 378
 379 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 380         return (value == 0) ? FALSE : TRUE;
 381 }
 382
 383 /*
 384 =============
 385 GetCvars
 386 =============
 387 Called with:
 388   0:  sends the request
 389   >0: receives a cvar from name=argv(f) value=argv(f+1)
 390 */
 391 void GetCvars_handleString(string thisname, float f, .string field, string name)
 392 {
 393         if (f < 0)
 394         {
 395                 if (self.field)
 396                         strunzone(self.field);
 397                 self.field = string_null;
 398         }
 399         else if (f > 0)
 400         {
 401                 if (thisname == name)
 402                 {
 403                         if (self.field)
 404                                 strunzone(self.field);
 405                         self.field = strzone(argv(f + 1));
 406                 }
 407         }
 408         else
 409                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 410 }
 411 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 412 {
 413         GetCvars_handleString(thisname, f, field, name);
 414         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 415                 if (thisname == name)
 416                 {
 417                         string s;
 418                         s = func(strcat1(self.field));
 419                         if (s != self.field)
 420                         {
 421                                 strunzone(self.field);
 422                                 self.field = strzone(s);
 423                         }
 424                 }
 425 }
 426 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 427 {
 428         if (f < 0)
 429         {
 430         }
 431         else if (f > 0)
 432         {
 433                 if (thisname == name)
 434                         self.field = stof(argv(f + 1));
 435         }
 436         else
 437                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 438 }
 439 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 440 {
 441         if (f < 0)
 442         {
 443         }
 444         else if (f > 0)
 445         {
 446                 if (thisname == name)
 447                 {
 448                         if(!self.field)
 449                         {
 450                                 self.field = stof(argv(f + 1));
 451                                 if(!self.field)
 452                                         self.field = -1;
 453                         }
 454                 }
 455         }
 456         else
 457         {
 458                 if(!self.field)
 459                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 460         }
 461 }
 462 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 463 {
 464         string o;
 465         o = W_FixWeaponOrder_ForceComplete(wo);
 466         if(self.weaponorder_byimpulse)
 467         {
 468                 strunzone(self.weaponorder_byimpulse);
 469                 self.weaponorder_byimpulse = string_null;
 470         }
 471         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 472         return o;
 473 }
 474 void GetCvars(float f)
 475 {
 476         string s = string_null;
 477
 478         if (f > 0)
 479                 s = strcat1(argv(f));
 480
 481         get_cvars_f = f;
 482         get_cvars_s = s;
 483
 484         MUTATOR_CALLHOOK(GetCvars);
 485
 486         Notification_GetCvars();
 487
 488         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 489         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 490         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 491         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 492         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 493         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 504         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 505         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 506         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 507         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 508         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 509         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 510         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 511         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 512
 513         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 514         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 515
 516         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 517         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 518         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 519         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 520         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 521
 522         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 523         if (f > 0)
 524         {
 525                 if (s == "cl_weaponpriority")
 526                         self.switchweapon = w_getbestweapon(self);
 527                 if (s == "cl_allow_uidtracking")
 528                         PlayerStats_GameReport_AddPlayer(self);
 529         }
 530 }
 531
 532 // decolorizes and team colors the player name when needed
 533 string playername(entity p)
 534 {
 535     string t;
 536     if (teamplay && !intermission_running && IS_PLAYER(p))
 537     {
 538         t = Team_ColorCode(p.team);
 539         return strcat(t, strdecolorize(p.netname));
 540     }
 541     else
 542         return p.netname;
 543 }
 544
 545 vector randompos(vector m1, vector m2)
 546 {
 547     vector v;
 548     m2 = m2 - m1;
 549     v_x = m2_x * random() + m1_x;
 550     v_y = m2_y * random() + m1_y;
 551     v_z = m2_z * random() + m1_z;
 552     return  v;
 553 }
 554
 555 //#NO AUTOCVARS START
 556
 557 float g_pickup_shells;
 558 float g_pickup_shells_max;
 559 float g_pickup_nails;
 560 float g_pickup_nails_max;
 561 float g_pickup_rockets;
 562 float g_pickup_rockets_max;
 563 float g_pickup_cells;
 564 float g_pickup_cells_max;
 565 float g_pickup_plasma;
 566 float g_pickup_plasma_max;
 567 float g_pickup_fuel;
 568 float g_pickup_fuel_jetpack;
 569 float g_pickup_fuel_max;
 570 float g_pickup_armorsmall;
 571 float g_pickup_armorsmall_max;
 572 float g_pickup_armorsmall_anyway;
 573 float g_pickup_armormedium;
 574 float g_pickup_armormedium_max;
 575 float g_pickup_armormedium_anyway;
 576 float g_pickup_armorbig;
 577 float g_pickup_armorbig_max;
 578 float g_pickup_armorbig_anyway;
 579 float g_pickup_armorlarge;
 580 float g_pickup_armorlarge_max;
 581 float g_pickup_armorlarge_anyway;
 582 float g_pickup_healthsmall;
 583 float g_pickup_healthsmall_max;
 584 float g_pickup_healthsmall_anyway;
 585 float g_pickup_healthmedium;
 586 float g_pickup_healthmedium_max;
 587 float g_pickup_healthmedium_anyway;
 588 float g_pickup_healthlarge;
 589 float g_pickup_healthlarge_max;
 590 float g_pickup_healthlarge_anyway;
 591 float g_pickup_healthmega;
 592 float g_pickup_healthmega_max;
 593 float g_pickup_healthmega_anyway;
 594 float g_pickup_ammo_anyway;
 595 float g_pickup_weapons_anyway;
 596 float g_weaponarena;
 597 WepSet g_weaponarena_weapons;
 598 float g_weaponarena_random;
 599 float g_weaponarena_random_with_blaster;
 600 string g_weaponarena_list;
 601 float g_weaponspeedfactor;
 602 float g_weaponratefactor;
 603 float g_weapondamagefactor;
 604 float g_weaponforcefactor;
 605 float g_weaponspreadfactor;
 606
 607 WepSet start_weapons;
 608 WepSet start_weapons_default;
 609 WepSet start_weapons_defaultmask;
 610 float start_items;
 611 float start_ammo_shells;
 612 float start_ammo_nails;
 613 float start_ammo_rockets;
 614 float start_ammo_cells;
 615 float start_ammo_plasma;
 616 float start_ammo_fuel;
 617 float start_health;
 618 float start_armorvalue;
 619 WepSet warmup_start_weapons;
 620 WepSet warmup_start_weapons_default;
 621 WepSet warmup_start_weapons_defaultmask;
 622 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 623 float warmup_start_ammo_shells;
 624 float warmup_start_ammo_nails;
 625 float warmup_start_ammo_rockets;
 626 float warmup_start_ammo_cells;
 627 float warmup_start_ammo_plasma;
 628 float warmup_start_ammo_fuel;
 629 float warmup_start_health;
 630 float warmup_start_armorvalue;
 631 float g_weapon_stay;
 632
 633 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 634 {
 635         var float i = weaponinfo.weapon;
 636         var float d = 0;
 637
 638         if (!i)
 639                 return 0;
 640
 641         if (g_lms || g_ca || allguns)
 642         {
 643                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 644                         d = TRUE;
 645                 else
 646                         d = FALSE;
 647         }
 648         else if (g_cts)
 649                 d = (i == WEP_SHOTGUN);
 650         else if (g_nexball)
 651                 d = 0; // weapon is set a few lines later
 652         else
 653                 d = !(!weaponinfo.weaponstart);
 654
 655         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 656                 d |= (i == WEP_HOOK);
 657         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 658                 d = 0;
 659
 660         var float t = weaponinfo.weaponstartoverride;
 661
 662         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 663
 664         // bit order in t:
 665         // 1: want or not
 666         // 2: is default?
 667         // 4: is set by default?
 668         if(t < 0)
 669                 t = 4 | (3 * d);
 670         else
 671                 t |= (2 * d);
 672
 673         return t;
 674 }
 675
 676 void readplayerstartcvars()
 677 {
 678         entity e;
 679         float i, j, t;
 680         string s;
 681
 682         // initialize starting values for players
 683         start_weapons = '0 0 0';
 684         start_weapons_default = '0 0 0';
 685         start_weapons_defaultmask = '0 0 0';
 686         start_items = 0;
 687         start_ammo_shells = 0;
 688         start_ammo_nails = 0;
 689         start_ammo_rockets = 0;
 690         start_ammo_cells = 0;
 691         start_ammo_plasma = 0;
 692         start_health = cvar("g_balance_health_start");
 693         start_armorvalue = cvar("g_balance_armor_start");
 694
 695         g_weaponarena = 0;
 696         g_weaponarena_weapons = '0 0 0';
 697
 698         s = cvar_string("g_weaponarena");
 699         if (s == "0" || s == "")
 700         {
 701                 if(g_ca)
 702                         s = "most";
 703         }
 704
 705         if (s == "0" || s == "")
 706         {
 707                 // no arena
 708         }
 709         else if (s == "off")
 710         {
 711                 // forcibly turn off weaponarena
 712         }
 713         else if (s == "all" || s == "1")
 714         {
 715                 g_weaponarena = 1;
 716                 g_weaponarena_list = "All Weapons";
 717                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 718                 {
 719                         e = get_weaponinfo(j);
 720                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 721                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 722                 }
 723         }
 724         else if (s == "most")
 725         {
 726                 g_weaponarena = 1;
 727                 g_weaponarena_list = "Most Weapons";
 728                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 729                 {
 730                         e = get_weaponinfo(j);
 731                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 732                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 733                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 734                 }
 735         }
 736         else if (s == "none")
 737         {
 738                 g_weaponarena = 1;
 739                 g_weaponarena_list = "No Weapons";
 740         }
 741         else
 742         {
 743                 g_weaponarena = 1;
 744                 t = tokenize_console(s);
 745                 g_weaponarena_list = "";
 746                 for (i = 0; i < t; ++i)
 747                 {
 748                         s = argv(i);
 749                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 750                         {
 751                                 e = get_weaponinfo(j);
 752                                 if (e.netname == s)
 753                                 {
 754                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 755                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 756                                         break;
 757                                 }
 758                         }
 759                         if (j > WEP_LAST)
 760                         {
 761                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 762                         }
 763                 }
 764                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 765         }
 766
 767         if(g_weaponarena)
 768                 g_weaponarena_random = cvar("g_weaponarena_random");
 769         else
 770                 g_weaponarena_random = 0;
 771         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 772
 773         if (g_weaponarena)
 774         {
 775                 g_weapon_stay = 0; // incompatible
 776                 start_weapons = g_weaponarena_weapons;
 777                 start_items |= IT_UNLIMITED_AMMO;
 778         }
 779         else
 780         {
 781                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 782                 {
 783                         e = get_weaponinfo(i);
 784                         float w = want_weapon(e, FALSE);
 785                         if(w & 1)
 786                                 start_weapons |= WepSet_FromWeapon(i);
 787                         if(w & 2)
 788                                 start_weapons_default |= WepSet_FromWeapon(i);
 789                         if(w & 4)
 790                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 791                 }
 792         }
 793
 794         if(!cvar("g_use_ammunition"))
 795                 start_items |= IT_UNLIMITED_AMMO;
 796
 797         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 798         {
 799                 start_ammo_shells = 999;
 800                 start_ammo_nails = 999;
 801                 start_ammo_rockets = 999;
 802                 start_ammo_cells = 999;
 803                 start_ammo_plasma = 999;
 804                 start_ammo_fuel = 999;
 805         }
 806         else
 807         {
 808                 start_ammo_shells = cvar("g_start_ammo_shells");
 809                 start_ammo_nails = cvar("g_start_ammo_nails");
 810                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 811                 start_ammo_cells = cvar("g_start_ammo_cells");
 812                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 813                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 814         }
 815
 816         if (warmup_stage)
 817         {
 818                 warmup_start_ammo_shells = start_ammo_shells;
 819                 warmup_start_ammo_nails = start_ammo_nails;
 820                 warmup_start_ammo_rockets = start_ammo_rockets;
 821                 warmup_start_ammo_cells = start_ammo_cells;
 822                 warmup_start_ammo_plasma = start_ammo_plasma;
 823                 warmup_start_ammo_fuel = start_ammo_fuel;
 824                 warmup_start_health = start_health;
 825                 warmup_start_armorvalue = start_armorvalue;
 826                 warmup_start_weapons = start_weapons;
 827                 warmup_start_weapons_default = start_weapons_default;
 828                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 829
 830                 if (!g_weaponarena && !g_ca)
 831                 {
 832                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 833                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 834                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 835                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 836                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 837                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 838                         warmup_start_health = cvar("g_warmup_start_health");
 839                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 840                         warmup_start_weapons = '0 0 0';
 841                         warmup_start_weapons_default = '0 0 0';
 842                         warmup_start_weapons_defaultmask = '0 0 0';
 843                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 844                         {
 845                                 e = get_weaponinfo(i);
 846                                 float w = want_weapon(e, g_warmup_allguns);
 847                                 if(w & 1)
 848                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 849                                 if(w & 2)
 850                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 851                                 if(w & 4)
 852                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 853                         }
 854                 }
 855         }
 856
 857         if (g_jetpack)
 858                 start_items |= IT_JETPACK;
 859
 860         MUTATOR_CALLHOOK(SetStartItems);
 861
 862         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 863         {
 864                 start_items |= IT_FUEL_REGEN;
 865                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 866                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 867         }
 868
 869         WepSet precache_weapons = start_weapons;
 870         if (g_warmup_allguns != 1)
 871                 precache_weapons |= warmup_start_weapons;
 872         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 873         {
 874                 e = get_weaponinfo(i);
 875                 if(precache_weapons & WepSet_FromWeapon(i))
 876                         WEP_ACTION(i, WR_INIT);
 877         }
 878
 879         start_ammo_shells = max(0, start_ammo_shells);
 880         start_ammo_nails = max(0, start_ammo_nails);
 881         start_ammo_rockets = max(0, start_ammo_rockets);
 882         start_ammo_cells = max(0, start_ammo_cells);
 883         start_ammo_plasma = max(0, start_ammo_plasma);
 884         start_ammo_fuel = max(0, start_ammo_fuel);
 885
 886         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 887         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 888         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 889         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 890         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 891         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 892 }
 893
 894 float g_bugrigs;
 895 float g_bugrigs_planar_movement;
 896 float g_bugrigs_planar_movement_car_jumping;
 897 float g_bugrigs_reverse_spinning;
 898 float g_bugrigs_reverse_speeding;
 899 float g_bugrigs_reverse_stopping;
 900 float g_bugrigs_air_steering;
 901 float g_bugrigs_angle_smoothing;
 902 float g_bugrigs_friction_floor;
 903 float g_bugrigs_friction_brake;
 904 float g_bugrigs_friction_air;
 905 float g_bugrigs_accel;
 906 float g_bugrigs_speed_ref;
 907 float g_bugrigs_speed_pow;
 908 float g_bugrigs_steer;
 909
 910 float sv_autotaunt;
 911 float sv_taunt;
 912
 913 string GetGametype(); // g_world.qc
 914 void mutators_add(); // mutators.qc
 915 void readlevelcvars(void)
 916 {
 917         // load mutators
 918         mutators_add();
 919
 920         if(cvar("sv_allow_fullbright"))
 921                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 922
 923     g_bugrigs = cvar("g_bugrigs");
 924     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 925     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 926     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 927     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 928     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 929     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 930     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 931     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 932     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 933     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 934     g_bugrigs_accel = cvar("g_bugrigs_accel");
 935     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 936     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 937     g_bugrigs_steer = cvar("g_bugrigs_steer");
 938
 939         g_instagib = cvar("g_instagib");
 940
 941         sv_clones = cvar("sv_clones");
 942         sv_foginterval = cvar("sv_foginterval");
 943         g_cloaked = cvar("g_cloaked");
 944         g_footsteps = cvar("g_footsteps");
 945         g_grappling_hook = cvar("g_grappling_hook");
 946         g_jetpack = cvar("g_jetpack");
 947         sv_maxidle = cvar("sv_maxidle");
 948         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 949         sv_autotaunt = cvar("sv_autotaunt");
 950         sv_taunt = cvar("sv_taunt");
 951
 952         warmup_stage = cvar("g_warmup");
 953         g_warmup_limit = cvar("g_warmup_limit");
 954         g_warmup_allguns = cvar("g_warmup_allguns");
 955         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 956
 957         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 958                 warmup_stage = 0; // these modes cannot work together, sorry
 959
 960         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 961         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 962         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 963         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 964         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 965         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 966         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 967         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 968         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 969         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 970         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 971         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 972         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 973         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 974
 975         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 976         g_weaponratefactor = cvar("g_weaponratefactor");
 977         g_weapondamagefactor = cvar("g_weapondamagefactor");
 978         g_weaponforcefactor = cvar("g_weaponforcefactor");
 979         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 980
 981         g_pickup_shells = cvar("g_pickup_shells");
 982         g_pickup_shells_max = cvar("g_pickup_shells_max");
 983         g_pickup_nails = cvar("g_pickup_nails");
 984         g_pickup_nails_max = cvar("g_pickup_nails_max");
 985         g_pickup_rockets = cvar("g_pickup_rockets");
 986         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
 987         g_pickup_cells = cvar("g_pickup_cells");
 988         g_pickup_cells_max = cvar("g_pickup_cells_max");
 989         g_pickup_plasma = cvar("g_pickup_plasma");
 990         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
 991         g_pickup_fuel = cvar("g_pickup_fuel");
 992         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
 993         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
 994         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
 995         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
 996         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
 997         g_pickup_armormedium = cvar("g_pickup_armormedium");
 998         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
 999         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1000         g_pickup_armorbig = cvar("g_pickup_armorbig");
1001         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1002         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1003         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1004         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1005         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1006         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1007         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1008         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1009         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1010         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1011         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1012         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1013         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1014         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1015         g_pickup_healthmega = cvar("g_pickup_healthmega");
1016         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1017         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1018
1019         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1020         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1021
1022     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1023     if(!g_weapon_stay)
1024         g_weapon_stay = cvar("g_weapon_stay");
1025
1026         if (!warmup_stage)
1027                 game_starttime = time + cvar("g_start_delay");
1028
1029         readplayerstartcvars();
1030 }
1031
1032 //#NO AUTOCVARS END
1033
1034 // Sound functions
1035 string precache_sound (string s) = #19;
1036 float precache_sound_index (string s) = #19;
1037
1038 #define SND_VOLUME      1
1039 #define SND_ATTENUATION 2
1040 #define SND_LARGEENTITY 8
1041 #define SND_LARGESOUND  16
1042
1043 float sound_allowed(float dest, entity e)
1044 {
1045     // sounds from world may always pass
1046     for (;;)
1047     {
1048         if (e.classname == "body")
1049             e = e.enemy;
1050         else if (e.realowner && e.realowner != e)
1051             e = e.realowner;
1052         else if (e.owner && e.owner != e)
1053             e = e.owner;
1054         else
1055             break;
1056     }
1057     // sounds to self may always pass
1058     if (dest == MSG_ONE)
1059         if (e == msg_entity)
1060             return TRUE;
1061     // sounds by players can be removed
1062     if (autocvar_bot_sound_monopoly)
1063         if (IS_REAL_CLIENT(e))
1064             return FALSE;
1065     // anything else may pass
1066     return TRUE;
1067 }
1068
1069 #undef sound
1070 void sound(entity e, float chan, string samp, float vol, float atten)
1071 {
1072     if (!sound_allowed(MSG_BROADCAST, e))
1073         return;
1074     sound7(e, chan, samp, vol, atten, 0, 0);
1075 }
1076
1077 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1078 {
1079     float entno, idx;
1080
1081     if (!sound_allowed(dest, e))
1082         return;
1083
1084     entno = num_for_edict(e);
1085     idx = precache_sound_index(samp);
1086
1087     float sflags;
1088     sflags = 0;
1089
1090     atten = floor(atten * 64);
1091     vol = floor(vol * 255);
1092
1093     if (vol != 255)
1094         sflags |= SND_VOLUME;
1095     if (atten != 64)
1096         sflags |= SND_ATTENUATION;
1097     if (entno >= 8192 || chan < 0 || chan > 7)
1098         sflags |= SND_LARGEENTITY;
1099     if (idx >= 256)
1100         sflags |= SND_LARGESOUND;
1101
1102     WriteByte(dest, SVC_SOUND);
1103     WriteByte(dest, sflags);
1104     if (sflags & SND_VOLUME)
1105         WriteByte(dest, vol);
1106     if (sflags & SND_ATTENUATION)
1107         WriteByte(dest, atten);
1108     if (sflags & SND_LARGEENTITY)
1109     {
1110         WriteShort(dest, entno);
1111         WriteByte(dest, chan);
1112     }
1113     else
1114     {
1115         WriteShort(dest, entno * 8 + chan);
1116     }
1117     if (sflags & SND_LARGESOUND)
1118         WriteShort(dest, idx);
1119     else
1120         WriteByte(dest, idx);
1121
1122     WriteCoord(dest, o_x);
1123     WriteCoord(dest, o_y);
1124     WriteCoord(dest, o_z);
1125 }
1126 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1127 {
1128     vector o;
1129
1130     if (!sound_allowed(dest, e))
1131         return;
1132
1133     o = e.origin + 0.5 * (e.mins + e.maxs);
1134     soundtoat(dest, e, o, chan, samp, vol, atten);
1135 }
1136 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1137 {
1138     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1139 }
1140 void stopsoundto(float dest, entity e, float chan)
1141 {
1142     float entno;
1143
1144     if (!sound_allowed(dest, e))
1145         return;
1146
1147     entno = num_for_edict(e);
1148
1149     if (entno >= 8192 || chan < 0 || chan > 7)
1150     {
1151         float idx, sflags;
1152         idx = precache_sound_index("misc/null.wav");
1153         sflags = SND_LARGEENTITY;
1154         if (idx >= 256)
1155             sflags |= SND_LARGESOUND;
1156         WriteByte(dest, SVC_SOUND);
1157         WriteByte(dest, sflags);
1158         WriteShort(dest, entno);
1159         WriteByte(dest, chan);
1160         if (sflags & SND_LARGESOUND)
1161             WriteShort(dest, idx);
1162         else
1163             WriteByte(dest, idx);
1164         WriteCoord(dest, e.origin_x);
1165         WriteCoord(dest, e.origin_y);
1166         WriteCoord(dest, e.origin_z);
1167     }
1168     else
1169     {
1170         WriteByte(dest, SVC_STOPSOUND);
1171         WriteShort(dest, entno * 8 + chan);
1172     }
1173 }
1174 void stopsound(entity e, float chan)
1175 {
1176     if (!sound_allowed(MSG_BROADCAST, e))
1177         return;
1178
1179     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1180     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1181 }
1182
1183 void play2(entity e, string filename)
1184 {
1185     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1186     msg_entity = e;
1187     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1188 }
1189
1190 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1191 .float spamtime;
1192 float spamsound(entity e, float chan, string samp, float vol, float atten)
1193 {
1194     if (!sound_allowed(MSG_BROADCAST, e))
1195         return FALSE;
1196
1197     if (time > e.spamtime)
1198     {
1199         e.spamtime = time;
1200         sound(e, chan, samp, vol, atten);
1201         return TRUE;
1202     }
1203     return FALSE;
1204 }
1205
1206 void play2team(float t, string filename)
1207 {
1208     entity head;
1209
1210     if (autocvar_bot_sound_monopoly)
1211         return;
1212
1213     FOR_EACH_REALPLAYER(head)
1214     {
1215         if (head.team == t)
1216             play2(head, filename);
1217     }
1218 }
1219
1220 void play2all(string samp)
1221 {
1222     if (autocvar_bot_sound_monopoly)
1223         return;
1224
1225     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1226 }
1227
1228 void PrecachePlayerSounds(string f);
1229 void precache_playermodel(string m)
1230 {
1231         float globhandle, i, n;
1232         string f;
1233
1234         if(substring(m, -9,5) == "_lod1")
1235                 return;
1236         if(substring(m, -9,5) == "_lod2")
1237                 return;
1238         precache_model(m);
1239         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1240         if(fexists(f))
1241                 precache_model(f);
1242         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1243         if(fexists(f))
1244                 precache_model(f);
1245
1246         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1247         if (globhandle < 0)
1248                 return;
1249         n = search_getsize(globhandle);
1250         for (i = 0; i < n; ++i)
1251         {
1252                 //print(search_getfilename(globhandle, i), "\n");
1253                 f = search_getfilename(globhandle, i);
1254                 PrecachePlayerSounds(f);
1255         }
1256         search_end(globhandle);
1257 }
1258 void precache_all_playermodels(string pattern)
1259 {
1260         float globhandle, i, n;
1261         string f;
1262
1263         globhandle = search_begin(pattern, TRUE, FALSE);
1264         if (globhandle < 0)
1265                 return;
1266         n = search_getsize(globhandle);
1267         for (i = 0; i < n; ++i)
1268         {
1269                 //print(search_getfilename(globhandle, i), "\n");
1270                 f = search_getfilename(globhandle, i);
1271                 precache_playermodel(f);
1272         }
1273         search_end(globhandle);
1274 }
1275
1276 void precache()
1277 {
1278     // gamemode related things
1279     precache_model ("models/misc/chatbubble.spr");
1280         precache_model("models/ice/ice.md3");
1281
1282 #ifdef TTURRETS_ENABLED
1283     if (autocvar_g_turrets)
1284         turrets_precash();
1285 #endif
1286
1287     // Precache all player models if desired
1288     if (autocvar_sv_precacheplayermodels)
1289     {
1290         PrecachePlayerSounds("sound/player/default.sounds");
1291         precache_all_playermodels("models/player/*.zym");
1292         precache_all_playermodels("models/player/*.dpm");
1293         precache_all_playermodels("models/player/*.md3");
1294         precache_all_playermodels("models/player/*.psk");
1295         precache_all_playermodels("models/player/*.iqm");
1296     }
1297
1298     if (autocvar_sv_defaultcharacter)
1299     {
1300         string s;
1301         s = autocvar_sv_defaultplayermodel_red;
1302         if (s != "")
1303             precache_playermodel(s);
1304         s = autocvar_sv_defaultplayermodel_blue;
1305         if (s != "")
1306             precache_playermodel(s);
1307         s = autocvar_sv_defaultplayermodel_yellow;
1308         if (s != "")
1309             precache_playermodel(s);
1310         s = autocvar_sv_defaultplayermodel_pink;
1311         if (s != "")
1312             precache_playermodel(s);
1313         s = autocvar_sv_defaultplayermodel;
1314         if (s != "")
1315             precache_playermodel(s);
1316     }
1317
1318     if (g_footsteps)
1319     {
1320         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1321         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1322     }
1323
1324     // gore and miscellaneous sounds
1325     //precache_sound ("misc/h2ohit.wav");
1326     precache_model ("models/hook.md3");
1327     precache_sound ("misc/armorimpact.wav");
1328     precache_sound ("misc/bodyimpact1.wav");
1329     precache_sound ("misc/bodyimpact2.wav");
1330     precache_sound ("misc/gib.wav");
1331     precache_sound ("misc/gib_splat01.wav");
1332     precache_sound ("misc/gib_splat02.wav");
1333     precache_sound ("misc/gib_splat03.wav");
1334     precache_sound ("misc/gib_splat04.wav");
1335     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1336     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1337     precache_sound ("misc/null.wav");
1338     precache_sound ("misc/spawn.wav");
1339     precache_sound ("misc/talk.wav");
1340     precache_sound ("misc/teleport.wav");
1341     precache_sound ("misc/poweroff.wav");
1342     precache_sound ("player/lava.wav");
1343     precache_sound ("player/slime.wav");
1344
1345     precache_model ("models/sprites/0.spr32");
1346     precache_model ("models/sprites/1.spr32");
1347     precache_model ("models/sprites/2.spr32");
1348     precache_model ("models/sprites/3.spr32");
1349     precache_model ("models/sprites/4.spr32");
1350     precache_model ("models/sprites/5.spr32");
1351     precache_model ("models/sprites/6.spr32");
1352     precache_model ("models/sprites/7.spr32");
1353     precache_model ("models/sprites/8.spr32");
1354     precache_model ("models/sprites/9.spr32");
1355     precache_model ("models/sprites/10.spr32");
1356
1357     // common weapon precaches
1358         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1359     precache_sound ("weapons/weapon_switch.wav");
1360     precache_sound ("weapons/weaponpickup.wav");
1361     precache_sound ("weapons/unavailable.wav");
1362     precache_sound ("weapons/dryfire.wav");
1363     if (g_grappling_hook)
1364     {
1365         precache_sound ("weapons/hook_fire.wav"); // hook
1366         precache_sound ("weapons/hook_impact.wav"); // hook
1367     }
1368
1369     precache_model("models/elaser.mdl");
1370     precache_model("models/laser.mdl");
1371     precache_model("models/ebomb.mdl");
1372
1373 #if 0
1374     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1375
1376     if (!self.noise && self.music) // quake 3 uses the music field
1377         self.noise = self.music;
1378
1379     // plays music for the level if there is any
1380     if (self.noise)
1381     {
1382         precache_sound (self.noise);
1383         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1384     }
1385 #endif
1386
1387 #include "precache-for-csqc.inc"
1388 }
1389
1390 // WARNING: this kills the trace globals
1391 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1392 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1393
1394 #define INITPRIO_FIRST              0
1395 #define INITPRIO_GAMETYPE           0
1396 #define INITPRIO_GAMETYPE_FALLBACK  1
1397 #define INITPRIO_FINDTARGET        10
1398 #define INITPRIO_DROPTOFLOOR       20
1399 #define INITPRIO_SETLOCATION       90
1400 #define INITPRIO_LINKDOORS         91
1401 #define INITPRIO_LAST              99
1402
1403 .void(void) initialize_entity;
1404 .float initialize_entity_order;
1405 .entity initialize_entity_next;
1406 entity initialize_entity_first;
1407
1408 void make_safe_for_remove(entity e)
1409 {
1410     if (e.initialize_entity)
1411     {
1412         entity ent, prev = world;
1413         for (ent = initialize_entity_first; ent; )
1414         {
1415             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1416             {
1417                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1418                 // skip it in linked list
1419                 if (prev)
1420                 {
1421                     prev.initialize_entity_next = ent.initialize_entity_next;
1422                     ent = prev.initialize_entity_next;
1423                 }
1424                 else
1425                 {
1426                     initialize_entity_first = ent.initialize_entity_next;
1427                     ent = initialize_entity_first;
1428                 }
1429             }
1430             else
1431             {
1432                 prev = ent;
1433                 ent = ent.initialize_entity_next;
1434             }
1435         }
1436     }
1437 }
1438
1439 void objerror(string s)
1440 {
1441     make_safe_for_remove(self);
1442     builtin_objerror(s);
1443 }
1444
1445 .float remove_except_protected_forbidden;
1446 void remove_except_protected(entity e)
1447 {
1448         if(e.remove_except_protected_forbidden)
1449                 error("not allowed to remove this at this point");
1450         builtin_remove(e);
1451 }
1452
1453 void remove_unsafely(entity e)
1454 {
1455     if(e.classname == "spike")
1456         error("Removing spikes is forbidden (crylink bug), please report");
1457     builtin_remove(e);
1458 }
1459
1460 void remove_safely(entity e)
1461 {
1462     make_safe_for_remove(e);
1463     builtin_remove(e);
1464 }
1465
1466 void InitializeEntity(entity e, void(void) func, float order)
1467 {
1468     entity prev, cur;
1469
1470     if (!e || e.initialize_entity)
1471     {
1472         // make a proxy initializer entity
1473         entity e_old;
1474         e_old = e;
1475         e = spawn();
1476         e.classname = "initialize_entity";
1477         e.enemy = e_old;
1478     }
1479
1480     e.initialize_entity = func;
1481     e.initialize_entity_order = order;
1482
1483     cur = initialize_entity_first;
1484     prev = world;
1485     for (;;)
1486     {
1487         if (!cur || cur.initialize_entity_order > order)
1488         {
1489             // insert between prev and cur
1490             if (prev)
1491                 prev.initialize_entity_next = e;
1492             else
1493                 initialize_entity_first = e;
1494             e.initialize_entity_next = cur;
1495             return;
1496         }
1497         prev = cur;
1498         cur = cur.initialize_entity_next;
1499     }
1500 }
1501 void InitializeEntitiesRun()
1502 {
1503     entity startoflist;
1504     startoflist = initialize_entity_first;
1505     initialize_entity_first = world;
1506     remove = remove_except_protected;
1507     for (self = startoflist; self; self = self.initialize_entity_next)
1508     {
1509         self.remove_except_protected_forbidden = 1;
1510     }
1511     for (self = startoflist; self; )
1512     {
1513         entity e;
1514         var void(void) func;
1515         e = self.initialize_entity_next;
1516         func = self.initialize_entity;
1517         self.initialize_entity_order = 0;
1518         self.initialize_entity = func_null;
1519         self.initialize_entity_next = world;
1520         self.remove_except_protected_forbidden = 0;
1521         if (self.classname == "initialize_entity")
1522         {
1523             entity e_old;
1524             e_old = self.enemy;
1525             builtin_remove(self);
1526             self = e_old;
1527         }
1528         //dprint("Delayed initialization: ", self.classname, "\n");
1529         if(func)
1530             func();
1531         else
1532         {
1533             eprint(self);
1534             backtrace(strcat("Null function in: ", self.classname, "\n"));
1535         }
1536         self = e;
1537     }
1538     remove = remove_unsafely;
1539 }
1540
1541 .float uncustomizeentityforclient_set;
1542 .void(void) uncustomizeentityforclient;
1543 void UncustomizeEntitiesRun()
1544 {
1545     entity oldself;
1546     oldself = self;
1547     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1548         self.uncustomizeentityforclient();
1549     self = oldself;
1550 }
1551 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1552 {
1553     e.customizeentityforclient = customizer;
1554     e.uncustomizeentityforclient = uncustomizer;
1555     e.uncustomizeentityforclient_set = !!uncustomizer;
1556 }
1557
1558 .float nottargeted;
1559 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1560
1561 void() SUB_Remove;
1562 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1563 {
1564     vector mi, ma;
1565
1566     if (e.classname == "")
1567         e.classname = "net_linked";
1568
1569     if (e.model == "" || self.modelindex == 0)
1570     {
1571         mi = e.mins;
1572         ma = e.maxs;
1573         setmodel(e, "null");
1574         setsize(e, mi, ma);
1575     }
1576
1577     e.SendEntity = sendfunc;
1578     e.SendFlags = 0xFFFFFF;
1579
1580     if (!docull)
1581         e.effects |= EF_NODEPTHTEST;
1582
1583     if (dt)
1584     {
1585         e.nextthink = time + dt;
1586         e.think = SUB_Remove;
1587     }
1588 }
1589
1590
1591 entity eliminatedPlayers;
1592 .float(entity) isEliminated;
1593 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1594 {
1595         float i, f, b;
1596         entity e;
1597         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1598         WriteByte(MSG_ENTITY, sendflags);
1599
1600         if(sendflags & 1)
1601         {
1602                 for(i = 1; i <= maxclients; i += 8)
1603                 {
1604                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1605                         {
1606                                 if(eliminatedPlayers.isEliminated(e))
1607                                         f |= b;
1608                         }
1609                         WriteByte(MSG_ENTITY, f);
1610                 }
1611         }
1612
1613         return TRUE;
1614 }
1615
1616 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1617 {
1618         if(eliminatedPlayers)
1619         {
1620                 backtrace("Can't spawn eliminatedPlayers again!");
1621                 return;
1622         }
1623         Net_LinkEntity(eliminatedPlayers = spawn(), FALSE, 0, EliminatedPlayers_SendEntity);
1624         eliminatedPlayers.isEliminated = isEliminated_func;
1625 }
1626
1627
1628 void adaptor_think2touch()
1629 {
1630     entity o;
1631     o = other;
1632     other = world;
1633     self.touch();
1634     other = o;
1635 }
1636
1637 void adaptor_think2use()
1638 {
1639     entity o, a;
1640     o = other;
1641     a = activator;
1642     activator = world;
1643     other = world;
1644     self.use();
1645     other = o;
1646     activator = a;
1647 }
1648
1649 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1650 {
1651         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1652                 self.projectiledeathtype |= HITTYPE_SPLASH;
1653         adaptor_think2use();
1654 }
1655
1656 // deferred dropping
1657 void DropToFloor_Handler()
1658 {
1659     builtin_droptofloor();
1660     self.dropped_origin = self.origin;
1661 }
1662
1663 void droptofloor()
1664 {
1665     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1666 }
1667
1668
1669
1670 float trace_hits_box_a0, trace_hits_box_a1;
1671
1672 float trace_hits_box_1d(float end, float thmi, float thma)
1673 {
1674     if (end == 0)
1675     {
1676         // just check if x is in range
1677         if (0 < thmi)
1678             return FALSE;
1679         if (0 > thma)
1680             return FALSE;
1681     }
1682     else
1683     {
1684         // do the trace with respect to x
1685         // 0 -> end has to stay in thmi -> thma
1686         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1687         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1688         if (trace_hits_box_a0 > trace_hits_box_a1)
1689             return FALSE;
1690     }
1691     return TRUE;
1692 }
1693
1694 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1695 {
1696     end -= start;
1697     thmi -= start;
1698     thma -= start;
1699     // now it is a trace from 0 to end
1700
1701     trace_hits_box_a0 = 0;
1702     trace_hits_box_a1 = 1;
1703
1704     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1705         return FALSE;
1706     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1707         return FALSE;
1708     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1709         return FALSE;
1710
1711     return TRUE;
1712 }
1713
1714 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1715 {
1716     return trace_hits_box(start, end, thmi - ma, thma - mi);
1717 }
1718
1719 float SUB_NoImpactCheck()
1720 {
1721         // zero hitcontents = this is not the real impact, but either the
1722         // mirror-impact of something hitting the projectile instead of the
1723         // projectile hitting the something, or a touchareagrid one. Neither of
1724         // these stop the projectile from moving, so...
1725         if(trace_dphitcontents == 0)
1726         {
1727                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1728                 dprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1729                 checkclient();
1730         }
1731     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1732         return 1;
1733     if (other == world && self.size != '0 0 0')
1734     {
1735         vector tic;
1736         tic = self.velocity * sys_frametime;
1737         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1738         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1739         if (trace_fraction >= 1)
1740         {
1741             dprint("Odd... did not hit...?\n");
1742         }
1743         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1744         {
1745             dprint("Detected and prevented the sky-grapple bug.\n");
1746             return 1;
1747         }
1748     }
1749
1750     return 0;
1751 }
1752
1753 #define SUB_OwnerCheck() (other && (other == self.owner))
1754
1755 void RemoveGrapplingHook(entity pl);
1756 void W_Crylink_Dequeue(entity e);
1757 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1758 {
1759         if(SUB_OwnerCheck())
1760                 return TRUE;
1761         if(SUB_NoImpactCheck())
1762         {
1763                 if(self.classname == "nade")
1764                         return FALSE; // no checks here
1765                 else if(self.classname == "grapplinghook")
1766                         RemoveGrapplingHook(self.realowner);
1767                 else if(self.classname == "spike")
1768                 {
1769                         W_Crylink_Dequeue(self);
1770                         remove(self);
1771                 }
1772                 else
1773                         remove(self);
1774                 return TRUE;
1775         }
1776         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1777                 UpdateCSQCProjectile(self);
1778         return FALSE;
1779 }
1780 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1781
1782 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1783 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1784
1785 void URI_Get_Callback(float id, float status, string data)
1786 {
1787         if(url_URI_Get_Callback(id, status, data))
1788         {
1789                 // handled
1790         }
1791         else if (id == URI_GET_DISCARD)
1792         {
1793                 // discard
1794         }
1795         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1796         {
1797                 // sv_cmd curl
1798                 Curl_URI_Get_Callback(id, status, data);
1799         }
1800         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1801         {
1802                 // online ban list
1803                 OnlineBanList_URI_Get_Callback(id, status, data);
1804         }
1805         else
1806         {
1807                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1808         }
1809 }
1810
1811 string uid2name(string myuid) {
1812         string s;
1813         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1814
1815         // FIXME remove this later after 0.6 release
1816         // convert old style broken records to correct style
1817         if(s == "")
1818         {
1819                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1820                 if(s != "")
1821                 {
1822                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1823                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1824                 }
1825         }
1826
1827         if(s == "")
1828                 s = "^1Unregistered Player";
1829         return s;
1830 }
1831
1832 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1833 {
1834     float m, i;
1835     vector start, org, delta, end, enddown, mstart;
1836     entity sp;
1837
1838     m = e.dphitcontentsmask;
1839     e.dphitcontentsmask = goodcontents | badcontents;
1840
1841     org = world.mins;
1842     delta = world.maxs - world.mins;
1843
1844     start = end = org;
1845
1846     for (i = 0; i < attempts; ++i)
1847     {
1848         start_x = org_x + random() * delta_x;
1849         start_y = org_y + random() * delta_y;
1850         start_z = org_z + random() * delta_z;
1851
1852         // rule 1: start inside world bounds, and outside
1853         // solid, and don't start from somewhere where you can
1854         // fall down to evil
1855         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1856         if (trace_fraction >= 1)
1857             continue;
1858         if (trace_startsolid)
1859             continue;
1860         if (trace_dphitcontents & badcontents)
1861             continue;
1862         if (trace_dphitq3surfaceflags & badsurfaceflags)
1863             continue;
1864
1865         // rule 2: if we are too high, lower the point
1866         if (trace_fraction * delta_z > maxaboveground)
1867             start = trace_endpos + '0 0 1' * maxaboveground;
1868         enddown = trace_endpos;
1869
1870         // rule 3: make sure we aren't outside the map. This only works
1871         // for somewhat well formed maps. A good rule of thumb is that
1872         // the map should have a convex outside hull.
1873         // these can be traceLINES as we already verified the starting box
1874         mstart = start + 0.5 * (e.mins + e.maxs);
1875         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1876         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1877             continue;
1878         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1879         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1880             continue;
1881         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1882         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1883             continue;
1884         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1885         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1886             continue;
1887         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1888         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1889             continue;
1890
1891         // rule 4: we must "see" some spawnpoint or item
1892         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1893                 if(checkpvs(mstart, sp))
1894                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1895                                 break;
1896         if(!sp)
1897         {
1898                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1899                         if(checkpvs(mstart, sp))
1900                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1901                                         break;
1902                 if(!sp)
1903                         continue;
1904         }
1905
1906         // find a random vector to "look at"
1907         end_x = org_x + random() * delta_x;
1908         end_y = org_y + random() * delta_y;
1909         end_z = org_z + random() * delta_z;
1910         end = start + normalize(end - start) * vlen(delta);
1911
1912         // rule 4: start TO end must not be too short
1913         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1914         if (trace_startsolid)
1915             continue;
1916         if (trace_fraction < minviewdistance / vlen(delta))
1917             continue;
1918
1919         // rule 5: don't want to look at sky
1920         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1921             continue;
1922
1923         // rule 6: we must not end up in trigger_hurt
1924         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1925             continue;
1926
1927         break;
1928     }
1929
1930     e.dphitcontentsmask = m;
1931
1932     if (i < attempts)
1933     {
1934         setorigin(e, start);
1935         e.angles = vectoangles(end - start);
1936         dprint("Needed ", ftos(i + 1), " attempts\n");
1937         return TRUE;
1938     }
1939     else
1940         return FALSE;
1941 }
1942
1943 void write_recordmarker(entity pl, float tstart, float dt)
1944 {
1945     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1946
1947     // also write a marker into demo files for demotc-race-record-extractor to find
1948     stuffcmd(pl,
1949              strcat(
1950                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1951                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1952 }
1953
1954 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1955 {
1956         switch(algn)
1957         {
1958                 default:
1959                 case 3: // right
1960                         break;
1961
1962                 case 4: // left
1963                         vecs_y = -vecs_y;
1964                         break;
1965
1966                 case 1:
1967                         if(allowcenter) // 2: allow center handedness
1968                         {
1969                                 // center
1970                                 vecs_y = 0;
1971                                 vecs_z -= 2;
1972                         }
1973                         else
1974                         {
1975                                 // right
1976                         }
1977                         break;
1978
1979                 case 2:
1980                         if(allowcenter) // 2: allow center handedness
1981                         {
1982                                 // center
1983                                 vecs_y = 0;
1984                                 vecs_z -= 2;
1985                         }
1986                         else
1987                         {
1988                                 // left
1989                                 vecs_y = -vecs_y;
1990                         }
1991                         break;
1992         }
1993         return vecs;
1994 }
1995
1996 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1997 {
1998         string s;
1999         vector v;
2000
2001         if (autocvar_g_shootfromeye)
2002         {
2003                 if (visual)
2004                 {
2005                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2006                         else { vecs_y = 0; vecs_z -= 2; }
2007                 }
2008                 else
2009                 {
2010                         vecs_y = 0;
2011                         vecs_z = 0;
2012                 }
2013         }
2014         else if (autocvar_g_shootfromcenter)
2015         {
2016                 vecs_y = 0;
2017                 vecs_z -= 2;
2018         }
2019         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2020         {
2021                 v = stov(s);
2022                 if (y_is_right)
2023                         v_y = -v_y;
2024                 if (v_x != 0)
2025                         vecs_x = v_x;
2026                 vecs_y = v_y;
2027                 vecs_z = v_z;
2028         }
2029         else if (autocvar_g_shootfromclient)
2030         {
2031                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2032         }
2033         return vecs;
2034 }
2035
2036 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2037 {
2038         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2039 }
2040
2041
2042 void attach_sameorigin(entity e, entity to, string tag)
2043 {
2044     vector org, t_forward, t_left, t_up, e_forward, e_up;
2045     float tagscale;
2046
2047     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2048     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2049     t_forward = v_forward * tagscale;
2050     t_left = v_right * -tagscale;
2051     t_up = v_up * tagscale;
2052
2053     e.origin_x = org * t_forward;
2054     e.origin_y = org * t_left;
2055     e.origin_z = org * t_up;
2056
2057     // current forward and up directions
2058     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2059                 e.angles = AnglesTransform_FromVAngles(e.angles);
2060         else
2061                 e.angles = AnglesTransform_FromAngles(e.angles);
2062     fixedmakevectors(e.angles);
2063
2064     // untransform forward, up!
2065     e_forward_x = v_forward * t_forward;
2066     e_forward_y = v_forward * t_left;
2067     e_forward_z = v_forward * t_up;
2068     e_up_x = v_up * t_forward;
2069     e_up_y = v_up * t_left;
2070     e_up_z = v_up * t_up;
2071
2072     e.angles = fixedvectoangles2(e_forward, e_up);
2073     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2074                 e.angles = AnglesTransform_ToVAngles(e.angles);
2075         else
2076                 e.angles = AnglesTransform_ToAngles(e.angles);
2077
2078     setattachment(e, to, tag);
2079     setorigin(e, e.origin);
2080 }
2081
2082 void detach_sameorigin(entity e)
2083 {
2084     vector org;
2085     org = gettaginfo(e, 0);
2086     e.angles = fixedvectoangles2(v_forward, v_up);
2087     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2088                 e.angles = AnglesTransform_ToVAngles(e.angles);
2089         else
2090                 e.angles = AnglesTransform_ToAngles(e.angles);
2091     setorigin(e, org);
2092     setattachment(e, world, "");
2093     setorigin(e, e.origin);
2094 }
2095
2096 void follow_sameorigin(entity e, entity to)
2097 {
2098     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2099     e.aiment = to; // make the hole follow bmodel
2100     e.punchangle = to.angles; // the original angles of bmodel
2101     e.view_ofs = e.origin - to.origin; // relative origin
2102     e.v_angle = e.angles - to.angles; // relative angles
2103 }
2104
2105 void unfollow_sameorigin(entity e)
2106 {
2107     e.movetype = MOVETYPE_NONE;
2108 }
2109
2110 entity gettaginfo_relative_ent;
2111 vector gettaginfo_relative(entity e, float tag)
2112 {
2113     if (!gettaginfo_relative_ent)
2114     {
2115         gettaginfo_relative_ent = spawn();
2116         gettaginfo_relative_ent.effects = EF_NODRAW;
2117     }
2118     gettaginfo_relative_ent.model = e.model;
2119     gettaginfo_relative_ent.modelindex = e.modelindex;
2120     gettaginfo_relative_ent.frame = e.frame;
2121     return gettaginfo(gettaginfo_relative_ent, tag);
2122 }
2123
2124 .float scale2;
2125
2126 float modeleffect_SendEntity(entity to, float sf)
2127 {
2128         float f;
2129         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2130
2131         f = 0;
2132         if(self.velocity != '0 0 0')
2133                 f |= 1;
2134         if(self.angles != '0 0 0')
2135                 f |= 2;
2136         if(self.avelocity != '0 0 0')
2137                 f |= 4;
2138
2139         WriteByte(MSG_ENTITY, f);
2140         WriteShort(MSG_ENTITY, self.modelindex);
2141         WriteByte(MSG_ENTITY, self.skin);
2142         WriteByte(MSG_ENTITY, self.frame);
2143         WriteCoord(MSG_ENTITY, self.origin_x);
2144         WriteCoord(MSG_ENTITY, self.origin_y);
2145         WriteCoord(MSG_ENTITY, self.origin_z);
2146         if(f & 1)
2147         {
2148                 WriteCoord(MSG_ENTITY, self.velocity_x);
2149                 WriteCoord(MSG_ENTITY, self.velocity_y);
2150                 WriteCoord(MSG_ENTITY, self.velocity_z);
2151         }
2152         if(f & 2)
2153         {
2154                 WriteCoord(MSG_ENTITY, self.angles_x);
2155                 WriteCoord(MSG_ENTITY, self.angles_y);
2156                 WriteCoord(MSG_ENTITY, self.angles_z);
2157         }
2158         if(f & 4)
2159         {
2160                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2161                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2162                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2163         }
2164         WriteShort(MSG_ENTITY, self.scale * 256.0);
2165         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2166         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2167         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2168         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2169
2170         return TRUE;
2171 }
2172
2173 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2174 {
2175         entity e;
2176         float sz;
2177         e = spawn();
2178         e.classname = "modeleffect";
2179         setmodel(e, m);
2180         e.frame = f;
2181         setorigin(e, o);
2182         e.velocity = v;
2183         e.angles = ang;
2184         e.avelocity = angv;
2185         e.alpha = a;
2186         e.teleport_time = t1;
2187         e.fade_time = t2;
2188         e.skin = s;
2189         if(s0 >= 0)
2190                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2191         else
2192                 e.scale = -s0;
2193         if(s2 >= 0)
2194                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2195         else
2196                 e.scale2 = -s2;
2197         sz = max(e.scale, e.scale2);
2198         setsize(e, e.mins * sz, e.maxs * sz);
2199         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2200 }
2201
2202 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2203 {
2204         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2205 }
2206
2207 float randombit(float bits)
2208 {
2209         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2210                 return bits;
2211
2212         float n, f, b, r;
2213
2214         r = random();
2215         b = 0;
2216         n = 0;
2217
2218         for(f = 1; f <= bits; f *= 2)
2219         {
2220                 if(bits & f)
2221                 {
2222                         ++n;
2223                         r *= n;
2224                         if(r <= 1)
2225                                 b = f;
2226                         else
2227                                 r = (r - 1) / (n - 1);
2228                 }
2229         }
2230
2231         return b;
2232 }
2233
2234 float randombits(float bits, float k, float error_return)
2235 {
2236         float r;
2237         r = 0;
2238         while(k > 0 && bits != r)
2239         {
2240                 r += randombit(bits - r);
2241                 --k;
2242         }
2243         if(error_return)
2244                 if(k > 0)
2245                         return -1; // all
2246         return r;
2247 }
2248
2249 void randombit_test(float bits, float iter)
2250 {
2251         while(iter > 0)
2252         {
2253                 print(ftos(randombit(bits)), "\n");
2254                 --iter;
2255         }
2256 }
2257
2258 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2259 {
2260         if(halflifedist > 0)
2261                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2262         else if(halflifedist < 0)
2263                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2264         else
2265                 return 1;
2266 }
2267
2268
2269
2270
2271 #ifdef RELEASE
2272 #define cvar_string_normal builtin_cvar_string
2273 #define cvar_normal builtin_cvar
2274 #else
2275 string cvar_string_normal(string n)
2276 {
2277         if (!(cvar_type(n) & 1))
2278                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2279         return builtin_cvar_string(n);
2280 }
2281
2282 float cvar_normal(string n)
2283 {
2284         return stof(cvar_string_normal(n));
2285 }
2286 #endif
2287 #define cvar_set_normal builtin_cvar_set
2288
2289 void defer_think()
2290 {
2291     entity oself;
2292
2293     oself           = self;
2294     self            = self.owner;
2295     oself.think     = SUB_Remove;
2296     oself.nextthink = time;
2297
2298     oself.use();
2299 }
2300
2301 /*
2302     Execute func() after time + fdelay.
2303     self when func is executed = self when defer is called
2304 */
2305 void defer(float fdelay, void() func)
2306 {
2307     entity e;
2308
2309     e           = spawn();
2310     e.owner     = self;
2311     e.use       = func;
2312     e.think     = defer_think;
2313     e.nextthink = time + fdelay;
2314 }
2315
2316 .string aiment_classname;
2317 .float aiment_deadflag;
2318 void SetMovetypeFollow(entity ent, entity e)
2319 {
2320         // FIXME this may not be warpzone aware
2321         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2322         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2323         ent.aiment = e; // make the hole follow bmodel
2324         ent.punchangle = e.angles; // the original angles of bmodel
2325         ent.view_ofs = ent.origin - e.origin; // relative origin
2326         ent.v_angle = ent.angles - e.angles; // relative angles
2327         ent.aiment_classname = strzone(e.classname);
2328         ent.aiment_deadflag = e.deadflag;
2329 }
2330 void UnsetMovetypeFollow(entity ent)
2331 {
2332         ent.movetype = MOVETYPE_FLY;
2333         PROJECTILE_MAKETRIGGER(ent);
2334         ent.aiment = world;
2335 }
2336 float LostMovetypeFollow(entity ent)
2337 {
2338 /*
2339         if(ent.movetype != MOVETYPE_FOLLOW)
2340                 if(ent.aiment)
2341                         error("???");
2342 */
2343         if(ent.aiment)
2344         {
2345                 if(ent.aiment.classname != ent.aiment_classname)
2346                         return 1;
2347                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2348                         return 1;
2349         }
2350         return 0;
2351 }
2352
2353 float isPushable(entity e)
2354 {
2355         if(e.iscreature)
2356                 return TRUE;
2357         if(e.pushable)
2358                 return TRUE;
2359         switch(e.classname)
2360         {
2361                 case "body":
2362                 case "droppedweapon":
2363                 case "keepawayball":
2364                 case "nexball_basketball":
2365                 case "nexball_football":
2366                         return TRUE;
2367                 case "bullet": // antilagged bullets can't hit this either
2368                         return FALSE;
2369         }
2370         if (e.projectiledeathtype)
2371                 return TRUE;
2372         return FALSE;
2373 }