qcsrc/server/mutators/gamemode_cts.qc

   1 // legacy bot roles
   2 .float race_checkpoint;
   3 void havocbot_role_cts()
   4 {
   5         if(self.deadflag != DEAD_NO)
   6                 return;
   7
   8         entity e;
   9         if (self.bot_strategytime < time)
  10         {
  11                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  12                 navigation_goalrating_start();
  13
  14                 for(e = world; (e = find(e, classname, "trigger_race_checkpoint")) != world; )
  15                 {
  16                         if(e.cnt == self.race_checkpoint)
  17                         {
  18                                 navigation_routerating(e, 1000000, 5000);
  19                         }
  20                         else if(self.race_checkpoint == -1)
  21                         {
  22                                 navigation_routerating(e, 1000000, 5000);
  23                         }
  24                 }
  25
  26                 navigation_goalrating_end();
  27         }
  28 }
  29
  30 void cts_ScoreRules()
  31 {
  32         ScoreRules_basics(0, 0, 0, FALSE);
  33         if(g_race_qualifying)
  34         {
  35                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_FASTEST, "fastest",   SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  36         }
  37         else
  38         {
  39                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  40                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  41                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_FASTEST, "fastest",   SFL_LOWER_IS_BETTER | SFL_TIME);
  42         }
  43         ScoreRules_basics_end();
  44 }
  45
  46 MUTATOR_HOOKFUNCTION(cts_PlayerPhysics)
  47 {
  48         // force kbd movement for fairness
  49         float wishspeed;
  50         vector wishvel;
  51
  52         // if record times matter
  53         // ensure nothing EVIL is being done (i.e. div0_evade)
  54         // this hinders joystick users though
  55         // but it still gives SOME analog control
  56         wishvel_x = fabs(self.movement_x);
  57         wishvel_y = fabs(self.movement_y);
  58         if(wishvel_x != 0 && wishvel_y != 0 && wishvel_x != wishvel_y)
  59         {
  60                 wishvel_z = 0;
  61                 wishspeed = vlen(wishvel);
  62                 if(wishvel_x >= 2 * wishvel_y)
  63                 {
  64                         // pure X motion
  65                         if(self.movement_x > 0)
  66                                 self.movement_x = wishspeed;
  67                         else
  68                                 self.movement_x = -wishspeed;
  69                         self.movement_y = 0;
  70                 }
  71                 else if(wishvel_y >= 2 * wishvel_x)
  72                 {
  73                         // pure Y motion
  74                         self.movement_x = 0;
  75                         if(self.movement_y > 0)
  76                                 self.movement_y = wishspeed;
  77                         else
  78                                 self.movement_y = -wishspeed;
  79                 }
  80                 else
  81                 {
  82                         // diagonal
  83                         if(self.movement_x > 0)
  84                                 self.movement_x = M_SQRT1_2 * wishspeed;
  85                         else
  86                                 self.movement_x = -M_SQRT1_2 * wishspeed;
  87                         if(self.movement_y > 0)
  88                                 self.movement_y = M_SQRT1_2 * wishspeed;
  89                         else
  90                                 self.movement_y = -M_SQRT1_2 * wishspeed;
  91                 }
  92         }
  93
  94         return FALSE;
  95 }
  96
  97 MUTATOR_HOOKFUNCTION(cts_ResetMap)
  98 {
  99         float s;
 100
 101         Score_NicePrint(world);
 102
 103         race_ClearRecords();
 104         PlayerScore_Sort(race_place, 0, 1, 0);
 105
 106         entity e;
 107         FOR_EACH_CLIENT(e)
 108         {
 109                 if(e.race_place)
 110                 {
 111                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 112                         if(!s)
 113                                 e.race_place = 0;
 114                 }
 115                 print(e.netname, " = ", ftos(e.race_place), "\n");
 116         }
 117
 118         if(g_race_qualifying == 2)
 119         {
 120                 g_race_qualifying = 0;
 121                 independent_players = 0;
 122                 cvar_set("fraglimit", ftos(race_fraglimit));
 123                 cvar_set("leadlimit", ftos(race_leadlimit));
 124                 cvar_set("timelimit", ftos(race_timelimit));
 125                 cts_ScoreRules();
 126         }
 127
 128         return FALSE;
 129 }
 130
 131 MUTATOR_HOOKFUNCTION(cts_PlayerPreThink)
 132 {
 133         if(IS_SPEC(self) || IS_OBSERVER(self))
 134         if(g_race_qualifying)
 135         if(msg_entity.enemy.race_laptime)
 136                 race_SendNextCheckpoint(msg_entity.enemy, 1);
 137
 138         return FALSE;
 139 }
 140
 141 MUTATOR_HOOKFUNCTION(cts_ClientConnect)
 142 {
 143         race_PreparePlayer();
 144         self.race_checkpoint = -1;
 145
 146         string rr = CTS_RECORD;
 147
 148         msg_entity = self;
 149         race_send_recordtime(MSG_ONE);
 150         race_send_speedaward(MSG_ONE);
 151
 152         speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 153         speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 154         race_send_speedaward_alltimebest(MSG_ONE);
 155
 156         float i;
 157         if(IS_REAL_CLIENT(self))
 158         for (i = 1; i <= RANKINGS_CNT; ++i)
 159         {
 160                 race_SendRankings(i, 0, 0, MSG_ONE);
 161         }
 162
 163         return FALSE;
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(cts_MakePlayerObserver)
 167 {
 168         if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 169                 self.frags = FRAGS_LMS_LOSER;
 170         else
 171                 self.frags = FRAGS_SPECTATOR;
 172
 173         race_PreparePlayer();
 174         self.race_checkpoint = -1;
 175
 176         return FALSE;
 177 }
 178
 179 MUTATOR_HOOKFUNCTION(cts_PlayerSpawn)
 180 {
 181         if(spawn_spot.target == "")
 182                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 183                 race_PreparePlayer();
 184
 185         // if we need to respawn, do it right
 186         self.race_respawn_checkpoint = self.race_checkpoint;
 187         self.race_respawn_spotref = spawn_spot;
 188
 189         self.race_place = 0;
 190
 191         return FALSE;
 192 }
 193
 194 MUTATOR_HOOKFUNCTION(cts_PutClientInServer)
 195 {
 196         if(IS_PLAYER(self))
 197         if(!gameover)
 198         {
 199                 if(self.killcount == -666 /* initial spawn */ || g_race_qualifying) // spawn
 200                         race_PreparePlayer();
 201                 else // respawn
 202                         race_RetractPlayer();
 203
 204                 race_AbandonRaceCheck(self);
 205         }
 206         return FALSE;
 207 }
 208
 209 MUTATOR_HOOKFUNCTION(cts_PlayerDies)
 210 {
 211         self.respawn_flags |= RESPAWN_FORCE;
 212         race_AbandonRaceCheck(self);
 213         return FALSE;
 214 }
 215
 216 MUTATOR_HOOKFUNCTION(cts_BotRoles)
 217 {
 218         self.havocbot_role = havocbot_role_cts;
 219         return TRUE;
 220 }
 221
 222 MUTATOR_HOOKFUNCTION(cts_PlayerPostThink)
 223 {
 224         if(self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
 225         {
 226                 if (!self.stored_netname)
 227                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
 228                 if(self.stored_netname != self.netname)
 229                 {
 230                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
 231                         strunzone(self.stored_netname);
 232                         self.stored_netname = strzone(self.netname);
 233                 }
 234         }
 235
 236         return FALSE;
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(cts_ForbidThrowing)
 240 {
 241         // no weapon dropping in CTS
 242         return TRUE;
 243 }
 244
 245 MUTATOR_HOOKFUNCTION(cts_FilterItem)
 246 {
 247         if(self.classname == "droppedweapon")
 248                 return TRUE;
 249
 250         return FALSE;
 251 }
 252
 253 MUTATOR_HOOKFUNCTION(cts_PlayerDamage)
 254 {
 255         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL)
 256         if(!autocvar_g_cts_selfdamage)
 257                 frag_damage = 0;
 258
 259         return FALSE;
 260 }
 261
 262 MUTATOR_HOOKFUNCTION(cts_ForbidClearPlayerScore)
 263 {
 264         return TRUE; // in CTS, you don't lose score by observing
 265 }
 266
 267 void cts_Initialize()
 268 {
 269         g_cloaked = 1; // always enable cloak in CTS
 270
 271         cts_ScoreRules();
 272 }
 273
 274 MUTATOR_DEFINITION(gamemode_cts)
 275 {
 276         MUTATOR_HOOK(PlayerPhysics, cts_PlayerPhysics, CBC_ORDER_ANY);
 277         MUTATOR_HOOK(reset_map_global, cts_ResetMap, CBC_ORDER_ANY);
 278         MUTATOR_HOOK(PlayerPreThink, cts_PlayerPreThink, CBC_ORDER_ANY);
 279         MUTATOR_HOOK(ClientConnect, cts_ClientConnect, CBC_ORDER_ANY);
 280         MUTATOR_HOOK(MakePlayerObserver, cts_MakePlayerObserver, CBC_ORDER_ANY);
 281         MUTATOR_HOOK(PlayerSpawn, cts_PlayerSpawn, CBC_ORDER_ANY);
 282         MUTATOR_HOOK(PutClientInServer, cts_PutClientInServer, CBC_ORDER_ANY);
 283         MUTATOR_HOOK(PlayerDies, cts_PlayerDies, CBC_ORDER_ANY);
 284         MUTATOR_HOOK(HavocBot_ChooseRule, cts_BotRoles, CBC_ORDER_ANY);
 285         MUTATOR_HOOK(GetPressedKeys, cts_PlayerPostThink, CBC_ORDER_ANY);
 286         MUTATOR_HOOK(ForbidThrowCurrentWeapon, cts_ForbidThrowing, CBC_ORDER_ANY);
 287         MUTATOR_HOOK(FilterItem, cts_FilterItem, CBC_ORDER_ANY);
 288         MUTATOR_HOOK(PlayerDamage_Calculate, cts_PlayerDamage, CBC_ORDER_ANY);
 289         MUTATOR_HOOK(ForbidPlayerScore_Clear, cts_ForbidClearPlayerScore, CBC_ORDER_ANY);
 290
 291         MUTATOR_ONADD
 292         {
 293                 if(time > 1) // game loads at time 1
 294                         error("This is a game type and it cannot be added at runtime.");
 295                 cts_Initialize();
 296         }
 297
 298         MUTATOR_ONROLLBACK_OR_REMOVE
 299         {
 300                 // we actually cannot roll back cts_Initialize here
 301                 // BUT: we don't need to! If this gets called, adding always
 302                 // succeeds.
 303         }
 304
 305         MUTATOR_ONREMOVE
 306         {
 307                 print("This is a game type and it cannot be removed at runtime.");
 308                 return -1;
 309         }
 310
 311         return 0;
 312 }