qcsrc/server/mutators/gamemode_ca.qc

   1 float total_players;
   2 float redalive, bluealive, yellowalive, pinkalive;
   3 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
   4 float ca_teams;
   5 float allowed_to_spawn;
   6
   7 void CA_count_alive_players()
   8 {
   9         entity e;
  10         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  11         FOR_EACH_PLAYER(e) {
  12                 if(e.team == NUM_TEAM_1)
  13                 {
  14                         ++total_players;
  15                         if (e.health >= 1) ++redalive;
  16                 }
  17                 else if(e.team == NUM_TEAM_2)
  18                 {
  19                         ++total_players;
  20                         if (e.health >= 1) ++bluealive;
  21                 }
  22                 else if(e.team == NUM_TEAM_3)
  23                 {
  24                         ++total_players;
  25                         if (e.health >= 1) ++yellowalive;
  26                 }
  27                 else if(e.team == NUM_TEAM_4)
  28                 {
  29                         ++total_players;
  30                         if (e.health >= 1) ++pinkalive;
  31                 }
  32         }
  33         FOR_EACH_REALCLIENT(e) {
  34                 e.redalive_stat = redalive;
  35                 e.bluealive_stat = bluealive;
  36                 e.yellowalive_stat = yellowalive;
  37                 e.pinkalive_stat = pinkalive;
  38         }
  39 }
  40
  41 float CA_GetWinnerTeam()
  42 {
  43         float winner_team = 0;
  44         if(redalive >= 1)
  45                 winner_team = NUM_TEAM_1;
  46         if(bluealive >= 1)
  47         {
  48                 if(winner_team) return 0;
  49                 winner_team = NUM_TEAM_2;
  50         }
  51         if(yellowalive >= 1)
  52         {
  53                 if(winner_team) return 0;
  54                 winner_team = NUM_TEAM_3;
  55         }
  56         if(pinkalive >= 1)
  57         {
  58                 if(winner_team) return 0;
  59                 winner_team = NUM_TEAM_4;
  60         }
  61         if(winner_team)
  62                 return winner_team;
  63         return -1; // no player left
  64 }
  65
  66 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  67 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
  68 float CA_CheckWinner()
  69 {
  70         entity e;
  71         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  72         {
  73                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  74                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  75                 allowed_to_spawn = FALSE;
  76                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  77                 FOR_EACH_PLAYER(e)
  78                         nades_Clear(e);
  79                 return 1;
  80         }
  81
  82         CA_count_alive_players();
  83         if(CA_ALIVE_TEAMS() > 1)
  84                 return 0;
  85
  86         float winner_team = CA_GetWinnerTeam();
  87         if(winner_team > 0)
  88         {
  89                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner_team, CENTER_ROUND_TEAM_WIN_));
  90                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner_team, INFO_ROUND_TEAM_WIN_));
  91                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
  92         }
  93         else if(winner_team == -1)
  94         {
  95                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
  96                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
  97         }
  98
  99         allowed_to_spawn = FALSE;
 100         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 101
 102         FOR_EACH_PLAYER(e)
 103                 nades_Clear(e);
 104
 105         return 1;
 106 }
 107
 108 void CA_RoundStart()
 109 {
 110         if(warmup_stage)
 111                 allowed_to_spawn = TRUE;
 112         else
 113                 allowed_to_spawn = FALSE;
 114 }
 115
 116 float prev_missing_teams_mask;
 117 float CA_CheckTeams()
 118 {
 119         allowed_to_spawn = TRUE;
 120         CA_count_alive_players();
 121         if(CA_ALIVE_TEAMS_OK())
 122         {
 123                 if(prev_missing_teams_mask > 0)
 124                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 125                 prev_missing_teams_mask = -1;
 126                 return 1;
 127         }
 128         if(total_players == 0)
 129         {
 130                 if(prev_missing_teams_mask > 0)
 131                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 132                 prev_missing_teams_mask = -1;
 133                 return 0;
 134         }
 135         float missing_teams_mask = (!redalive) + (!bluealive) * 2;
 136         if(ca_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 137         if(ca_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 138         if(prev_missing_teams_mask != missing_teams_mask)
 139         {
 140                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 141                 prev_missing_teams_mask = missing_teams_mask;
 142         }
 143         return 0;
 144 }
 145
 146 float ca_isEliminated(entity e)
 147 {
 148         if(e.caplayer == 1 && (e.deadflag != DEAD_NO || e.frags == FRAGS_LMS_LOSER))
 149                 return TRUE;
 150         if(e.caplayer == 0.5)
 151                 return TRUE;
 152         return FALSE;
 153 }
 154
 155 MUTATOR_HOOKFUNCTION(ca_PlayerSpawn)
 156 {
 157         self.caplayer = 1;
 158         if(!warmup_stage)
 159                 eliminatedPlayers.SendFlags |= 1;
 160         return 1;
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(ca_PutClientInServer)
 164 {
 165         if(!allowed_to_spawn)
 166         if(IS_PLAYER(self)) // this is true even when player is trying to join
 167         {
 168                 self.classname = "observer";
 169                 if(self.jointime != time) //not when connecting
 170                 if(!self.caplayer)
 171                 {
 172                         self.caplayer = 0.5;
 173                         if(IS_REAL_CLIENT(self))
 174                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_JOIN_LATE);
 175                 }
 176         }
 177         return 1;
 178 }
 179
 180 MUTATOR_HOOKFUNCTION(ca_reset_map_players)
 181 {
 182         FOR_EACH_CLIENT(self)
 183         {
 184                 self.killcount = 0;
 185                 if(!self.caplayer && IS_BOT_CLIENT(self))
 186                 {
 187                         self.team = -1;
 188                         self.caplayer = 1;
 189                 }
 190                 if(self.caplayer)
 191                 {
 192                         self.classname = "player";
 193                         self.caplayer = 1;
 194                         PutClientInServer();
 195                 }
 196         }
 197         return 1;
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(ca_ClientConnect)
 201 {
 202         self.classname = "observer";
 203         return 1;
 204 }
 205
 206 MUTATOR_HOOKFUNCTION(ca_reset_map_global)
 207 {
 208         allowed_to_spawn = TRUE;
 209         return 1;
 210 }
 211
 212 MUTATOR_HOOKFUNCTION(ca_GetTeamCount)
 213 {
 214         ret_float = ca_teams;
 215         return 0;
 216 }
 217
 218 entity ca_LastPlayerForTeam()
 219 {
 220         entity pl, last_pl = world;
 221         FOR_EACH_PLAYER(pl)
 222         {
 223                 if(pl.health >= 1)
 224                 if(pl != self)
 225                 if(pl.team == self.team)
 226                 if(!last_pl)
 227                         last_pl = pl;
 228                 else
 229                         return world;
 230         }
 231         return last_pl;
 232 }
 233
 234 void ca_LastPlayerForTeam_Notify()
 235 {
 236         if(round_handler_IsActive())
 237         if(round_handler_IsRoundStarted())
 238         {
 239                 entity pl = ca_LastPlayerForTeam();
 240                 if(pl)
 241                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 242         }
 243 }
 244
 245 MUTATOR_HOOKFUNCTION(ca_PlayerDies)
 246 {
 247         ca_LastPlayerForTeam_Notify();
 248         if(!allowed_to_spawn)
 249                 self.respawn_flags =  RESPAWN_SILENT;
 250         if(!warmup_stage)
 251                 eliminatedPlayers.SendFlags |= 1;
 252         return 1;
 253 }
 254
 255 MUTATOR_HOOKFUNCTION(ca_ClientDisconnect)
 256 {
 257         if(self.caplayer == 1)
 258                 ca_LastPlayerForTeam_Notify();
 259         return 1;
 260 }
 261
 262 MUTATOR_HOOKFUNCTION(ca_ForbidPlayerScore_Clear)
 263 {
 264         return 1;
 265 }
 266
 267 MUTATOR_HOOKFUNCTION(ca_MakePlayerObserver)
 268 {
 269         if(self.caplayer == 1)
 270                 ca_LastPlayerForTeam_Notify();
 271         if(self.killindicator_teamchange == -2)
 272                 self.caplayer = 0;
 273         if(self.caplayer)
 274                 self.frags = FRAGS_LMS_LOSER;
 275         if(!warmup_stage)
 276                 eliminatedPlayers.SendFlags |= 1;
 277         return 1;
 278 }
 279
 280 MUTATOR_HOOKFUNCTION(ca_ForbidThrowCurrentWeapon)
 281 {
 282         return 1;
 283 }
 284
 285 MUTATOR_HOOKFUNCTION(ca_GiveFragsForKill)
 286 {
 287         frag_score = 0; // score will be given to the winner team when the round ends
 288         return 1;
 289 }
 290
 291 MUTATOR_HOOKFUNCTION(ca_SetStartItems)
 292 {
 293         start_items &= ~IT_UNLIMITED_AMMO;
 294         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 295         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 296         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 297         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 298         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 299         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 300         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 301         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 302
 303         return 0;
 304 }
 305
 306 MUTATOR_HOOKFUNCTION(ca_PlayerDamage)
 307 {
 308         if(IS_PLAYER(frag_target))
 309         if(frag_target.deadflag == DEAD_NO)
 310         if(frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL)
 311                 frag_damage = 0;
 312
 313         frag_mirrordamage = 0;
 314
 315         return FALSE;
 316 }
 317
 318 MUTATOR_HOOKFUNCTION(ca_FilterItem)
 319 {
 320         if(autocvar_g_powerups <= 0)
 321         if(self.flags & FL_POWERUP)
 322                 return TRUE;
 323
 324         if(autocvar_g_pickup_items <= 0)
 325                 return TRUE;
 326
 327         return FALSE;
 328 }
 329
 330 MUTATOR_HOOKFUNCTION(ca_PlayerDamage_SplitHealthArmor)
 331 {
 332         float excess = max(0, frag_damage - damage_take - damage_save);
 333
 334         if(frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 335                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 336
 337         return FALSE;
 338 }
 339
 340 MUTATOR_HOOKFUNCTION(ca_PlayerRegen)
 341 {
 342         // no regeneration in CA
 343         return TRUE;
 344 }
 345
 346 void ca_Initialize()
 347 {
 348         allowed_to_spawn = TRUE;
 349
 350         ca_teams = autocvar_g_ca_teams_override;
 351         if(ca_teams < 2)
 352                 ca_teams = autocvar_g_ca_teams;
 353         ca_teams = bound(2, ca_teams, 4);
 354         ret_float = ca_teams;
 355         ScoreRules_ca(ca_teams);
 356
 357         round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
 358         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 359
 360         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 361         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 362         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 363         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 364
 365         EliminatedPlayers_Init(ca_isEliminated);
 366 }
 367
 368 MUTATOR_DEFINITION(gamemode_ca)
 369 {
 370         MUTATOR_HOOK(PlayerSpawn, ca_PlayerSpawn, CBC_ORDER_ANY);
 371         MUTATOR_HOOK(PutClientInServer, ca_PutClientInServer, CBC_ORDER_ANY);
 372         MUTATOR_HOOK(MakePlayerObserver, ca_MakePlayerObserver, CBC_ORDER_ANY);
 373         MUTATOR_HOOK(ClientConnect, ca_ClientConnect, CBC_ORDER_ANY);
 374         MUTATOR_HOOK(reset_map_global, ca_reset_map_global, CBC_ORDER_ANY);
 375         MUTATOR_HOOK(reset_map_players, ca_reset_map_players, CBC_ORDER_ANY);
 376         MUTATOR_HOOK(GetTeamCount, ca_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 377         MUTATOR_HOOK(PlayerDies, ca_PlayerDies, CBC_ORDER_ANY);
 378         MUTATOR_HOOK(ClientDisconnect, ca_ClientDisconnect, CBC_ORDER_ANY);
 379         MUTATOR_HOOK(ForbidPlayerScore_Clear, ca_ForbidPlayerScore_Clear, CBC_ORDER_ANY);
 380         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ca_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 381         MUTATOR_HOOK(GiveFragsForKill, ca_GiveFragsForKill, CBC_ORDER_FIRST);
 382         MUTATOR_HOOK(SetStartItems, ca_SetStartItems, CBC_ORDER_ANY);
 383         MUTATOR_HOOK(PlayerDamage_Calculate, ca_PlayerDamage, CBC_ORDER_ANY);
 384         MUTATOR_HOOK(FilterItem, ca_FilterItem, CBC_ORDER_ANY);
 385         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, ca_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 386         MUTATOR_HOOK(PlayerRegen, ca_PlayerRegen, CBC_ORDER_ANY);
 387
 388         MUTATOR_ONADD
 389         {
 390                 if(time > 1) // game loads at time 1
 391                         error("This is a game type and it cannot be added at runtime.");
 392                 ca_Initialize();
 393         }
 394
 395         MUTATOR_ONREMOVE
 396         {
 397                 print("This is a game type and it cannot be removed at runtime.");
 398                 return -1;
 399         }
 400
 401         return 0;
 402 }