qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + autocvar_g_start_delay + autocvar_g_freezetag_warmup;
   5         ScoreRules_freezetag();
   6 }
   7
   8 void freezetag_CheckWinner()
   9 {
  10         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  11                 return;
  12
  13         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  14                 return; // already waiting for next round to start
  15
  16         if((redalive >= 1 && bluealive >= 1)
  17                 || (redalive >= 1 && yellowalive >= 1)
  18                 || (redalive >= 1 && pinkalive >= 1)
  19                 || (bluealive >= 1 && yellowalive >= 1)
  20                 || (bluealive >= 1 && pinkalive >= 1)
  21                 || (yellowalive >= 1 && pinkalive >= 1))
  22                 return; // we still have active players on two or more teams, nobody won yet
  23
  24         entity e, winner;
  25         string teamname;
  26         winner = world;
  27
  28         FOR_EACH_PLAYER(e)
  29         {
  30                 if(e.freezetag_frozen == 0 && e.health >= 1) // here's one player from the winning team... good
  31                 {
  32                         winner = e;
  33                         break; // break, we found the winner
  34                 }
  35         }
  36
  37         if(winner != world) // just in case a winner wasn't found
  38         {
  39                 if(winner.team == COLOR_TEAM1)
  40                         teamname = "^1Red Team";
  41                 else if(winner.team == COLOR_TEAM2)
  42                         teamname = "^4Blue Team";
  43                 else if(winner.team == COLOR_TEAM3)
  44                         teamname = "^3Yellow Team";
  45                 else
  46                         teamname = "^6Pink Team";
  47                 FOR_EACH_PLAYER(e) {
  48                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  49                 }
  50                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  51                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  52         }
  53
  54         next_round = time + 5;
  55 }
  56
  57 // this is needed to allow the player to turn his view around (fixangle can't
  58 // be used to freeze his view, as that also changes the angles), while not
  59 // turning that ice object with the player
  60 void freezetag_Ice_Think()
  61 {
  62         setorigin(self, self.owner.origin - '0 0 16');
  63         self.nextthink = time;
  64 }
  65
  66 void freezetag_Freeze(entity attacker)
  67 {
  68         if(self.freezetag_frozen)
  69                 return;
  70         self.freezetag_frozen = 1;
  71         self.freezetag_revive_progress = 0;
  72         self.health = 1;
  73
  74         entity ice;
  75         ice = spawn();
  76         ice.owner = self;
  77         ice.classname = "freezetag_ice";
  78         ice.think = freezetag_Ice_Think;
  79         ice.nextthink = time;
  80         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  81         setmodel(ice, "models/ice/ice.md3");
  82
  83         entity oldself;
  84         oldself = self;
  85         self = ice;
  86         freezetag_Ice_Think();
  87         self = oldself;
  88
  89         RemoveGrapplingHook(self);
  90
  91         // add waypoint
  92         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
  93
  94         if(attacker == self)
  95         {
  96                 // you froze your own dumb self
  97                 // counted as "suicide" already
  98                 PlayerScore_Add(self, SP_SCORE, -1);
  99         }
 100         else if(IS_PLAYER(attacker))
 101         {
 102                 // got frozen by an enemy
 103                 // counted as "kill" and "death" already
 104                 PlayerScore_Add(self, SP_SCORE, -1);
 105                 PlayerScore_Add(attacker, SP_SCORE, +1);
 106         }
 107         else
 108         {
 109                 // nothing - got frozen by the game type rules themselves
 110         }
 111 }
 112
 113 void freezetag_Unfreeze(entity attacker)
 114 {
 115         self.freezetag_frozen = 0;
 116         self.freezetag_revive_progress = 0;
 117         self.health = autocvar_g_balance_health_start;
 118
 119         // remove the ice block
 120         entity ice;
 121         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 122         {
 123                 remove(ice);
 124                 break;
 125         }
 126
 127         // remove waypoint
 128         if(self.waypointsprite_attached)
 129                 WaypointSprite_Kill(self.waypointsprite_attached);
 130 }
 131
 132
 133 // ================
 134 // Bot player logic
 135 // ================
 136
 137 void() havocbot_role_ft_freeing;
 138 void() havocbot_role_ft_offense;
 139
 140 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 141 {
 142         entity head;
 143         float distance;
 144
 145         FOR_EACH_PLAYER(head)
 146         {
 147                 if ((head != self) && (head.team == self.team))
 148                 {
 149                         if (head.freezetag_frozen)
 150                         {
 151                                 distance = vlen(head.origin - org);
 152                                 if (distance > sradius)
 153                                         continue;
 154                                 navigation_routerating(head, ratingscale, 2000);
 155                         }
 156                         else
 157                         {
 158                                 // If teamate is not frozen still seek them out as fight better
 159                                 // in a group.
 160                                 navigation_routerating(head, ratingscale/3, 2000);
 161                         }
 162                 }
 163         }
 164 }
 165
 166 void havocbot_role_ft_offense()
 167 {
 168         entity head;
 169         float unfrozen;
 170
 171         if(self.deadflag != DEAD_NO)
 172                 return;
 173
 174         if (!self.havocbot_role_timeout)
 175                 self.havocbot_role_timeout = time + random() * 10 + 20;
 176
 177         // Count how many players on team are unfrozen.
 178         unfrozen = 0;
 179         FOR_EACH_PLAYER(head)
 180         {
 181                 if ((head.team == self.team) && (!head.freezetag_frozen))
 182                         unfrozen++;
 183         }
 184
 185         // If only one left on team or if role has timed out then start trying to free players.
 186         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 187         {
 188                 dprint("changing role to freeing\n");
 189                 self.havocbot_role = havocbot_role_ft_freeing;
 190                 self.havocbot_role_timeout = 0;
 191                 return;
 192         }
 193
 194         if (time > self.bot_strategytime)
 195         {
 196                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 197
 198                 navigation_goalrating_start();
 199                 havocbot_goalrating_items(10000, self.origin, 10000);
 200                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 201                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 202                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 203                 navigation_goalrating_end();
 204         }
 205 }
 206
 207 void havocbot_role_ft_freeing()
 208 {
 209         if(self.deadflag != DEAD_NO)
 210                 return;
 211
 212         if (!self.havocbot_role_timeout)
 213                 self.havocbot_role_timeout = time + random() * 10 + 20;
 214
 215         if (time > self.havocbot_role_timeout)
 216         {
 217                 dprint("changing role to offense\n");
 218                 self.havocbot_role = havocbot_role_ft_offense;
 219                 self.havocbot_role_timeout = 0;
 220                 return;
 221         }
 222
 223         if (time > self.bot_strategytime)
 224         {
 225                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 226
 227                 navigation_goalrating_start();
 228                 havocbot_goalrating_items(8000, self.origin, 10000);
 229                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 230                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 231                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 232                 navigation_goalrating_end();
 233         }
 234 }
 235
 236
 237 // ==============
 238 // Hook Functions
 239 // ==============
 240
 241 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 242 {
 243         if(self.freezetag_frozen == 0 && self.health >= 1)
 244         {
 245                 if(self.team == COLOR_TEAM1)
 246                         --redalive;
 247                 else if(self.team == COLOR_TEAM2)
 248                         --bluealive;
 249                 else if(self.team == COLOR_TEAM3)
 250                         --yellowalive;
 251                 else if(self.team == COLOR_TEAM4)
 252                         --pinkalive;
 253                 --totalalive;
 254         }
 255
 256         if(total_players > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 257                 freezetag_CheckWinner();
 258
 259         freezetag_Unfreeze(world);
 260
 261         return 1;
 262 }
 263
 264 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 265 {
 266         if(self.freezetag_frozen == 0)
 267         {
 268                 if(self.team == COLOR_TEAM1)
 269                         --redalive;
 270                 else if(self.team == COLOR_TEAM2)
 271                         --bluealive;
 272                 else if(self.team == COLOR_TEAM3)
 273                         --yellowalive;
 274                 else if(self.team == COLOR_TEAM4)
 275                         --pinkalive;
 276                 --totalalive;
 277
 278                 freezetag_Freeze(frag_attacker);
 279         }
 280
 281         if(frag_attacker == frag_target || frag_attacker == world)
 282         {
 283                 if(IS_PLAYER(frag_target))
 284                         centerprint(frag_target, "^1You froze yourself.\n");
 285                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 286         }
 287         else
 288         {
 289                 if(IS_PLAYER(frag_target))
 290                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 291                 if(IS_PLAYER(frag_attacker))
 292                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 293                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 294         }
 295
 296         frag_target.health = 1; // "respawn" the player :P
 297
 298         freezetag_CheckWinner();
 299
 300         return 1;
 301 }
 302
 303 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 304 {
 305         freezetag_Unfreeze(world); // start by making sure that all ice blocks are removed
 306
 307         if(total_players == 1 && time > game_starttime) // only one player active on server, start a new match immediately
 308         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 309         {
 310                 next_round = time;
 311                 return 1;
 312         }
 313         if(warmup && time > warmup) // spawn too late, freeze player
 314         {
 315                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 316                 freezetag_Freeze(world);
 317         }
 318
 319         return 1;
 320 }
 321
 322 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 323 {
 324         frag_score = 0; // no frags counted in Freeze Tag
 325         return 1;
 326 }
 327
 328 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 329 {
 330         float n;
 331         vector revive_extra_size;
 332
 333         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 334
 335         entity o;
 336         o = world;
 337         n = 0;
 338         FOR_EACH_PLAYER(other) if(self != other)
 339         {
 340                 if(other.freezetag_frozen == 0)
 341                 {
 342                         if(other.team == self.team)
 343                         {
 344                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 345                                 {
 346                                         if(!o)
 347                                                 o = other;
 348                                         ++n;
 349                                 }
 350                         }
 351                 }
 352         }
 353
 354         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 355         {
 356                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 357                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 358
 359                 if(self.freezetag_revive_progress >= 1)
 360                 {
 361                         freezetag_Unfreeze(self);
 362
 363                         // EVERY team mate nearby gets a point (even if multiple!)
 364                         FOR_EACH_PLAYER(other) if(self != other)
 365                         {
 366                                 if(other.freezetag_frozen == 0)
 367                                 {
 368                                         if(other.team == self.team)
 369                                         {
 370                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 371                                                 {
 372                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 373                                                         PlayerScore_Add(other, SP_SCORE, +1);
 374                                                 }
 375                                         }
 376                                 }
 377                         }
 378
 379                         if(n > 1)
 380                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 381                         else
 382                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 383                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 384                         if(n > 1)
 385                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 386                         else
 387                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 388                 }
 389
 390                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 391                 FOR_EACH_PLAYER(other) if(self != other)
 392                 {
 393                         if(other.freezetag_frozen == 0)
 394                         {
 395                                 if(other.team == self.team)
 396                                 {
 397                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 398                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 399                                 }
 400                         }
 401                 }
 402         }
 403         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 404         {
 405                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 406                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 407         }
 408         else if(!n)
 409         {
 410                 self.freezetag_revive_progress = 0; // thawing nobody
 411         }
 412
 413         return 1;
 414 }
 415
 416 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 417 {
 418         if(self.freezetag_frozen)
 419         {
 420                 self.movement = '0 0 0';
 421                 self.disableclientprediction = 1;
 422         }
 423         return 1;
 424 }
 425
 426 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 427 {
 428     if(g_freezetag)
 429     {
 430         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 431         {
 432             frag_damage = 0;
 433             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 434         }
 435     }
 436     return 1;
 437 }
 438
 439 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 440 {
 441         if (self.freezetag_frozen)
 442                 return 1;
 443         return 0;
 444 }
 445
 446 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 447 {
 448         if not(self.deadflag)
 449         {
 450                 if (random() < 0.5)
 451                         self.havocbot_role = havocbot_role_ft_freeing;
 452                 else
 453                         self.havocbot_role = havocbot_role_ft_offense;
 454         }
 455
 456         return TRUE;
 457 }
 458
 459 MUTATOR_DEFINITION(gamemode_freezetag)
 460 {
 461         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 462         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 463         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 464         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 465         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 466         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 467         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 468         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 469         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_FIRST); //first, last or any? dunno.
 470         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 471
 472         MUTATOR_ONADD
 473         {
 474                 if(time > 1) // game loads at time 1
 475                         error("This is a game type and it cannot be added at runtime.");
 476                 freezetag_Initialize();
 477         }
 478
 479         MUTATOR_ONROLLBACK_OR_REMOVE
 480         {
 481                 // we actually cannot roll back freezetag_Initialize here
 482                 // BUT: we don't need to! If this gets called, adding always
 483                 // succeeds.
 484         }
 485
 486         MUTATOR_ONREMOVE
 487         {
 488                 print("This is a game type and it cannot be removed at runtime.");
 489                 return -1;
 490         }
 491
 492         return 0;
 493 }