qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + cvar("g_start_delay") + cvar("g_freezetag_warmup");
   5 }
   6
   7 void freezetag_CheckWinner()
   8 {
   9         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  10                 return;
  11
  12         if(next_round || (time > warmup - cvar("g_freezetag_warmup") && time < warmup))
  13                 return; // already waiting for next round to start
  14
  15         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  16                 || (redalive >= 1 && yellowalive >= 1)
  17                 || (redalive >= 1 && pinkalive >= 1)
  18                 || (bluealive >= 1 && yellowalive >= 1)
  19                 || (bluealive >= 1 && pinkalive >= 1)
  20                 || (yellowalive >= 1 && pinkalive >= 1))
  21                 return; // we still have active players on two or more teams, nobody won yet
  22
  23         entity e, winner;
  24         string teamname;
  25
  26         FOR_EACH_PLAYER(e)
  27         {
  28                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  29                 {
  30                         winner = e;
  31                         break; // break, we found the winner
  32                 }
  33         }
  34
  35         if(winner != world) // just in case a winner wasn't found
  36         {
  37                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  38                 if(winner.team == COLOR_TEAM1)
  39                         teamname = "^1Red Team";
  40                 else if(winner.team == COLOR_TEAM2)
  41                         teamname = "^4Blue Team";
  42                 else if(winner.team == COLOR_TEAM3)
  43                         teamname = "^3Yellow Team";
  44                 else
  45                         teamname = "^6Pink Team";
  46                 FOR_EACH_PLAYER(e) {
  47                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  48                 }
  49                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  50         }
  51
  52         next_round = time + 5;
  53 }
  54
  55 void freezetag_Ice_Think()
  56 {
  57         setorigin(self, self.owner.origin - '0 0 16');
  58         self.nextthink = time;
  59 }
  60
  61 void freezetag_Freeze()
  62 {
  63         self.freezetag_frozen = 1;
  64
  65         entity ice;
  66         ice = spawn();
  67         ice.owner = self;
  68         ice.classname = "freezetag_ice";
  69         ice.think = freezetag_Ice_Think;
  70         ice.nextthink = time;
  71         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  72         setmodel(ice, "models/ice/ice.md3");
  73
  74         self.movement = '0 0 0';
  75
  76         // add waypoint
  77         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE);
  78         if(self.waypointsprite_attached)
  79         {
  80                 WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_WAYPOINT, '0.25 0.90 1');
  81         }
  82 }
  83
  84 void freezetag_Unfreeze()
  85 {
  86         self.freezetag_frozen = 0;
  87
  88         // remove the ice block
  89         entity ice;
  90         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
  91         {
  92                 remove(ice);
  93                 break;
  94         }
  95
  96         // remove waypoint
  97         if(self.waypointsprite_attached)
  98                 WaypointSprite_Kill(self.waypointsprite_attached);
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 102 {
 103         if(self.freezetag_frozen == 0)
 104         {
 105                 if(self.team == COLOR_TEAM1)
 106                         --redalive;
 107                 else if(self.team == COLOR_TEAM2)
 108                         --bluealive;
 109                 else if(self.team == COLOR_TEAM3)
 110                         --yellowalive;
 111                 else if(self.team == COLOR_TEAM4)
 112                         --pinkalive;
 113                 --totalalive;
 114         }
 115
 116         if(totalspawned > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 117                 freezetag_CheckWinner();
 118
 119         freezetag_Unfreeze();
 120
 121         return 1;
 122 }
 123
 124 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 125 {
 126         if(self.freezetag_frozen == 0)
 127         {
 128                 if(self.team == COLOR_TEAM1)
 129                         --redalive;
 130                 else if(self.team == COLOR_TEAM2)
 131                         --bluealive;
 132                 else if(self.team == COLOR_TEAM3)
 133                         --yellowalive;
 134                 else if(self.team == COLOR_TEAM4)
 135                         --pinkalive;
 136                 --totalalive;
 137         }
 138
 139         freezetag_Freeze();
 140
 141         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 142         if(frag_attacker == frag_target || frag_attacker == world)
 143         {
 144                 centerprint(frag_target, "^1You froze yourself.\n");
 145                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 146         }
 147         else
 148         {
 149                 centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 150                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 151         }
 152
 153         frag_target.health = cvar("g_balance_health_start"); // "respawn" the player :P
 154
 155         freezetag_CheckWinner();
 156
 157         return 1;
 158 }
 159
 160 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 161 {
 162     freezetag_Unfreeze(); // start by making sure that all ice blocks are removed
 163
 164         if(totalspawned == 1 && time > game_starttime) // only one player active on server, start a new match immediately
 165         if(!next_round && warmup && (time < warmup - cvar("g_freezetag_warmup") || time > warmup)) // not awaiting next round
 166         {
 167                 next_round = time;
 168                 return 1;
 169         }
 170         if(warmup && time > warmup) // spawn too late, freeze player
 171         {
 172                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 173                 freezetag_Freeze();
 174         }
 175
 176         return 1;
 177 }
 178
 179 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 180 {
 181         frag_score = 0; // no frags counted in Freeze Tag
 182         return 1;
 183 }
 184
 185 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 186 {
 187         vector revive_extra_size;
 188         revive_extra_size = '1 1 1' * cvar("g_freezetag_revive_extra_size");
 189
 190         float teammate_nearby;
 191         FOR_EACH_PLAYER(other) if(self != other)
 192         {
 193                 if(other.freezetag_frozen == 0)
 194                 {
 195                         if(other.team == self.team)
 196                         {
 197                                 teammate_nearby = boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax);
 198                                 if(teammate_nearby)
 199                                         break;
 200                         }
 201                 }
 202         }
 203
 204         if(teammate_nearby && self.freezetag_frozen == 1)
 205         {
 206                 if(self.freezetag_beginrevive_time == -9999)
 207                 {
 208                         self.freezetag_beginrevive_time = time;
 209                         self.freezetag_revive_progress = 0;
 210                         other.freezetag_revive_progress = 0;
 211                 }
 212                 else
 213                 {
 214                         self.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / cvar("g_freezetag_revive_time");
 215                         other.freezetag_revive_progress = (time - self.freezetag_beginrevive_time) / cvar("g_freezetag_revive_time");
 216                         if(time - self.freezetag_beginrevive_time >= cvar("g_freezetag_revive_time"))
 217                         {
 218                                 freezetag_Unfreeze();
 219
 220                                 centerprint(self, strcat("^5You were revived by ^7", other.netname, ".\n"));
 221                                 centerprint(other, strcat("^5You revived ^7", self.netname, ".\n"));
 222                                 bprint("^7", other.netname, "^5 revived ^7", self.netname, ".\n");
 223
 224                                 self.freezetag_beginrevive_time = -9999;
 225                                 self.freezetag_revive_progress = 0;
 226                                 other.freezetag_revive_progress = 0;
 227                         }
 228                 }
 229         }
 230         else if(!teammate_nearby) // only if no teammate is nearby will we reset
 231         {
 232                 self.freezetag_beginrevive_time = -9999;
 233                 self.freezetag_revive_progress = 0;
 234         }
 235
 236         return 1;
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 240 {
 241         if(self.freezetag_frozen)
 242                 self.movement = '0 0 0';
 243         return 1;
 244 }
 245
 246 MUTATOR_DEFINITION(gamemode_freezetag)
 247 {
 248         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 249         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 250         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 251         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 252         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 253         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 254         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 255
 256         MUTATOR_ONADD
 257         {
 258                 if(time > 1) // game loads at time 1
 259                         error("This is a game type and it cannot be added at runtime.");
 260                 g_freezetag = 1;
 261                 freezetag_Initialize();
 262         }
 263
 264         MUTATOR_ONREMOVE
 265         {
 266                 g_freezetag = 0;
 267                 error("This is a game type and it cannot be removed at runtime.");
 268         }
 269
 270         return 0;
 271 }