qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + cvar("g_freezetag_warmup");
   5 }
   6
   7 void freezetag_CheckWinner()
   8 {
   9         if(next_round || (time > warmup - cvar("g_freezetag_warmup") && time < warmup))
  10                 return; // already waiting for next round to start
  11
  12         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  13                 || (redalive >= 1 && yellowalive >= 1)
  14                 || (redalive >= 1 && pinkalive >= 1)
  15                 || (bluealive >= 1 && yellowalive >= 1)
  16                 || (bluealive >= 1 && pinkalive >= 1)
  17                 || (yellowalive >= 1 && pinkalive >= 1))
  18                 return; // we still have active players on two or more teams
  19
  20         if(redalive + bluealive + yellowalive + pinkalive <= 0)
  21         {
  22                 next_round = time + 5;
  23                 return;
  24         }
  25
  26         entity e, winner;
  27         string teamname;
  28
  29         FOR_EACH_PLAYER(e)
  30         {
  31                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  32                 {
  33                         winner = e;
  34                         TeamScore_AddToTeam(winner.team, ST_SCORE, +1); // just in case a winner isn't found, we do this already here (causes crashes otherwise...)
  35                         break; // break, we found the winner
  36                 }
  37         }
  38
  39         if(winner.team == COLOR_TEAM1)
  40                 teamname = "^1Red Team";
  41         else if(winner.team == COLOR_TEAM2)
  42                 teamname = "^4Blue Team";
  43         else if(winner.team == COLOR_TEAM3)
  44                 teamname = "^3Yellow Team";
  45         else
  46                 teamname = "^6Pink Team";
  47         FOR_EACH_PLAYER(e) {
  48                 centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  49         }
  50         bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  51
  52         next_round = time + 5;
  53 }
  54
  55 void freezetag_Ice_Think()
  56 {
  57         setorigin(self, self.owner.origin - '0 0 16');
  58         self.nextthink = time;
  59 }
  60
  61 void freezetag_Freeze()
  62 {
  63         self.freezetag_frozen = 1;
  64
  65         entity ice;
  66         ice = spawn();
  67         ice.owner = self;
  68         ice.classname = "freezetag_ice";
  69         ice.think = freezetag_Ice_Think;
  70         ice.nextthink = time;
  71         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  72         setmodel(ice, "models/ice/ice.md3");
  73
  74         self.movement = '0 0 0';
  75
  76         // add waypoint
  77         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  78         if(self.waypointsprite_attached)
  79         {
  80                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  81         }
  82 }
  83
  84 void freezetag_Unfreeze()
  85 {
  86         self.freezetag_frozen = 0;
  87
  88         // remove the ice block
  89         entity ice;
  90         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
  91         {
  92                 remove(ice);
  93                 break;
  94         }
  95
  96         // remove waypoint
  97         if(self.waypointsprite_attached)
  98                 WaypointSprite_Kill(self.waypointsprite_attached);
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 102 {
 103         freezetag_CheckWinner();
 104         freezetag_Unfreeze();
 105
 106         return 1;
 107 }
 108
 109 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 110 {
 111         // if the player was previously not frozen (should be the case anyway), decrement alive playercount before running CheckWinner
 112         if (self.team == COLOR_TEAM1 && self.freezetag_frozen == 0) redalive -= 1;
 113         else if (self.team == COLOR_TEAM2 && self.freezetag_frozen == 0) bluealive -= 1;
 114         else if (self.team == COLOR_TEAM3 && self.freezetag_frozen == 0) yellowalive -= 1;
 115         else if (self.team == COLOR_TEAM4 && self.freezetag_frozen == 0) pinkalive -= 1;
 116
 117         freezetag_Freeze();
 118
 119         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 120         if(frag_attacker == frag_target || frag_attacker == world)
 121         {
 122                 centerprint(frag_target, "^1You froze yourself.\n");
 123                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 124         }
 125         else
 126         {
 127                 centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 128                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 129         }
 130
 131         frag_target.health = cvar("g_balance_health_start"); // "respawn" the player :P
 132
 133         freezetag_CheckWinner();
 134
 135         return 1;
 136 }
 137
 138 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 139 {
 140         if(time > warmup) // spawn too late, freeze player
 141         {
 142                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 143                 freezetag_Freeze();
 144         }
 145         else // we are still in the delay period before the round starts
 146         {
 147                 freezetag_Unfreeze();
 148         }
 149
 150         return 1;
 151 }
 152
 153 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 154 {
 155         frag_score = 0; // no frags counted in Freeze Tag
 156         return 1;
 157 }
 158
 159 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 160 {
 161         vector revive_extra_size;
 162         revive_extra_size = '1 1 1' * cvar("g_freezetag_revive_extra_size");
 163
 164         float teammate_nearby;
 165         FOR_EACH_PLAYER(other) if(self != other)
 166         {
 167                 if(other.freezetag_frozen == 0)
 168                 {
 169                         if(other.team == self.team)
 170                         {
 171                                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 172                                 break;
 173                         }
 174                 }
 175         }
 176
 177         if(teammate_nearby && self.freezetag_frozen == 1)
 178         {
 179                 if(self.freezetag_beginrevive_time == -9999)
 180                 {
 181                         self.freezetag_beginrevive_time = time;
 182                         self.freezetag_revive_progress = 0;
 183                         other.freezetag_revive_progress = 0;
 184                 }
 185                 else
 186                 {
 187                         self.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / cvar("g_freezetag_revive_time");
 188                         other.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / cvar("g_freezetag_revive_time");
 189                         if(time - self.freezetag_beginrevive_time >= cvar("g_freezetag_revive_time"))
 190                         {
 191                                 freezetag_Unfreeze();
 192
 193                                 centerprint(self, strcat("^5You were revived by ^7", other.netname, ".\n"));
 194                                 centerprint(other, strcat("^5You revived ^7", self.netname, ".\n"));
 195                                 bprint("^7", other.netname, "^5 revived ^7", self.netname, ".\n");
 196
 197                                 self.freezetag_beginrevive_time = -9999;
 198                                 self.freezetag_revive_progress = 0;
 199                                 other.freezetag_revive_progress = 0;
 200                         }
 201                 }
 202         }
 203         else
 204         {
 205                 self.freezetag_beginrevive_time = -9999;
 206                 self.freezetag_revive_progress = 0;
 207                 other.freezetag_revive_progress = 0;
 208         }
 209
 210         return 1;
 211 }
 212
 213 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 214 {
 215         if(self.freezetag_frozen)
 216                 self.movement = '0 0 0';
 217         return 1;
 218 }
 219
 220 MUTATOR_DEFINITION(gamemode_freezetag)
 221 {
 222         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 223         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 224         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 225         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 226         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 227         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 228         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 229
 230         MUTATOR_ONADD
 231         {
 232                 if(time > 1) // game loads at time 1
 233                         error("This is a game type and it cannot be added at runtime.");
 234                 g_freezetag = 1;
 235                 freezetag_Initialize();
 236         }
 237
 238         MUTATOR_ONREMOVE
 239         {
 240                 g_freezetag = 0;
 241                 error("This is a game type and it cannot be removed at runtime.");
 242         }
 243
 244         return 0;
 245 }