qcsrc/server/mutators/gamemode_invasion.qc

   1 void invasion_spawnpoint()
   2 {
   3         if not(g_invasion) { remove(self); return; }
   4
   5         self.classname = "invasion_spawnpoint";
   6 }
   7
   8 float invasion_PickMonster(float supermonster_count)
   9 {
  10         if(autocvar_g_invasion_zombies_only)
  11                 return MON_ZOMBIE;
  12
  13         float i;
  14         entity mon;
  15
  16         RandomSelection_Init();
  17
  18         for(i = MON_FIRST; i <= MON_LAST; ++i)
  19         {
  20                 mon = get_monsterinfo(i);
  21                 if((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM) || (mon.spawnflags & MON_FLAG_SUPERMONSTER && supermonster_count >= 1))
  22                         continue; // flying/swimming monsters not yet supported
  23
  24                 RandomSelection_Add(world, i, "", 1, 1);
  25         }
  26
  27         return RandomSelection_chosen_float;
  28 }
  29
  30 entity invasion_PickSpawn()
  31 {
  32         entity e;
  33
  34         RandomSelection_Init();
  35
  36         for(e = world;(e = find(e, classname, "invasion_spawnpoint")); )
  37                 RandomSelection_Add(e, 0, string_null, 1, 1);
  38
  39         return RandomSelection_chosen_ent;
  40 }
  41
  42 void invasion_SpawnChosenMonster(float mon)
  43 {
  44         entity spawn_point, monster;
  45
  46         spawn_point = invasion_PickSpawn();
  47
  48         if(spawn_point == world)
  49         {
  50                 dprint("Warning: couldn't find any invasion_spawnpoint spawnpoints, no monsters will spawn!\n");
  51                 return;
  52         }
  53
  54         monster = spawnmonster("", mon, spawn_point, spawn_point, spawn_point.origin, FALSE, 2);
  55
  56         if(roundcnt >= maxrounds)
  57                 monster.spawnflags |= MONSTERFLAG_MINIBOSS;
  58 }
  59
  60 void invasion_SpawnMonsters(float supermonster_count)
  61 {
  62         float chosen_monster = invasion_PickMonster(supermonster_count);
  63
  64         invasion_SpawnChosenMonster(chosen_monster);
  65 }
  66
  67 float Invasion_CheckWinner()
  68 {
  69         entity head;
  70         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  71         {
  72                 FOR_EACH_MONSTER(head)
  73                 {
  74                         if(head.weaponentity) remove(head.weaponentity);
  75                         if(head.iceblock) remove(head.iceblock);
  76                         remove(head);
  77                 }
  78
  79                 if(roundcnt >= maxrounds)
  80                 {
  81                         NextLevel();
  82                         return 1;
  83                 }
  84
  85                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  86                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  87                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
  88                 return 1;
  89         }
  90
  91         // boss round
  92         if(roundcnt >= maxrounds)
  93         {
  94                 if(numspawned < 1)
  95                 {
  96                         maxspawned = 1;
  97                         invasion_SpawnMonsters(0);
  98                 }
  99         }
 100         else
 101         {
 102                 float total_alive_monsters = 0, supermonster_count = 0;
 103
 104                 FOR_EACH_MONSTER(head) if(head.health > 0)
 105                 {
 106                         if((get_monsterinfo(head.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
 107                                 ++supermonster_count;
 108                         ++total_alive_monsters;
 109                 }
 110
 111                 if((total_alive_monsters + numkilled) < maxspawned && maxcurrent < 10) // 10 at a time should be plenty
 112                 {
 113                         if(time >= last_check)
 114                         {
 115                                 invasion_SpawnMonsters(supermonster_count);
 116                                 last_check = time + 2;
 117                         }
 118
 119                         return 0;
 120                 }
 121         }
 122
 123         if(numspawned < 1 || numkilled < maxspawned)
 124                 return 0; // nothing has spawned yet, or there are still alive monsters
 125
 126         if(roundcnt >= maxrounds)
 127         {
 128                 NextLevel();
 129                 return 1;
 130         }
 131
 132         entity winner = world;
 133         float winning_score = 0;
 134
 135         FOR_EACH_PLAYER(head)
 136         {
 137                 float cs = PlayerScore_Add(head, SP_KILLS, 0);
 138                 if(cs > winning_score)
 139                 {
 140                         winning_score = cs;
 141                         winner = head;
 142                 }
 143         }
 144
 145         if(winner)
 146         {
 147                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
 148                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
 149         }
 150
 151         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 152
 153         return 1;
 154 }
 155
 156 float Invasion_CheckPlayers()
 157 {
 158         return TRUE;
 159 }
 160
 161 void Invasion_RoundStart()
 162 {
 163         entity e;
 164         float numplayers = 0;
 165         FOR_EACH_PLAYER(e)
 166         {
 167                 e.player_blocked = 0;
 168                 ++numplayers;
 169         }
 170
 171         roundcnt += 1;
 172
 173         maxcurrent = 0;
 174         numspawned = 0;
 175         numkilled = 0;
 176
 177         if(roundcnt > 1)
 178                 maxspawned = rint(autocvar_g_invasion_monster_count * (roundcnt * 0.5));
 179         else
 180                 maxspawned = autocvar_g_invasion_monster_count;
 181
 182         monster_skill += 0.1 * numplayers;
 183 }
 184
 185 MUTATOR_HOOKFUNCTION(invasion_MonsterDies)
 186 {
 187         if not(self.monster_respawned)
 188         {
 189                 numkilled += 1;
 190                 maxcurrent -= 1;
 191
 192                 if(IS_PLAYER(frag_attacker))
 193                         PlayerScore_Add(frag_attacker, SP_KILLS, +1);
 194         }
 195
 196         return FALSE;
 197 }
 198
 199 MUTATOR_HOOKFUNCTION(invasion_MonsterSpawn)
 200 {
 201         if not(self.spawnflags & MONSTERFLAG_SPAWNED)
 202         {
 203                 if(self.weaponentity) remove(self.weaponentity);
 204                 if(self.iceblock) remove(self.iceblock);
 205                 remove(self);
 206                 return FALSE;
 207         }
 208
 209         if(roundcnt < maxrounds && self.spawnflags & MONSTERFLAG_MINIBOSS)
 210                 self.spawnflags &= ~MONSTERFLAG_MINIBOSS;
 211
 212         if not(self.monster_respawned)
 213         {
 214                 numspawned += 1;
 215                 maxcurrent += 1;
 216         }
 217
 218         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
 219
 220         return FALSE;
 221 }
 222
 223 MUTATOR_HOOKFUNCTION(invasion_PlayerThink)
 224 {
 225         monsters_total = maxspawned; // TODO: make sure numspawned never exceeds maxspawned
 226         monsters_killed = numkilled;
 227
 228         return FALSE;
 229 }
 230
 231 MUTATOR_HOOKFUNCTION(invasion_PlayerSpawn)
 232 {
 233         self.bot_attack = FALSE;
 234         return FALSE;
 235 }
 236
 237 MUTATOR_HOOKFUNCTION(invasion_PlayerDamage)
 238 {
 239         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target) && frag_attacker != frag_target)
 240         {
 241                 frag_damage = 0;
 242                 frag_force = '0 0 0';
 243         }
 244
 245         return FALSE;
 246 }
 247
 248 MUTATOR_HOOKFUNCTION(invasion_PlayerCommand)
 249 {
 250         if(MUTATOR_RETURNVALUE) // command was already handled?
 251                 return FALSE;
 252
 253         if(cmd_name == "debuginvasion")
 254         {
 255                 sprint(self, strcat("maxspawned = ", ftos(maxspawned), "\n"));
 256                 sprint(self, strcat("numspawned = ", ftos(numspawned), "\n"));
 257                 sprint(self, strcat("numkilled = ", ftos(numkilled), "\n"));
 258                 sprint(self, strcat("roundcnt = ", ftos(roundcnt), "\n"));
 259                 sprint(self, strcat("monsters_total = ", ftos(monsters_total), "\n"));
 260                 sprint(self, strcat("monsters_killed = ", ftos(monsters_killed), "\n"));
 261                 sprint(self, strcat("monster_skill = ", ftos(monster_skill), "\n"));
 262
 263                 return TRUE;
 264         }
 265
 266         return FALSE;
 267 }
 268
 269 MUTATOR_HOOKFUNCTION(invasion_SetStartItems)
 270 {
 271         start_health = 200;
 272         start_armorvalue = 200;
 273
 274         return FALSE;
 275 }
 276
 277 void invasion_ScoreRules()
 278 {
 279         ScoreRules_basics(0, 0, 0, FALSE);
 280         ScoreInfo_SetLabel_PlayerScore(SP_KILLS, "frags", SFL_SORT_PRIO_PRIMARY);
 281         ScoreRules_basics_end();
 282 }
 283
 284 void invasion_Initialize()
 285 {
 286         independent_players = 1; // to disable extra useless scores
 287
 288         invasion_ScoreRules();
 289
 290         independent_players = 0;
 291
 292         round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
 293         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 294
 295         allowed_to_spawn = TRUE;
 296
 297         monster_skill = 0.5;
 298
 299         roundcnt = 0;
 300 }
 301
 302 MUTATOR_DEFINITION(gamemode_invasion)
 303 {
 304         MUTATOR_HOOK(MonsterDies, invasion_MonsterDies, CBC_ORDER_ANY);
 305         MUTATOR_HOOK(MonsterSpawn, invasion_MonsterSpawn, CBC_ORDER_ANY);
 306         MUTATOR_HOOK(PlayerPreThink, invasion_PlayerThink, CBC_ORDER_ANY);
 307         MUTATOR_HOOK(PlayerSpawn, invasion_PlayerSpawn, CBC_ORDER_ANY);
 308         MUTATOR_HOOK(PlayerDamage_Calculate, invasion_PlayerDamage, CBC_ORDER_ANY);
 309         MUTATOR_HOOK(SV_ParseClientCommand, invasion_PlayerCommand, CBC_ORDER_ANY);
 310         MUTATOR_HOOK(SetStartItems, invasion_SetStartItems, CBC_ORDER_ANY);
 311
 312         MUTATOR_ONADD
 313         {
 314                 if(time > 1) // game loads at time 1
 315                         error("This is a game type and it cannot be added at runtime.");
 316                 invasion_Initialize();
 317
 318                 cvar_settemp("g_monsters", "1");
 319         }
 320
 321         MUTATOR_ONROLLBACK_OR_REMOVE
 322         {
 323                 // we actually cannot roll back invasion_Initialize here
 324                 // BUT: we don't need to! If this gets called, adding always
 325                 // succeeds.
 326         }
 327
 328         MUTATOR_ONREMOVE
 329         {
 330                 print("This is a game type and it cannot be removed at runtime.");
 331                 return -1;
 332         }
 333
 334         return 0;
 335 }