qcsrc/server/miscfunctions.qc

   1 #include "miscfunctions.qh"
   2 #include "_all.qh"
   3 #include "antilag.qh"
   4 #include "command/common.qh"
   5 #include "constants.qh"
   6 #include "g_hook.qh"
   7 #include "ipban.qh"
   8 #include "mutators/mutators_include.qh"
   9 #include "t_items.qh"
  10 #include "weapons/accuracy.qh"
  11 #include "weapons/csqcprojectile.qh"
  12 #include "weapons/selection.qh"
  13 #include "../common/command/generic.qh"
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes.qh"
  16 #include "../common/mapinfo.qh"
  17 #include "../common/notifications.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../common/teams.qh"
  20 #include "../common/triggers/subs.qh"
  21 #include "../common/util.qh"
  22 #include "../common/turrets/sv_turrets.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../csqcmodellib/sv_model.qh"
  25 #include "../warpzonelib/anglestransform.qh"
  26 #include "../warpzonelib/server.qh"
  27
  28 void crosshair_trace(entity pl)
  29 {
  30         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  31 }
  32 void crosshair_trace_plusvisibletriggers(entity pl)
  33 {
  34         entity first;
  35         entity e;
  36         first = findchainfloat(solid, SOLID_TRIGGER);
  37
  38         for (e = first; e; e = e.chain)
  39                 if (e.model != "")
  40                         e.solid = SOLID_BSP;
  41
  42         crosshair_trace(pl);
  43
  44         for (e = first; e; e = e.chain)
  45                 e.solid = SOLID_TRIGGER;
  46 }
  47 void WarpZone_crosshair_trace(entity pl)
  48 {
  49         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  50 }
  51
  52
  53 string admin_name(void)
  54 {
  55         if(autocvar_sv_adminnick != "")
  56                 return autocvar_sv_adminnick;
  57         else
  58                 return "SERVER ADMIN";
  59 }
  60
  61 void DistributeEvenly_Init(float amount, float totalweight)
  62 {
  63     if (DistributeEvenly_amount)
  64     {
  65         LOG_TRACE("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  66         LOG_TRACE(ftos(DistributeEvenly_totalweight), " left!)\n");
  67     }
  68     if (totalweight == 0)
  69         DistributeEvenly_amount = 0;
  70     else
  71         DistributeEvenly_amount = amount;
  72     DistributeEvenly_totalweight = totalweight;
  73 }
  74 float DistributeEvenly_Get(float weight)
  75 {
  76     float f;
  77     if (weight <= 0)
  78         return 0;
  79     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  80     DistributeEvenly_totalweight -= weight;
  81     DistributeEvenly_amount -= f;
  82     return f;
  83 }
  84 float DistributeEvenly_GetRandomized(float weight)
  85 {
  86     float f;
  87     if (weight <= 0)
  88         return 0;
  89     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  90     DistributeEvenly_totalweight -= weight;
  91     DistributeEvenly_amount -= f;
  92     return f;
  93 }
  94
  95
  96 void GameLogEcho(string s)
  97 {
  98     string fn;
  99     int matches;
 100
 101     if (autocvar_sv_eventlog_files)
 102     {
 103         if (!logfile_open)
 104         {
 105             logfile_open = true;
 106             matches = autocvar_sv_eventlog_files_counter + 1;
 107             cvar_set("sv_eventlog_files_counter", itos(matches));
 108             fn = ftos(matches);
 109             if (strlen(fn) < 8)
 110                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 111             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 112             logfile = fopen(fn, FILE_APPEND);
 113             fputs(logfile, ":logversion:3\n");
 114         }
 115         if (logfile >= 0)
 116         {
 117             if (autocvar_sv_eventlog_files_timestamps)
 118                 fputs(logfile, strcat(":time:", strftime(true, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 119             else
 120                 fputs(logfile, strcat(s, "\n"));
 121         }
 122     }
 123     if (autocvar_sv_eventlog_console)
 124     {
 125         LOG_INFO(s, "\n");
 126     }
 127 }
 128
 129 void GameLogInit()
 130 {
 131     logfile_open = 0;
 132     // will be opened later
 133 }
 134
 135 void GameLogClose()
 136 {
 137     if (logfile_open && logfile >= 0)
 138     {
 139         fclose(logfile);
 140         logfile = -1;
 141     }
 142 }
 143
 144 entity findnearest(vector point, .string field, string value, vector axismod)
 145 {
 146     entity localhead;
 147     float i;
 148     float j;
 149     float len;
 150     vector dist;
 151
 152     float num_nearest;
 153     num_nearest = 0;
 154
 155     localhead = find(world, field, value);
 156     while (localhead)
 157     {
 158         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 159             dist = localhead.oldorigin;
 160         else
 161             dist = localhead.origin;
 162         dist = dist - point;
 163         dist = dist.x * axismod.x * '1 0 0' + dist.y * axismod.y * '0 1 0' + dist.z * axismod.z * '0 0 1';
 164         len = vlen(dist);
 165
 166         for (i = 0; i < num_nearest; ++i)
 167         {
 168             if (len < nearest_length[i])
 169                 break;
 170         }
 171
 172         // now i tells us where to insert at
 173         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 174         if (i < NUM_NEAREST_ENTITIES)
 175         {
 176             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 177             {
 178                 nearest_length[j + 1] = nearest_length[j];
 179                 nearest_entity[j + 1] = nearest_entity[j];
 180             }
 181             nearest_length[i] = len;
 182             nearest_entity[i] = localhead;
 183             if (num_nearest < NUM_NEAREST_ENTITIES)
 184                 num_nearest = num_nearest + 1;
 185         }
 186
 187         localhead = find(localhead, field, value);
 188     }
 189
 190     // now use the first one from our list that we can see
 191     for (i = 0; i < num_nearest; ++i)
 192     {
 193         traceline(point, nearest_entity[i].origin, true, world);
 194         if (trace_fraction == 1)
 195         {
 196             if (i != 0)
 197             {
 198                 LOG_TRACE("Nearest point (");
 199                 LOG_TRACE(nearest_entity[0].netname);
 200                 LOG_TRACE(") is not visible, using a visible one.\n");
 201             }
 202             return nearest_entity[i];
 203         }
 204     }
 205
 206     if (num_nearest == 0)
 207         return world;
 208
 209     LOG_TRACE("Not seeing any location point, using nearest as fallback.\n");
 210     /* DEBUGGING CODE:
 211     dprint("Candidates were: ");
 212     for(j = 0; j < num_nearest; ++j)
 213     {
 214         if(j != 0)
 215                 dprint(", ");
 216         dprint(nearest_entity[j].netname);
 217     }
 218     dprint("\n");
 219     */
 220
 221     return nearest_entity[0];
 222 }
 223
 224 string NearestLocation(vector p)
 225 {
 226     entity loc;
 227     string ret;
 228     ret = "somewhere";
 229     loc = findnearest(p, classname, "target_location", '1 1 1');
 230     if (loc)
 231     {
 232         ret = loc.message;
 233     }
 234     else
 235     {
 236         loc = findnearest(p, target, "###item###", '1 1 4');
 237         if (loc)
 238             ret = loc.netname;
 239     }
 240     return ret;
 241 }
 242
 243 string formatmessage(string msg)
 244 {SELFPARAM();
 245         float p, p1, p2;
 246         float n;
 247         vector cursor;
 248         entity cursor_ent;
 249         string escape;
 250         string replacement;
 251         string ammoitems;
 252         p = 0;
 253         n = 7;
 254
 255         ammoitems = "batteries";
 256         if(self.items & ITEM_Plasma.m_itemid) ammoitems = ITEM_Plasma.m_name;
 257         if(self.items & ITEM_Cells.m_itemid) ammoitems = ITEM_Cells.m_name;
 258         if(self.items & ITEM_Rockets.m_itemid) ammoitems = ITEM_Rockets.m_name;
 259         if(self.items & ITEM_Shells.m_itemid) ammoitems = ITEM_Shells.m_name;
 260
 261         WarpZone_crosshair_trace(self);
 262         cursor = trace_endpos;
 263         cursor_ent = trace_ent;
 264
 265         while (1) {
 266                 if (n < 1)
 267                         break; // too many replacements
 268
 269                 n = n - 1;
 270                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 271                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 272
 273                 if (p1 < 0)
 274                         p1 = p2;
 275
 276                 if (p2 < 0)
 277                         p2 = p1;
 278
 279                 p = min(p1, p2);
 280
 281                 if (p < 0)
 282                         break;
 283
 284                 replacement = substring(msg, p, 2);
 285                 escape = substring(msg, p + 1, 1);
 286
 287                 switch(escape)
 288                 {
 289                         case "%": replacement = "%"; break;
 290                         case "\\":replacement = "\\"; break;
 291                         case "n": replacement = "\n"; break;
 292                         case "a": replacement = ftos(floor(self.armorvalue)); break;
 293                         case "h": replacement = ftos(floor(self.health)); break;
 294                         case "l": replacement = NearestLocation(self.origin); break;
 295                         case "y": replacement = NearestLocation(cursor); break;
 296                         case "d": replacement = NearestLocation(self.death_origin); break;
 297                         case "w": replacement = WEP_NAME((!self.weapon) ? (!self.switchweapon ? self.cnt : self.switchweapon) : self.weapon); break;
 298                         case "W": replacement = ammoitems; break;
 299                         case "x": replacement = ((cursor_ent.netname == "" || !cursor_ent) ? "nothing" : cursor_ent.netname); break;
 300                         case "s": replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1')); break;
 301                         case "S": replacement = ftos(vlen(self.velocity)); break;
 302                         default:
 303                         {
 304                                 MUTATOR_CALLHOOK(FormatMessage, escape, replacement, msg);
 305                                 escape = format_escape;
 306                                 replacement = format_replacement;
 307                                 break;
 308                         }
 309                 }
 310
 311                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 312                 p = p + strlen(replacement);
 313         }
 314         return msg;
 315 }
 316
 317 /*
 318 =============
 319 GetCvars
 320 =============
 321 Called with:
 322   0:  sends the request
 323   >0: receives a cvar from name=argv(f) value=argv(f+1)
 324 */
 325 void GetCvars_handleString(string thisname, float f, .string field, string name)
 326 {SELFPARAM();
 327         if (f < 0)
 328         {
 329                 if (self.(field))
 330                         strunzone(self.(field));
 331                 self.(field) = string_null;
 332         }
 333         else if (f > 0)
 334         {
 335                 if (thisname == name)
 336                 {
 337                         if (self.(field))
 338                                 strunzone(self.(field));
 339                         self.(field) = strzone(argv(f + 1));
 340                 }
 341         }
 342         else
 343                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 344 }
 345 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 346 {SELFPARAM();
 347         GetCvars_handleString(thisname, f, field, name);
 348         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 349                 if (thisname == name)
 350                 {
 351                         string s = func(strcat1(self.(field)));
 352                         if (s != self.(field))
 353                         {
 354                                 strunzone(self.(field));
 355                                 self.(field) = strzone(s);
 356                         }
 357                 }
 358 }
 359 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 360 {SELFPARAM();
 361         if (f < 0)
 362         {
 363         }
 364         else if (f > 0)
 365         {
 366                 if (thisname == name)
 367                         self.(field) = stof(argv(f + 1));
 368         }
 369         else
 370                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 371 }
 372 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 373 {SELFPARAM();
 374         if (f < 0)
 375         {
 376         }
 377         else if (f > 0)
 378         {
 379                 if (thisname == name)
 380                 {
 381                         if (!self.(field))
 382                         {
 383                                 self.(field) = stof(argv(f + 1));
 384                                 if (!self.(field))
 385                                         self.(field) = -1;
 386                         }
 387                 }
 388         }
 389         else
 390         {
 391                 if (!self.(field))
 392                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 393         }
 394 }
 395 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 396 {SELFPARAM();
 397         string o;
 398         o = W_FixWeaponOrder_ForceComplete(wo);
 399         if(self.weaponorder_byimpulse)
 400         {
 401                 strunzone(self.weaponorder_byimpulse);
 402                 self.weaponorder_byimpulse = string_null;
 403         }
 404         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 405         return o;
 406 }
 407 void GetCvars(float f)
 408 {SELFPARAM();
 409         string s = string_null;
 410
 411         if (f > 0)
 412                 s = strcat1(argv(f));
 413
 414         get_cvars_f = f;
 415         get_cvars_s = s;
 416         MUTATOR_CALLHOOK(GetCvars);
 417
 418         Notification_GetCvars();
 419
 420         ReplicateVars(this, s, f);
 421
 422         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 423         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 424         GetCvars_handleFloat(s, f, cvar_cl_jetpack_jump, "cl_jetpack_jump");
 425         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 426         GetCvars_handleString(s, f, cvar_cl_physics, "cl_physics");
 427         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 428         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 429         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 430         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 431         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 432         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 433         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 434         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 435         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 436         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 437         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 438         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 439         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 440         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 441         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 442         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 443         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 444         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 445         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 446         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 447
 448         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 449         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 450
 451         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 452         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 453         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 454         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 455         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 456
 457         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 458         if (f > 0)
 459         {
 460                 if (s == "cl_weaponpriority")
 461                         self.switchweapon = w_getbestweapon(self);
 462                 if (s == "cl_allow_uidtracking")
 463                         PlayerStats_GameReport_AddPlayer(self);
 464         }
 465 }
 466
 467 // decolorizes and team colors the player name when needed
 468 string playername(entity p)
 469 {
 470     string t;
 471     if (teamplay && !intermission_running && IS_PLAYER(p))
 472     {
 473         t = Team_ColorCode(p.team);
 474         return strcat(t, strdecolorize(p.netname));
 475     }
 476     else
 477         return p.netname;
 478 }
 479
 480 float want_weapon(entity weaponinfo, float allguns) // WEAPONTODO: what still needs done?
 481 {
 482         int i = weaponinfo.weapon;
 483         int d = 0;
 484
 485         if (!i)
 486                 return 0;
 487
 488         if (g_lms || g_ca || allguns)
 489         {
 490                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 491                         d = true;
 492                 else
 493                         d = false;
 494         }
 495         else if (g_cts)
 496                 d = (i == WEP_SHOTGUN.m_id);
 497         else if (g_nexball)
 498                 d = 0; // weapon is set a few lines later
 499         else
 500                 d = !(!weaponinfo.weaponstart);
 501
 502         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 503                 d |= (i == WEP_HOOK.m_id);
 504         if(!g_cts && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
 505                 d = 0;
 506
 507         float t = weaponinfo.weaponstartoverride;
 508
 509         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 510
 511         // bit order in t:
 512         // 1: want or not
 513         // 2: is default?
 514         // 4: is set by default?
 515         if(t < 0)
 516                 t = 4 | (3 * d);
 517         else
 518                 t |= (2 * d);
 519
 520         return t;
 521 }
 522
 523 void readplayerstartcvars()
 524 {
 525         entity e;
 526         float i, j, t;
 527         string s;
 528
 529         // initialize starting values for players
 530         start_weapons = '0 0 0';
 531         start_weapons_default = '0 0 0';
 532         start_weapons_defaultmask = '0 0 0';
 533         start_items = 0;
 534         start_ammo_shells = 0;
 535         start_ammo_nails = 0;
 536         start_ammo_rockets = 0;
 537         start_ammo_cells = 0;
 538         start_ammo_plasma = 0;
 539         start_health = cvar("g_balance_health_start");
 540         start_armorvalue = cvar("g_balance_armor_start");
 541
 542         g_weaponarena = 0;
 543         g_weaponarena_weapons = '0 0 0';
 544
 545         s = cvar_string("g_weaponarena");
 546         if (s == "0" || s == "")
 547         {
 548                 if(g_ca || g_freezetag)
 549                         s = "most";
 550         }
 551
 552         if (s == "0" || s == "")
 553         {
 554                 // no arena
 555         }
 556         else if (s == "off")
 557         {
 558                 // forcibly turn off weaponarena
 559         }
 560         else if (s == "all" || s == "1")
 561         {
 562                 g_weaponarena = 1;
 563                 g_weaponarena_list = "All Weapons";
 564                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 565                 {
 566                         e = get_weaponinfo(j);
 567                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 568                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 569                 }
 570         }
 571         else if (s == "most")
 572         {
 573                 g_weaponarena = 1;
 574                 g_weaponarena_list = "Most Weapons";
 575                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 576                 {
 577                         e = get_weaponinfo(j);
 578                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 579                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 580                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 581                 }
 582         }
 583         else if (s == "none")
 584         {
 585                 g_weaponarena = 1;
 586                 g_weaponarena_list = "No Weapons";
 587         }
 588         else
 589         {
 590                 g_weaponarena = 1;
 591                 t = tokenize_console(s);
 592                 g_weaponarena_list = "";
 593                 for (i = 0; i < t; ++i)
 594                 {
 595                         s = argv(i);
 596                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 597                         {
 598                                 e = get_weaponinfo(j);
 599                                 if (e.netname == s)
 600                                 {
 601                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 602                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 603                                         break;
 604                                 }
 605                         }
 606                         if (j > WEP_LAST)
 607                         {
 608                                 LOG_INFO("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 609                         }
 610                 }
 611                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 612         }
 613
 614         if(g_weaponarena)
 615                 g_weaponarena_random = cvar("g_weaponarena_random");
 616         else
 617                 g_weaponarena_random = 0;
 618         g_weaponarena_random_with_blaster = cvar("g_weaponarena_random_with_blaster");
 619
 620         if (g_weaponarena)
 621         {
 622                 g_weapon_stay = 0; // incompatible
 623                 start_weapons = g_weaponarena_weapons;
 624                 start_items |= IT_UNLIMITED_AMMO;
 625         }
 626         else
 627         {
 628                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 629                 {
 630                         e = get_weaponinfo(i);
 631                         int w = want_weapon(e, false);
 632                         if(w & 1)
 633                                 start_weapons |= WepSet_FromWeapon(i);
 634                         if(w & 2)
 635                                 start_weapons_default |= WepSet_FromWeapon(i);
 636                         if(w & 4)
 637                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 638                 }
 639         }
 640
 641         if(!cvar("g_use_ammunition"))
 642                 start_items |= IT_UNLIMITED_AMMO;
 643
 644         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 645         {
 646                 start_ammo_shells = 999;
 647                 start_ammo_nails = 999;
 648                 start_ammo_rockets = 999;
 649                 start_ammo_cells = 999;
 650                 start_ammo_plasma = 999;
 651                 start_ammo_fuel = 999;
 652         }
 653         else
 654         {
 655                 start_ammo_shells = cvar("g_start_ammo_shells");
 656                 start_ammo_nails = cvar("g_start_ammo_nails");
 657                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 658                 start_ammo_cells = cvar("g_start_ammo_cells");
 659                 start_ammo_plasma = cvar("g_start_ammo_plasma");
 660                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 661         }
 662
 663         if (warmup_stage)
 664         {
 665                 warmup_start_ammo_shells = start_ammo_shells;
 666                 warmup_start_ammo_nails = start_ammo_nails;
 667                 warmup_start_ammo_rockets = start_ammo_rockets;
 668                 warmup_start_ammo_cells = start_ammo_cells;
 669                 warmup_start_ammo_plasma = start_ammo_plasma;
 670                 warmup_start_ammo_fuel = start_ammo_fuel;
 671                 warmup_start_health = start_health;
 672                 warmup_start_armorvalue = start_armorvalue;
 673                 warmup_start_weapons = start_weapons;
 674                 warmup_start_weapons_default = start_weapons_default;
 675                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 676
 677                 if (!g_weaponarena && !g_ca && !g_freezetag)
 678                 {
 679                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 680                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 681                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 682                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 683                         warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
 684                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 685                         warmup_start_health = cvar("g_warmup_start_health");
 686                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 687                         warmup_start_weapons = '0 0 0';
 688                         warmup_start_weapons_default = '0 0 0';
 689                         warmup_start_weapons_defaultmask = '0 0 0';
 690                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 691                         {
 692                                 e = get_weaponinfo(i);
 693                                 int w = want_weapon(e, g_warmup_allguns);
 694                                 if(w & 1)
 695                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 696                                 if(w & 2)
 697                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 698                                 if(w & 4)
 699                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 700                         }
 701                 }
 702         }
 703
 704         if (g_jetpack)
 705                 start_items |= ITEM_Jetpack.m_itemid;
 706
 707         MUTATOR_CALLHOOK(SetStartItems);
 708
 709         if (start_items & ITEM_Jetpack.m_itemid)
 710         {
 711                 start_items |= ITEM_JetpackRegen.m_itemid;
 712                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 713                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 714         }
 715
 716         WepSet precache_weapons = start_weapons;
 717         if (g_warmup_allguns != 1)
 718                 precache_weapons |= warmup_start_weapons;
 719         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 720         {
 721                 e = get_weaponinfo(i);
 722                 if(precache_weapons & WepSet_FromWeapon(i))
 723                         _WEP_ACTION(i, WR_INIT);
 724         }
 725
 726         start_ammo_shells = max(0, start_ammo_shells);
 727         start_ammo_nails = max(0, start_ammo_nails);
 728         start_ammo_rockets = max(0, start_ammo_rockets);
 729         start_ammo_cells = max(0, start_ammo_cells);
 730         start_ammo_plasma = max(0, start_ammo_plasma);
 731         start_ammo_fuel = max(0, start_ammo_fuel);
 732
 733         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 734         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 735         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 736         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 737         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
 738         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 739 }
 740
 741 float sound_allowed(float destin, entity e)
 742 {
 743     // sounds from world may always pass
 744     for (;;)
 745     {
 746         if (e.classname == "body")
 747             e = e.enemy;
 748         else if (e.realowner && e.realowner != e)
 749             e = e.realowner;
 750         else if (e.owner && e.owner != e)
 751             e = e.owner;
 752         else
 753             break;
 754     }
 755     // sounds to self may always pass
 756     if (destin == MSG_ONE)
 757         if (e == msg_entity)
 758             return true;
 759     // sounds by players can be removed
 760     if (autocvar_bot_sound_monopoly)
 761         if (IS_REAL_CLIENT(e))
 762             return false;
 763     // anything else may pass
 764     return true;
 765 }
 766
 767 void soundtoat(float _dest, entity e, vector o, float chan, string samp, float vol, float attenu)
 768 {
 769     float entno, idx;
 770
 771     if (!sound_allowed(_dest, e))
 772         return;
 773
 774     entno = num_for_edict(e);
 775     idx = precache_sound_index(samp);
 776
 777     int sflags;
 778     sflags = 0;
 779
 780     attenu = floor(attenu * 64);
 781     vol = floor(vol * 255);
 782
 783     if (vol != 255)
 784         sflags |= SND_VOLUME;
 785     if (attenu != 64)
 786         sflags |= SND_ATTENUATION;
 787     if (entno >= 8192 || chan < 0 || chan > 7)
 788         sflags |= SND_LARGEENTITY;
 789     if (idx >= 256)
 790         sflags |= SND_LARGESOUND;
 791
 792     WriteByte(_dest, SVC_SOUND);
 793     WriteByte(_dest, sflags);
 794     if (sflags & SND_VOLUME)
 795         WriteByte(_dest, vol);
 796     if (sflags & SND_ATTENUATION)
 797         WriteByte(_dest, attenu);
 798     if (sflags & SND_LARGEENTITY)
 799     {
 800         WriteShort(_dest, entno);
 801         WriteByte(_dest, chan);
 802     }
 803     else
 804     {
 805         WriteShort(_dest, entno * 8 + chan);
 806     }
 807     if (sflags & SND_LARGESOUND)
 808         WriteShort(_dest, idx);
 809     else
 810         WriteByte(_dest, idx);
 811
 812     WriteCoord(_dest, o.x);
 813     WriteCoord(_dest, o.y);
 814     WriteCoord(_dest, o.z);
 815 }
 816 void soundto(float _dest, entity e, float chan, string samp, float vol, float _atten)
 817 {
 818     vector o;
 819
 820     if (!sound_allowed(_dest, e))
 821         return;
 822
 823     o = e.origin + 0.5 * (e.mins + e.maxs);
 824     soundtoat(_dest, e, o, chan, samp, vol, _atten);
 825 }
 826 void soundat(entity e, vector o, float chan, string samp, float vol, float _atten)
 827 {
 828     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, _atten);
 829 }
 830 void stopsoundto(float _dest, entity e, float chan)
 831 {
 832     float entno;
 833
 834     if (!sound_allowed(_dest, e))
 835         return;
 836
 837     entno = num_for_edict(e);
 838
 839     if (entno >= 8192 || chan < 0 || chan > 7)
 840     {
 841         float idx, sflags;
 842         idx = precache_sound_index(SND(Null));
 843         sflags = SND_LARGEENTITY;
 844         if (idx >= 256)
 845             sflags |= SND_LARGESOUND;
 846         WriteByte(_dest, SVC_SOUND);
 847         WriteByte(_dest, sflags);
 848         WriteShort(_dest, entno);
 849         WriteByte(_dest, chan);
 850         if (sflags & SND_LARGESOUND)
 851             WriteShort(_dest, idx);
 852         else
 853             WriteByte(_dest, idx);
 854         WriteCoord(_dest, e.origin.x);
 855         WriteCoord(_dest, e.origin.y);
 856         WriteCoord(_dest, e.origin.z);
 857     }
 858     else
 859     {
 860         WriteByte(_dest, SVC_STOPSOUND);
 861         WriteShort(_dest, entno * 8 + chan);
 862     }
 863 }
 864 void stopsound(entity e, float chan)
 865 {
 866     if (!sound_allowed(MSG_BROADCAST, e))
 867         return;
 868
 869     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
 870     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
 871 }
 872
 873 void play2(entity e, string filename)
 874 {
 875     //stuffcmd(e, strcat("play2 ", filename, "\n"));
 876     msg_entity = e;
 877     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
 878 }
 879
 880 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
 881 .float spamtime;
 882 float spamsound(entity e, float chan, string samp, float vol, float _atten)
 883 {
 884     if (!sound_allowed(MSG_BROADCAST, e))
 885         return false;
 886
 887     if (time > e.spamtime)
 888     {
 889         e.spamtime = time;
 890         _sound(e, chan, samp, vol, _atten);
 891         return true;
 892     }
 893     return false;
 894 }
 895
 896 void play2team(float t, string filename)
 897 {
 898     entity head;
 899
 900     if (autocvar_bot_sound_monopoly)
 901         return;
 902
 903     FOR_EACH_REALPLAYER(head)
 904     {
 905         if (head.team == t)
 906             play2(head, filename);
 907     }
 908 }
 909
 910 void play2all(string samp)
 911 {
 912     if (autocvar_bot_sound_monopoly)
 913         return;
 914
 915     _sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
 916 }
 917
 918 void PrecachePlayerSounds(string f);
 919 void precache_playermodel(string m)
 920 {
 921         float globhandle, i, n;
 922         string f;
 923
 924         if(substring(m, -9,5) == "_lod1")
 925                 return;
 926         if(substring(m, -9,5) == "_lod2")
 927                 return;
 928         precache_model(m);
 929         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
 930         if(fexists(f))
 931                 precache_model(f);
 932         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
 933         if(fexists(f))
 934                 precache_model(f);
 935
 936         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 937         if (globhandle < 0)
 938                 return;
 939         n = search_getsize(globhandle);
 940         for (i = 0; i < n; ++i)
 941         {
 942                 //print(search_getfilename(globhandle, i), "\n");
 943                 f = search_getfilename(globhandle, i);
 944                 PrecachePlayerSounds(f);
 945         }
 946         search_end(globhandle);
 947 }
 948 void precache_all_playermodels(string pattern)
 949 {
 950         float globhandle, i, n;
 951         string f;
 952
 953         globhandle = search_begin(pattern, true, false);
 954         if (globhandle < 0)
 955                 return;
 956         n = search_getsize(globhandle);
 957         for (i = 0; i < n; ++i)
 958         {
 959                 //print(search_getfilename(globhandle, i), "\n");
 960                 f = search_getfilename(globhandle, i);
 961                 precache_playermodel(f);
 962         }
 963         search_end(globhandle);
 964 }
 965
 966 void precache()
 967 {SELFPARAM();
 968     // gamemode related things
 969
 970     // Precache all player models if desired
 971     if (autocvar_sv_precacheplayermodels)
 972     {
 973         PrecachePlayerSounds("sound/player/default.sounds");
 974         precache_all_playermodels("models/player/*.zym");
 975         precache_all_playermodels("models/player/*.dpm");
 976         precache_all_playermodels("models/player/*.md3");
 977         precache_all_playermodels("models/player/*.psk");
 978         precache_all_playermodels("models/player/*.iqm");
 979     }
 980
 981     if (autocvar_sv_defaultcharacter)
 982     {
 983         string s;
 984         s = autocvar_sv_defaultplayermodel_red;
 985         if (s != "")
 986             precache_playermodel(s);
 987         s = autocvar_sv_defaultplayermodel_blue;
 988         if (s != "")
 989             precache_playermodel(s);
 990         s = autocvar_sv_defaultplayermodel_yellow;
 991         if (s != "")
 992             precache_playermodel(s);
 993         s = autocvar_sv_defaultplayermodel_pink;
 994         if (s != "")
 995             precache_playermodel(s);
 996         s = autocvar_sv_defaultplayermodel;
 997         if (s != "")
 998             precache_playermodel(s);
 999     }
1000
1001     if (g_footsteps)
1002     {
1003         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1004         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1005     }
1006
1007     // gore and miscellaneous sounds
1008     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1009     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1010
1011 #if 0
1012     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1013
1014     if (!self.noise && self.music) // quake 3 uses the music field
1015         self.noise = self.music;
1016
1017     // plays music for the level if there is any
1018     if (self.noise)
1019     {
1020         precache_sound (self.noise);
1021         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1022     }
1023 #endif
1024 }
1025
1026
1027 void make_safe_for_remove(entity e)
1028 {
1029     if (e.initialize_entity)
1030     {
1031         entity ent, prev = world;
1032         for (ent = initialize_entity_first; ent; )
1033         {
1034             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1035             {
1036                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1037                 // skip it in linked list
1038                 if (prev)
1039                 {
1040                     prev.initialize_entity_next = ent.initialize_entity_next;
1041                     ent = prev.initialize_entity_next;
1042                 }
1043                 else
1044                 {
1045                     initialize_entity_first = ent.initialize_entity_next;
1046                     ent = initialize_entity_first;
1047                 }
1048             }
1049             else
1050             {
1051                 prev = ent;
1052                 ent = ent.initialize_entity_next;
1053             }
1054         }
1055     }
1056 }
1057
1058 void objerror(string s)
1059 {SELFPARAM();
1060     make_safe_for_remove(self);
1061     builtin_objerror(s);
1062 }
1063
1064 .float remove_except_protected_forbidden;
1065 void remove_except_protected(entity e)
1066 {
1067         if(e.remove_except_protected_forbidden)
1068                 error("not allowed to remove this at this point");
1069         builtin_remove(e);
1070 }
1071
1072 void remove_unsafely(entity e)
1073 {
1074     if(e.classname == "spike")
1075         error("Removing spikes is forbidden (crylink bug), please report");
1076     builtin_remove(e);
1077 }
1078
1079 void remove_safely(entity e)
1080 {
1081     make_safe_for_remove(e);
1082     builtin_remove(e);
1083 }
1084
1085 void InitializeEntity(entity e, void(void) func, float order)
1086 {
1087     entity prev, cur;
1088
1089     if (!e || e.initialize_entity)
1090     {
1091         // make a proxy initializer entity
1092         entity e_old = e;
1093         e = new(initialize_entity);
1094         e.enemy = e_old;
1095     }
1096
1097     e.initialize_entity = func;
1098     e.initialize_entity_order = order;
1099
1100     cur = initialize_entity_first;
1101     prev = world;
1102     for (;;)
1103     {
1104         if (!cur || cur.initialize_entity_order > order)
1105         {
1106             // insert between prev and cur
1107             if (prev)
1108                 prev.initialize_entity_next = e;
1109             else
1110                 initialize_entity_first = e;
1111             e.initialize_entity_next = cur;
1112             return;
1113         }
1114         prev = cur;
1115         cur = cur.initialize_entity_next;
1116     }
1117 }
1118 void InitializeEntitiesRun()
1119 {SELFPARAM();
1120     entity startoflist = initialize_entity_first;
1121     initialize_entity_first = NULL;
1122     remove = remove_except_protected;
1123     for (entity e = startoflist; e; e = e.initialize_entity_next)
1124     {
1125                 e.remove_except_protected_forbidden = 1;
1126     }
1127     for (entity e = startoflist; e; )
1128     {
1129                 e.remove_except_protected_forbidden = 0;
1130         e.initialize_entity_order = 0;
1131         entity next = e.initialize_entity_next;
1132         e.initialize_entity_next = NULL;
1133         var void() func = e.initialize_entity;
1134         e.initialize_entity = func_null;
1135         if (e.classname == "initialize_entity")
1136         {
1137             entity wrappee = e.enemy;
1138             builtin_remove(e);
1139             e = wrappee;
1140         }
1141         //dprint("Delayed initialization: ", e.classname, "\n");
1142         if (func)
1143         {
1144                 WITH(entity, self, e, func());
1145         }
1146         else
1147         {
1148             eprint(e);
1149             backtrace(strcat("Null function in: ", e.classname, "\n"));
1150         }
1151         e = next;
1152     }
1153     remove = remove_unsafely;
1154 }
1155
1156 void UncustomizeEntitiesRun()
1157 {SELFPARAM();
1158     for (entity e = NULL; (e = findfloat(e, uncustomizeentityforclient_set, 1)); )
1159     {
1160         WITH(entity, self, e, e.uncustomizeentityforclient());
1161     }
1162 }
1163 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1164 {
1165     e.customizeentityforclient = customizer;
1166     e.uncustomizeentityforclient = uncustomizer;
1167     e.uncustomizeentityforclient_set = !!uncustomizer;
1168 }
1169
1170 void Net_LinkEntity(entity e, bool docull, float dt, bool(entity, int) sendfunc)
1171 {SELFPARAM();
1172     vector mi, ma;
1173
1174     if (e.classname == "")
1175         e.classname = "net_linked";
1176
1177     if (e.model == "" || self.modelindex == 0)
1178     {
1179         mi = e.mins;
1180         ma = e.maxs;
1181         setmodel(e, MDL_Null);
1182         setsize(e, mi, ma);
1183     }
1184
1185     e.SendEntity = sendfunc;
1186     e.SendFlags = 0xFFFFFF;
1187
1188     if (!docull)
1189         e.effects |= EF_NODEPTHTEST;
1190
1191     if (dt)
1192     {
1193         e.nextthink = time + dt;
1194         e.think = SUB_Remove;
1195     }
1196 }
1197
1198
1199 .float(entity) isEliminated;
1200 float EliminatedPlayers_SendEntity(entity to, float sendflags)
1201 {
1202         float i, f, b;
1203         entity e;
1204         WriteByte(MSG_ENTITY, ENT_CLIENT_ELIMINATEDPLAYERS);
1205         WriteByte(MSG_ENTITY, sendflags);
1206
1207         if(sendflags & 1)
1208         {
1209                 for(i = 1; i <= maxclients; i += 8)
1210                 {
1211                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
1212                         {
1213                                 if(eliminatedPlayers.isEliminated(e))
1214                                         f |= b;
1215                         }
1216                         WriteByte(MSG_ENTITY, f);
1217                 }
1218         }
1219
1220         return true;
1221 }
1222
1223 void EliminatedPlayers_Init(float(entity) isEliminated_func)
1224 {
1225         if(eliminatedPlayers)
1226         {
1227                 backtrace("Can't spawn eliminatedPlayers again!");
1228                 return;
1229         }
1230         Net_LinkEntity(eliminatedPlayers = spawn(), false, 0, EliminatedPlayers_SendEntity);
1231         eliminatedPlayers.isEliminated = isEliminated_func;
1232 }
1233
1234
1235 void adaptor_think2touch()
1236 {SELFPARAM();
1237     entity o;
1238     o = other;
1239     other = world;
1240     self.touch();
1241     other = o;
1242 }
1243
1244 void adaptor_think2use()
1245 {SELFPARAM();
1246     entity o, a;
1247     o = other;
1248     a = activator;
1249     activator = world;
1250     other = world;
1251     self.use();
1252     other = o;
1253     activator = a;
1254 }
1255
1256 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1257 {SELFPARAM();
1258         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1259                 self.projectiledeathtype |= HITTYPE_SPLASH;
1260         adaptor_think2use();
1261 }
1262
1263 // deferred dropping
1264 void DropToFloor_Handler()
1265 {SELFPARAM();
1266     builtin_droptofloor();
1267     self.dropped_origin = self.origin;
1268 }
1269
1270 void droptofloor()
1271 {SELFPARAM();
1272     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1273 }
1274
1275
1276
1277 float trace_hits_box_a0, trace_hits_box_a1;
1278
1279 float trace_hits_box_1d(float end, float thmi, float thma)
1280 {
1281     if (end == 0)
1282     {
1283         // just check if x is in range
1284         if (0 < thmi)
1285             return false;
1286         if (0 > thma)
1287             return false;
1288     }
1289     else
1290     {
1291         // do the trace with respect to x
1292         // 0 -> end has to stay in thmi -> thma
1293         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1294         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1295         if (trace_hits_box_a0 > trace_hits_box_a1)
1296             return false;
1297     }
1298     return true;
1299 }
1300
1301 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1302 {
1303     end -= start;
1304     thmi -= start;
1305     thma -= start;
1306     // now it is a trace from 0 to end
1307
1308     trace_hits_box_a0 = 0;
1309     trace_hits_box_a1 = 1;
1310
1311     if (!trace_hits_box_1d(end.x, thmi.x, thma.x))
1312         return false;
1313     if (!trace_hits_box_1d(end.y, thmi.y, thma.y))
1314         return false;
1315     if (!trace_hits_box_1d(end.z, thmi.z, thma.z))
1316         return false;
1317
1318     return true;
1319 }
1320
1321 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1322 {
1323     return trace_hits_box(start, end, thmi - ma, thma - mi);
1324 }
1325
1326 float SUB_NoImpactCheck()
1327 {SELFPARAM();
1328         // zero hitcontents = this is not the real impact, but either the
1329         // mirror-impact of something hitting the projectile instead of the
1330         // projectile hitting the something, or a touchareagrid one. Neither of
1331         // these stop the projectile from moving, so...
1332         if(trace_dphitcontents == 0)
1333         {
1334                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1335                 LOG_TRACEF("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin));
1336                 checkclient();
1337         }
1338     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1339         return 1;
1340     if (other == world && self.size != '0 0 0')
1341     {
1342         vector tic;
1343         tic = self.velocity * sys_frametime;
1344         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1345         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1346         if (trace_fraction >= 1)
1347         {
1348             LOG_TRACE("Odd... did not hit...?\n");
1349         }
1350         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1351         {
1352             LOG_TRACE("Detected and prevented the sky-grapple bug.\n");
1353             return 1;
1354         }
1355     }
1356
1357     return 0;
1358 }
1359
1360 #define SUB_OwnerCheck() (other && (other == self.owner))
1361
1362 void W_Crylink_Dequeue(entity e);
1363 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1364 {SELFPARAM();
1365         if(SUB_OwnerCheck())
1366                 return true;
1367         if(SUB_NoImpactCheck())
1368         {
1369                 if(self.classname == "nade")
1370                         return false; // no checks here
1371                 else if(self.classname == "grapplinghook")
1372                         RemoveGrapplingHook(self.realowner);
1373                 else if(self.classname == "spike")
1374                 {
1375                         W_Crylink_Dequeue(self);
1376                         remove(self);
1377                 }
1378                 else
1379                         remove(self);
1380                 return true;
1381         }
1382         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1383                 UpdateCSQCProjectile(self);
1384         return false;
1385 }
1386
1387
1388 void URI_Get_Callback(float id, float status, string data)
1389 {
1390         if(url_URI_Get_Callback(id, status, data))
1391         {
1392                 // handled
1393         }
1394         else if (id == URI_GET_DISCARD)
1395         {
1396                 // discard
1397         }
1398         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1399         {
1400                 // sv_cmd curl
1401                 Curl_URI_Get_Callback(id, status, data);
1402         }
1403         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1404         {
1405                 // online ban list
1406                 OnlineBanList_URI_Get_Callback(id, status, data);
1407         }
1408         else
1409         {
1410                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1411         }
1412 }
1413
1414 string uid2name(string myuid) {
1415         string s;
1416         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1417
1418         // FIXME remove this later after 0.6 release
1419         // convert old style broken records to correct style
1420         if(s == "")
1421         {
1422                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1423                 if(s != "")
1424                 {
1425                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1426                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1427                 }
1428         }
1429
1430         if(s == "")
1431                 s = "^1Unregistered Player";
1432         return s;
1433 }
1434
1435 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1436 {
1437     float m, i;
1438     vector start, org, delta, end, enddown, mstart;
1439     entity sp;
1440
1441     m = e.dphitcontentsmask;
1442     e.dphitcontentsmask = goodcontents | badcontents;
1443
1444     org = world.mins;
1445     delta = world.maxs - world.mins;
1446
1447     start = end = org;
1448
1449     for (i = 0; i < attempts; ++i)
1450     {
1451         start.x = org.x + random() * delta.x;
1452         start.y = org.y + random() * delta.y;
1453         start.z = org.z + random() * delta.z;
1454
1455         // rule 1: start inside world bounds, and outside
1456         // solid, and don't start from somewhere where you can
1457         // fall down to evil
1458         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1459         if (trace_fraction >= 1)
1460             continue;
1461         if (trace_startsolid)
1462             continue;
1463         if (trace_dphitcontents & badcontents)
1464             continue;
1465         if (trace_dphitq3surfaceflags & badsurfaceflags)
1466             continue;
1467
1468         // rule 2: if we are too high, lower the point
1469         if (trace_fraction * delta.z > maxaboveground)
1470             start = trace_endpos + '0 0 1' * maxaboveground;
1471         enddown = trace_endpos;
1472
1473         // rule 3: make sure we aren't outside the map. This only works
1474         // for somewhat well formed maps. A good rule of thumb is that
1475         // the map should have a convex outside hull.
1476         // these can be traceLINES as we already verified the starting box
1477         mstart = start + 0.5 * (e.mins + e.maxs);
1478         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1479         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1480             continue;
1481         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1482         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1483             continue;
1484         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1485         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1486             continue;
1487         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1488         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1489             continue;
1490         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1491         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1492             continue;
1493
1494         // rule 4: we must "see" some spawnpoint or item
1495         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1496                 if(checkpvs(mstart, sp))
1497                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1498                                 break;
1499         if(!sp)
1500         {
1501                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1502                         if(checkpvs(mstart, sp))
1503                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1504                                         break;
1505                 if(!sp)
1506                         continue;
1507         }
1508
1509         // find a random vector to "look at"
1510         end.x = org.x + random() * delta.x;
1511         end.y = org.y + random() * delta.y;
1512         end.z = org.z + random() * delta.z;
1513         end = start + normalize(end - start) * vlen(delta);
1514
1515         // rule 4: start TO end must not be too short
1516         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1517         if (trace_startsolid)
1518             continue;
1519         if (trace_fraction < minviewdistance / vlen(delta))
1520             continue;
1521
1522         // rule 5: don't want to look at sky
1523         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1524             continue;
1525
1526         // rule 6: we must not end up in trigger_hurt
1527         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1528             continue;
1529
1530         break;
1531     }
1532
1533     e.dphitcontentsmask = m;
1534
1535     if (i < attempts)
1536     {
1537         setorigin(e, start);
1538         e.angles = vectoangles(end - start);
1539         LOG_TRACE("Needed ", ftos(i + 1), " attempts\n");
1540         return true;
1541     }
1542     else
1543         return false;
1544 }
1545
1546 void write_recordmarker(entity pl, float tstart, float dt)
1547 {
1548     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
1549
1550     // also write a marker into demo files for demotc-race-record-extractor to find
1551     stuffcmd(pl,
1552              strcat(
1553                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
1554                  " ", ftos(tstart), " ", ftos(dt), "\n"));
1555 }
1556
1557 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
1558 {
1559         switch(algn)
1560         {
1561                 default:
1562                 case 3: // right
1563                         break;
1564
1565                 case 4: // left
1566                         vecs.y = -vecs.y;
1567                         break;
1568
1569                 case 1:
1570                         if(allowcenter) // 2: allow center handedness
1571                         {
1572                                 // center
1573                                 vecs.y = 0;
1574                                 vecs.z -= 2;
1575                         }
1576                         else
1577                         {
1578                                 // right
1579                         }
1580                         break;
1581
1582                 case 2:
1583                         if(allowcenter) // 2: allow center handedness
1584                         {
1585                                 // center
1586                                 vecs.y = 0;
1587                                 vecs.z -= 2;
1588                         }
1589                         else
1590                         {
1591                                 // left
1592                                 vecs.y = -vecs.y;
1593                         }
1594                         break;
1595         }
1596         return vecs;
1597 }
1598
1599 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
1600 {
1601         string s;
1602         vector v;
1603
1604         if (autocvar_g_shootfromeye)
1605         {
1606                 if (visual)
1607                 {
1608                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
1609                         else { vecs.y = 0; vecs.z -= 2; }
1610                 }
1611                 else
1612                 {
1613                         vecs.y = 0;
1614                         vecs.z = 0;
1615                 }
1616         }
1617         else if (autocvar_g_shootfromcenter)
1618         {
1619                 vecs.y = 0;
1620                 vecs.z -= 2;
1621         }
1622         else if ((s = autocvar_g_shootfromfixedorigin) != "")
1623         {
1624                 v = stov(s);
1625                 if (y_is_right)
1626                         v.y = -v.y;
1627                 if (v.x != 0)
1628                         vecs.x = v.x;
1629                 vecs.y = v.y;
1630                 vecs.z = v.z;
1631         }
1632         else if (autocvar_g_shootfromclient)
1633         {
1634                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
1635         }
1636         return vecs;
1637 }
1638
1639 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
1640 {SELFPARAM();
1641         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
1642 }
1643
1644
1645 void attach_sameorigin(entity e, entity to, string tag)
1646 {
1647     vector org, t_forward, t_left, t_up, e_forward, e_up;
1648     float tagscale;
1649
1650     org = e.origin - gettaginfo(to, gettagindex(to, tag));
1651     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
1652     t_forward = v_forward * tagscale;
1653     t_left = v_right * -tagscale;
1654     t_up = v_up * tagscale;
1655
1656     e.origin_x = org * t_forward;
1657     e.origin_y = org * t_left;
1658     e.origin_z = org * t_up;
1659
1660     // current forward and up directions
1661     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1662                 e.angles = AnglesTransform_FromVAngles(e.angles);
1663         else
1664                 e.angles = AnglesTransform_FromAngles(e.angles);
1665     fixedmakevectors(e.angles);
1666
1667     // untransform forward, up!
1668     e_forward.x = v_forward * t_forward;
1669     e_forward.y = v_forward * t_left;
1670     e_forward.z = v_forward * t_up;
1671     e_up.x = v_up * t_forward;
1672     e_up.y = v_up * t_left;
1673     e_up.z = v_up * t_up;
1674
1675     e.angles = fixedvectoangles2(e_forward, e_up);
1676     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1677                 e.angles = AnglesTransform_ToVAngles(e.angles);
1678         else
1679                 e.angles = AnglesTransform_ToAngles(e.angles);
1680
1681     setattachment(e, to, tag);
1682     setorigin(e, e.origin);
1683 }
1684
1685 void detach_sameorigin(entity e)
1686 {
1687     vector org;
1688     org = gettaginfo(e, 0);
1689     e.angles = fixedvectoangles2(v_forward, v_up);
1690     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
1691                 e.angles = AnglesTransform_ToVAngles(e.angles);
1692         else
1693                 e.angles = AnglesTransform_ToAngles(e.angles);
1694     setorigin(e, org);
1695     setattachment(e, world, "");
1696     setorigin(e, e.origin);
1697 }
1698
1699 void follow_sameorigin(entity e, entity to)
1700 {
1701     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
1702     e.aiment = to; // make the hole follow bmodel
1703     e.punchangle = to.angles; // the original angles of bmodel
1704     e.view_ofs = e.origin - to.origin; // relative origin
1705     e.v_angle = e.angles - to.angles; // relative angles
1706 }
1707
1708 void unfollow_sameorigin(entity e)
1709 {
1710     e.movetype = MOVETYPE_NONE;
1711 }
1712
1713 entity gettaginfo_relative_ent;
1714 vector gettaginfo_relative(entity e, float tag)
1715 {
1716     if (!gettaginfo_relative_ent)
1717     {
1718         gettaginfo_relative_ent = spawn();
1719         gettaginfo_relative_ent.effects = EF_NODRAW;
1720     }
1721     gettaginfo_relative_ent.model = e.model;
1722     gettaginfo_relative_ent.modelindex = e.modelindex;
1723     gettaginfo_relative_ent.frame = e.frame;
1724     return gettaginfo(gettaginfo_relative_ent, tag);
1725 }
1726
1727 .float scale2;
1728
1729 float modeleffect_SendEntity(entity to, int sf)
1730 {SELFPARAM();
1731         float f;
1732         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
1733
1734         f = 0;
1735         if(self.velocity != '0 0 0')
1736                 f |= 1;
1737         if(self.angles != '0 0 0')
1738                 f |= 2;
1739         if(self.avelocity != '0 0 0')
1740                 f |= 4;
1741
1742         WriteByte(MSG_ENTITY, f);
1743         WriteShort(MSG_ENTITY, self.modelindex);
1744         WriteByte(MSG_ENTITY, self.skin);
1745         WriteByte(MSG_ENTITY, self.frame);
1746         WriteCoord(MSG_ENTITY, self.origin.x);
1747         WriteCoord(MSG_ENTITY, self.origin.y);
1748         WriteCoord(MSG_ENTITY, self.origin.z);
1749         if(f & 1)
1750         {
1751                 WriteCoord(MSG_ENTITY, self.velocity.x);
1752                 WriteCoord(MSG_ENTITY, self.velocity.y);
1753                 WriteCoord(MSG_ENTITY, self.velocity.z);
1754         }
1755         if(f & 2)
1756         {
1757                 WriteCoord(MSG_ENTITY, self.angles.x);
1758                 WriteCoord(MSG_ENTITY, self.angles.y);
1759                 WriteCoord(MSG_ENTITY, self.angles.z);
1760         }
1761         if(f & 4)
1762         {
1763                 WriteCoord(MSG_ENTITY, self.avelocity.x);
1764                 WriteCoord(MSG_ENTITY, self.avelocity.y);
1765                 WriteCoord(MSG_ENTITY, self.avelocity.z);
1766         }
1767         WriteShort(MSG_ENTITY, self.scale * 256.0);
1768         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
1769         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
1770         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
1771         WriteByte(MSG_ENTITY, self.alpha * 255.0);
1772
1773         return true;
1774 }
1775
1776 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
1777 {
1778         entity e;
1779         float sz;
1780         e = spawn();
1781         e.classname = "modeleffect";
1782         _setmodel(e, m);
1783         e.frame = f;
1784         setorigin(e, o);
1785         e.velocity = v;
1786         e.angles = ang;
1787         e.avelocity = angv;
1788         e.alpha = a;
1789         e.teleport_time = t1;
1790         e.fade_time = t2;
1791         e.skin = s;
1792         if(s0 >= 0)
1793                 e.scale = s0 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1794         else
1795                 e.scale = -s0;
1796         if(s2 >= 0)
1797                 e.scale2 = s2 / max6(-e.mins.x, -e.mins.y, -e.mins.z, e.maxs.x, e.maxs.y, e.maxs.z);
1798         else
1799                 e.scale2 = -s2;
1800         sz = max(e.scale, e.scale2);
1801         setsize(e, e.mins * sz, e.maxs * sz);
1802         Net_LinkEntity(e, false, 0.1, modeleffect_SendEntity);
1803 }
1804
1805 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
1806 {
1807         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
1808 }
1809
1810 float randombit(float bits)
1811 {
1812         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
1813                 return bits;
1814
1815         float n, f, b, r;
1816
1817         r = random();
1818         b = 0;
1819         n = 0;
1820
1821         for(f = 1; f <= bits; f *= 2)
1822         {
1823                 if(bits & f)
1824                 {
1825                         ++n;
1826                         r *= n;
1827                         if(r <= 1)
1828                                 b = f;
1829                         else
1830                                 r = (r - 1) / (n - 1);
1831                 }
1832         }
1833
1834         return b;
1835 }
1836
1837 float randombits(float bits, float k, float error_return)
1838 {
1839         float r;
1840         r = 0;
1841         while(k > 0 && bits != r)
1842         {
1843                 r += randombit(bits - r);
1844                 --k;
1845         }
1846         if(error_return)
1847                 if(k > 0)
1848                         return -1; // all
1849         return r;
1850 }
1851
1852 void randombit_test(float bits, float iter)
1853 {
1854         while(iter > 0)
1855         {
1856                 LOG_INFO(ftos(randombit(bits)), "\n");
1857                 --iter;
1858         }
1859 }
1860
1861 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
1862 {
1863         if(halflifedist > 0)
1864                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
1865         else if(halflifedist < 0)
1866                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
1867         else
1868                 return 1;
1869 }
1870
1871
1872 .string aiment_classname;
1873 .float aiment_deadflag;
1874 void SetMovetypeFollow(entity ent, entity e)
1875 {
1876         // FIXME this may not be warpzone aware
1877         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
1878         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
1879         ent.aiment = e; // make the hole follow bmodel
1880         ent.punchangle = e.angles; // the original angles of bmodel
1881         ent.view_ofs = ent.origin - e.origin; // relative origin
1882         ent.v_angle = ent.angles - e.angles; // relative angles
1883         ent.aiment_classname = strzone(e.classname);
1884         ent.aiment_deadflag = e.deadflag;
1885 }
1886 void UnsetMovetypeFollow(entity ent)
1887 {
1888         ent.movetype = MOVETYPE_FLY;
1889         PROJECTILE_MAKETRIGGER(ent);
1890         ent.aiment = world;
1891 }
1892 float LostMovetypeFollow(entity ent)
1893 {
1894 /*
1895         if(ent.movetype != MOVETYPE_FOLLOW)
1896                 if(ent.aiment)
1897                         error("???");
1898 */
1899         if(ent.aiment)
1900         {
1901                 if(ent.aiment.classname != ent.aiment_classname)
1902                         return 1;
1903                 if(ent.aiment.deadflag != ent.aiment_deadflag)
1904                         return 1;
1905         }
1906         return 0;
1907 }
1908
1909 float isPushable(entity e)
1910 {
1911         if(e.pushable)
1912                 return true;
1913         if(IS_VEHICLE(e))
1914                 return false;
1915         if(e.iscreature)
1916                 return true;
1917         switch(e.classname)
1918         {
1919                 case "body":
1920                 case "droppedweapon":
1921                 case "keepawayball":
1922                 case "nexball_basketball":
1923                 case "nexball_football":
1924                         return true;
1925                 case "bullet": // antilagged bullets can't hit this either
1926                         return false;
1927         }
1928         if (e.projectiledeathtype)
1929                 return true;
1930         return false;
1931 }