qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = time + autocvar_g_start_delay + autocvar_g_freezetag_warmup;
   5         ScoreRules_freezetag();
   6 }
   7
   8 void freezetag_CheckWinner()
   9 {
  10         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  11                 return;
  12
  13         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  14                 return; // already waiting for next round to start
  15
  16         if((redalive >= 1 && bluealive >= 1) // counted in arena.qc
  17                 || (redalive >= 1 && yellowalive >= 1)
  18                 || (redalive >= 1 && pinkalive >= 1)
  19                 || (bluealive >= 1 && yellowalive >= 1)
  20                 || (bluealive >= 1 && pinkalive >= 1)
  21                 || (yellowalive >= 1 && pinkalive >= 1))
  22                 return; // we still have active players on two or more teams, nobody won yet
  23
  24         entity e, winner;
  25         string teamname;
  26         winner = world;
  27
  28         FOR_EACH_PLAYER(e)
  29         {
  30                 if(e.freezetag_frozen == 0 && e.classname == "player" && e.health >= 1) // here's one player from the winning team... good
  31                 {
  32                         winner = e;
  33                         break; // break, we found the winner
  34                 }
  35         }
  36
  37         if(winner != world) // just in case a winner wasn't found
  38         {
  39                 if(winner.team == COLOR_TEAM1)
  40                         teamname = "^1Red Team";
  41                 else if(winner.team == COLOR_TEAM2)
  42                         teamname = "^4Blue Team";
  43                 else if(winner.team == COLOR_TEAM3)
  44                         teamname = "^3Yellow Team";
  45                 else
  46                         teamname = "^6Pink Team";
  47                 FOR_EACH_PLAYER(e) {
  48                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  49                 }
  50                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  51                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  52         }
  53
  54         next_round = time + 5;
  55 }
  56
  57 // this is needed to allow the player to turn his view around (fixangle can't
  58 // be used to freeze his view, as that also changes the angles), while not
  59 // turning that ice object with the player
  60 void freezetag_Ice_Think()
  61 {
  62         setorigin(self, self.owner.origin - '0 0 16');
  63         self.nextthink = time;
  64 }
  65
  66 void freezetag_Freeze(entity attacker)
  67 {
  68         if(self.freezetag_frozen)
  69                 return;
  70         self.freezetag_frozen = 1;
  71         self.freezetag_revive_progress = 0;
  72
  73         entity ice;
  74         ice = spawn();
  75         ice.owner = self;
  76         ice.classname = "freezetag_ice";
  77         ice.think = freezetag_Ice_Think;
  78         ice.nextthink = time;
  79         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  80         setmodel(ice, "models/ice/ice.md3");
  81
  82         entity oldself;
  83         oldself = self;
  84         self = ice;
  85         freezetag_Ice_Think();
  86         self = oldself;
  87
  88         RemoveGrapplingHook(self);
  89
  90         // add waypoint
  91         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
  92
  93         if(attacker == self)
  94         {
  95                 // you froze your own dumb self
  96                 // counted as "suicide" already
  97                 PlayerScore_Add(self, SP_SCORE, -1);
  98         }
  99         else if(attacker.classname == "player")
 100         {
 101                 // got frozen by an enemy
 102                 // counted as "kill" and "death" already
 103                 PlayerScore_Add(self, SP_SCORE, -1);
 104                 PlayerScore_Add(attacker, SP_SCORE, +1);
 105         }
 106         else
 107         {
 108                 // nothing - got frozen by the game type rules themselves
 109         }
 110 }
 111
 112 void freezetag_Unfreeze(entity attacker)
 113 {
 114         self.freezetag_frozen = 0;
 115         self.freezetag_revive_progress = 0;
 116
 117         // remove the ice block
 118         entity ice;
 119         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 120         {
 121                 remove(ice);
 122                 break;
 123         }
 124
 125         // remove waypoint
 126         if(self.waypointsprite_attached)
 127                 WaypointSprite_Kill(self.waypointsprite_attached);
 128 }
 129
 130 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 131 {
 132         if(self.freezetag_frozen == 0)
 133         {
 134                 if(self.team == COLOR_TEAM1)
 135                         --redalive;
 136                 else if(self.team == COLOR_TEAM2)
 137                         --bluealive;
 138                 else if(self.team == COLOR_TEAM3)
 139                         --yellowalive;
 140                 else if(self.team == COLOR_TEAM4)
 141                         --pinkalive;
 142                 --totalalive;
 143         }
 144
 145         if(totalspawned > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 146                 freezetag_CheckWinner();
 147
 148         freezetag_Unfreeze(world);
 149
 150         return 1;
 151 }
 152
 153 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 154 {
 155         if(self.freezetag_frozen == 0)
 156         {
 157                 if(self.team == COLOR_TEAM1)
 158                         --redalive;
 159                 else if(self.team == COLOR_TEAM2)
 160                         --bluealive;
 161                 else if(self.team == COLOR_TEAM3)
 162                         --yellowalive;
 163                 else if(self.team == COLOR_TEAM4)
 164                         --pinkalive;
 165                 --totalalive;
 166
 167         freezetag_Freeze(frag_attacker);
 168         }
 169
 170     if(frag_attacker.classname == STR_PLAYER)
 171         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 172
 173         if(frag_attacker == frag_target || frag_attacker == world)
 174         {
 175         if(frag_target.classname == STR_PLAYER)
 176             centerprint(frag_target, "^1You froze yourself.\n");
 177                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 178         }
 179         else
 180         {
 181         if(frag_target.classname == STR_PLAYER)
 182             centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 183                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 184         }
 185
 186         frag_target.health = autocvar_g_balance_health_start; // "respawn" the player :P
 187
 188         freezetag_CheckWinner();
 189
 190         return 1;
 191 }
 192
 193 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 194 {
 195     freezetag_Unfreeze(world); // start by making sure that all ice blocks are removed
 196
 197         if(totalspawned == 1 && time > game_starttime) // only one player active on server, start a new match immediately
 198         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 199         {
 200                 next_round = time;
 201                 return 1;
 202         }
 203         if(warmup && time > warmup) // spawn too late, freeze player
 204         {
 205                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 206                 freezetag_Freeze(world);
 207         }
 208
 209         return 1;
 210 }
 211
 212 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 213 {
 214         frag_score = 0; // no frags counted in Freeze Tag
 215         return 1;
 216 }
 217
 218 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 219 {
 220         float n;
 221         vector revive_extra_size;
 222
 223         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 224
 225         entity o;
 226         o = world;
 227         n = 0;
 228         FOR_EACH_PLAYER(other) if(self != other)
 229         {
 230                 if(other.freezetag_frozen == 0)
 231                 {
 232                         if(other.team == self.team)
 233                         {
 234                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 235                                 {
 236                                         if(!o)
 237                                                 o = other;
 238                                         ++n;
 239                                 }
 240                         }
 241                 }
 242         }
 243
 244         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 245         {
 246                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 247
 248                 if(self.freezetag_revive_progress >= 1)
 249                 {
 250                         freezetag_Unfreeze(self);
 251
 252                         // EVERY team mate nearby gets a point (even if multiple!)
 253                         FOR_EACH_PLAYER(other) if(self != other)
 254                         {
 255                                 if(other.freezetag_frozen == 0)
 256                                 {
 257                                         if(other.team == self.team)
 258                                         {
 259                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 260                                                 {
 261                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 262                                                         PlayerScore_Add(other, SP_SCORE, +1);
 263                                                 }
 264                                         }
 265                                 }
 266                         }
 267
 268                         if(n > 1)
 269                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 270                         else
 271                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 272                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 273                         if(n > 1)
 274                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 275                         else
 276                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 277                 }
 278
 279                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 280                 FOR_EACH_PLAYER(other) if(self != other)
 281                 {
 282                         if(other.freezetag_frozen == 0)
 283                         {
 284                                 if(other.team == self.team)
 285                                 {
 286                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 287                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 288                                 }
 289                         }
 290                 }
 291         }
 292         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 293         {
 294                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 295         }
 296         else if(!n)
 297         {
 298                 self.freezetag_revive_progress = 0; // thawing nobody
 299         }
 300
 301         return 1;
 302 }
 303
 304 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 305 {
 306         if(self.freezetag_frozen)
 307         {
 308                 self.movement = '0 0 0';
 309                 self.disableclientprediction = 1;
 310         }
 311         return 1;
 312 }
 313
 314 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 315 {
 316     if(g_freezetag)
 317     {
 318         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 319         {
 320             frag_damage = 0;
 321             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 322         }
 323     }
 324     return 1;
 325 }
 326
 327 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 328 {
 329         if (self.freezetag_frozen)
 330                 return 1;
 331         return 0;
 332 }
 333
 334 MUTATOR_DEFINITION(gamemode_freezetag)
 335 {
 336         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 337         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 338         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 339         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 340         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 341         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 342         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 343         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 344         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_FIRST); //first, last or any? dunno.
 345
 346         MUTATOR_ONADD
 347         {
 348                 if(time > 1) // game loads at time 1
 349                         error("This is a game type and it cannot be added at runtime.");
 350                 g_freezetag = 1;
 351                 freezetag_Initialize();
 352         }
 353
 354         MUTATOR_ONREMOVE
 355         {
 356                 g_freezetag = 0;
 357                 error("This is a game type and it cannot be removed at runtime.");
 358         }
 359
 360         return 0;
 361 }