qcsrc/server/mutators/gamemode_freezetag.qc

   1 float freezetag_teams;
   2 float freezetag_CheckTeams();
   3 float freezetag_CheckWinner();
   4 void freezetag_Initialize()
   5 {
   6         precache_model("models/ice/ice.md3");
   7         ScoreRules_freezetag();
   8
   9         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null, 5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
  10
  11         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
  12         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
  13         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
  14         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
  15
  16         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
  17         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
  18 }
  19
  20 void freezetag_count_alive_players()
  21 {
  22         entity e;
  23         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  24         FOR_EACH_PLAYER(e) {
  25                 if(e.team == COLOR_TEAM1 && e.health >= 1)
  26                 {
  27                         ++total_players;
  28                         if (!e.freezetag_frozen) ++redalive;
  29                 }
  30                 else if(e.team == COLOR_TEAM2 && e.health >= 1)
  31                 {
  32                         ++total_players;
  33                         if (!e.freezetag_frozen) ++bluealive;
  34                 }
  35                 else if(e.team == COLOR_TEAM3 && e.health >= 1)
  36                 {
  37                         ++total_players;
  38                         if (!e.freezetag_frozen) ++yellowalive;
  39                 }
  40                 else if(e.team == COLOR_TEAM4 && e.health >= 1)
  41                 {
  42                         ++total_players;
  43                         if (!e.freezetag_frozen) ++pinkalive;
  44                 }
  45         }
  46         FOR_EACH_REALCLIENT(e) {
  47                 e.redalive_stat = redalive;
  48                 e.bluealive_stat = bluealive;
  49                 e.yellowalive_stat = yellowalive;
  50                 e.pinkalive_stat = pinkalive;
  51         }
  52 }
  53 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  54 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  55
  56 float prev_total_players;
  57 float freezetag_CheckTeams()
  58 {
  59         entity e;
  60         if(FREEZETAG_ALIVE_TEAMS_OK())
  61         {
  62                 if(prev_total_players != -1)
  63                 {
  64                         FOR_EACH_REALCLIENT(e)
  65                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_WAITING_PLAYERS);
  66                 }
  67                 prev_total_players = -1;
  68                 return 1;
  69         }
  70         if(prev_total_players != total_players)
  71         {
  72                 string teams_missing;
  73                 if(!redalive)   teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM1), ", ");
  74                 if(!bluealive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM2), ", ");
  75                 if(freezetag_teams >= 3)
  76                 if(!yellowalive)        teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM3), ", ");
  77                 if(freezetag_teams == 4)
  78                 if(!pinkalive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM4), ", ");
  79                 teams_missing = substring(teams_missing, 0, strlen(teams_missing)-2);
  80
  81                 FOR_EACH_REALCLIENT(e)
  82                         Send_CSQC_Centerprint_Generic(e, CPID_WAITING_PLAYERS, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, 0);
  83                 prev_total_players = total_players;
  84         }
  85         return 0;
  86 }
  87
  88 float freezetag_getWinnerTeam()
  89 {
  90         float winner_team;
  91         if(redalive >= 1)
  92                 winner_team = COLOR_TEAM1;
  93         if(bluealive >= 1)
  94         {
  95                 if(winner_team) return 0;
  96                 winner_team = COLOR_TEAM2;
  97         }
  98         if(yellowalive >= 1)
  99         {
 100                 if(winner_team) return 0;
 101                 winner_team = COLOR_TEAM3;
 102         }
 103         if(pinkalive >= 1)
 104         {
 105                 if(winner_team) return 0;
 106                 winner_team = COLOR_TEAM4;
 107         }
 108         if(winner_team)
 109                 return winner_team;
 110         return -1; // no player left
 111 }
 112
 113 float freezetag_CheckWinner()
 114 {
 115         entity e;
 116         if(round_handler_GetTimeLeft() <= 0)
 117         {
 118                 FOR_EACH_REALCLIENT(e)
 119                         centerprint(e, "Round over, there's no winner");
 120                 bprint("Round over, there's no winner.\n");
 121                 return 1;
 122         }
 123
 124         if(FREEZETAG_ALIVE_TEAMS() > 1)
 125                 return 0;
 126
 127         float winner_team;
 128         string teamname;
 129         winner_team = freezetag_getWinnerTeam();
 130         if(winner_team > 0)
 131         {
 132                 teamname = ColoredTeamName(winner_team);
 133                 FOR_EACH_REALCLIENT(e)
 134                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen."));
 135                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
 136                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 137         }
 138         else if(winner_team == -1)
 139         {
 140                 FOR_EACH_REALCLIENT(e)
 141                         centerprint(e, "^5Round tied! All teams were frozen.");
 142                 bprint("^5Round tied! All teams were frozen.\n");
 143         }
 144
 145         return 1;
 146 }
 147
 148 // this is needed to allow the player to turn his view around (fixangle can't
 149 // be used to freeze his view, as that also changes the angles), while not
 150 // turning that ice object with the player
 151 void freezetag_Ice_Think()
 152 {
 153         setorigin(self, self.owner.origin - '0 0 16');
 154         self.nextthink = time;
 155 }
 156
 157 void freezetag_Add_Score(entity attacker)
 158 {
 159         if(attacker == self)
 160         {
 161                 // you froze your own dumb self
 162                 // counted as "suicide" already
 163                 PlayerScore_Add(self, SP_SCORE, -1);
 164         }
 165         else if(attacker.classname == "player")
 166         {
 167                 // got frozen by an enemy
 168                 // counted as "kill" and "death" already
 169                 PlayerScore_Add(self, SP_SCORE, -1);
 170                 PlayerScore_Add(attacker, SP_SCORE, +1);
 171         }
 172         // else nothing - got frozen by the game type rules themselves
 173 }
 174
 175 void freezetag_Freeze(entity attacker)
 176 {
 177         if(self.freezetag_frozen)
 178                 return;
 179         self.freezetag_frozen = 1;
 180         self.freezetag_revive_progress = 0;
 181         self.health = 1;
 182         // if(inWarmupStage)
 183                 // self.freezetag_frozen_timeout = time + 5;
 184
 185         freezetag_count_alive_players();
 186
 187         entity ice;
 188         ice = spawn();
 189         ice.owner = self;
 190         ice.classname = "freezetag_ice";
 191         ice.think = freezetag_Ice_Think;
 192         ice.nextthink = time;
 193         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 194         setmodel(ice, "models/ice/ice.md3");
 195
 196         entity oldself;
 197         oldself = self;
 198         self = ice;
 199         freezetag_Ice_Think();
 200         self = oldself;
 201
 202         RemoveGrapplingHook(self);
 203
 204         // add waypoint
 205         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 206
 207         freezetag_Add_Score(attacker);
 208 }
 209
 210 void freezetag_Unfreeze(entity attacker)
 211 {
 212         self.freezetag_frozen = 0;
 213         self.freezetag_frozen_timeout = 0;
 214         self.freezetag_revive_progress = 0;
 215
 216         // remove the ice block
 217         entity ice;
 218         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 219         {
 220                 remove(ice);
 221                 break;
 222         }
 223
 224         // remove waypoint
 225         if(self.waypointsprite_attached)
 226                 WaypointSprite_Kill(self.waypointsprite_attached);
 227 }
 228
 229
 230 // ================
 231 // Bot player logic
 232 // ================
 233
 234 void() havocbot_role_ft_freeing;
 235 void() havocbot_role_ft_offense;
 236
 237 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 238 {
 239         entity head;
 240         float distance;
 241
 242         FOR_EACH_PLAYER(head)
 243         {
 244                 if ((head != self) && (head.team == self.team))
 245                 {
 246                         if (head.freezetag_frozen)
 247                         {
 248                                 distance = vlen(head.origin - org);
 249                                 if (distance > sradius)
 250                                         continue;
 251                                 navigation_routerating(head, ratingscale, 2000);
 252                         }
 253                         else
 254                         {
 255                                 // If teamate is not frozen still seek them out as fight better
 256                                 // in a group.
 257                                 navigation_routerating(head, ratingscale/3, 2000);
 258                         }
 259                 }
 260         }
 261 }
 262
 263 void havocbot_role_ft_offense()
 264 {
 265         entity head;
 266         float unfrozen;
 267
 268         if(self.deadflag != DEAD_NO)
 269                 return;
 270
 271         if (!self.havocbot_role_timeout)
 272                 self.havocbot_role_timeout = time + random() * 10 + 20;
 273
 274         // Count how many players on team are unfrozen.
 275         unfrozen = 0;
 276         FOR_EACH_PLAYER(head)
 277         {
 278                 if ((head.team == self.team) && (!head.freezetag_frozen))
 279                         unfrozen++;
 280         }
 281
 282         // If only one left on team or if role has timed out then start trying to free players.
 283         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 284         {
 285                 dprint("changing role to freeing\n");
 286                 self.havocbot_role = havocbot_role_ft_freeing;
 287                 self.havocbot_role_timeout = 0;
 288                 return;
 289         }
 290
 291         if (time > self.bot_strategytime)
 292         {
 293                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 294
 295                 navigation_goalrating_start();
 296                 havocbot_goalrating_items(10000, self.origin, 10000);
 297                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 298                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 299                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 300                 navigation_goalrating_end();
 301         }
 302 }
 303
 304 void havocbot_role_ft_freeing()
 305 {
 306         if(self.deadflag != DEAD_NO)
 307                 return;
 308
 309         if (!self.havocbot_role_timeout)
 310                 self.havocbot_role_timeout = time + random() * 10 + 20;
 311
 312         if (time > self.havocbot_role_timeout)
 313         {
 314                 dprint("changing role to offense\n");
 315                 self.havocbot_role = havocbot_role_ft_offense;
 316                 self.havocbot_role_timeout = 0;
 317                 return;
 318         }
 319
 320         if (time > self.bot_strategytime)
 321         {
 322                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 323
 324                 navigation_goalrating_start();
 325                 havocbot_goalrating_items(8000, self.origin, 10000);
 326                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 327                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 328                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 329                 navigation_goalrating_end();
 330         }
 331 }
 332
 333
 334 // ==============
 335 // Hook Functions
 336 // ==============
 337
 338 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 339 {
 340         self.health = 0; // neccessary to update correctly alive stats
 341         freezetag_Unfreeze(world);
 342         freezetag_count_alive_players();
 343         return 1;
 344 }
 345
 346 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 347 {
 348         if(round_handler_IsActive())
 349         if(round_handler_CountdownRunning())
 350         {
 351                 if(self.freezetag_frozen)
 352                         freezetag_Unfreeze(world);
 353                 freezetag_count_alive_players();
 354                 return 1; // let the player die so that he can respawn whenever he wants
 355         }
 356
 357         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 358         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 359         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 360                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 361         {
 362                 // let the player die, he will be automatically frozen when he respawns
 363                 if(!self.freezetag_frozen)
 364                 {
 365                         freezetag_Add_Score(frag_attacker);
 366                         freezetag_count_alive_players();
 367                 }
 368                 else
 369                         freezetag_Unfreeze(world); // remove ice
 370                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 371                 return 1;
 372         }
 373
 374         if(self.freezetag_frozen)
 375                 return 1;
 376
 377         freezetag_Freeze(frag_attacker);
 378
 379         if(frag_attacker == frag_target || frag_attacker == world)
 380         {
 381                 if(frag_target.classname == STR_PLAYER)
 382                         centerprint(frag_target, "^1You froze yourself.\n");
 383                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 384         }
 385         else
 386         {
 387                 if(frag_target.classname == STR_PLAYER)
 388                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 389                 if(frag_attacker.classname == STR_PLAYER)
 390                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 391                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 392         }
 393
 394         frag_target.health = 1; // "respawn" the player :P
 395
 396         return 1;
 397 }
 398
 399 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 400 {
 401         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 402                 return 1; // do nothing, round is starting right now
 403
 404         if(self.freezetag_frozen_timeout == -2) // player was dead
 405         {
 406                 freezetag_Freeze(world);
 407                 return 1;
 408         }
 409
 410         freezetag_count_alive_players();
 411
 412         if(round_handler_IsActive())
 413         if(round_handler_IsRoundStarted())
 414         {
 415                 centerprint(self, "^1Round already started, you spawn as frozen.");
 416                 freezetag_Freeze(world);
 417         }
 418
 419         return 1;
 420 }
 421
 422 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 423 {
 424         FOR_EACH_PLAYER(self)
 425         {
 426                 if (self.freezetag_frozen)
 427                         freezetag_Unfreeze(world);
 428                 self.freezetag_frozen_timeout = -1;
 429                 PutClientInServer();
 430                 self.freezetag_frozen_timeout = 0;
 431         }
 432         freezetag_count_alive_players();
 433         return 1;
 434 }
 435
 436 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 437 {
 438         frag_score = 0; // no frags counted in Freeze Tag
 439         return 1;
 440 }
 441
 442 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 443 {
 444         float n;
 445         vector revive_extra_size;
 446
 447         if(gameover)
 448                 return 1;
 449
 450         if(self.freezetag_frozen)
 451         {
 452                 // keep health = 1
 453                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 454
 455                 if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 456                 {
 457                         self.health = autocvar_g_balance_health_start;
 458                         freezetag_Unfreeze(world);
 459                         freezetag_count_alive_players();
 460                         return 1;
 461                 }
 462         }
 463
 464         if(round_handler_IsActive())
 465         if(!round_handler_IsRoundStarted())
 466                 return 1;
 467
 468         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 469
 470         entity o;
 471         o = world;
 472         n = 0;
 473         FOR_EACH_PLAYER(other) if(self != other)
 474         {
 475                 if(other.freezetag_frozen == 0)
 476                 {
 477                         if(other.team == self.team)
 478                         {
 479                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 480                                 {
 481                                         if(!o)
 482                                                 o = other;
 483                                         ++n;
 484                                 }
 485                         }
 486                 }
 487         }
 488
 489         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 490         {
 491                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 492                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 493
 494                 if(self.freezetag_revive_progress >= 1)
 495                 {
 496                         freezetag_Unfreeze(self);
 497                         freezetag_count_alive_players();
 498
 499                         // EVERY team mate nearby gets a point (even if multiple!)
 500                         FOR_EACH_PLAYER(other) if(self != other)
 501                         {
 502                                 if(other.freezetag_frozen == 0)
 503                                 {
 504                                         if(other.team == self.team)
 505                                         {
 506                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 507                                                 {
 508                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 509                                                         PlayerScore_Add(other, SP_SCORE, +1);
 510                                                 }
 511                                         }
 512                                 }
 513                         }
 514
 515                         if(n > 1)
 516                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 517                         else
 518                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 519                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 520                         if(n > 1)
 521                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 522                         else
 523                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 524                 }
 525
 526                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 527                 FOR_EACH_PLAYER(other) if(self != other)
 528                 {
 529                         if(other.freezetag_frozen == 0)
 530                         {
 531                                 if(other.team == self.team)
 532                                 {
 533                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 534                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 535                                 }
 536                         }
 537                 }
 538         }
 539         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 540         {
 541                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 542                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 543         }
 544         else if(!n)
 545         {
 546                 self.freezetag_revive_progress = 0; // thawing nobody
 547         }
 548
 549         return 1;
 550 }
 551
 552 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 553 {
 554         if(self.freezetag_frozen)
 555         {
 556                 self.movement = '0 0 0';
 557                 self.disableclientprediction = 1;
 558         }
 559         return 1;
 560 }
 561
 562 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 563 {
 564         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 565         {
 566                 frag_damage = 0;
 567                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 568         }
 569         return 1;
 570 }
 571
 572 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 573 {
 574         if (self.freezetag_frozen)
 575                 return 1;
 576         return 0;
 577 }
 578
 579 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 580 {
 581         if not(self.deadflag)
 582         {
 583                 if (random() < 0.5)
 584                         self.havocbot_role = havocbot_role_ft_freeing;
 585                 else
 586                         self.havocbot_role = havocbot_role_ft_offense;
 587         }
 588
 589         return TRUE;
 590 }
 591
 592 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 593 {
 594         self.freezetag_frozen = other.freezetag_frozen;
 595         self.freezetag_revive_progress = other.freezetag_revive_progress;
 596         return 0;
 597 }
 598
 599 MUTATOR_HOOKFUNCTION(freezetag_GetTeamCount)
 600 {
 601         freezetag_teams = autocvar_g_freezetag_teams_override;
 602         if(freezetag_teams < 2)
 603                 freezetag_teams = autocvar_g_freezetag_teams;
 604         freezetag_teams = bound(2, freezetag_teams, 4);
 605         ret_float = freezetag_teams;
 606         return 0;
 607 }
 608
 609 MUTATOR_DEFINITION(gamemode_freezetag)
 610 {
 611         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 612         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 613         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 614         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 615         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 616         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 617         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 618         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 619         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 620         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 621         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 622         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 623         MUTATOR_HOOK(GetTeamCount, freezetag_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 624
 625         MUTATOR_ONADD
 626         {
 627                 if(time > 1) // game loads at time 1
 628                         error("This is a game type and it cannot be added at runtime.");
 629                 freezetag_Initialize();
 630         }
 631
 632         MUTATOR_ONREMOVE
 633         {
 634                 error("This is a game type and it cannot be removed at runtime.");
 635         }
 636
 637         return 0;
 638 }