qcsrc/server/mutators/gamemode_freezetag.qc

   1 .float freezetag_frozen_time;
   2 .float freezetag_frozen_timeout;
   3 .float freezetag_revive_progress;
   4 .entity freezetag_ice;
   5 float freezetag_teams;
   6
   7 float freezetag_CheckTeams();
   8 float freezetag_CheckWinner();
   9 void freezetag_Initialize()
  10 {
  11         precache_model("models/ice/ice.md3");
  12         ScoreRules_freezetag();
  13
  14         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null, 5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
  15
  16         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
  17         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
  18         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
  19         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
  20
  21         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
  22         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
  23 }
  24
  25 void freezetag_count_alive_players()
  26 {
  27         entity e;
  28         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  29         FOR_EACH_PLAYER(e) {
  30                 if(e.team == COLOR_TEAM1 && e.health >= 1)
  31                 {
  32                         ++total_players;
  33                         if (!e.freezetag_frozen) ++redalive;
  34                 }
  35                 else if(e.team == COLOR_TEAM2 && e.health >= 1)
  36                 {
  37                         ++total_players;
  38                         if (!e.freezetag_frozen) ++bluealive;
  39                 }
  40                 else if(e.team == COLOR_TEAM3 && e.health >= 1)
  41                 {
  42                         ++total_players;
  43                         if (!e.freezetag_frozen) ++yellowalive;
  44                 }
  45                 else if(e.team == COLOR_TEAM4 && e.health >= 1)
  46                 {
  47                         ++total_players;
  48                         if (!e.freezetag_frozen) ++pinkalive;
  49                 }
  50         }
  51         FOR_EACH_REALCLIENT(e) {
  52                 e.redalive_stat = redalive;
  53                 e.bluealive_stat = bluealive;
  54                 e.yellowalive_stat = yellowalive;
  55                 e.pinkalive_stat = pinkalive;
  56         }
  57 }
  58 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  59 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  60
  61 float prev_total_players;
  62 float freezetag_CheckTeams()
  63 {
  64         entity e;
  65         if(FREEZETAG_ALIVE_TEAMS_OK())
  66         {
  67                 if(prev_total_players != -1)
  68                 {
  69                         FOR_EACH_REALCLIENT(e)
  70                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_WAITING_PLAYERS);
  71                 }
  72                 prev_total_players = -1;
  73                 return 1;
  74         }
  75         if(prev_total_players != total_players)
  76         {
  77                 string teams_missing = "";
  78                 if(!redalive)   teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM1), ", ");
  79                 if(!bluealive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM2), ", ");
  80                 if(freezetag_teams >= 3)
  81                 if(!yellowalive)        teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM3), ", ");
  82                 if(freezetag_teams == 4)
  83                 if(!pinkalive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM4), ", ");
  84                 teams_missing = substring(teams_missing, 0, strlen(teams_missing)-2);
  85
  86                 FOR_EACH_REALCLIENT(e)
  87                         Send_CSQC_Centerprint_Generic(e, CPID_WAITING_PLAYERS, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, 0);
  88                 prev_total_players = total_players;
  89         }
  90         return 0;
  91 }
  92
  93 float freezetag_getWinnerTeam()
  94 {
  95         float winner_team = 0;
  96         if(redalive >= 1)
  97                 winner_team = COLOR_TEAM1;
  98         if(bluealive >= 1)
  99         {
 100                 if(winner_team) return 0;
 101                 winner_team = COLOR_TEAM2;
 102         }
 103         if(yellowalive >= 1)
 104         {
 105                 if(winner_team) return 0;
 106                 winner_team = COLOR_TEAM3;
 107         }
 108         if(pinkalive >= 1)
 109         {
 110                 if(winner_team) return 0;
 111                 winner_team = COLOR_TEAM4;
 112         }
 113         if(winner_team)
 114                 return winner_team;
 115         return -1; // no player left
 116 }
 117
 118 float freezetag_CheckWinner()
 119 {
 120         entity e;
 121         if(round_handler_GetTimeLeft() <= 0)
 122         {
 123                 FOR_EACH_REALCLIENT(e)
 124                         centerprint(e, "Round over, there's no winner");
 125                 bprint("Round over, there's no winner.\n");
 126                 FOR_EACH_PLAYER(e)
 127                         e.freezetag_frozen_timeout = 0;
 128                 return 1;
 129         }
 130
 131         if(FREEZETAG_ALIVE_TEAMS() > 1)
 132                 return 0;
 133
 134         float winner_team;
 135         string teamname;
 136         winner_team = freezetag_getWinnerTeam();
 137         if(winner_team > 0)
 138         {
 139                 teamname = ColoredTeamName(winner_team);
 140                 FOR_EACH_REALCLIENT(e)
 141                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen."));
 142                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
 143                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 144         }
 145         else if(winner_team == -1)
 146         {
 147                 FOR_EACH_REALCLIENT(e)
 148                         centerprint(e, "^5Round tied! All teams were frozen.");
 149                 bprint("^5Round tied! All teams were frozen.\n");
 150         }
 151
 152         FOR_EACH_PLAYER(e)
 153                 e.freezetag_frozen_timeout = 0;
 154         return 1;
 155 }
 156
 157 // this is needed to allow the player to turn his view around (fixangle can't
 158 // be used to freeze his view, as that also changes the angles), while not
 159 // turning that ice object with the player
 160 void freezetag_Ice_Think()
 161 {
 162         setorigin(self, self.owner.origin - '0 0 16');
 163         self.nextthink = time;
 164 }
 165
 166 void freezetag_Add_Score(entity attacker)
 167 {
 168         if(attacker == self)
 169         {
 170                 // you froze your own dumb self
 171                 // counted as "suicide" already
 172                 PlayerScore_Add(self, SP_SCORE, -1);
 173         }
 174         else if(attacker.classname == "player")
 175         {
 176                 // got frozen by an enemy
 177                 // counted as "kill" and "death" already
 178                 PlayerScore_Add(self, SP_SCORE, -1);
 179                 PlayerScore_Add(attacker, SP_SCORE, +1);
 180         }
 181         // else nothing - got frozen by the game type rules themselves
 182 }
 183
 184 void freezetag_Freeze(entity attacker)
 185 {
 186         if(self.freezetag_frozen)
 187                 return;
 188         self.freezetag_frozen = 1;
 189         self.freezetag_frozen_time = time;
 190         self.freezetag_revive_progress = 0;
 191         self.health = 1;
 192         if(autocvar_g_freezetag_frozen_timeout > 0)
 193                 self.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_timeout;
 194
 195         freezetag_count_alive_players();
 196
 197         entity ice;
 198         ice = spawn();
 199         ice.owner = self;
 200         ice.classname = "freezetag_ice";
 201         ice.think = freezetag_Ice_Think;
 202         ice.nextthink = time;
 203         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 204         setmodel(ice, "models/ice/ice.md3");
 205
 206         self.freezetag_ice = ice;
 207
 208         RemoveGrapplingHook(self);
 209
 210         // add waypoint
 211         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 212
 213         freezetag_Add_Score(attacker);
 214 }
 215
 216 void freezetag_Unfreeze(entity attacker)
 217 {
 218         self.freezetag_frozen = 0;
 219         self.freezetag_frozen_time = 0;
 220         self.freezetag_frozen_timeout = 0;
 221         self.freezetag_revive_progress = 0;
 222
 223         remove(self.freezetag_ice);
 224         self.freezetag_ice = world;
 225
 226         if(self.waypointsprite_attached)
 227                 WaypointSprite_Kill(self.waypointsprite_attached);
 228 }
 229
 230
 231 // ================
 232 // Bot player logic
 233 // ================
 234
 235 void() havocbot_role_ft_freeing;
 236 void() havocbot_role_ft_offense;
 237
 238 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 239 {
 240         entity head;
 241         float distance;
 242
 243         FOR_EACH_PLAYER(head)
 244         {
 245                 if ((head != self) && (head.team == self.team))
 246                 {
 247                         if (head.freezetag_frozen)
 248                         {
 249                                 distance = vlen(head.origin - org);
 250                                 if (distance > sradius)
 251                                         continue;
 252                                 navigation_routerating(head, ratingscale, 2000);
 253                         }
 254                         else
 255                         {
 256                                 // If teamate is not frozen still seek them out as fight better
 257                                 // in a group.
 258                                 navigation_routerating(head, ratingscale/3, 2000);
 259                         }
 260                 }
 261         }
 262 }
 263
 264 void havocbot_role_ft_offense()
 265 {
 266         entity head;
 267         float unfrozen;
 268
 269         if(self.deadflag != DEAD_NO)
 270                 return;
 271
 272         if (!self.havocbot_role_timeout)
 273                 self.havocbot_role_timeout = time + random() * 10 + 20;
 274
 275         // Count how many players on team are unfrozen.
 276         unfrozen = 0;
 277         FOR_EACH_PLAYER(head)
 278         {
 279                 if ((head.team == self.team) && (!head.freezetag_frozen))
 280                         unfrozen++;
 281         }
 282
 283         // If only one left on team or if role has timed out then start trying to free players.
 284         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 285         {
 286                 dprint("changing role to freeing\n");
 287                 self.havocbot_role = havocbot_role_ft_freeing;
 288                 self.havocbot_role_timeout = 0;
 289                 return;
 290         }
 291
 292         if (time > self.bot_strategytime)
 293         {
 294                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 295
 296                 navigation_goalrating_start();
 297                 havocbot_goalrating_items(10000, self.origin, 10000);
 298                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 299                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 300                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 301                 navigation_goalrating_end();
 302         }
 303 }
 304
 305 void havocbot_role_ft_freeing()
 306 {
 307         if(self.deadflag != DEAD_NO)
 308                 return;
 309
 310         if (!self.havocbot_role_timeout)
 311                 self.havocbot_role_timeout = time + random() * 10 + 20;
 312
 313         if (time > self.havocbot_role_timeout)
 314         {
 315                 dprint("changing role to offense\n");
 316                 self.havocbot_role = havocbot_role_ft_offense;
 317                 self.havocbot_role_timeout = 0;
 318                 return;
 319         }
 320
 321         if (time > self.bot_strategytime)
 322         {
 323                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 324
 325                 navigation_goalrating_start();
 326                 havocbot_goalrating_items(8000, self.origin, 10000);
 327                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 328                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 329                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 330                 navigation_goalrating_end();
 331         }
 332 }
 333
 334
 335 // ==============
 336 // Hook Functions
 337 // ==============
 338
 339 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 340 {
 341         self.health = 0; // neccessary to update correctly alive stats
 342         freezetag_Unfreeze(world);
 343         freezetag_count_alive_players();
 344         return 1;
 345 }
 346
 347 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 348 {
 349         if(round_handler_IsActive())
 350         if(round_handler_CountdownRunning())
 351         {
 352                 if(self.freezetag_frozen)
 353                         freezetag_Unfreeze(world);
 354                 freezetag_count_alive_players();
 355                 return 1; // let the player die so that he can respawn whenever he wants
 356         }
 357
 358         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 359         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 360         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 361                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 362         {
 363                 // let the player die, he will be automatically frozen when he respawns
 364                 if(!self.freezetag_frozen)
 365                 {
 366                         freezetag_Add_Score(frag_attacker);
 367                         freezetag_count_alive_players();
 368                 }
 369                 else
 370                         freezetag_Unfreeze(world); // remove ice
 371                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 372                 return 1;
 373         }
 374
 375         if(self.freezetag_frozen)
 376                 return 1;
 377
 378         freezetag_Freeze(frag_attacker);
 379
 380         if(frag_attacker == frag_target || frag_attacker == world)
 381         {
 382                 if(frag_target.classname == STR_PLAYER)
 383                         centerprint(frag_target, "^1You froze yourself.\n");
 384                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 385         }
 386         else
 387         {
 388                 if(frag_target.classname == STR_PLAYER)
 389                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 390                 if(frag_attacker.classname == STR_PLAYER)
 391                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 392                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 393         }
 394
 395         frag_target.health = 1; // "respawn" the player :P
 396
 397         return 1;
 398 }
 399
 400 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 401 {
 402         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 403                 return 1; // do nothing, round is starting right now
 404
 405         if(self.freezetag_frozen_timeout == -2) // player was dead
 406         {
 407                 freezetag_Freeze(world);
 408                 return 1;
 409         }
 410
 411         freezetag_count_alive_players();
 412
 413         if(round_handler_IsActive())
 414         if(round_handler_IsRoundStarted())
 415         {
 416                 centerprint(self, "^1Round already started, you spawn as frozen.");
 417                 freezetag_Freeze(world);
 418         }
 419
 420         return 1;
 421 }
 422
 423 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 424 {
 425         FOR_EACH_PLAYER(self)
 426         {
 427                 if (self.freezetag_frozen)
 428                         freezetag_Unfreeze(world);
 429                 self.freezetag_frozen_timeout = -1;
 430                 PutClientInServer();
 431                 self.freezetag_frozen_timeout = 0;
 432         }
 433         freezetag_count_alive_players();
 434         return 1;
 435 }
 436
 437 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 438 {
 439         frag_score = 0; // no frags counted in Freeze Tag
 440         return 1;
 441 }
 442
 443 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 444 {
 445         float n;
 446         vector revive_extra_size;
 447
 448         if(gameover)
 449                 return 1;
 450
 451         if(self.freezetag_frozen)
 452         {
 453                 // keep health = 1
 454                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 455         }
 456
 457         if(round_handler_IsActive())
 458         if(!round_handler_IsRoundStarted())
 459                 return 1;
 460
 461         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 462
 463         entity o;
 464         o = world;
 465         if(self.freezetag_frozen_timeout > 0 && time < self.freezetag_frozen_timeout)
 466                 self.freezetag_ice.alpha = 0.1 + (self.freezetag_frozen_timeout - time) / (self.freezetag_frozen_timeout - self.freezetag_frozen_time);
 467
 468         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 469                 n = -1;
 470         else
 471         {
 472                 n = 0;
 473                 FOR_EACH_PLAYER(other) if(self != other)
 474                 {
 475                         if(other.freezetag_frozen == 0)
 476                         {
 477                                 if(other.team == self.team)
 478                                 {
 479                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 480                                         {
 481                                                 if(!o)
 482                                                         o = other;
 483                                                 ++n;
 484                                         }
 485                                 }
 486                         }
 487                 }
 488         }
 489
 490         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 491         {
 492                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 493                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 494
 495                 if(self.freezetag_revive_progress >= 1)
 496                 {
 497                         freezetag_Unfreeze(self);
 498                         freezetag_count_alive_players();
 499
 500                         if(n == -1)
 501                         {
 502                                 string s = ftos(autocvar_g_freezetag_frozen_timeout);
 503                                 centerprint(self, strcat("^5You were automatically revived after ", s, " seconds^5.\n"));
 504                                 bprint("^7", self.netname, "^5 were automatically revived after ", s, " seconds^5.\n");
 505                                 return 1;
 506                         }
 507
 508                         // EVERY team mate nearby gets a point (even if multiple!)
 509                         FOR_EACH_PLAYER(other) if(self != other)
 510                         {
 511                                 if(other.freezetag_frozen == 0)
 512                                 {
 513                                         if(other.team == self.team)
 514                                         {
 515                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 516                                                 {
 517                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 518                                                         PlayerScore_Add(other, SP_SCORE, +1);
 519                                                 }
 520                                         }
 521                                 }
 522                         }
 523
 524                         if(n > 1)
 525                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 526                         else
 527                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 528                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 529                         if(n > 1)
 530                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 531                         else
 532                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 533                 }
 534
 535                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 536                 FOR_EACH_PLAYER(other) if(self != other)
 537                 {
 538                         if(other.freezetag_frozen == 0)
 539                         {
 540                                 if(other.team == self.team)
 541                                 {
 542                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 543                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 544                                 }
 545                         }
 546                 }
 547         }
 548         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 549         {
 550                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 551                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 552         }
 553         else if(!n)
 554         {
 555                 self.freezetag_revive_progress = 0; // thawing nobody
 556         }
 557
 558         return 1;
 559 }
 560
 561 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 562 {
 563         if(self.freezetag_frozen)
 564         {
 565                 self.movement = '0 0 0';
 566                 self.disableclientprediction = 1;
 567         }
 568         return 1;
 569 }
 570
 571 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 572 {
 573         if(frag_target.freezetag_frozen && frag_deathtype != DEATH_HURTTRIGGER)
 574         {
 575                 frag_damage = 0;
 576                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 577         }
 578         return 1;
 579 }
 580
 581 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 582 {
 583         if (self.freezetag_frozen)
 584                 return 1;
 585         return 0;
 586 }
 587
 588 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 589 {
 590         if not(self.deadflag)
 591         {
 592                 if (random() < 0.5)
 593                         self.havocbot_role = havocbot_role_ft_freeing;
 594                 else
 595                         self.havocbot_role = havocbot_role_ft_offense;
 596         }
 597
 598         return TRUE;
 599 }
 600
 601 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 602 {
 603         self.freezetag_frozen = other.freezetag_frozen;
 604         self.freezetag_revive_progress = other.freezetag_revive_progress;
 605         return 0;
 606 }
 607
 608 MUTATOR_HOOKFUNCTION(freezetag_GetTeamCount)
 609 {
 610         freezetag_teams = autocvar_g_freezetag_teams_override;
 611         if(freezetag_teams < 2)
 612                 freezetag_teams = autocvar_g_freezetag_teams;
 613         freezetag_teams = bound(2, freezetag_teams, 4);
 614         ret_float = freezetag_teams;
 615         return 0;
 616 }
 617
 618 MUTATOR_DEFINITION(gamemode_freezetag)
 619 {
 620         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 621         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 622         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 623         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 624         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 625         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 626         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 627         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 628         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 629         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 630         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 631         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 632         MUTATOR_HOOK(GetTeamCount, freezetag_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 633
 634         MUTATOR_ONADD
 635         {
 636                 if(time > 1) // game loads at time 1
 637                         error("This is a game type and it cannot be added at runtime.");
 638                 freezetag_Initialize();
 639         }
 640
 641         MUTATOR_ONROLLBACK_OR_REMOVE
 642         {
 643                 // we actually cannot roll back freezetag_Initialize here
 644                 // BUT: we don't need to! If this gets called, adding always
 645                 // succeeds.
 646         }
 647
 648         MUTATOR_ONREMOVE
 649         {
 650                 print("This is a game type and it cannot be removed at runtime.");
 651                 return -1;
 652         }
 653
 654         return 0;
 655 }