qcsrc/server/mutators/gamemode_ca.qc

   1 float total_players;
   2 float redalive, bluealive, yellowalive, pinkalive;
   3 .float redalive_stat, bluealive_stat, yellowalive_stat, pinkalive_stat;
   4 float ca_teams;
   5 float allowed_to_spawn;
   6
   7 void CA_count_alive_players()
   8 {
   9         entity e;
  10         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  11         FOR_EACH_PLAYER(e) {
  12                 if(e.team == NUM_TEAM_1)
  13                 {
  14                         ++total_players;
  15                         if (e.health >= 1) ++redalive;
  16                 }
  17                 else if(e.team == NUM_TEAM_2)
  18                 {
  19                         ++total_players;
  20                         if (e.health >= 1) ++bluealive;
  21                 }
  22                 else if(e.team == NUM_TEAM_3)
  23                 {
  24                         ++total_players;
  25                         if (e.health >= 1) ++yellowalive;
  26                 }
  27                 else if(e.team == NUM_TEAM_4)
  28                 {
  29                         ++total_players;
  30                         if (e.health >= 1) ++pinkalive;
  31                 }
  32         }
  33         FOR_EACH_REALCLIENT(e) {
  34                 e.redalive_stat = redalive;
  35                 e.bluealive_stat = bluealive;
  36                 e.yellowalive_stat = yellowalive;
  37                 e.pinkalive_stat = pinkalive;
  38         }
  39 }
  40
  41 float CA_GetWinnerTeam()
  42 {
  43         float winner_team = 0;
  44         if(redalive >= 1)
  45                 winner_team = NUM_TEAM_1;
  46         if(bluealive >= 1)
  47         {
  48                 if(winner_team) return 0;
  49                 winner_team = NUM_TEAM_2;
  50         }
  51         if(yellowalive >= 1)
  52         {
  53                 if(winner_team) return 0;
  54                 winner_team = NUM_TEAM_3;
  55         }
  56         if(pinkalive >= 1)
  57         {
  58                 if(winner_team) return 0;
  59                 winner_team = NUM_TEAM_4;
  60         }
  61         if(winner_team)
  62                 return winner_team;
  63         return -1; // no player left
  64 }
  65
  66 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  67 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
  68 float CA_CheckWinner()
  69 {
  70         if(round_handler_GetTimeLeft() <= 0)
  71         {
  72                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  73                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  74                 allowed_to_spawn = FALSE;
  75                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  76                 return 1;
  77         }
  78
  79         CA_count_alive_players();
  80         if(CA_ALIVE_TEAMS() > 1)
  81                 return 0;
  82
  83         float winner_team = CA_GetWinnerTeam();
  84         if(winner_team > 0)
  85         {
  86                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner_team, CENTER_ROUND_TEAM_WIN_));
  87                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner_team, INFO_ROUND_TEAM_WIN_));
  88                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
  89         }
  90         else if(winner_team == -1)
  91         {
  92                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
  93                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
  94         }
  95
  96         allowed_to_spawn = FALSE;
  97         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  98         return 1;
  99 }
 100
 101 void CA_RoundStart()
 102 {
 103         if(inWarmupStage)
 104                 allowed_to_spawn = TRUE;
 105         else
 106                 allowed_to_spawn = FALSE;
 107 }
 108
 109 float prev_total_players;
 110 float CA_CheckTeams()
 111 {
 112         allowed_to_spawn = TRUE;
 113         CA_count_alive_players();
 114         if(CA_ALIVE_TEAMS_OK())
 115         {
 116                 if(prev_total_players > 0)
 117                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 118                 prev_total_players = -1;
 119                 return 1;
 120         }
 121         if(prev_total_players != total_players)
 122         {
 123                 float p1 = 0, p2 = 0, p3 = 0, p4 = 0;
 124                 if(!redalive) p1 = NUM_TEAM_1;
 125                 if(!bluealive) p2 = NUM_TEAM_2;
 126                 if(ca_teams >= 3)
 127                 if(!yellowalive) p3 = NUM_TEAM_3;
 128                 if(ca_teams >= 4)
 129                 if(!pinkalive) p4 = NUM_TEAM_4;
 130                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, p1, p2, p3, p4);
 131                 prev_total_players = total_players;
 132         }
 133         return 0;
 134 }
 135
 136 MUTATOR_HOOKFUNCTION(ca_PlayerSpawn)
 137 {
 138         self.caplayer = 1;
 139         return 1;
 140 }
 141
 142 MUTATOR_HOOKFUNCTION(ca_PutClientInServer)
 143 {
 144         if(!allowed_to_spawn)
 145         {
 146                 self.classname = "observer";
 147                 if(!self.caplayer)
 148                 {
 149                         self.caplayer = 0.5;
 150                         if(clienttype(self) == CLIENTTYPE_REAL)
 151                                 sprint(self, "You will join the game in the next round.\n");
 152                 }
 153         }
 154         return 1;
 155 }
 156
 157 MUTATOR_HOOKFUNCTION(ca_reset_map_players)
 158 {
 159         FOR_EACH_CLIENT(self)
 160         {
 161                 if(self.caplayer)
 162                 {
 163                         self.classname = "player";
 164                         self.caplayer = 1;
 165                         PutClientInServer();
 166                 }
 167         }
 168         return 1;
 169 }
 170
 171 MUTATOR_HOOKFUNCTION(ca_ClientConnect)
 172 {
 173         self.classname = "observer";
 174         return 1;
 175 }
 176
 177 MUTATOR_HOOKFUNCTION(ca_reset_map_global)
 178 {
 179         allowed_to_spawn = TRUE;
 180         return 1;
 181 }
 182
 183 MUTATOR_HOOKFUNCTION(ca_GetTeamCount)
 184 {
 185         ca_teams = autocvar_g_ca_teams_override;
 186         if(ca_teams < 2)
 187                 ca_teams = autocvar_g_ca_teams;
 188         ca_teams = bound(2, ca_teams, 4);
 189         ret_float = ca_teams;
 190         return 1;
 191 }
 192
 193 MUTATOR_HOOKFUNCTION(ca_PlayerDies)
 194 {
 195         if(!allowed_to_spawn)
 196                 self.respawn_flags =  RESPAWN_SILENT;
 197         return 1;
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(ca_ForbidPlayerScore_Clear)
 201 {
 202         return 1;
 203 }
 204
 205 MUTATOR_HOOKFUNCTION(ca_MakePlayerObserver)
 206 {
 207         if(self.killindicator_teamchange == -2)
 208                 self.caplayer = 0;
 209         if(self.caplayer)
 210                 self.frags = FRAGS_LMS_LOSER;
 211         return 1;
 212 }
 213
 214 MUTATOR_HOOKFUNCTION(ca_ForbidThrowCurrentWeapon)
 215 {
 216         return 1;
 217 }
 218
 219 MUTATOR_HOOKFUNCTION(ca_GiveFragsForKill)
 220 {
 221         frag_score = 0; // score will be given to the winner team when the round ends
 222         return 1;
 223 }
 224
 225 void ca_Initialize()
 226 {
 227         allowed_to_spawn = TRUE;
 228
 229         round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
 230         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 231
 232         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 233         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 234         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 235         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 236 }
 237
 238 MUTATOR_DEFINITION(gamemode_ca)
 239 {
 240         MUTATOR_HOOK(PlayerSpawn, ca_PlayerSpawn, CBC_ORDER_ANY);
 241         MUTATOR_HOOK(PutClientInServer, ca_PutClientInServer, CBC_ORDER_ANY);
 242         MUTATOR_HOOK(MakePlayerObserver, ca_MakePlayerObserver, CBC_ORDER_ANY);
 243         MUTATOR_HOOK(ClientConnect, ca_ClientConnect, CBC_ORDER_ANY);
 244         MUTATOR_HOOK(reset_map_global, ca_reset_map_global, CBC_ORDER_ANY);
 245         MUTATOR_HOOK(reset_map_players, ca_reset_map_players, CBC_ORDER_ANY);
 246         MUTATOR_HOOK(GetTeamCount, ca_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 247         MUTATOR_HOOK(PlayerDies, ca_PlayerDies, CBC_ORDER_ANY);
 248         MUTATOR_HOOK(ForbidPlayerScore_Clear, ca_ForbidPlayerScore_Clear, CBC_ORDER_ANY);
 249         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ca_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 250         MUTATOR_HOOK(GiveFragsForKill, ca_GiveFragsForKill, CBC_ORDER_FIRST);
 251
 252         MUTATOR_ONADD
 253         {
 254                 if(time > 1) // game loads at time 1
 255                         error("This is a game type and it cannot be added at runtime.");
 256                 ca_Initialize();
 257         }
 258
 259         MUTATOR_ONREMOVE
 260         {
 261                 print("This is a game type and it cannot be removed at runtime.");
 262                 return -1;
 263         }
 264
 265         return 0;
 266 }