qcsrc/server/mutators/gamemode_cts.qc

   1 // legacy bot roles
   2 .float race_checkpoint;
   3 void havocbot_role_cts()
   4 {
   5         if(self.deadflag != DEAD_NO)
   6                 return;
   7
   8         entity e;
   9         if (self.bot_strategytime < time)
  10         {
  11                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  12                 navigation_goalrating_start();
  13
  14                 for(e = world; (e = find(e, classname, "trigger_race_checkpoint")) != world; )
  15                 {
  16                         if(e.cnt == self.race_checkpoint)
  17                         {
  18                                 navigation_routerating(e, 1000000, 5000);
  19                         }
  20                         else if(self.race_checkpoint == -1)
  21                         {
  22                                 navigation_routerating(e, 1000000, 5000);
  23                         }
  24                 }
  25
  26                 navigation_goalrating_end();
  27         }
  28 }
  29
  30 void cts_ScoreRules()
  31 {
  32         ScoreRules_basics(0, 0, 0, FALSE);
  33         if(g_race_qualifying)
  34         {
  35                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_FASTEST, "fastest",   SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  36         }
  37         else
  38         {
  39                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  40                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  41                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_FASTEST, "fastest",   SFL_LOWER_IS_BETTER | SFL_TIME);
  42         }
  43         ScoreRules_basics_end();
  44 }
  45
  46 MUTATOR_HOOKFUNCTION(cts_PlayerPhysics)
  47 {
  48         // force kbd movement for fairness
  49         float wishspeed;
  50         vector wishvel;
  51
  52         // if record times matter
  53         // ensure nothing EVIL is being done (i.e. div0_evade)
  54         // this hinders joystick users though
  55         // but it still gives SOME analog control
  56         wishvel_x = fabs(self.movement_x);
  57         wishvel_y = fabs(self.movement_y);
  58         if(wishvel_x != 0 && wishvel_y != 0 && wishvel_x != wishvel_y)
  59         {
  60                 wishvel_z = 0;
  61                 wishspeed = vlen(wishvel);
  62                 if(wishvel_x >= 2 * wishvel_y)
  63                 {
  64                         // pure X motion
  65                         if(self.movement_x > 0)
  66                                 self.movement_x = wishspeed;
  67                         else
  68                                 self.movement_x = -wishspeed;
  69                         self.movement_y = 0;
  70                 }
  71                 else if(wishvel_y >= 2 * wishvel_x)
  72                 {
  73                         // pure Y motion
  74                         self.movement_x = 0;
  75                         if(self.movement_y > 0)
  76                                 self.movement_y = wishspeed;
  77                         else
  78                                 self.movement_y = -wishspeed;
  79                 }
  80                 else
  81                 {
  82                         // diagonal
  83                         if(self.movement_x > 0)
  84                                 self.movement_x = M_SQRT1_2 * wishspeed;
  85                         else
  86                                 self.movement_x = -M_SQRT1_2 * wishspeed;
  87                         if(self.movement_y > 0)
  88                                 self.movement_y = M_SQRT1_2 * wishspeed;
  89                         else
  90                                 self.movement_y = -M_SQRT1_2 * wishspeed;
  91                 }
  92         }
  93
  94         return FALSE;
  95 }
  96
  97 MUTATOR_HOOKFUNCTION(cts_ResetMap)
  98 {
  99         float s;
 100
 101         Score_NicePrint(world);
 102
 103         race_ClearRecords();
 104         PlayerScore_Sort(race_place, 0, 1, 0);
 105
 106         entity e;
 107         FOR_EACH_CLIENT(e)
 108         {
 109                 if(e.race_place)
 110                 {
 111                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 112                         if(!s)
 113                                 e.race_place = 0;
 114                 }
 115                 print(e.netname, " = ", ftos(e.race_place), "\n");
 116         }
 117
 118         if(g_race_qualifying == 2)
 119         {
 120                 g_race_qualifying = 0;
 121                 independent_players = 0;
 122                 cvar_set("fraglimit", ftos(race_fraglimit));
 123                 cvar_set("leadlimit", ftos(race_leadlimit));
 124                 cvar_set("timelimit", ftos(race_timelimit));
 125                 cts_ScoreRules();
 126         }
 127
 128         return FALSE;
 129 }
 130
 131 MUTATOR_HOOKFUNCTION(cts_PlayerPreThink)
 132 {
 133         if(IS_SPEC(self) || IS_OBSERVER(self))
 134         if(g_race_qualifying)
 135         if(msg_entity.enemy.race_laptime)
 136                 race_SendNextCheckpoint(msg_entity.enemy, 1);
 137
 138         return FALSE;
 139 }
 140
 141 MUTATOR_HOOKFUNCTION(cts_ClientConnect)
 142 {
 143         race_PreparePlayer();
 144         self.race_checkpoint = -1;
 145
 146         if(IS_REAL_CLIENT(self))
 147         {
 148                 string rr = CTS_RECORD;
 149
 150                 msg_entity = self;
 151                 race_send_recordtime(MSG_ONE);
 152                 race_send_speedaward(MSG_ONE);
 153
 154                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 155                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 156                 race_send_speedaward_alltimebest(MSG_ONE);
 157
 158                 float i;
 159                 for (i = 1; i <= RANKINGS_CNT; ++i)
 160                 {
 161                         race_SendRankings(i, 0, 0, MSG_ONE);
 162                 }
 163         }
 164
 165         return FALSE;
 166 }
 167
 168 MUTATOR_HOOKFUNCTION(cts_MakePlayerObserver)
 169 {
 170         if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 171                 self.frags = FRAGS_LMS_LOSER;
 172         else
 173                 self.frags = FRAGS_SPECTATOR;
 174
 175         race_PreparePlayer();
 176         self.race_checkpoint = -1;
 177
 178         return FALSE;
 179 }
 180
 181 MUTATOR_HOOKFUNCTION(cts_PlayerSpawn)
 182 {
 183         if(spawn_spot.target == "")
 184                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 185                 race_PreparePlayer();
 186
 187         // if we need to respawn, do it right
 188         self.race_respawn_checkpoint = self.race_checkpoint;
 189         self.race_respawn_spotref = spawn_spot;
 190
 191         self.race_place = 0;
 192
 193         return FALSE;
 194 }
 195
 196 MUTATOR_HOOKFUNCTION(cts_PutClientInServer)
 197 {
 198         if(IS_PLAYER(self))
 199         if(!gameover)
 200         {
 201                 if(self.killcount == -666 /* initial spawn */ || g_race_qualifying) // spawn
 202                         race_PreparePlayer();
 203                 else // respawn
 204                         race_RetractPlayer();
 205
 206                 race_AbandonRaceCheck(self);
 207         }
 208         return FALSE;
 209 }
 210
 211 MUTATOR_HOOKFUNCTION(cts_PlayerDies)
 212 {
 213         self.respawn_flags |= RESPAWN_FORCE;
 214         race_AbandonRaceCheck(self);
 215         return FALSE;
 216 }
 217
 218 MUTATOR_HOOKFUNCTION(cts_BotRoles)
 219 {
 220         self.havocbot_role = havocbot_role_cts;
 221         return TRUE;
 222 }
 223
 224 MUTATOR_HOOKFUNCTION(cts_PlayerPostThink)
 225 {
 226         if(self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
 227         {
 228                 if (!self.stored_netname)
 229                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
 230                 if(self.stored_netname != self.netname)
 231                 {
 232                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
 233                         strunzone(self.stored_netname);
 234                         self.stored_netname = strzone(self.netname);
 235                 }
 236         }
 237
 238         return FALSE;
 239 }
 240
 241 MUTATOR_HOOKFUNCTION(cts_ForbidThrowing)
 242 {
 243         // no weapon dropping in CTS
 244         return TRUE;
 245 }
 246
 247 MUTATOR_HOOKFUNCTION(cts_FilterItem)
 248 {
 249         if(self.classname == "droppedweapon")
 250                 return TRUE;
 251
 252         return FALSE;
 253 }
 254
 255 MUTATOR_HOOKFUNCTION(cts_PlayerDamage)
 256 {
 257         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL)
 258         if(!autocvar_g_cts_selfdamage)
 259                 frag_damage = 0;
 260
 261         return FALSE;
 262 }
 263
 264 MUTATOR_HOOKFUNCTION(cts_ForbidClearPlayerScore)
 265 {
 266         return TRUE; // in CTS, you don't lose score by observing
 267 }
 268
 269 void cts_Initialize()
 270 {
 271         g_cloaked = 1; // always enable cloak in CTS
 272
 273         cts_ScoreRules();
 274 }
 275
 276 MUTATOR_DEFINITION(gamemode_cts)
 277 {
 278         MUTATOR_HOOK(PlayerPhysics, cts_PlayerPhysics, CBC_ORDER_ANY);
 279         MUTATOR_HOOK(reset_map_global, cts_ResetMap, CBC_ORDER_ANY);
 280         MUTATOR_HOOK(PlayerPreThink, cts_PlayerPreThink, CBC_ORDER_ANY);
 281         MUTATOR_HOOK(ClientConnect, cts_ClientConnect, CBC_ORDER_ANY);
 282         MUTATOR_HOOK(MakePlayerObserver, cts_MakePlayerObserver, CBC_ORDER_ANY);
 283         MUTATOR_HOOK(PlayerSpawn, cts_PlayerSpawn, CBC_ORDER_ANY);
 284         MUTATOR_HOOK(PutClientInServer, cts_PutClientInServer, CBC_ORDER_ANY);
 285         MUTATOR_HOOK(PlayerDies, cts_PlayerDies, CBC_ORDER_ANY);
 286         MUTATOR_HOOK(HavocBot_ChooseRole, cts_BotRoles, CBC_ORDER_ANY);
 287         MUTATOR_HOOK(GetPressedKeys, cts_PlayerPostThink, CBC_ORDER_ANY);
 288         MUTATOR_HOOK(ForbidThrowCurrentWeapon, cts_ForbidThrowing, CBC_ORDER_ANY);
 289         MUTATOR_HOOK(FilterItem, cts_FilterItem, CBC_ORDER_ANY);
 290         MUTATOR_HOOK(PlayerDamage_Calculate, cts_PlayerDamage, CBC_ORDER_ANY);
 291         MUTATOR_HOOK(ForbidPlayerScore_Clear, cts_ForbidClearPlayerScore, CBC_ORDER_ANY);
 292
 293         MUTATOR_ONADD
 294         {
 295                 if(time > 1) // game loads at time 1
 296                         error("This is a game type and it cannot be added at runtime.");
 297                 cts_Initialize();
 298         }
 299
 300         MUTATOR_ONROLLBACK_OR_REMOVE
 301         {
 302                 // we actually cannot roll back cts_Initialize here
 303                 // BUT: we don't need to! If this gets called, adding always
 304                 // succeeds.
 305         }
 306
 307         MUTATOR_ONREMOVE
 308         {
 309                 print("This is a game type and it cannot be removed at runtime.");
 310                 return -1;
 311         }
 312
 313         return 0;
 314 }