qcsrc/server/mutators/gamemode_invasion.qc

   1 void invasion_spawnpoint()
   2 {
   3         if(!g_invasion) { remove(self); return; }
   4
   5         self.classname = "invasion_spawnpoint";
   6 }
   7
   8 float invasion_PickMonster(float supermonster_count)
   9 {
  10         if(autocvar_g_invasion_zombies_only)
  11                 return MON_ZOMBIE;
  12
  13         float i;
  14         entity mon;
  15
  16         RandomSelection_Init();
  17
  18         for(i = MON_FIRST; i <= MON_LAST; ++i)
  19         {
  20                 mon = get_monsterinfo(i);
  21                 if((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM) || ((mon.spawnflags & MON_FLAG_SUPERMONSTER) && supermonster_count >= 1))
  22                         continue; // flying/swimming monsters not yet supported
  23
  24                 RandomSelection_Add(world, i, "", 1, 1);
  25         }
  26
  27         return RandomSelection_chosen_float;
  28 }
  29
  30 entity invasion_PickSpawn()
  31 {
  32         entity e;
  33
  34         RandomSelection_Init();
  35
  36         for(e = world;(e = find(e, classname, "invasion_spawnpoint")); )
  37                 RandomSelection_Add(e, 0, string_null, 1, 1);
  38
  39         return RandomSelection_chosen_ent;
  40 }
  41
  42 void invasion_SpawnChosenMonster(float mon)
  43 {
  44         entity spawn_point, monster;
  45
  46         spawn_point = invasion_PickSpawn();
  47
  48         if(spawn_point == world)
  49         {
  50                 dprint("Warning: couldn't find any invasion_spawnpoint spawnpoints, no monsters will spawn!\n");
  51                 return;
  52         }
  53
  54         monster = spawnmonster("", mon, spawn_point, spawn_point, spawn_point.origin, FALSE, 2);
  55
  56         if(roundcnt >= maxrounds)
  57                 monster.spawnflags |= MONSTERFLAG_MINIBOSS;
  58 }
  59
  60 void invasion_SpawnMonsters(float supermonster_count)
  61 {
  62         float chosen_monster = invasion_PickMonster(supermonster_count);
  63
  64         invasion_SpawnChosenMonster(chosen_monster);
  65 }
  66
  67 float Invasion_CheckWinner()
  68 {
  69         entity head;
  70         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  71         {
  72                 FOR_EACH_MONSTER(head)
  73                         monster_remove(head);
  74
  75                 if(roundcnt >= maxrounds)
  76                 {
  77                         NextLevel();
  78                         return 1;
  79                 }
  80
  81                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  82                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  83                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
  84                 return 1;
  85         }
  86
  87         // boss round
  88         if(roundcnt >= maxrounds)
  89         {
  90                 if(numspawned < 1)
  91                 {
  92                         maxspawned = 1;
  93                         invasion_SpawnMonsters(0);
  94                 }
  95         }
  96         else
  97         {
  98                 float total_alive_monsters = 0, supermonster_count = 0;
  99
 100                 FOR_EACH_MONSTER(head) if(head.health > 0)
 101                 {
 102                         if((get_monsterinfo(head.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
 103                                 ++supermonster_count;
 104                         ++total_alive_monsters;
 105                 }
 106
 107                 if((total_alive_monsters + numkilled) < maxspawned && maxcurrent < 10) // 10 at a time should be plenty
 108                 {
 109                         if(time >= last_check)
 110                         {
 111                                 invasion_SpawnMonsters(supermonster_count);
 112                                 last_check = time + 2;
 113                         }
 114
 115                         return 0;
 116                 }
 117         }
 118
 119         if(numspawned < 1 || numkilled < maxspawned)
 120                 return 0; // nothing has spawned yet, or there are still alive monsters
 121
 122         if(roundcnt >= maxrounds)
 123         {
 124                 NextLevel();
 125                 return 1;
 126         }
 127
 128         entity winner = world;
 129         float winning_score = 0;
 130
 131         FOR_EACH_PLAYER(head)
 132         {
 133                 float cs = PlayerScore_Add(head, SP_KILLS, 0);
 134                 if(cs > winning_score)
 135                 {
 136                         winning_score = cs;
 137                         winner = head;
 138                 }
 139         }
 140
 141         FOR_EACH_MONSTER(head)
 142                 monster_remove(head);
 143
 144         if(winner)
 145         {
 146                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
 147                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
 148         }
 149
 150         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 151
 152         return 1;
 153 }
 154
 155 float Invasion_CheckPlayers()
 156 {
 157         return TRUE;
 158 }
 159
 160 void Invasion_RoundStart()
 161 {
 162         entity e;
 163         float numplayers = 0;
 164         FOR_EACH_PLAYER(e)
 165         {
 166                 e.player_blocked = 0;
 167                 ++numplayers;
 168         }
 169
 170         roundcnt += 1;
 171
 172         invasion_monsterskill = roundcnt + (numplayers * 0.3);
 173
 174         maxcurrent = 0;
 175         numspawned = 0;
 176         numkilled = 0;
 177
 178         if(roundcnt > 1)
 179                 maxspawned = rint(autocvar_g_invasion_monster_count * (roundcnt * 0.5));
 180         else
 181                 maxspawned = autocvar_g_invasion_monster_count;
 182 }
 183
 184 MUTATOR_HOOKFUNCTION(invasion_MonsterDies)
 185 {
 186         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 187         {
 188                 numkilled += 1;
 189                 maxcurrent -= 1;
 190
 191                 if(IS_PLAYER(frag_attacker))
 192                         PlayerScore_Add(frag_attacker, SP_KILLS, +1);
 193         }
 194
 195         return FALSE;
 196 }
 197
 198 MUTATOR_HOOKFUNCTION(invasion_MonsterSpawn)
 199 {
 200         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
 201         {
 202                 monster_remove(self);
 203                 return FALSE;
 204         }
 205
 206         if(roundcnt < maxrounds && self.spawnflags & MONSTERFLAG_MINIBOSS)
 207                 self.spawnflags &= ~MONSTERFLAG_MINIBOSS;
 208
 209         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 210         {
 211                 numspawned += 1;
 212                 maxcurrent += 1;
 213         }
 214
 215         self.monster_skill = invasion_monsterskill;
 216
 217         if((get_monsterinfo(self.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
 218                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_INVASION_SUPERMONSTER, M_NAME(self.monsterid));
 219
 220         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
 221
 222         return FALSE;
 223 }
 224
 225 MUTATOR_HOOKFUNCTION(invasion_PlayerThink)
 226 {
 227         monsters_total = maxspawned; // TODO: make sure numspawned never exceeds maxspawned
 228         monsters_killed = numkilled;
 229
 230         return FALSE;
 231 }
 232
 233 MUTATOR_HOOKFUNCTION(invasion_PlayerSpawn)
 234 {
 235         self.bot_attack = FALSE;
 236         return FALSE;
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(invasion_PlayerDamage)
 240 {
 241         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target) && frag_attacker != frag_target)
 242         {
 243                 frag_damage = 0;
 244                 frag_force = '0 0 0';
 245         }
 246
 247         return FALSE;
 248 }
 249
 250 MUTATOR_HOOKFUNCTION(invasion_PlayerCommand)
 251 {
 252         if(MUTATOR_RETURNVALUE) // command was already handled?
 253                 return FALSE;
 254
 255         if(cmd_name == "debuginvasion")
 256         {
 257                 sprint(self, strcat("maxspawned = ", ftos(maxspawned), "\n"));
 258                 sprint(self, strcat("numspawned = ", ftos(numspawned), "\n"));
 259                 sprint(self, strcat("numkilled = ", ftos(numkilled), "\n"));
 260                 sprint(self, strcat("roundcnt = ", ftos(roundcnt), "\n"));
 261                 sprint(self, strcat("monsters_total = ", ftos(monsters_total), "\n"));
 262                 sprint(self, strcat("monsters_killed = ", ftos(monsters_killed), "\n"));
 263                 sprint(self, strcat("invasion_monsterskill = ", ftos(invasion_monsterskill), "\n"));
 264
 265                 return TRUE;
 266         }
 267
 268         return FALSE;
 269 }
 270
 271 MUTATOR_HOOKFUNCTION(invasion_SetStartItems)
 272 {
 273         start_health = 200;
 274         start_armorvalue = 200;
 275
 276         return FALSE;
 277 }
 278
 279 MUTATOR_HOOKFUNCTION(invasion_AccuracyTargetValid)
 280 {
 281         if(frag_target.flags & FL_MONSTER)
 282                 return MUT_ACCADD_INVALID;
 283         return MUT_ACCADD_INDIFFERENT;
 284 }
 285
 286 void invasion_ScoreRules()
 287 {
 288         ScoreRules_basics(0, 0, 0, FALSE);
 289         ScoreInfo_SetLabel_PlayerScore(SP_KILLS, "frags", SFL_SORT_PRIO_PRIMARY);
 290         ScoreRules_basics_end();
 291 }
 292
 293 void invasion_Initialize()
 294 {
 295         independent_players = 1; // to disable extra useless scores
 296
 297         invasion_ScoreRules();
 298
 299         independent_players = 0;
 300
 301         round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
 302         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 303
 304         allowed_to_spawn = TRUE;
 305
 306         roundcnt = 0;
 307 }
 308
 309 MUTATOR_DEFINITION(gamemode_invasion)
 310 {
 311         MUTATOR_HOOK(MonsterDies, invasion_MonsterDies, CBC_ORDER_ANY);
 312         MUTATOR_HOOK(MonsterSpawn, invasion_MonsterSpawn, CBC_ORDER_ANY);
 313         MUTATOR_HOOK(PlayerPreThink, invasion_PlayerThink, CBC_ORDER_ANY);
 314         MUTATOR_HOOK(PlayerSpawn, invasion_PlayerSpawn, CBC_ORDER_ANY);
 315         MUTATOR_HOOK(PlayerDamage_Calculate, invasion_PlayerDamage, CBC_ORDER_ANY);
 316         MUTATOR_HOOK(SV_ParseClientCommand, invasion_PlayerCommand, CBC_ORDER_ANY);
 317         MUTATOR_HOOK(SetStartItems, invasion_SetStartItems, CBC_ORDER_ANY);
 318         MUTATOR_HOOK(AccuracyTargetValid, invasion_AccuracyTargetValid, CBC_ORDER_ANY);
 319
 320         MUTATOR_ONADD
 321         {
 322                 if(time > 1) // game loads at time 1
 323                         error("This is a game type and it cannot be added at runtime.");
 324                 invasion_Initialize();
 325
 326                 cvar_settemp("g_monsters", "1");
 327         }
 328
 329         MUTATOR_ONROLLBACK_OR_REMOVE
 330         {
 331                 // we actually cannot roll back invasion_Initialize here
 332                 // BUT: we don't need to! If this gets called, adding always
 333                 // succeeds.
 334         }
 335
 336         MUTATOR_ONREMOVE
 337         {
 338                 print("This is a game type and it cannot be removed at runtime.");
 339                 return -1;
 340         }
 341
 342         return 0;
 343 }