qcsrc/server/mutators/base.qh

   1 #define CBC_ORDER_EXCLUSIVE 3
   2 #define CBC_ORDER_FIRST 1
   3 #define CBC_ORDER_LAST 2
   4 #define CBC_ORDER_ANY 4
   5
   6 float CallbackChain_ReturnValue; // read-only field of the current return value
   7
   8 entity CallbackChain_New(string name);
   9 float CallbackChain_Add(entity cb, float() func, float order);
  10 float CallbackChain_Remove(entity cb, float() func);
  11 // a callback function is like this:
  12 // float mycallback(entity me)
  13 // {
  14 //   do something
  15 //   return r;
  16 // }
  17 float CallbackChain_Call(entity cb);
  18
  19 #define MUTATOR_REMOVING 0
  20 #define MUTATOR_ADDING 1
  21 #define MUTATOR_ROLLING_BACK 2
  22 typedef float(float) mutatorfunc_t;
  23 float Mutator_Add(mutatorfunc_t func, string name);
  24 void Mutator_Remove(mutatorfunc_t func, string name); // calls error() on fail
  25
  26 #define MUTATOR_ADD(name) Mutator_Add(MUTATOR_##name, #name)
  27 #define MUTATOR_REMOVE(name) Mutator_Remove(MUTATOR_##name, #name)
  28 #define MUTATOR_DEFINITION(name) float MUTATOR_##name(float mode)
  29 #define MUTATOR_DECLARATION(name) float MUTATOR_##name(float mode)
  30 #define MUTATOR_HOOKFUNCTION(name) float HOOKFUNCTION_##name()
  31 #define MUTATOR_HOOK(cb,func,order) do { if(mode == MUTATOR_ADDING) { if(!HOOK_##cb) HOOK_##cb = CallbackChain_New(#cb); if(!CallbackChain_Add(HOOK_##cb,HOOKFUNCTION_##func,order)) { print("HOOK FAILED: ", #func, "\n"); return 1; } } else if(mode == MUTATOR_REMOVING || mode == MUTATOR_ROLLING_BACK) { if(HOOK_##cb) CallbackChain_Remove(HOOK_##cb,HOOKFUNCTION_##func); } } while(0)
  32 #define MUTATOR_ONADD if(mode == MUTATOR_ADDING)
  33 #define MUTATOR_ONREMOVE if(mode == MUTATOR_REMOVING)
  34 #define MUTATOR_ONROLLBACK_OR_REMOVE if(mode == MUTATOR_REMOVING || mode == MUTATOR_ROLLING_BACK)
  35
  36 #define MUTATOR_HOOKABLE(cb) entity HOOK_##cb
  37 #define MUTATOR_CALLHOOK(cb) CallbackChain_Call(HOOK_##cb)
  38
  39 #define MUTATOR_RETURNVALUE CallbackChain_ReturnValue
  40
  41
  42
  43
  44 // register all possible hooks here
  45
  46 MUTATOR_HOOKABLE(MakePlayerObserver);
  47         // called when a player becomes observer, after shared setup
  48
  49 MUTATOR_HOOKABLE(PlayerSpawn);
  50         entity spawn_spot; // spot that was used, or world
  51         // called when a player spawns as player, after shared setup, before his weapon is chosen (so items may be changed in here)
  52
  53 MUTATOR_HOOKABLE(ClientDisconnect);
  54         // called when a player disconnects
  55
  56 MUTATOR_HOOKABLE(PlayerDies);
  57         // called when a player dies to e.g. remove stuff he was carrying.
  58         // INPUT:
  59                 entity frag_inflictor;
  60                 entity frag_attacker;
  61                 entity frag_target; // same as self
  62
  63 MUTATOR_HOOKABLE(GiveFragsForKill);
  64         // called when someone was fragged by "self", and is expected to change frag_score to adjust scoring for the kill
  65         // INPUT:
  66                 entity frag_attacker; // same as self
  67                 entity frag_target;
  68         // INPUT, OUTPUT:
  69                 float frag_score;
  70
  71 MUTATOR_HOOKABLE(PlayerClearScore);
  72         // called when a player's scores are going to be cleared
  73         // returning TRUE prevents score clearing
  74
  75 MUTATOR_HOOKABLE(MatchEnd);
  76         // called when the match ends
  77
  78 MUTATOR_HOOKABLE(GetTeamCount);
  79         // should adjust ret_float to contain the team count
  80         // INPUT, OUTPUT:
  81                 float ret_float;
  82
  83 MUTATOR_HOOKABLE(SpectateCopy);
  84         // copies variables for spectating "other" to "self"
  85         // INPUT:
  86                 entity other;
  87
  88 MUTATOR_HOOKABLE(ForbidThrowCurrentWeapon);
  89         // returns 1 if throwing the current weapon shall not be allowed
  90
  91 MUTATOR_HOOKABLE(SetStartItems);
  92         // adjusts {warmup_}start_{items,weapons,ammo_{cells,rockets,nails,shells,fuel}}
  93
  94 MUTATOR_HOOKABLE(BuildMutatorsString);
  95         // appends ":mutatorname" to ret_string for logging
  96         // INPUT, OUTPUT:
  97                 string ret_string;
  98
  99 MUTATOR_HOOKABLE(BuildMutatorsPrettyString);
 100         // appends ", Mutator name" to ret_string for display
 101         // INPUT, OUTPUT:
 102                 string ret_string;
 103
 104 MUTATOR_HOOKABLE(FilterItem);
 105         // checks if the current item may be spawned (self.items and self.weapons may be read and written to, as well as the ammo_ fields)
 106         // return error to request removal
 107
 108 MUTATOR_HOOKABLE(TurretSpawn);
 109         // return error to request removal
 110         // INPUT: self - turret
 111
 112 MUTATOR_HOOKABLE(OnEntityPreSpawn);
 113         // return error to prevent entity spawn, or modify the entity
 114
 115 MUTATOR_HOOKABLE(PlayerPreThink);
 116         // runs in the event loop for players; is called for ALL player entities, also bots, also the dead, or spectators
 117
 118 MUTATOR_HOOKABLE(GetPressedKeys);
 119         // TODO change this into a general PlayerPostThink hook?
 120
 121 MUTATOR_HOOKABLE(PlayerPhysics);
 122         // called before any player physics, may adjust variables for movement,
 123         // is run AFTER bot code and idle checking
 124
 125 MUTATOR_HOOKABLE(GetCvars);
 126         // is meant to call GetCvars_handle*(get_cvars_s, get_cvars_f, cvarfield, "cvarname") for cvars this mutator needs from the client
 127         // INPUT:
 128                 float get_cvars_f;
 129                 string get_cvars_s;
 130
 131 MUTATOR_HOOKABLE(EditProjectile);
 132         // can edit any "just fired" projectile
 133         // INPUT:
 134                 entity self;
 135                 entity other;
 136
 137 MUTATOR_HOOKABLE(PlayerDamage_SplitHealthArmor);
 138         // called when a player gets damaged to e.g. remove stuff he was carrying.
 139         // INPUT:
 140                 entity frag_inflictor;
 141                 entity frag_attacker;
 142                 entity frag_target; // same as self
 143                 vector damage_force; // NOTE: this force already HAS been applied
 144         // INPUT, OUTPUT:
 145                 float damage_take;
 146                 float damage_save;
 147
 148 MUTATOR_HOOKABLE(PlayerDamage_Calculate);
 149         // called to adjust damage and force values which are applied to the player, used for e.g. strength damage/force multiplier
 150         // i'm not sure if I should change this around slightly (Naming of the entities, and also how they're done in g_damage).
 151         // INPUT:
 152                 entity frag_attacker;
 153                 entity frag_target;
 154                 float frag_deathtype;
 155         // INPUT, OUTPUT:
 156                 float frag_damage;
 157                 vector frag_force;
 158
 159 MUTATOR_HOOKABLE(PlayerPowerups);
 160         // called at the end of player_powerups() in cl_client.qc, used for manipulating the values which are set by powerup items.
 161         // INPUT
 162         entity self;
 163         float olditems; // also technically output, but since it is at the end of the function it's useless for that :P
 164
 165 MUTATOR_HOOKABLE(PlayerUseKey);
 166         // called when the use key is pressed
 167         // if MUTATOR_RETURNVALUE is 1, don't do anything
 168         // return 1 if the use key actually did something
 169
 170 MUTATOR_HOOKABLE(SV_ParseClientCommand);
 171         // called when a client command is parsed
 172         // NOTE: hooks MUST start with if(MUTATOR_RETURNVALUE) return 0;
 173         // NOTE: return 1 if you handled the command, return 0 to continue handling
 174         // NOTE: THESE HOOKS MUST NEVER EVER CALL tokenize()
 175         // INPUT
 176         string cmd_name; // command name
 177         float cmd_argc; // also, argv() can be used
 178         string cmd_string; // whole command, use only if you really have to
 179         /*
 180                 // example:
 181                 MUTATOR_HOOKFUNCTION(foo_SV_ParseClientCommand)
 182                 {
 183                         if(MUTATOR_RETURNVALUE) // command was already handled?
 184                                 return 0;
 185                         if(cmd_name == "echocvar" && cmd_argc >= 2)
 186                         {
 187                                 print(cvar_string(argv(1)), "\n");
 188                                 return 1;
 189                         }
 190                         if(cmd_name == "echostring" && cmd_argc >= 2)
 191                         {
 192                                 print(substring(cmd_string, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), "\n");
 193                                 return 1;
 194                         }
 195                         return 0;
 196                 }
 197         */
 198
 199 MUTATOR_HOOKABLE(Spawn_Score);
 200         // called when a spawnpoint is being evaluated
 201         // return 1 to make the spawnpoint unusable
 202         // INPUT
 203         entity self; // player wanting to spawn
 204         entity spawn_spot; // spot to be evaluated
 205         // IN+OUT
 206         vector spawn_score; // _x is priority, _y is "distance"
 207
 208 MUTATOR_HOOKABLE(SV_StartFrame);
 209         // runs globally each server frame
 210
 211 MUTATOR_HOOKABLE(SetModname);
 212         // OUT
 213         string modname; // name of the mutator/mod if it warrants showing as such in the server browser
 214
 215 MUTATOR_HOOKABLE(Item_Spawn);
 216         // called for each item being spawned on a map, including dropped weapons
 217         // return 1 to remove an item
 218         // INPUT
 219         entity self; // the item
 220
 221 MUTATOR_HOOKABLE(SetWeaponreplace);
 222         // IN
 223                 entity self; // map entity
 224                 entity other; // weapon info
 225         // IN+OUT
 226                 string ret_string;
 227
 228 MUTATOR_HOOKABLE(PortalTeleport);
 229         // called whenever a player goes through a portal gun teleport
 230         // allows you to strip a player of an item if they go through the teleporter to help prevent cheating
 231         // INPUT
 232         entity self;
 233
 234 MUTATOR_HOOKABLE(HelpMePing);
 235         // called whenever a player uses impulse 33 (help me) in cl_impulse.qc
 236         // normally help me ping uses self.waypointsprite_attachedforcarrier,
 237         // but if your mutator uses something different then you can handle it
 238         // in a special manner using this hook
 239         // INPUT
 240         entity self; // the player who pressed impulse 33
 241
 242 MUTATOR_HOOKABLE(VehicleEnter);
 243         // called when a player enters a vehicle
 244         // allows mutators to set special settings in this event
 245         // INPUT
 246         entity vh_player; // player
 247         entity vh_vehicle; // vehicle
 248
 249 MUTATOR_HOOKABLE(VehicleExit);
 250         // called when a player exits a vehicle
 251         // allows mutators to set special settings in this event
 252         // INPUT
 253         entity vh_player; // player
 254         entity vh_vehicle; // vehicle
 255
 256 MUTATOR_HOOKABLE(AbortSpeedrun);
 257         // called when a speedrun is aborted and the player is teleported back to start position
 258         // INPUT
 259         entity self; // player
 260
 261 MUTATOR_HOOKABLE(ItemTouch);
 262         // called at when a item is touched. Called early, can edit item properties.
 263         entity self;    // item
 264         entity other;   // player
 265
 266 MUTATOR_HOOKABLE(ClientConnect);
 267         // called at when a player connect
 268         entity self;    // player
 269
 270 MUTATOR_HOOKABLE(HavocBot_ChooseRule);
 271         entity self;