qcsrc/server/mutators/gamemode_ca.qc

   1 float total_players;
   2 float redalive, bluealive, yellowalive, pinkalive;
   3 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
   4 float ca_teams;
   5 float allowed_to_spawn;
   6
   7 void CA_count_alive_players()
   8 {
   9         entity e;
  10         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  11         FOR_EACH_PLAYER(e) {
  12                 if(e.team == NUM_TEAM_1)
  13                 {
  14                         ++total_players;
  15                         if (e.health >= 1) ++redalive;
  16                 }
  17                 else if(e.team == NUM_TEAM_2)
  18                 {
  19                         ++total_players;
  20                         if (e.health >= 1) ++bluealive;
  21                 }
  22                 else if(e.team == NUM_TEAM_3)
  23                 {
  24                         ++total_players;
  25                         if (e.health >= 1) ++yellowalive;
  26                 }
  27                 else if(e.team == NUM_TEAM_4)
  28                 {
  29                         ++total_players;
  30                         if (e.health >= 1) ++pinkalive;
  31                 }
  32         }
  33         FOR_EACH_REALCLIENT(e) {
  34                 e.redalive_stat = redalive;
  35                 e.bluealive_stat = bluealive;
  36                 e.yellowalive_stat = yellowalive;
  37                 e.pinkalive_stat = pinkalive;
  38         }
  39 }
  40
  41 float CA_GetWinnerTeam()
  42 {
  43         float winner_team = 0;
  44         if(redalive >= 1)
  45                 winner_team = NUM_TEAM_1;
  46         if(bluealive >= 1)
  47         {
  48                 if(winner_team) return 0;
  49                 winner_team = NUM_TEAM_2;
  50         }
  51         if(yellowalive >= 1)
  52         {
  53                 if(winner_team) return 0;
  54                 winner_team = NUM_TEAM_3;
  55         }
  56         if(pinkalive >= 1)
  57         {
  58                 if(winner_team) return 0;
  59                 winner_team = NUM_TEAM_4;
  60         }
  61         if(winner_team)
  62                 return winner_team;
  63         return -1; // no player left
  64 }
  65
  66 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  67 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
  68 float CA_CheckWinner()
  69 {
  70         entity e;
  71         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  72         {
  73                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  74                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  75                 allowed_to_spawn = FALSE;
  76                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  77                 FOR_EACH_PLAYER(e)
  78                         nades_Clear(e);
  79                 return 1;
  80         }
  81
  82         CA_count_alive_players();
  83         if(CA_ALIVE_TEAMS() > 1)
  84                 return 0;
  85
  86         float winner_team = CA_GetWinnerTeam();
  87         if(winner_team > 0)
  88         {
  89                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner_team, CENTER_ROUND_TEAM_WIN_));
  90                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner_team, INFO_ROUND_TEAM_WIN_));
  91                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
  92         }
  93         else if(winner_team == -1)
  94         {
  95                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
  96                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
  97         }
  98
  99         allowed_to_spawn = FALSE;
 100         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 101
 102         FOR_EACH_PLAYER(e)
 103                 nades_Clear(e);
 104
 105         return 1;
 106 }
 107
 108 void CA_RoundStart()
 109 {
 110         if(warmup_stage)
 111                 allowed_to_spawn = TRUE;
 112         else
 113                 allowed_to_spawn = FALSE;
 114 }
 115
 116 float prev_missing_teams_mask;
 117 float CA_CheckTeams()
 118 {
 119         allowed_to_spawn = TRUE;
 120         CA_count_alive_players();
 121         if(CA_ALIVE_TEAMS_OK())
 122         {
 123                 if(prev_missing_teams_mask > 0)
 124                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 125                 prev_missing_teams_mask = -1;
 126                 return 1;
 127         }
 128         if(total_players == 0)
 129         {
 130                 if(prev_missing_teams_mask > 0)
 131                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 132                 prev_missing_teams_mask = -1;
 133                 return 0;
 134         }
 135         float missing_teams_mask = (!redalive) + (!bluealive) * 2;
 136         if(ca_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 137         if(ca_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 138         if(prev_missing_teams_mask != missing_teams_mask)
 139         {
 140                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 141                 prev_missing_teams_mask = missing_teams_mask;
 142         }
 143         return 0;
 144 }
 145
 146 MUTATOR_HOOKFUNCTION(ca_PlayerSpawn)
 147 {
 148         self.caplayer = 1;
 149         return 1;
 150 }
 151
 152 MUTATOR_HOOKFUNCTION(ca_PutClientInServer)
 153 {
 154         if(!allowed_to_spawn)
 155         if(IS_PLAYER(self)) // this is true even when player is trying to join
 156         {
 157                 self.classname = "observer";
 158                 if(self.jointime != time) //not when connecting
 159                 if(!self.caplayer)
 160                 {
 161                         self.caplayer = 0.5;
 162                         if(IS_REAL_CLIENT(self))
 163                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_JOIN_LATE);
 164                 }
 165         }
 166         return 1;
 167 }
 168
 169 MUTATOR_HOOKFUNCTION(ca_reset_map_players)
 170 {
 171         FOR_EACH_CLIENT(self)
 172         {
 173                 self.killcount = 0;
 174                 if(!self.caplayer && IS_BOT_CLIENT(self))
 175                 {
 176                         self.team = -1;
 177                         self.caplayer = 1;
 178                 }
 179                 if(self.caplayer)
 180                 {
 181                         self.classname = "player";
 182                         self.caplayer = 1;
 183                         PutClientInServer();
 184                 }
 185         }
 186         return 1;
 187 }
 188
 189 MUTATOR_HOOKFUNCTION(ca_ClientConnect)
 190 {
 191         self.classname = "observer";
 192         return 1;
 193 }
 194
 195 MUTATOR_HOOKFUNCTION(ca_reset_map_global)
 196 {
 197         allowed_to_spawn = TRUE;
 198         return 1;
 199 }
 200
 201 MUTATOR_HOOKFUNCTION(ca_GetTeamCount)
 202 {
 203         ret_float = ca_teams;
 204         return 0;
 205 }
 206
 207 entity ca_LastPlayerForTeam()
 208 {
 209         entity pl, last_pl = world;
 210         FOR_EACH_PLAYER(pl)
 211         {
 212                 if(pl.health >= 1)
 213                 if(pl != self)
 214                 if(pl.team == self.team)
 215                 if(!last_pl)
 216                         last_pl = pl;
 217                 else
 218                         return world;
 219         }
 220         return last_pl;
 221 }
 222
 223 void ca_LastPlayerForTeam_Notify()
 224 {
 225         if(round_handler_IsActive())
 226         if(round_handler_IsRoundStarted())
 227         {
 228                 entity pl = ca_LastPlayerForTeam();
 229                 if(pl)
 230                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 231         }
 232 }
 233
 234 MUTATOR_HOOKFUNCTION(ca_PlayerDies)
 235 {
 236         ca_LastPlayerForTeam_Notify();
 237         if(!allowed_to_spawn)
 238                 self.respawn_flags =  RESPAWN_SILENT;
 239         return 1;
 240 }
 241
 242 MUTATOR_HOOKFUNCTION(ca_ClientDisconnect)
 243 {
 244         if(self.caplayer == 1)
 245                 ca_LastPlayerForTeam_Notify();
 246         return 1;
 247 }
 248
 249 MUTATOR_HOOKFUNCTION(ca_ForbidPlayerScore_Clear)
 250 {
 251         return 1;
 252 }
 253
 254 MUTATOR_HOOKFUNCTION(ca_MakePlayerObserver)
 255 {
 256         if(self.caplayer == 1)
 257                 ca_LastPlayerForTeam_Notify();
 258         if(self.killindicator_teamchange == -2)
 259                 self.caplayer = 0;
 260         if(self.caplayer)
 261                 self.frags = FRAGS_LMS_LOSER;
 262         return 1;
 263 }
 264
 265 MUTATOR_HOOKFUNCTION(ca_ForbidThrowCurrentWeapon)
 266 {
 267         return 1;
 268 }
 269
 270 MUTATOR_HOOKFUNCTION(ca_GiveFragsForKill)
 271 {
 272         frag_score = 0; // score will be given to the winner team when the round ends
 273         return 1;
 274 }
 275
 276 MUTATOR_HOOKFUNCTION(ca_SetStartItems)
 277 {
 278         start_items &= ~IT_UNLIMITED_AMMO;
 279         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 280         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 281         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 282         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 283         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 284         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 285         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 286
 287         return 0;
 288 }
 289
 290 MUTATOR_HOOKFUNCTION(ca_PlayerDamage)
 291 {
 292         if(IS_PLAYER(frag_target))
 293         if(frag_target.deadflag == DEAD_NO)
 294         if(frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL)
 295                 frag_damage = 0;
 296
 297         frag_mirrordamage = 0;
 298
 299         return FALSE;
 300 }
 301
 302 MUTATOR_HOOKFUNCTION(ca_FilterItem)
 303 {
 304         if(autocvar_g_powerups <= 0)
 305         if(self.flags & FL_POWERUP)
 306                 return TRUE;
 307
 308         if(autocvar_g_pickup_items <= 0)
 309                 return TRUE;
 310
 311         return FALSE;
 312 }
 313
 314 MUTATOR_HOOKFUNCTION(ca_PlayerDamage_SplitHealthArmor)
 315 {
 316         float excess = max(0, frag_damage - damage_take - damage_save);
 317
 318         if(frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 319                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 320
 321         return FALSE;
 322 }
 323
 324 MUTATOR_HOOKFUNCTION(ca_PlayerRegen)
 325 {
 326         // no regeneration in CA
 327         return TRUE;
 328 }
 329
 330 void ca_Initialize()
 331 {
 332         allowed_to_spawn = TRUE;
 333
 334         ca_teams = autocvar_g_ca_teams_override;
 335         if(ca_teams < 2)
 336                 ca_teams = autocvar_g_ca_teams;
 337         ca_teams = bound(2, ca_teams, 4);
 338         ret_float = ca_teams;
 339         ScoreRules_ca(ca_teams);
 340
 341         round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
 342         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 343
 344         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 345         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 346         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 347         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 348 }
 349
 350 MUTATOR_DEFINITION(gamemode_ca)
 351 {
 352         MUTATOR_HOOK(PlayerSpawn, ca_PlayerSpawn, CBC_ORDER_ANY);
 353         MUTATOR_HOOK(PutClientInServer, ca_PutClientInServer, CBC_ORDER_ANY);
 354         MUTATOR_HOOK(MakePlayerObserver, ca_MakePlayerObserver, CBC_ORDER_ANY);
 355         MUTATOR_HOOK(ClientConnect, ca_ClientConnect, CBC_ORDER_ANY);
 356         MUTATOR_HOOK(reset_map_global, ca_reset_map_global, CBC_ORDER_ANY);
 357         MUTATOR_HOOK(reset_map_players, ca_reset_map_players, CBC_ORDER_ANY);
 358         MUTATOR_HOOK(GetTeamCount, ca_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 359         MUTATOR_HOOK(PlayerDies, ca_PlayerDies, CBC_ORDER_ANY);
 360         MUTATOR_HOOK(ClientDisconnect, ca_ClientDisconnect, CBC_ORDER_ANY);
 361         MUTATOR_HOOK(ForbidPlayerScore_Clear, ca_ForbidPlayerScore_Clear, CBC_ORDER_ANY);
 362         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ca_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 363         MUTATOR_HOOK(GiveFragsForKill, ca_GiveFragsForKill, CBC_ORDER_FIRST);
 364         MUTATOR_HOOK(SetStartItems, ca_SetStartItems, CBC_ORDER_ANY);
 365         MUTATOR_HOOK(PlayerDamage_Calculate, ca_PlayerDamage, CBC_ORDER_ANY);
 366         MUTATOR_HOOK(FilterItem, ca_FilterItem, CBC_ORDER_ANY);
 367         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, ca_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 368         MUTATOR_HOOK(PlayerRegen, ca_PlayerRegen, CBC_ORDER_ANY);
 369
 370         MUTATOR_ONADD
 371         {
 372                 if(time > 1) // game loads at time 1
 373                         error("This is a game type and it cannot be added at runtime.");
 374                 ca_Initialize();
 375         }
 376
 377         MUTATOR_ONREMOVE
 378         {
 379                 print("This is a game type and it cannot be removed at runtime.");
 380                 return -1;
 381         }
 382
 383         return 0;
 384 }