qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82
  83 string STR_PLAYER = "player";
  84 string STR_SPECTATOR = "spectator";
  85 string STR_OBSERVER = "observer";
  86
  87 #if 0
  88 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  89 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  90 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  91 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  92 #else
  93 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  94 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  95 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  96 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  97 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if(v.classname != STR_PLAYER)
  98 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  99 #endif
 100
 101 #define CENTER_OR_VIEWOFS(ent) (ent.origin + ((ent.classname == STR_PLAYER) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 102
 103 // copies a string to a tempstring (so one can strunzone it)
 104 string strcat1(string s) = #115; // FRIK_FILE
 105
 106 float logfile_open;
 107 float logfile;
 108
 109 void bcenterprint(string s)
 110 {
 111     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 112     entity head;
 113     FOR_EACH_PLAYER(head)
 114     if (clienttype(head) == CLIENTTYPE_REAL)
 115         centerprint(head, s);
 116 }
 117
 118 void GameLogEcho(string s)
 119 {
 120     string fn;
 121     float matches;
 122
 123     if (autocvar_sv_eventlog_files)
 124     {
 125         if (!logfile_open)
 126         {
 127             logfile_open = TRUE;
 128             matches = autocvar_sv_eventlog_files_counter + 1;
 129             cvar_set("sv_eventlog_files_counter", ftos(matches));
 130             fn = ftos(matches);
 131             if (strlen(fn) < 8)
 132                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 133             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 134             logfile = fopen(fn, FILE_APPEND);
 135             fputs(logfile, ":logversion:3\n");
 136         }
 137         if (logfile >= 0)
 138         {
 139             if (autocvar_sv_eventlog_files_timestamps)
 140                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 141             else
 142                 fputs(logfile, strcat(s, "\n"));
 143         }
 144     }
 145     if (autocvar_sv_eventlog_console)
 146     {
 147         print(s, "\n");
 148     }
 149 }
 150
 151 void GameLogInit()
 152 {
 153     logfile_open = 0;
 154     // will be opened later
 155 }
 156
 157 void GameLogClose()
 158 {
 159     if (logfile_open && logfile >= 0)
 160     {
 161         fclose(logfile);
 162         logfile = -1;
 163     }
 164 }
 165
 166 float spawnpoint_nag;
 167 void relocate_spawnpoint()
 168 {
 169     // nudge off the floor
 170     setorigin(self, self.origin + '0 0 1');
 171
 172     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 173     if (trace_startsolid)
 174     {
 175         vector o;
 176         o = self.origin;
 177         self.mins = PL_MIN;
 178         self.maxs = PL_MAX;
 179         if (!move_out_of_solid(self))
 180             objerror("could not get out of solid at all!");
 181         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 182         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 183         print(" ", ftos(self.origin_y - o_y));
 184         print(" ", ftos(self.origin_z - o_z), "'\n");
 185         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 186         {
 187             if (!spawnpoint_nag)
 188                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 189             spawnpoint_nag = 1;
 190         }
 191         else
 192         {
 193             setorigin(self, o);
 194             self.mins = self.maxs = '0 0 0';
 195             objerror("player spawn point in solid, mapper sucks!\n");
 196             return;
 197         }
 198     }
 199
 200     self.use = spawnpoint_use;
 201     self.team_saved = self.team;
 202     if (!self.cnt)
 203         self.cnt = 1;
 204
 205     if (have_team_spawns != 0)
 206         if (self.team)
 207             have_team_spawns = 1;
 208     have_team_spawns_forteam[self.team] = 1;
 209
 210     if (autocvar_r_showbboxes)
 211     {
 212         // show where spawnpoints point at too
 213         makevectors(self.angles);
 214         entity e;
 215         e = spawn();
 216         e.classname = "info_player_foo";
 217         setorigin(e, self.origin + v_forward * 24);
 218         setsize(e, '-8 -8 -8', '8 8 8');
 219         e.solid = SOLID_TRIGGER;
 220     }
 221 }
 222
 223 #define strstr strstrofs
 224 /*
 225 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 226 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 227 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 228 // BE CONSTANT OR strzoneD!
 229 float strstr(string haystack, string needle, float offset)
 230 {
 231         float len, endpos;
 232         string found;
 233         len = strlen(needle);
 234         endpos = strlen(haystack) - len;
 235         while(offset <= endpos)
 236         {
 237                 found = substring(haystack, offset, len);
 238                 if(found == needle)
 239                         return offset;
 240                 offset = offset + 1;
 241         }
 242         return -1;
 243 }
 244 */
 245
 246 float NUM_NEAREST_ENTITIES = 4;
 247 entity nearest_entity[NUM_NEAREST_ENTITIES];
 248 float nearest_length[NUM_NEAREST_ENTITIES];
 249 entity findnearest(vector point, .string field, string value, vector axismod)
 250 {
 251     entity localhead;
 252     float i;
 253     float j;
 254     float len;
 255     vector dist;
 256
 257     float num_nearest;
 258     num_nearest = 0;
 259
 260     localhead = find(world, field, value);
 261     while (localhead)
 262     {
 263         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 264             dist = localhead.oldorigin;
 265         else
 266             dist = localhead.origin;
 267         dist = dist - point;
 268         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 269         len = vlen(dist);
 270
 271         for (i = 0; i < num_nearest; ++i)
 272         {
 273             if (len < nearest_length[i])
 274                 break;
 275         }
 276
 277         // now i tells us where to insert at
 278         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 279         if (i < NUM_NEAREST_ENTITIES)
 280         {
 281             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 282             {
 283                 nearest_length[j + 1] = nearest_length[j];
 284                 nearest_entity[j + 1] = nearest_entity[j];
 285             }
 286             nearest_length[i] = len;
 287             nearest_entity[i] = localhead;
 288             if (num_nearest < NUM_NEAREST_ENTITIES)
 289                 num_nearest = num_nearest + 1;
 290         }
 291
 292         localhead = find(localhead, field, value);
 293     }
 294
 295     // now use the first one from our list that we can see
 296     for (i = 0; i < num_nearest; ++i)
 297     {
 298         traceline(point, nearest_entity[i].origin, TRUE, world);
 299         if (trace_fraction == 1)
 300         {
 301             if (i != 0)
 302             {
 303                 dprint("Nearest point (");
 304                 dprint(nearest_entity[0].netname);
 305                 dprint(") is not visible, using a visible one.\n");
 306             }
 307             return nearest_entity[i];
 308         }
 309     }
 310
 311     if (num_nearest == 0)
 312         return world;
 313
 314     dprint("Not seeing any location point, using nearest as fallback.\n");
 315     /* DEBUGGING CODE:
 316     dprint("Candidates were: ");
 317     for(j = 0; j < num_nearest; ++j)
 318     {
 319         if(j != 0)
 320                 dprint(", ");
 321         dprint(nearest_entity[j].netname);
 322     }
 323     dprint("\n");
 324     */
 325
 326     return nearest_entity[0];
 327 }
 328
 329 void spawnfunc_target_location()
 330 {
 331     self.classname = "target_location";
 332     // location name in netname
 333     // eventually support: count, teamgame selectors, line of sight?
 334 }
 335
 336 void spawnfunc_info_location()
 337 {
 338     self.classname = "target_location";
 339     self.message = self.netname;
 340 }
 341
 342 string NearestLocation(vector p)
 343 {
 344     entity loc;
 345     string ret;
 346     ret = "somewhere";
 347     loc = findnearest(p, classname, "target_location", '1 1 1');
 348     if (loc)
 349     {
 350         ret = loc.message;
 351     }
 352     else
 353     {
 354         loc = findnearest(p, target, "###item###", '1 1 4');
 355         if (loc)
 356             ret = loc.netname;
 357     }
 358     return ret;
 359 }
 360
 361 string formatmessage(string msg)
 362 {
 363         float p, p1, p2;
 364         float n;
 365         vector cursor;
 366         entity cursor_ent;
 367         string escape;
 368         string replacement;
 369         p = 0;
 370         n = 7;
 371
 372         WarpZone_crosshair_trace(self);
 373         cursor = trace_endpos;
 374         cursor_ent = trace_ent;
 375
 376         while (1) {
 377                 if (n < 1)
 378                         break; // too many replacements
 379
 380                 n = n - 1;
 381                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 382                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 383
 384                 if (p1 < 0)
 385                         p1 = p2;
 386
 387                 if (p2 < 0)
 388                         p2 = p1;
 389
 390                 p = min(p1, p2);
 391
 392                 if (p < 0)
 393                         break;
 394
 395                 replacement = substring(msg, p, 2);
 396                 escape = substring(msg, p + 1, 1);
 397
 398                 if (escape == "%")
 399                         replacement = "%";
 400                 else if (escape == "\\")
 401                         replacement = "\\";
 402                 else if (escape == "n")
 403                         replacement = "\n";
 404                 else if (escape == "a")
 405                         replacement = ftos(floor(self.armorvalue));
 406                 else if (escape == "h")
 407                         replacement = ftos(floor(self.health));
 408                 else if (escape == "l")
 409                         replacement = NearestLocation(self.origin);
 410                 else if (escape == "y")
 411                         replacement = NearestLocation(cursor);
 412                 else if (escape == "d")
 413                         replacement = NearestLocation(self.death_origin);
 414                 else if (escape == "w") {
 415                         float wep;
 416                         wep = self.weapon;
 417                         if (!wep)
 418                                 wep = self.switchweapon;
 419                         if (!wep)
 420                                 wep = self.cnt;
 421                         replacement = W_Name(wep);
 422                 } else if (escape == "W") {
 423                         if (self.items & IT_SHELLS) replacement = "shells";
 424                         else if (self.items & IT_NAILS) replacement = "bullets";
 425                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 426                         else if (self.items & IT_CELLS) replacement = "cells";
 427                         else replacement = "batteries"; // ;)
 428                 } else if (escape == "x") {
 429                         replacement = cursor_ent.netname;
 430                         if (replacement == "" || !cursor_ent)
 431                                 replacement = "nothing";
 432                 } else if (escape == "s")
 433                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 434                 else if (escape == "S")
 435                         replacement = ftos(vlen(self.velocity));
 436
 437                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 438                 p = p + strlen(replacement);
 439         }
 440         return msg;
 441 }
 442
 443 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 444         return (value == 0) ? FALSE : TRUE;
 445 }
 446
 447 /*
 448 =============
 449 GetCvars
 450 =============
 451 Called with:
 452   0:  sends the request
 453   >0: receives a cvar from name=argv(f) value=argv(f+1)
 454 */
 455 void GetCvars_handleString(string thisname, float f, .string field, string name)
 456 {
 457         if (f < 0)
 458         {
 459                 if (self.field)
 460                         strunzone(self.field);
 461                 self.field = string_null;
 462         }
 463         else if (f > 0)
 464         {
 465                 if (thisname == name)
 466                 {
 467                         if (self.field)
 468                                 strunzone(self.field);
 469                         self.field = strzone(argv(f + 1));
 470                 }
 471         }
 472         else
 473                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 474 }
 475 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 476 {
 477         GetCvars_handleString(thisname, f, field, name);
 478         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 479                 if (thisname == name)
 480                 {
 481                         string s;
 482                         s = func(strcat1(self.field));
 483                         if (s != self.field)
 484                         {
 485                                 strunzone(self.field);
 486                                 self.field = strzone(s);
 487                         }
 488                 }
 489 }
 490 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 491 {
 492         if (f < 0)
 493         {
 494         }
 495         else if (f > 0)
 496         {
 497                 if (thisname == name)
 498                         self.field = stof(argv(f + 1));
 499         }
 500         else
 501                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 502 }
 503 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 504 {
 505         if (f < 0)
 506         {
 507         }
 508         else if (f > 0)
 509         {
 510                 if (thisname == name)
 511                 {
 512                         if(!self.field)
 513                         {
 514                                 self.field = stof(argv(f + 1));
 515                                 if(!self.field)
 516                                         self.field = -1;
 517                         }
 518                 }
 519         }
 520         else
 521         {
 522                 if(!self.field)
 523                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 524         }
 525 }
 526 float w_getbestweapon(entity e);
 527 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 528 {
 529         string o;
 530         o = W_FixWeaponOrder_ForceComplete(wo);
 531         if(self.weaponorder_byimpulse)
 532         {
 533                 strunzone(self.weaponorder_byimpulse);
 534                 self.weaponorder_byimpulse = string_null;
 535         }
 536         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 537         return o;
 538 }
 539 void GetCvars(float f)
 540 {
 541         string s = string_null;
 542
 543         if (f > 0)
 544                 s = strcat1(argv(f));
 545
 546         get_cvars_f = f;
 547         get_cvars_s = s;
 548         MUTATOR_CALLHOOK(GetCvars);
 549         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 550         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 551         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 552         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 553         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 562         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 563         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 564         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 565         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 566         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 567         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 568         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 569         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 570         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 571         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 572
 573         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 574         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 575
 576 #ifdef ALLOW_FORCEMODELS
 577         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 578         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 579 #endif
 580         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 581         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 582         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 583         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 584         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 585
 586         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 587         if (f > 0)
 588         {
 589                 if (s == "cl_weaponpriority")
 590                         self.switchweapon = w_getbestweapon(self);
 591                 if (s == "cl_allow_uidtracking")
 592                         PlayerStats_AddPlayer(self);
 593         }
 594 }
 595
 596 // decolorizes and team colors the player name when needed
 597 string playername(entity p)
 598 {
 599     string t;
 600     if (teamplay && !intermission_running && p.classname == "player")
 601     {
 602         t = Team_ColorCode(p.team);
 603         return strcat(t, strdecolorize(p.netname));
 604     }
 605     else
 606         return p.netname;
 607 }
 608
 609 vector randompos(vector m1, vector m2)
 610 {
 611     vector v;
 612     m2 = m2 - m1;
 613     v_x = m2_x * random() + m1_x;
 614     v_y = m2_y * random() + m1_y;
 615     v_z = m2_z * random() + m1_z;
 616     return  v;
 617 }
 618
 619 //#NO AUTOCVARS START
 620
 621 float g_pickup_shells;
 622 float g_pickup_shells_max;
 623 float g_pickup_nails;
 624 float g_pickup_nails_max;
 625 float g_pickup_rockets;
 626 float g_pickup_rockets_max;
 627 float g_pickup_cells;
 628 float g_pickup_cells_max;
 629 float g_pickup_fuel;
 630 float g_pickup_fuel_jetpack;
 631 float g_pickup_fuel_max;
 632 float g_pickup_armorsmall;
 633 float g_pickup_armorsmall_max;
 634 float g_pickup_armorsmall_anyway;
 635 float g_pickup_armormedium;
 636 float g_pickup_armormedium_max;
 637 float g_pickup_armormedium_anyway;
 638 float g_pickup_armorbig;
 639 float g_pickup_armorbig_max;
 640 float g_pickup_armorbig_anyway;
 641 float g_pickup_armorlarge;
 642 float g_pickup_armorlarge_max;
 643 float g_pickup_armorlarge_anyway;
 644 float g_pickup_healthsmall;
 645 float g_pickup_healthsmall_max;
 646 float g_pickup_healthsmall_anyway;
 647 float g_pickup_healthmedium;
 648 float g_pickup_healthmedium_max;
 649 float g_pickup_healthmedium_anyway;
 650 float g_pickup_healthlarge;
 651 float g_pickup_healthlarge_max;
 652 float g_pickup_healthlarge_anyway;
 653 float g_pickup_healthmega;
 654 float g_pickup_healthmega_max;
 655 float g_pickup_healthmega_anyway;
 656 float g_pickup_ammo_anyway;
 657 float g_pickup_weapons_anyway;
 658 float g_weaponarena;
 659 WEPSET_DECLARE_A(g_weaponarena_weapons);
 660 float g_weaponarena_random;
 661 float g_weaponarena_random_with_laser;
 662 string g_weaponarena_list;
 663 float g_weaponspeedfactor;
 664 float g_weaponratefactor;
 665 float g_weapondamagefactor;
 666 float g_weaponforcefactor;
 667 float g_weaponspreadfactor;
 668
 669 WEPSET_DECLARE_A(start_weapons);
 670 WEPSET_DECLARE_A(start_weapons_default);
 671 WEPSET_DECLARE_A(start_weapons_defaultmask);
 672 float start_items;
 673 float start_ammo_shells;
 674 float start_ammo_nails;
 675 float start_ammo_rockets;
 676 float start_ammo_cells;
 677 float start_ammo_fuel;
 678 float start_health;
 679 float start_armorvalue;
 680 WEPSET_DECLARE_A(warmup_start_weapons);
 681 WEPSET_DECLARE_A(warmup_start_weapons_default);
 682 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 683 float warmup_start_ammo_shells;
 684 float warmup_start_ammo_nails;
 685 float warmup_start_ammo_rockets;
 686 float warmup_start_ammo_cells;
 687 float warmup_start_ammo_fuel;
 688 float warmup_start_health;
 689 float warmup_start_armorvalue;
 690 float g_weapon_stay;
 691
 692 entity get_weaponinfo(float w);
 693
 694 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 695 {
 696         var float i = weaponinfo.weapon;
 697         var float d = 0;
 698
 699         if (!i)
 700                 return 0;
 701
 702         if (g_lms || g_ca || allguns)
 703         {
 704                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 705                         d = TRUE;
 706                 else
 707                         d = FALSE;
 708         }
 709         else if (g_cts)
 710                 d = (i == WEP_SHOTGUN);
 711         else if (g_nexball)
 712                 d = 0; // weapon is set a few lines later
 713         else
 714                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 715
 716         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 717                 d |= (i == WEP_HOOK);
 718         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 719                 d = 0;
 720
 721         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 722
 723         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 724
 725         // bit order in t:
 726         // 1: want or not
 727         // 2: is default?
 728         // 4: is set by default?
 729         if(t < 0)
 730                 t = 4 | (3 * d);
 731         else
 732                 t |= (2 * d);
 733
 734         return t;
 735 }
 736
 737 void readplayerstartcvars()
 738 {
 739         entity e;
 740         float i, j, t;
 741         string s;
 742
 743         // initialize starting values for players
 744         WEPSET_CLEAR_A(start_weapons);
 745         WEPSET_CLEAR_A(start_weapons_default);
 746         WEPSET_CLEAR_A(start_weapons_defaultmask);
 747         start_items = 0;
 748         start_ammo_shells = 0;
 749         start_ammo_nails = 0;
 750         start_ammo_rockets = 0;
 751         start_ammo_cells = 0;
 752         start_health = cvar("g_balance_health_start");
 753         start_armorvalue = cvar("g_balance_armor_start");
 754
 755         g_weaponarena = 0;
 756         WEPSET_CLEAR_A(g_weaponarena_weapons);
 757
 758         s = cvar_string("g_weaponarena");
 759         if (s == "0" || s == "")
 760         {
 761                 if(g_lms || g_ca)
 762                         s = "most";
 763         }
 764
 765         if (s == "0" || s == "")
 766         {
 767                 // no arena
 768         }
 769         else if (s == "off")
 770         {
 771                 // forcibly turn off weaponarena
 772         }
 773         else if (s == "all")
 774         {
 775                 g_weaponarena = 1;
 776                 g_weaponarena_list = "All Weapons";
 777                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 778                 {
 779                         e = get_weaponinfo(j);
 780                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 781                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 782                 }
 783         }
 784         else if (s == "most")
 785         {
 786                 g_weaponarena = 1;
 787                 g_weaponarena_list = "Most Weapons";
 788                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 789                 {
 790                         e = get_weaponinfo(j);
 791                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 792                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 793                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 794                 }
 795         }
 796         else if (s == "none")
 797         {
 798                 g_weaponarena = 1;
 799                 g_weaponarena_list = "No Weapons";
 800         }
 801         else
 802         {
 803                 g_weaponarena = 1;
 804                 t = tokenize_console(s);
 805                 g_weaponarena_list = "";
 806                 for (i = 0; i < t; ++i)
 807                 {
 808                         s = argv(i);
 809                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 810                         {
 811                                 e = get_weaponinfo(j);
 812                                 if (e.netname == s)
 813                                 {
 814                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 815                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 816                                         break;
 817                                 }
 818                         }
 819                         if (j > WEP_LAST)
 820                         {
 821                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 822                         }
 823                 }
 824                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 825         }
 826
 827         if(g_weaponarena)
 828                 g_weaponarena_random = cvar("g_weaponarena_random");
 829         else
 830                 g_weaponarena_random = 0;
 831         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 832
 833         if (g_weaponarena)
 834         {
 835                 g_minstagib = 0; // incompatible
 836                 g_pinata = 0; // incompatible
 837                 g_weapon_stay = 0; // incompatible
 838                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 839                 if(!(g_lms || g_ca))
 840                         start_items |= IT_UNLIMITED_AMMO;
 841         }
 842         else if (g_minstagib)
 843         {
 844                 g_pinata = 0; // incompatible
 845                 g_weapon_stay = 0; // incompatible
 846                 g_bloodloss = 0; // incompatible
 847                 start_health = 100;
 848                 start_armorvalue = 0;
 849                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 850                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 851                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 852
 853                 if (g_minstagib_invis_alpha <= 0)
 854                         g_minstagib_invis_alpha = -1;
 855         }
 856         else
 857         {
 858                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 859                 {
 860                         e = get_weaponinfo(i);
 861                         float w = want_weapon("g_start_weapon_", e, FALSE);
 862                         if(w & 1)
 863                                 WEPSET_OR_AW(start_weapons, i);
 864                         if(w & 2)
 865                                 WEPSET_OR_AW(start_weapons_default, i);
 866                         if(w & 4)
 867                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 868                 }
 869         }
 870
 871         if(!cvar("g_use_ammunition"))
 872                 start_items |= IT_UNLIMITED_AMMO;
 873
 874         if(cvar("g_nexball"))
 875                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 876
 877         if(g_minstagib)
 878         {
 879                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 880                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 881         }
 882         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 883         {
 884                 start_ammo_rockets = 999;
 885                 start_ammo_shells = 999;
 886                 start_ammo_cells = 999;
 887                 start_ammo_nails = 999;
 888                 start_ammo_fuel = 999;
 889         }
 890         else
 891         {
 892                 if(g_lms || g_ca)
 893                 {
 894                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 895                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 896                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 897                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 898                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 899                 }
 900                 else
 901                 {
 902                         start_ammo_shells = cvar("g_start_ammo_shells");
 903                         start_ammo_nails = cvar("g_start_ammo_nails");
 904                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 905                         start_ammo_cells = cvar("g_start_ammo_cells");
 906                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 907                 }
 908         }
 909
 910         if (g_lms || g_ca)
 911         {
 912                 start_health = cvar("g_lms_start_health");
 913                 start_armorvalue = cvar("g_lms_start_armor");
 914         }
 915
 916         if (inWarmupStage)
 917         {
 918                 warmup_start_ammo_shells = start_ammo_shells;
 919                 warmup_start_ammo_nails = start_ammo_nails;
 920                 warmup_start_ammo_rockets = start_ammo_rockets;
 921                 warmup_start_ammo_cells = start_ammo_cells;
 922                 warmup_start_ammo_fuel = start_ammo_fuel;
 923                 warmup_start_health = start_health;
 924                 warmup_start_armorvalue = start_armorvalue;
 925                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 926                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 927                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 928
 929                 if (!g_weaponarena && !g_minstagib && !g_ca)
 930                 {
 931                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 932                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 933                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 934                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 935                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 936                         warmup_start_health = cvar("g_warmup_start_health");
 937                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 938                         WEPSET_CLEAR_A(warmup_start_weapons);
 939                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 940                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 941                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 942                         {
 943                                 e = get_weaponinfo(i);
 944                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 945                                 if(w & 1)
 946                                         WEPSET_OR_AW(warmup_start_weapons, i);
 947                                 if(w & 2)
 948                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 949                                 if(w & 4)
 950                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 951                         }
 952                 }
 953         }
 954
 955         if (g_jetpack)
 956                 start_items |= IT_JETPACK;
 957
 958         MUTATOR_CALLHOOK(SetStartItems);
 959
 960         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 961         {
 962                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 963                 start_items |= IT_FUEL_REGEN;
 964                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 965                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 966         }
 967
 968         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 969         {
 970                 e = get_weaponinfo(i);
 971                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 972                         weapon_action(i, WR_PRECACHE);
 973         }
 974
 975         start_ammo_shells = max(0, start_ammo_shells);
 976         start_ammo_nails = max(0, start_ammo_nails);
 977         start_ammo_cells = max(0, start_ammo_cells);
 978         start_ammo_rockets = max(0, start_ammo_rockets);
 979         start_ammo_fuel = max(0, start_ammo_fuel);
 980
 981         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 982         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 983         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 984         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 985         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 986 }
 987
 988 float g_bugrigs;
 989 float g_bugrigs_planar_movement;
 990 float g_bugrigs_planar_movement_car_jumping;
 991 float g_bugrigs_reverse_spinning;
 992 float g_bugrigs_reverse_speeding;
 993 float g_bugrigs_reverse_stopping;
 994 float g_bugrigs_air_steering;
 995 float g_bugrigs_angle_smoothing;
 996 float g_bugrigs_friction_floor;
 997 float g_bugrigs_friction_brake;
 998 float g_bugrigs_friction_air;
 999 float g_bugrigs_accel;
1000 float g_bugrigs_speed_ref;
1001 float g_bugrigs_speed_pow;
1002 float g_bugrigs_steer;
1003
1004 float g_touchexplode;
1005 float g_touchexplode_radius;
1006 float g_touchexplode_damage;
1007 float g_touchexplode_edgedamage;
1008 float g_touchexplode_force;
1009
1010 float sv_autotaunt;
1011 float sv_taunt;
1012
1013 float sv_pitch_min;
1014 float sv_pitch_max;
1015 float sv_pitch_fixyaw;
1016
1017 string GetGametype(); // g_world.qc
1018 void readlevelcvars(void)
1019 {
1020         g_minstagib = cvar("g_minstagib");
1021
1022         // load ALL the mutators
1023         if(cvar("g_dodging"))
1024                 MUTATOR_ADD(mutator_dodging);
1025         if(cvar("g_spawn_near_teammate"))
1026                 MUTATOR_ADD(mutator_spawn_near_teammate);
1027         if(cvar("g_physical_items"))
1028                 MUTATOR_ADD(mutator_physical_items);
1029         if(!g_minstagib)
1030         {
1031                 if(cvar("g_invincible_projectiles"))
1032                         MUTATOR_ADD(mutator_invincibleprojectiles);
1033                 if(cvar("g_new_toys"))
1034                         MUTATOR_ADD(mutator_new_toys);
1035                 if(cvar("g_nix"))
1036                         MUTATOR_ADD(mutator_nix);
1037                 if(cvar("g_rocket_flying"))
1038                         MUTATOR_ADD(mutator_rocketflying);
1039                 if(cvar("g_vampire"))
1040                         MUTATOR_ADD(mutator_vampire);
1041                 if(cvar("g_superspectate"))
1042                         MUTATOR_ADD(mutator_superspec);
1043         }
1044
1045         // is this a mutator? is this a mode?
1046         if(cvar("g_sandbox"))
1047                 MUTATOR_ADD(sandbox);
1048
1049         if(cvar("sv_allow_fullbright"))
1050                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1051
1052     g_bugrigs = cvar("g_bugrigs");
1053     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1054     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1055     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1056     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1057     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1058     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1059     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1060     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1061     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1062     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1063     g_bugrigs_accel = cvar("g_bugrigs_accel");
1064     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1065     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1066     g_bugrigs_steer = cvar("g_bugrigs_steer");
1067
1068     g_touchexplode = cvar("g_touchexplode");
1069     g_touchexplode_radius = cvar("g_touchexplode_radius");
1070     g_touchexplode_damage = cvar("g_touchexplode_damage");
1071     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1072     g_touchexplode_force = cvar("g_touchexplode_force");
1073
1074 #ifdef ALLOW_FORCEMODELS
1075         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1076 #endif
1077
1078         sv_clones = cvar("sv_clones");
1079         sv_foginterval = cvar("sv_foginterval");
1080         g_cloaked = cvar("g_cloaked");
1081     if(g_cts)
1082         g_cloaked = 1; // always enable cloak in CTS
1083         g_jump_grunt = cvar("g_jump_grunt");
1084         g_footsteps = cvar("g_footsteps");
1085         g_grappling_hook = cvar("g_grappling_hook");
1086         g_jetpack = cvar("g_jetpack");
1087         g_midair = cvar("g_midair");
1088         g_norecoil = cvar("g_norecoil");
1089         g_bloodloss = cvar("g_bloodloss");
1090         sv_maxidle = cvar("sv_maxidle");
1091         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1092         sv_autotaunt = cvar("sv_autotaunt");
1093         sv_taunt = cvar("sv_taunt");
1094
1095         inWarmupStage = cvar("g_warmup");
1096         g_warmup_limit = cvar("g_warmup_limit");
1097         g_warmup_allguns = cvar("g_warmup_allguns");
1098         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1099
1100         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1101                 inWarmupStage = 0; // these modes cannot work together, sorry
1102
1103         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1104         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1105         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1106         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1107         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1108         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1109         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1110         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1111         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1112         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1113         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1114         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1115         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1116         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1117
1118         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1119         g_weaponratefactor = cvar("g_weaponratefactor");
1120         g_weapondamagefactor = cvar("g_weapondamagefactor");
1121         g_weaponforcefactor = cvar("g_weaponforcefactor");
1122         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1123
1124         g_pickup_shells = cvar("g_pickup_shells");
1125         g_pickup_shells_max = cvar("g_pickup_shells_max");
1126         g_pickup_nails = cvar("g_pickup_nails");
1127         g_pickup_nails_max = cvar("g_pickup_nails_max");
1128         g_pickup_rockets = cvar("g_pickup_rockets");
1129         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1130         g_pickup_cells = cvar("g_pickup_cells");
1131         g_pickup_cells_max = cvar("g_pickup_cells_max");
1132         g_pickup_fuel = cvar("g_pickup_fuel");
1133         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1134         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1135         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1136         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1137         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1138         g_pickup_armormedium = cvar("g_pickup_armormedium");
1139         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1140         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1141         g_pickup_armorbig = cvar("g_pickup_armorbig");
1142         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1143         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1144         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1145         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1146         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1147         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1148         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1149         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1150         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1151         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1152         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1153         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1154         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1155         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1156         g_pickup_healthmega = cvar("g_pickup_healthmega");
1157         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1158         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1159
1160         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1161         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1162
1163         g_pinata = cvar("g_pinata");
1164
1165     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1166     if(!g_weapon_stay)
1167         g_weapon_stay = cvar("g_weapon_stay");
1168
1169         if not(inWarmupStage && !g_ca)
1170                 game_starttime = cvar("g_start_delay");
1171
1172         sv_pitch_min = cvar("sv_pitch_min");
1173         sv_pitch_max = cvar("sv_pitch_max");
1174         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1175
1176         readplayerstartcvars();
1177 }
1178
1179 //#NO AUTOCVARS END
1180
1181 // Sound functions
1182 string precache_sound (string s) = #19;
1183 float precache_sound_index (string s) = #19;
1184
1185 #define SND_VOLUME      1
1186 #define SND_ATTENUATION 2
1187 #define SND_LARGEENTITY 8
1188 #define SND_LARGESOUND  16
1189
1190 float sound_allowed(float dest, entity e)
1191 {
1192     // sounds from world may always pass
1193     for (;;)
1194     {
1195         if (e.classname == "body")
1196             e = e.enemy;
1197         else if (e.realowner && e.realowner != e)
1198             e = e.realowner;
1199         else if (e.owner && e.owner != e)
1200             e = e.owner;
1201         else
1202             break;
1203     }
1204     // sounds to self may always pass
1205     if (dest == MSG_ONE)
1206         if (e == msg_entity)
1207             return TRUE;
1208     // sounds by players can be removed
1209     if (autocvar_bot_sound_monopoly)
1210         if (clienttype(e) == CLIENTTYPE_REAL)
1211             return FALSE;
1212     // anything else may pass
1213     return TRUE;
1214 }
1215
1216 #ifdef COMPAT_XON010_CHANNELS
1217 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1218 void sound(entity e, float chan, string samp, float vol, float atten)
1219 {
1220     if (!sound_allowed(MSG_BROADCAST, e))
1221         return;
1222     builtin_sound(e, chan, samp, vol, atten);
1223 }
1224 #else
1225 #undef sound
1226 void sound(entity e, float chan, string samp, float vol, float atten)
1227 {
1228     if (!sound_allowed(MSG_BROADCAST, e))
1229         return;
1230     sound7(e, chan, samp, vol, atten, 0, 0);
1231 }
1232 #endif
1233
1234 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1235 {
1236     float entno, idx;
1237
1238     if (!sound_allowed(dest, e))
1239         return;
1240
1241     entno = num_for_edict(e);
1242     idx = precache_sound_index(samp);
1243
1244     float sflags;
1245     sflags = 0;
1246
1247     atten = floor(atten * 64);
1248     vol = floor(vol * 255);
1249
1250     if (vol != 255)
1251         sflags |= SND_VOLUME;
1252     if (atten != 64)
1253         sflags |= SND_ATTENUATION;
1254     if (entno >= 8192 || chan < 0 || chan > 7)
1255         sflags |= SND_LARGEENTITY;
1256     if (idx >= 256)
1257         sflags |= SND_LARGESOUND;
1258
1259     WriteByte(dest, SVC_SOUND);
1260     WriteByte(dest, sflags);
1261     if (sflags & SND_VOLUME)
1262         WriteByte(dest, vol);
1263     if (sflags & SND_ATTENUATION)
1264         WriteByte(dest, atten);
1265     if (sflags & SND_LARGEENTITY)
1266     {
1267         WriteShort(dest, entno);
1268         WriteByte(dest, chan);
1269     }
1270     else
1271     {
1272         WriteShort(dest, entno * 8 + chan);
1273     }
1274     if (sflags & SND_LARGESOUND)
1275         WriteShort(dest, idx);
1276     else
1277         WriteByte(dest, idx);
1278
1279     WriteCoord(dest, o_x);
1280     WriteCoord(dest, o_y);
1281     WriteCoord(dest, o_z);
1282 }
1283 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1284 {
1285     vector o;
1286
1287     if (!sound_allowed(dest, e))
1288         return;
1289
1290     o = e.origin + 0.5 * (e.mins + e.maxs);
1291     soundtoat(dest, e, o, chan, samp, vol, atten);
1292 }
1293 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1294 {
1295     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1296 }
1297 void stopsoundto(float dest, entity e, float chan)
1298 {
1299     float entno;
1300
1301     if (!sound_allowed(dest, e))
1302         return;
1303
1304     entno = num_for_edict(e);
1305
1306     if (entno >= 8192 || chan < 0 || chan > 7)
1307     {
1308         float idx, sflags;
1309         idx = precache_sound_index("misc/null.wav");
1310         sflags = SND_LARGEENTITY;
1311         if (idx >= 256)
1312             sflags |= SND_LARGESOUND;
1313         WriteByte(dest, SVC_SOUND);
1314         WriteByte(dest, sflags);
1315         WriteShort(dest, entno);
1316         WriteByte(dest, chan);
1317         if (sflags & SND_LARGESOUND)
1318             WriteShort(dest, idx);
1319         else
1320             WriteByte(dest, idx);
1321         WriteCoord(dest, e.origin_x);
1322         WriteCoord(dest, e.origin_y);
1323         WriteCoord(dest, e.origin_z);
1324     }
1325     else
1326     {
1327         WriteByte(dest, SVC_STOPSOUND);
1328         WriteShort(dest, entno * 8 + chan);
1329     }
1330 }
1331 void stopsound(entity e, float chan)
1332 {
1333     if (!sound_allowed(MSG_BROADCAST, e))
1334         return;
1335
1336     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1337     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1338 }
1339
1340 void play2(entity e, string filename)
1341 {
1342     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1343     msg_entity = e;
1344     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1345 }
1346
1347 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1348 .float spamtime;
1349 float spamsound(entity e, float chan, string samp, float vol, float atten)
1350 {
1351     if (!sound_allowed(MSG_BROADCAST, e))
1352         return FALSE;
1353
1354     if (time > e.spamtime)
1355     {
1356         e.spamtime = time;
1357         sound(e, chan, samp, vol, atten);
1358         return TRUE;
1359     }
1360     return FALSE;
1361 }
1362
1363 void play2team(float t, string filename)
1364 {
1365     entity head;
1366
1367     if (autocvar_bot_sound_monopoly)
1368         return;
1369
1370     FOR_EACH_REALPLAYER(head)
1371     {
1372         if (head.team == t)
1373             play2(head, filename);
1374     }
1375 }
1376
1377 void play2all(string samp)
1378 {
1379     if (autocvar_bot_sound_monopoly)
1380         return;
1381
1382     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1383 }
1384
1385 void PrecachePlayerSounds(string f);
1386 void precache_playermodel(string m)
1387 {
1388         float globhandle, i, n;
1389         string f;
1390
1391         if(substring(m, -9,5) == "_lod1")
1392                 return;
1393         if(substring(m, -9,5) == "_lod2")
1394                 return;
1395         precache_model(m);
1396         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1397         if(fexists(f))
1398                 precache_model(f);
1399         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1400         if(fexists(f))
1401                 precache_model(f);
1402
1403         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1404         if (globhandle < 0)
1405                 return;
1406         n = search_getsize(globhandle);
1407         for (i = 0; i < n; ++i)
1408         {
1409                 //print(search_getfilename(globhandle, i), "\n");
1410                 f = search_getfilename(globhandle, i);
1411                 PrecachePlayerSounds(f);
1412         }
1413         search_end(globhandle);
1414 }
1415 void precache_all_playermodels(string pattern)
1416 {
1417         float globhandle, i, n;
1418         string f;
1419
1420         globhandle = search_begin(pattern, TRUE, FALSE);
1421         if (globhandle < 0)
1422                 return;
1423         n = search_getsize(globhandle);
1424         for (i = 0; i < n; ++i)
1425         {
1426                 //print(search_getfilename(globhandle, i), "\n");
1427                 f = search_getfilename(globhandle, i);
1428                 precache_playermodel(f);
1429         }
1430         search_end(globhandle);
1431 }
1432
1433 void precache()
1434 {
1435     // gamemode related things
1436     precache_model ("models/misc/chatbubble.spr");
1437     if (g_runematch)
1438     {
1439         precache_model ("models/runematch/curse.mdl");
1440         precache_model ("models/runematch/rune.mdl");
1441     }
1442
1443 #ifdef TTURRETS_ENABLED
1444     if (autocvar_g_turrets)
1445         turrets_precash();
1446 #endif
1447
1448     // Precache all player models if desired
1449     if (autocvar_sv_precacheplayermodels)
1450     {
1451         PrecachePlayerSounds("sound/player/default.sounds");
1452         precache_all_playermodels("models/player/*.zym");
1453         precache_all_playermodels("models/player/*.dpm");
1454         precache_all_playermodels("models/player/*.md3");
1455         precache_all_playermodels("models/player/*.psk");
1456         precache_all_playermodels("models/player/*.iqm");
1457     }
1458
1459     if (autocvar_sv_defaultcharacter)
1460     {
1461         string s;
1462         s = autocvar_sv_defaultplayermodel_red;
1463         if (s != "")
1464             precache_playermodel(s);
1465         s = autocvar_sv_defaultplayermodel_blue;
1466         if (s != "")
1467             precache_playermodel(s);
1468         s = autocvar_sv_defaultplayermodel_yellow;
1469         if (s != "")
1470             precache_playermodel(s);
1471         s = autocvar_sv_defaultplayermodel_pink;
1472         if (s != "")
1473             precache_playermodel(s);
1474         s = autocvar_sv_defaultplayermodel;
1475         if (s != "")
1476             precache_playermodel(s);
1477     }
1478
1479     if (g_footsteps)
1480     {
1481         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1482         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1483     }
1484
1485     // gore and miscellaneous sounds
1486     //precache_sound ("misc/h2ohit.wav");
1487     precache_model ("models/hook.md3");
1488     precache_sound ("misc/armorimpact.wav");
1489     precache_sound ("misc/bodyimpact1.wav");
1490     precache_sound ("misc/bodyimpact2.wav");
1491     precache_sound ("misc/gib.wav");
1492     precache_sound ("misc/gib_splat01.wav");
1493     precache_sound ("misc/gib_splat02.wav");
1494     precache_sound ("misc/gib_splat03.wav");
1495     precache_sound ("misc/gib_splat04.wav");
1496     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1497     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1498     precache_sound ("misc/null.wav");
1499     precache_sound ("misc/spawn.wav");
1500     precache_sound ("misc/talk.wav");
1501     precache_sound ("misc/teleport.wav");
1502     precache_sound ("misc/poweroff.wav");
1503     precache_sound ("player/lava.wav");
1504     precache_sound ("player/slime.wav");
1505
1506     precache_model ("models/sprites/0.spr32");
1507     precache_model ("models/sprites/1.spr32");
1508     precache_model ("models/sprites/2.spr32");
1509     precache_model ("models/sprites/3.spr32");
1510     precache_model ("models/sprites/4.spr32");
1511     precache_model ("models/sprites/5.spr32");
1512     precache_model ("models/sprites/6.spr32");
1513     precache_model ("models/sprites/7.spr32");
1514     precache_model ("models/sprites/8.spr32");
1515     precache_model ("models/sprites/9.spr32");
1516     precache_model ("models/sprites/10.spr32");
1517
1518     // common weapon precaches
1519         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1520     precache_sound ("weapons/weapon_switch.wav");
1521     precache_sound ("weapons/weaponpickup.wav");
1522     precache_sound ("weapons/unavailable.wav");
1523     precache_sound ("weapons/dryfire.wav");
1524     if (g_grappling_hook)
1525     {
1526         precache_sound ("weapons/hook_fire.wav"); // hook
1527         precache_sound ("weapons/hook_impact.wav"); // hook
1528     }
1529
1530     if(autocvar_sv_precacheweapons)
1531     {
1532         //precache weapon models/sounds
1533         float wep;
1534         wep = WEP_FIRST;
1535         while (wep <= WEP_LAST)
1536         {
1537             weapon_action(wep, WR_PRECACHE);
1538             wep = wep + 1;
1539         }
1540     }
1541
1542     precache_model("models/elaser.mdl");
1543     precache_model("models/laser.mdl");
1544     precache_model("models/ebomb.mdl");
1545
1546 #if 0
1547     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1548
1549     if (!self.noise && self.music) // quake 3 uses the music field
1550         self.noise = self.music;
1551
1552     // plays music for the level if there is any
1553     if (self.noise)
1554     {
1555         precache_sound (self.noise);
1556         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1557     }
1558 #endif
1559 }
1560
1561 // WARNING: this kills the trace globals
1562 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1563 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1564
1565 #define INITPRIO_FIRST              0
1566 #define INITPRIO_GAMETYPE           0
1567 #define INITPRIO_GAMETYPE_FALLBACK  1
1568 #define INITPRIO_FINDTARGET        10
1569 #define INITPRIO_DROPTOFLOOR       20
1570 #define INITPRIO_SETLOCATION       90
1571 #define INITPRIO_LINKDOORS         91
1572 #define INITPRIO_LAST              99
1573
1574 .void(void) initialize_entity;
1575 .float initialize_entity_order;
1576 .entity initialize_entity_next;
1577 entity initialize_entity_first;
1578
1579 void make_safe_for_remove(entity e)
1580 {
1581     if (e.initialize_entity)
1582     {
1583         entity ent, prev = world;
1584         for (ent = initialize_entity_first; ent; )
1585         {
1586             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1587             {
1588                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1589                 // skip it in linked list
1590                 if (prev)
1591                 {
1592                     prev.initialize_entity_next = ent.initialize_entity_next;
1593                     ent = prev.initialize_entity_next;
1594                 }
1595                 else
1596                 {
1597                     initialize_entity_first = ent.initialize_entity_next;
1598                     ent = initialize_entity_first;
1599                 }
1600             }
1601             else
1602             {
1603                 prev = ent;
1604                 ent = ent.initialize_entity_next;
1605             }
1606         }
1607     }
1608 }
1609
1610 void objerror(string s)
1611 {
1612     make_safe_for_remove(self);
1613     builtin_objerror(s);
1614 }
1615
1616 .float remove_except_protected_forbidden;
1617 void remove_except_protected(entity e)
1618 {
1619         if(e.remove_except_protected_forbidden)
1620                 error("not allowed to remove this at this point");
1621         builtin_remove(e);
1622 }
1623
1624 void remove_unsafely(entity e)
1625 {
1626     if(e.classname == "spike")
1627         error("Removing spikes is forbidden (crylink bug), please report");
1628     builtin_remove(e);
1629 }
1630
1631 void remove_safely(entity e)
1632 {
1633     make_safe_for_remove(e);
1634     builtin_remove(e);
1635 }
1636
1637 void InitializeEntity(entity e, void(void) func, float order)
1638 {
1639     entity prev, cur;
1640
1641     if (!e || e.initialize_entity)
1642     {
1643         // make a proxy initializer entity
1644         entity e_old;
1645         e_old = e;
1646         e = spawn();
1647         e.classname = "initialize_entity";
1648         e.enemy = e_old;
1649     }
1650
1651     e.initialize_entity = func;
1652     e.initialize_entity_order = order;
1653
1654     cur = initialize_entity_first;
1655     prev = world;
1656     for (;;)
1657     {
1658         if (!cur || cur.initialize_entity_order > order)
1659         {
1660             // insert between prev and cur
1661             if (prev)
1662                 prev.initialize_entity_next = e;
1663             else
1664                 initialize_entity_first = e;
1665             e.initialize_entity_next = cur;
1666             return;
1667         }
1668         prev = cur;
1669         cur = cur.initialize_entity_next;
1670     }
1671 }
1672 void InitializeEntitiesRun()
1673 {
1674     entity startoflist;
1675     startoflist = initialize_entity_first;
1676     initialize_entity_first = world;
1677     remove = remove_except_protected;
1678     for (self = startoflist; self; self = self.initialize_entity_next)
1679     {
1680         self.remove_except_protected_forbidden = 1;
1681     }
1682     for (self = startoflist; self; )
1683     {
1684         entity e;
1685         var void(void) func;
1686         e = self.initialize_entity_next;
1687         func = self.initialize_entity;
1688         self.initialize_entity_order = 0;
1689         self.initialize_entity = func_null;
1690         self.initialize_entity_next = world;
1691         self.remove_except_protected_forbidden = 0;
1692         if (self.classname == "initialize_entity")
1693         {
1694             entity e_old;
1695             e_old = self.enemy;
1696             builtin_remove(self);
1697             self = e_old;
1698         }
1699         //dprint("Delayed initialization: ", self.classname, "\n");
1700         if(func)
1701             func();
1702         else
1703         {
1704             eprint(self);
1705             backtrace(strcat("Null function in: ", self.classname, "\n"));
1706         }
1707         self = e;
1708     }
1709     remove = remove_unsafely;
1710 }
1711
1712 .float uncustomizeentityforclient_set;
1713 .void(void) uncustomizeentityforclient;
1714 void UncustomizeEntitiesRun()
1715 {
1716     entity oldself;
1717     oldself = self;
1718     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1719         self.uncustomizeentityforclient();
1720     self = oldself;
1721 }
1722 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1723 {
1724     e.customizeentityforclient = customizer;
1725     e.uncustomizeentityforclient = uncustomizer;
1726     e.uncustomizeentityforclient_set = !!uncustomizer;
1727 }
1728
1729 .float nottargeted;
1730 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1731
1732 void() SUB_Remove;
1733 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1734 {
1735     vector mi, ma;
1736
1737     if (e.classname == "")
1738         e.classname = "net_linked";
1739
1740     if (e.model == "" || self.modelindex == 0)
1741     {
1742         mi = e.mins;
1743         ma = e.maxs;
1744         setmodel(e, "null");
1745         setsize(e, mi, ma);
1746     }
1747
1748     e.SendEntity = sendfunc;
1749     e.SendFlags = 0xFFFFFF;
1750
1751     if (!docull)
1752         e.effects |= EF_NODEPTHTEST;
1753
1754     if (dt)
1755     {
1756         e.nextthink = time + dt;
1757         e.think = SUB_Remove;
1758     }
1759 }
1760
1761 void adaptor_think2touch()
1762 {
1763     entity o;
1764     o = other;
1765     other = world;
1766     self.touch();
1767     other = o;
1768 }
1769
1770 void adaptor_think2use()
1771 {
1772     entity o, a;
1773     o = other;
1774     a = activator;
1775     activator = world;
1776     other = world;
1777     self.use();
1778     other = o;
1779     activator = a;
1780 }
1781
1782 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1783 {
1784         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1785                 self.projectiledeathtype |= HITTYPE_SPLASH;
1786         adaptor_think2use();
1787 }
1788
1789 // deferred dropping
1790 void DropToFloor_Handler()
1791 {
1792     builtin_droptofloor();
1793     self.dropped_origin = self.origin;
1794 }
1795
1796 void droptofloor()
1797 {
1798     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1799 }
1800
1801
1802
1803 float trace_hits_box_a0, trace_hits_box_a1;
1804
1805 float trace_hits_box_1d(float end, float thmi, float thma)
1806 {
1807     if (end == 0)
1808     {
1809         // just check if x is in range
1810         if (0 < thmi)
1811             return FALSE;
1812         if (0 > thma)
1813             return FALSE;
1814     }
1815     else
1816     {
1817         // do the trace with respect to x
1818         // 0 -> end has to stay in thmi -> thma
1819         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1820         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1821         if (trace_hits_box_a0 > trace_hits_box_a1)
1822             return FALSE;
1823     }
1824     return TRUE;
1825 }
1826
1827 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1828 {
1829     end -= start;
1830     thmi -= start;
1831     thma -= start;
1832     // now it is a trace from 0 to end
1833
1834     trace_hits_box_a0 = 0;
1835     trace_hits_box_a1 = 1;
1836
1837     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1838         return FALSE;
1839     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1840         return FALSE;
1841     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1842         return FALSE;
1843
1844     return TRUE;
1845 }
1846
1847 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1848 {
1849     return trace_hits_box(start, end, thmi - ma, thma - mi);
1850 }
1851
1852 float SUB_NoImpactCheck()
1853 {
1854         // zero hitcontents = this is not the real impact, but either the
1855         // mirror-impact of something hitting the projectile instead of the
1856         // projectile hitting the something, or a touchareagrid one. Neither of
1857         // these stop the projectile from moving, so...
1858         if(trace_dphitcontents == 0)
1859         {
1860                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1861                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1862                 checkclient();
1863         }
1864     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1865         return 1;
1866     if (other == world && self.size != '0 0 0')
1867     {
1868         vector tic;
1869         tic = self.velocity * sys_frametime;
1870         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1871         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1872         if (trace_fraction >= 1)
1873         {
1874             dprint("Odd... did not hit...?\n");
1875         }
1876         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1877         {
1878             dprint("Detected and prevented the sky-grapple bug.\n");
1879             return 1;
1880         }
1881     }
1882
1883     return 0;
1884 }
1885
1886 #define SUB_OwnerCheck() (other && (other == self.owner))
1887
1888 void RemoveGrapplingHook(entity pl);
1889 void W_Crylink_Dequeue(entity e);
1890 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1891 {
1892         if(SUB_OwnerCheck())
1893                 return TRUE;
1894         if(SUB_NoImpactCheck())
1895         {
1896                 if(self.classname == "grapplinghook")
1897                         RemoveGrapplingHook(self.realowner);
1898                 else if(self.classname == "spike")
1899                 {
1900                         W_Crylink_Dequeue(self);
1901                         remove(self);
1902                 }
1903                 else
1904                         remove(self);
1905                 return TRUE;
1906         }
1907         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1908                 UpdateCSQCProjectile(self);
1909         return FALSE;
1910 }
1911 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1912
1913 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1914 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1915
1916 void URI_Get_Callback(float id, float status, string data)
1917 {
1918         if(url_URI_Get_Callback(id, status, data))
1919         {
1920                 // handled
1921         }
1922         else if (id == URI_GET_DISCARD)
1923         {
1924                 // discard
1925         }
1926         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1927         {
1928                 // sv_cmd curl
1929                 Curl_URI_Get_Callback(id, status, data);
1930         }
1931         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1932         {
1933                 // online ban list
1934                 OnlineBanList_URI_Get_Callback(id, status, data);
1935         }
1936         else
1937         {
1938                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1939         }
1940 }
1941
1942 string uid2name(string myuid) {
1943         string s;
1944         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1945
1946         // FIXME remove this later after 0.6 release
1947         // convert old style broken records to correct style
1948         if(s == "")
1949         {
1950                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1951                 if(s != "")
1952                 {
1953                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1954                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1955                 }
1956         }
1957
1958         if(s == "")
1959                 s = "^1Unregistered Player";
1960         return s;
1961 }
1962
1963 float race_readTime(string map, float pos)
1964 {
1965         string rr;
1966         if(g_cts)
1967                 rr = CTS_RECORD;
1968         else
1969                 rr = RACE_RECORD;
1970
1971         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1972 }
1973
1974 string race_readUID(string map, float pos)
1975 {
1976         string rr;
1977         if(g_cts)
1978                 rr = CTS_RECORD;
1979         else
1980                 rr = RACE_RECORD;
1981
1982         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1983 }
1984
1985 float race_readPos(string map, float t) {
1986         float i;
1987         for (i = 1; i <= RANKINGS_CNT; ++i)
1988                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1989                         return i;
1990
1991         return 0; // pos is zero if unranked
1992 }
1993
1994 void race_writeTime(string map, float t, string myuid)
1995 {
1996         string rr;
1997         if(g_cts)
1998                 rr = CTS_RECORD;
1999         else
2000                 rr = RACE_RECORD;
2001
2002         float newpos;
2003         newpos = race_readPos(map, t);
2004
2005         float i, prevpos = 0;
2006         for(i = 1; i <= RANKINGS_CNT; ++i)
2007         {
2008                 if(race_readUID(map, i) == myuid)
2009                         prevpos = i;
2010         }
2011         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2012                 for (i = prevpos; i > newpos; --i) {
2013                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2014                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2015                 }
2016         } else { // player has no ranked record yet
2017                 for (i = RANKINGS_CNT; i > newpos; --i) {
2018                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2019                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2020                 }
2021         }
2022
2023         // store new time itself
2024         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2025         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2026 }
2027
2028 string race_readName(string map, float pos)
2029 {
2030         string rr;
2031         if(g_cts)
2032                 rr = CTS_RECORD;
2033         else
2034                 rr = RACE_RECORD;
2035
2036         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2037 }
2038
2039 string race_placeName(float pos) {
2040         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2041         {
2042                 if(mod(pos, 10) == 1)
2043                         return strcat(ftos(pos), "st");
2044                 else if(mod(pos, 10) == 2)
2045                         return strcat(ftos(pos), "nd");
2046                 else if(mod(pos, 10) == 3)
2047                         return strcat(ftos(pos), "rd");
2048                 else
2049                         return strcat(ftos(pos), "th");
2050         }
2051         else
2052                 return strcat(ftos(pos), "th");
2053 }
2054
2055 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2056 {
2057     float m, i;
2058     vector start, org, delta, end, enddown, mstart;
2059     entity sp;
2060
2061     m = e.dphitcontentsmask;
2062     e.dphitcontentsmask = goodcontents | badcontents;
2063
2064     org = world.mins;
2065     delta = world.maxs - world.mins;
2066
2067     start = end = org;
2068
2069     for (i = 0; i < attempts; ++i)
2070     {
2071         start_x = org_x + random() * delta_x;
2072         start_y = org_y + random() * delta_y;
2073         start_z = org_z + random() * delta_z;
2074
2075         // rule 1: start inside world bounds, and outside
2076         // solid, and don't start from somewhere where you can
2077         // fall down to evil
2078         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2079         if (trace_fraction >= 1)
2080             continue;
2081         if (trace_startsolid)
2082             continue;
2083         if (trace_dphitcontents & badcontents)
2084             continue;
2085         if (trace_dphitq3surfaceflags & badsurfaceflags)
2086             continue;
2087
2088         // rule 2: if we are too high, lower the point
2089         if (trace_fraction * delta_z > maxaboveground)
2090             start = trace_endpos + '0 0 1' * maxaboveground;
2091         enddown = trace_endpos;
2092
2093         // rule 3: make sure we aren't outside the map. This only works
2094         // for somewhat well formed maps. A good rule of thumb is that
2095         // the map should have a convex outside hull.
2096         // these can be traceLINES as we already verified the starting box
2097         mstart = start + 0.5 * (e.mins + e.maxs);
2098         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2099         if (trace_fraction >= 1)
2100             continue;
2101         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2102         if (trace_fraction >= 1)
2103             continue;
2104         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2105         if (trace_fraction >= 1)
2106             continue;
2107         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2108         if (trace_fraction >= 1)
2109             continue;
2110         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2111         if (trace_fraction >= 1)
2112             continue;
2113
2114         // rule 4: we must "see" some spawnpoint
2115         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2116                 if(checkpvs(mstart, sp))
2117                         break;
2118         if(!sp)
2119         {
2120                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2121                         if(checkpvs(mstart, sp))
2122                                 break;
2123                 if(!sp)
2124                         continue;
2125         }
2126
2127         // find a random vector to "look at"
2128         end_x = org_x + random() * delta_x;
2129         end_y = org_y + random() * delta_y;
2130         end_z = org_z + random() * delta_z;
2131         end = start + normalize(end - start) * vlen(delta);
2132
2133         // rule 4: start TO end must not be too short
2134         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2135         if (trace_startsolid)
2136             continue;
2137         if (trace_fraction < minviewdistance / vlen(delta))
2138             continue;
2139
2140         // rule 5: don't want to look at sky
2141         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2142             continue;
2143
2144         // rule 6: we must not end up in trigger_hurt
2145         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2146             continue;
2147
2148         break;
2149     }
2150
2151     e.dphitcontentsmask = m;
2152
2153     if (i < attempts)
2154     {
2155         setorigin(e, start);
2156         e.angles = vectoangles(end - start);
2157         dprint("Needed ", ftos(i + 1), " attempts\n");
2158         return TRUE;
2159     }
2160     else
2161         return FALSE;
2162 }
2163
2164 float zcurveparticles_effectno;
2165 vector zcurveparticles_start;
2166 float zcurveparticles_spd;
2167
2168 void endzcurveparticles()
2169 {
2170         if(zcurveparticles_effectno)
2171         {
2172                 // terminator
2173                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2174         }
2175         zcurveparticles_effectno = 0;
2176 }
2177
2178 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2179 {
2180         spd = bound(0, floor(spd / 16), 32767);
2181         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2182         {
2183                 endzcurveparticles();
2184                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2185                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2186                 WriteShort(MSG_BROADCAST, effectno);
2187                 WriteCoord(MSG_BROADCAST, start_x);
2188                 WriteCoord(MSG_BROADCAST, start_y);
2189                 WriteCoord(MSG_BROADCAST, start_z);
2190                 zcurveparticles_effectno = effectno;
2191                 zcurveparticles_start = start;
2192         }
2193         else
2194                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2195         WriteCoord(MSG_BROADCAST, end_x);
2196         WriteCoord(MSG_BROADCAST, end_y);
2197         WriteCoord(MSG_BROADCAST, end_z);
2198         WriteCoord(MSG_BROADCAST, end_dz);
2199         zcurveparticles_spd = spd;
2200 }
2201
2202 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2203 {
2204         float end_dz;
2205         vector vecxy, velxy;
2206
2207         vecxy = end - start;
2208         vecxy_z = 0;
2209         velxy = vel;
2210         velxy_z = 0;
2211
2212         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2213         {
2214                 endzcurveparticles();
2215                 trailparticles(world, effectno, start, end);
2216                 return;
2217         }
2218
2219         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2220         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2221 }
2222
2223 void write_recordmarker(entity pl, float tstart, float dt)
2224 {
2225     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2226
2227     // also write a marker into demo files for demotc-race-record-extractor to find
2228     stuffcmd(pl,
2229              strcat(
2230                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2231                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2232 }
2233
2234 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2235 {
2236         switch(algn)
2237         {
2238                 default:
2239                 case 3: // right
2240                         break;
2241
2242                 case 4: // left
2243                         vecs_y = -vecs_y;
2244                         break;
2245
2246                 case 1:
2247                         if(allowcenter) // 2: allow center handedness
2248                         {
2249                                 // center
2250                                 vecs_y = 0;
2251                                 vecs_z -= 2;
2252                         }
2253                         else
2254                         {
2255                                 // right
2256                         }
2257                         break;
2258
2259                 case 2:
2260                         if(allowcenter) // 2: allow center handedness
2261                         {
2262                                 // center
2263                                 vecs_y = 0;
2264                                 vecs_z -= 2;
2265                         }
2266                         else
2267                         {
2268                                 // left
2269                                 vecs_y = -vecs_y;
2270                         }
2271                         break;
2272         }
2273         return vecs;
2274 }
2275
2276 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2277 {
2278         string s;
2279         vector v;
2280
2281         if (autocvar_g_shootfromeye)
2282         {
2283                 if (visual)
2284                 {
2285                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2286                         else { vecs_y = 0; vecs_z -= 2; }
2287                 }
2288                 else
2289                 {
2290                         vecs_y = 0;
2291                         vecs_z = 0;
2292                 }
2293         }
2294         else if (autocvar_g_shootfromcenter)
2295         {
2296                 vecs_y = 0;
2297                 vecs_z -= 2;
2298         }
2299         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2300         {
2301                 v = stov(s);
2302                 if (y_is_right)
2303                         v_y = -v_y;
2304                 if (v_x != 0)
2305                         vecs_x = v_x;
2306                 vecs_y = v_y;
2307                 vecs_z = v_z;
2308         }
2309         else if (autocvar_g_shootfromclient)
2310         {
2311                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2312         }
2313         return vecs;
2314 }
2315
2316 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2317 {
2318         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2319 }
2320
2321
2322 void attach_sameorigin(entity e, entity to, string tag)
2323 {
2324     vector org, t_forward, t_left, t_up, e_forward, e_up;
2325     float tagscale;
2326
2327     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2328     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2329     t_forward = v_forward * tagscale;
2330     t_left = v_right * -tagscale;
2331     t_up = v_up * tagscale;
2332
2333     e.origin_x = org * t_forward;
2334     e.origin_y = org * t_left;
2335     e.origin_z = org * t_up;
2336
2337     // current forward and up directions
2338     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2339                 e.angles = AnglesTransform_FromVAngles(e.angles);
2340         else
2341                 e.angles = AnglesTransform_FromAngles(e.angles);
2342     fixedmakevectors(e.angles);
2343
2344     // untransform forward, up!
2345     e_forward_x = v_forward * t_forward;
2346     e_forward_y = v_forward * t_left;
2347     e_forward_z = v_forward * t_up;
2348     e_up_x = v_up * t_forward;
2349     e_up_y = v_up * t_left;
2350     e_up_z = v_up * t_up;
2351
2352     e.angles = fixedvectoangles2(e_forward, e_up);
2353     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2354                 e.angles = AnglesTransform_ToVAngles(e.angles);
2355         else
2356                 e.angles = AnglesTransform_ToAngles(e.angles);
2357
2358     setattachment(e, to, tag);
2359     setorigin(e, e.origin);
2360 }
2361
2362 void detach_sameorigin(entity e)
2363 {
2364     vector org;
2365     org = gettaginfo(e, 0);
2366     e.angles = fixedvectoangles2(v_forward, v_up);
2367     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2368                 e.angles = AnglesTransform_ToVAngles(e.angles);
2369         else
2370                 e.angles = AnglesTransform_ToAngles(e.angles);
2371     setorigin(e, org);
2372     setattachment(e, world, "");
2373     setorigin(e, e.origin);
2374 }
2375
2376 void follow_sameorigin(entity e, entity to)
2377 {
2378     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2379     e.aiment = to; // make the hole follow bmodel
2380     e.punchangle = to.angles; // the original angles of bmodel
2381     e.view_ofs = e.origin - to.origin; // relative origin
2382     e.v_angle = e.angles - to.angles; // relative angles
2383 }
2384
2385 void unfollow_sameorigin(entity e)
2386 {
2387     e.movetype = MOVETYPE_NONE;
2388 }
2389
2390 entity gettaginfo_relative_ent;
2391 vector gettaginfo_relative(entity e, float tag)
2392 {
2393     if (!gettaginfo_relative_ent)
2394     {
2395         gettaginfo_relative_ent = spawn();
2396         gettaginfo_relative_ent.effects = EF_NODRAW;
2397     }
2398     gettaginfo_relative_ent.model = e.model;
2399     gettaginfo_relative_ent.modelindex = e.modelindex;
2400     gettaginfo_relative_ent.frame = e.frame;
2401     return gettaginfo(gettaginfo_relative_ent, tag);
2402 }
2403
2404 .float scale2;
2405
2406 float modeleffect_SendEntity(entity to, float sf)
2407 {
2408         float f;
2409         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2410
2411         f = 0;
2412         if(self.velocity != '0 0 0')
2413                 f |= 1;
2414         if(self.angles != '0 0 0')
2415                 f |= 2;
2416         if(self.avelocity != '0 0 0')
2417                 f |= 4;
2418
2419         WriteByte(MSG_ENTITY, f);
2420         WriteShort(MSG_ENTITY, self.modelindex);
2421         WriteByte(MSG_ENTITY, self.skin);
2422         WriteByte(MSG_ENTITY, self.frame);
2423         WriteCoord(MSG_ENTITY, self.origin_x);
2424         WriteCoord(MSG_ENTITY, self.origin_y);
2425         WriteCoord(MSG_ENTITY, self.origin_z);
2426         if(f & 1)
2427         {
2428                 WriteCoord(MSG_ENTITY, self.velocity_x);
2429                 WriteCoord(MSG_ENTITY, self.velocity_y);
2430                 WriteCoord(MSG_ENTITY, self.velocity_z);
2431         }
2432         if(f & 2)
2433         {
2434                 WriteCoord(MSG_ENTITY, self.angles_x);
2435                 WriteCoord(MSG_ENTITY, self.angles_y);
2436                 WriteCoord(MSG_ENTITY, self.angles_z);
2437         }
2438         if(f & 4)
2439         {
2440                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2441                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2442                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2443         }
2444         WriteShort(MSG_ENTITY, self.scale * 256.0);
2445         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2446         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2447         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2448         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2449
2450         return TRUE;
2451 }
2452
2453 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2454 {
2455         entity e;
2456         float sz;
2457         e = spawn();
2458         e.classname = "modeleffect";
2459         setmodel(e, m);
2460         e.frame = f;
2461         setorigin(e, o);
2462         e.velocity = v;
2463         e.angles = ang;
2464         e.avelocity = angv;
2465         e.alpha = a;
2466         e.teleport_time = t1;
2467         e.fade_time = t2;
2468         e.skin = s;
2469         if(s0 >= 0)
2470                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2471         else
2472                 e.scale = -s0;
2473         if(s2 >= 0)
2474                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2475         else
2476                 e.scale2 = -s2;
2477         sz = max(e.scale, e.scale2);
2478         setsize(e, e.mins * sz, e.maxs * sz);
2479         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2480 }
2481
2482 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2483 {
2484         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2485 }
2486
2487 float randombit(float bits)
2488 {
2489         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2490                 return bits;
2491
2492         float n, f, b, r;
2493
2494         r = random();
2495         b = 0;
2496         n = 0;
2497
2498         for(f = 1; f <= bits; f *= 2)
2499         {
2500                 if(bits & f)
2501                 {
2502                         ++n;
2503                         r *= n;
2504                         if(r <= 1)
2505                                 b = f;
2506                         else
2507                                 r = (r - 1) / (n - 1);
2508                 }
2509         }
2510
2511         return b;
2512 }
2513
2514 float randombits(float bits, float k, float error_return)
2515 {
2516         float r;
2517         r = 0;
2518         while(k > 0 && bits != r)
2519         {
2520                 r += randombit(bits - r);
2521                 --k;
2522         }
2523         if(error_return)
2524                 if(k > 0)
2525                         return -1; // all
2526         return r;
2527 }
2528
2529 void randombit_test(float bits, float iter)
2530 {
2531         while(iter > 0)
2532         {
2533                 print(ftos(randombit(bits)), "\n");
2534                 --iter;
2535         }
2536 }
2537
2538 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2539 {
2540         if(halflifedist > 0)
2541                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2542         else if(halflifedist < 0)
2543                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2544         else
2545                 return 1;
2546 }
2547
2548
2549
2550
2551 #ifdef RELEASE
2552 #define cvar_string_normal builtin_cvar_string
2553 #define cvar_normal builtin_cvar
2554 #else
2555 string cvar_string_normal(string n)
2556 {
2557         if not(cvar_type(n) & 1)
2558                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2559         return builtin_cvar_string(n);
2560 }
2561
2562 float cvar_normal(string n)
2563 {
2564         return stof(cvar_string_normal(n));
2565 }
2566 #endif
2567 #define cvar_set_normal builtin_cvar_set
2568
2569 void defer_think()
2570 {
2571     entity oself;
2572
2573     oself           = self;
2574     self            = self.owner;
2575     oself.think     = SUB_Remove;
2576     oself.nextthink = time;
2577
2578     oself.use();
2579 }
2580
2581 /*
2582     Execute func() after time + fdelay.
2583     self when func is executed = self when defer is called
2584 */
2585 void defer(float fdelay, void() func)
2586 {
2587     entity e;
2588
2589     e           = spawn();
2590     e.owner     = self;
2591     e.use       = func;
2592     e.think     = defer_think;
2593     e.nextthink = time + fdelay;
2594 }
2595
2596 .string aiment_classname;
2597 .float aiment_deadflag;
2598 void SetMovetypeFollow(entity ent, entity e)
2599 {
2600         // FIXME this may not be warpzone aware
2601         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2602         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2603         ent.aiment = e; // make the hole follow bmodel
2604         ent.punchangle = e.angles; // the original angles of bmodel
2605         ent.view_ofs = ent.origin - e.origin; // relative origin
2606         ent.v_angle = ent.angles - e.angles; // relative angles
2607         ent.aiment_classname = strzone(e.classname);
2608         ent.aiment_deadflag = e.deadflag;
2609 }
2610 void UnsetMovetypeFollow(entity ent)
2611 {
2612         ent.movetype = MOVETYPE_FLY;
2613         PROJECTILE_MAKETRIGGER(ent);
2614         ent.aiment = world;
2615 }
2616 float LostMovetypeFollow(entity ent)
2617 {
2618 /*
2619         if(ent.movetype != MOVETYPE_FOLLOW)
2620                 if(ent.aiment)
2621                         error("???");
2622 */
2623         if(ent.aiment)
2624         {
2625                 if(ent.aiment.classname != ent.aiment_classname)
2626                         return 1;
2627                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2628                         return 1;
2629         }
2630         return 0;
2631 }
2632
2633 float isPushable(entity e)
2634 {
2635         if(e.iscreature)
2636                 return TRUE;
2637         if(e.pushable)
2638                 return TRUE;
2639         switch(e.classname)
2640         {
2641                 case "body":
2642                 case "droppedweapon":
2643                 case "keepawayball":
2644                 case "nexball_basketball":
2645                 case "nexball_football":
2646                         return TRUE;
2647                 case "bullet": // antilagged bullets can't hit this either
2648                         return FALSE;
2649         }
2650         if (e.projectiledeathtype)
2651                 return TRUE;
2652         return FALSE;
2653 }
2654
2655 void dedicated_print(string input) // print(), but only print if the server is not local
2656 {
2657         if not(server_is_local) { print(input); }
2658 }