qcsrc/server/mutators/gamemode_invasion.qc

   1 #include "gamemode_invasion.qh"
   2 #include "../_all.qh"
   3
   4 #include "gamemode.qh"
   5
   6 #include "../../common/monsters/spawn.qh"
   7 #include "../../common/monsters/sv_monsters.qh"
   8
   9 spawnfunc(invasion_spawnpoint)
  10 {
  11         if(!g_invasion) { remove(self); return; }
  12
  13         self.classname = "invasion_spawnpoint";
  14
  15         if(autocvar_g_invasion_zombies_only) // precache only if it hasn't been already
  16         if(self.monsterid) {
  17                 Monster mon = get_monsterinfo(self.monsterid);
  18                 mon.mr_precache(mon);
  19         }
  20 }
  21
  22 float invasion_PickMonster(float supermonster_count)
  23 {
  24         if(autocvar_g_invasion_zombies_only)
  25                 return MON_ZOMBIE.monsterid;
  26
  27         float i;
  28         entity mon;
  29
  30         RandomSelection_Init();
  31
  32         for(i = MON_FIRST; i <= MON_LAST; ++i)
  33         {
  34                 mon = get_monsterinfo(i);
  35                 if((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM) || ((mon.spawnflags & MON_FLAG_SUPERMONSTER) && supermonster_count >= 1))
  36                         continue; // flying/swimming monsters not yet supported
  37
  38                 RandomSelection_Add(world, i, string_null, 1, 1);
  39         }
  40
  41         return RandomSelection_chosen_float;
  42 }
  43
  44 entity invasion_PickSpawn()
  45 {
  46         entity e;
  47
  48         RandomSelection_Init();
  49
  50         for(e = world;(e = find(e, classname, "invasion_spawnpoint")); )
  51         {
  52                 RandomSelection_Add(e, 0, string_null, 1, ((time >= e.spawnshieldtime) ? 0.2 : 1)); // give recently used spawnpoints a very low rating
  53                 e.spawnshieldtime = time + autocvar_g_invasion_spawnpoint_spawn_delay;
  54         }
  55
  56         return RandomSelection_chosen_ent;
  57 }
  58
  59 void invasion_SpawnChosenMonster(float mon)
  60 {
  61         entity spawn_point, monster;
  62
  63         spawn_point = invasion_PickSpawn();
  64
  65         if(spawn_point == world)
  66         {
  67                 LOG_TRACE("Warning: couldn't find any invasion_spawnpoint spawnpoints, attempting to spawn monsters in random locations\n");
  68                 entity e = spawn();
  69                 setsize(e, (get_monsterinfo(mon)).mins, (get_monsterinfo(mon)).maxs);
  70
  71                 if(MoveToRandomMapLocation(e, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  72                         monster = spawnmonster("", mon, world, world, e.origin, false, false, 2);
  73                 else return;
  74
  75                 e.think = SUB_Remove;
  76                 e.nextthink = time + 0.1;
  77         }
  78         else
  79                 monster = spawnmonster("", ((spawn_point.monsterid) ? spawn_point.monsterid : mon), spawn_point, spawn_point, spawn_point.origin, false, false, 2);
  80
  81         if(spawn_point) monster.target2 = spawn_point.target2;
  82         monster.spawnshieldtime = time;
  83         if(spawn_point && spawn_point.target_range) monster.target_range = spawn_point.target_range;
  84
  85         if(teamplay)
  86         if(spawn_point && spawn_point.team && inv_monsters_perteam[spawn_point.team] > 0)
  87                 monster.team = spawn_point.team;
  88         else
  89         {
  90                 RandomSelection_Init();
  91                 if(inv_monsters_perteam[NUM_TEAM_1] > 0) RandomSelection_Add(world, NUM_TEAM_1, string_null, 1, 1);
  92                 if(inv_monsters_perteam[NUM_TEAM_2] > 0) RandomSelection_Add(world, NUM_TEAM_2, string_null, 1, 1);
  93                 if(invasion_teams >= 3) if(inv_monsters_perteam[NUM_TEAM_3] > 0) { RandomSelection_Add(world, NUM_TEAM_3, string_null, 1, 1); }
  94                 if(invasion_teams >= 4) if(inv_monsters_perteam[NUM_TEAM_4] > 0) { RandomSelection_Add(world, NUM_TEAM_4, string_null, 1, 1); }
  95
  96                 monster.team = RandomSelection_chosen_float;
  97         }
  98
  99         if(teamplay)
 100         {
 101                 monster_setupcolors(monster);
 102
 103                 if(monster.sprite)
 104                 {
 105                         WaypointSprite_UpdateTeamRadar(monster.sprite, RADARICON_DANGER, ((monster.team) ? Team_ColorRGB(monster.team) : '1 0 0'));
 106
 107                         monster.sprite.team = 0;
 108                         monster.sprite.SendFlags |= 1;
 109                 }
 110         }
 111
 112         monster.monster_attack = false; // it's the player's job to kill all the monsters
 113
 114         if(inv_roundcnt >= inv_maxrounds)
 115                 monster.spawnflags |= MONSTERFLAG_MINIBOSS; // last round spawns minibosses
 116 }
 117
 118 void invasion_SpawnMonsters(float supermonster_count)
 119 {
 120         float chosen_monster = invasion_PickMonster(supermonster_count);
 121
 122         invasion_SpawnChosenMonster(chosen_monster);
 123 }
 124
 125 float Invasion_CheckWinner()
 126 {
 127         entity head;
 128         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 129         {
 130                 FOR_EACH_MONSTER(head)
 131                         Monster_Remove(head);
 132
 133                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
 134                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
 135                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 136                 return 1;
 137         }
 138
 139         float total_alive_monsters = 0, supermonster_count = 0, red_alive = 0, blue_alive = 0, yellow_alive = 0, pink_alive = 0;
 140
 141         FOR_EACH_MONSTER(head) if(head.health > 0)
 142         {
 143                 if((get_monsterinfo(head.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
 144                         ++supermonster_count;
 145                 ++total_alive_monsters;
 146
 147                 if(teamplay)
 148                 switch(head.team)
 149                 {
 150                         case NUM_TEAM_1: ++red_alive; break;
 151                         case NUM_TEAM_2: ++blue_alive; break;
 152                         case NUM_TEAM_3: ++yellow_alive; break;
 153                         case NUM_TEAM_4: ++pink_alive; break;
 154                 }
 155         }
 156
 157         if((total_alive_monsters + inv_numkilled) < inv_maxspawned && inv_maxcurrent < inv_maxspawned)
 158         {
 159                 if(time >= inv_lastcheck)
 160                 {
 161                         invasion_SpawnMonsters(supermonster_count);
 162                         inv_lastcheck = time + autocvar_g_invasion_spawn_delay;
 163                 }
 164
 165                 return 0;
 166         }
 167
 168         if(inv_numspawned < 1)
 169                 return 0; // nothing has spawned yet
 170
 171         if(teamplay)
 172         {
 173                 if(((red_alive > 0) + (blue_alive > 0) + (yellow_alive > 0) + (pink_alive > 0)) > 1)
 174                         return 0;
 175         }
 176         else if(inv_numkilled < inv_maxspawned)
 177                 return 0;
 178
 179         entity winner = world;
 180         float winning_score = 0, winner_team = 0;
 181
 182
 183         if(teamplay)
 184         {
 185                 if(red_alive > 0) { winner_team = NUM_TEAM_1; }
 186                 if(blue_alive > 0)
 187                 if(winner_team) { winner_team = 0; }
 188                 else { winner_team = NUM_TEAM_2; }
 189                 if(yellow_alive > 0)
 190                 if(winner_team) { winner_team = 0; }
 191                 else { winner_team = NUM_TEAM_3; }
 192                 if(pink_alive > 0)
 193                 if(winner_team) { winner_team = 0; }
 194                 else { winner_team = NUM_TEAM_4; }
 195         }
 196         else
 197         FOR_EACH_PLAYER(head)
 198         {
 199                 float cs = PlayerScore_Add(head, SP_KILLS, 0);
 200                 if(cs > winning_score)
 201                 {
 202                         winning_score = cs;
 203                         winner = head;
 204                 }
 205         }
 206
 207         FOR_EACH_MONSTER(head)
 208                 Monster_Remove(head);
 209
 210         if(teamplay)
 211         {
 212                 if(winner_team)
 213                 {
 214                         Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM_4(winner_team, CENTER_ROUND_TEAM_WIN_));
 215                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(winner_team, INFO_ROUND_TEAM_WIN_));
 216                 }
 217         }
 218         else if(winner)
 219         {
 220                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
 221                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
 222         }
 223
 224         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 225
 226         return 1;
 227 }
 228
 229 float Invasion_CheckPlayers()
 230 {
 231         return true;
 232 }
 233
 234 void Invasion_RoundStart()
 235 {
 236         entity e;
 237         float numplayers = 0;
 238         FOR_EACH_PLAYER(e)
 239         {
 240                 e.player_blocked = 0;
 241                 ++numplayers;
 242         }
 243
 244         if(inv_roundcnt < inv_maxrounds)
 245                 inv_roundcnt += 1; // a limiter to stop crazy counts
 246
 247         inv_monsterskill = inv_roundcnt + max(1, numplayers * 0.3);
 248
 249         inv_maxcurrent = 0;
 250         inv_numspawned = 0;
 251         inv_numkilled = 0;
 252
 253         inv_maxspawned = rint(max(autocvar_g_invasion_monster_count, autocvar_g_invasion_monster_count * (inv_roundcnt * 0.5)));
 254
 255         if(teamplay)
 256         {
 257                 DistributeEvenly_Init(inv_maxspawned, invasion_teams);
 258                 inv_monsters_perteam[NUM_TEAM_1] = DistributeEvenly_Get(1);
 259                 inv_monsters_perteam[NUM_TEAM_2] = DistributeEvenly_Get(1);
 260                 if(invasion_teams >= 3) inv_monsters_perteam[NUM_TEAM_3] = DistributeEvenly_Get(1);
 261                 if(invasion_teams >= 4) inv_monsters_perteam[NUM_TEAM_4] = DistributeEvenly_Get(1);
 262         }
 263 }
 264
 265 MUTATOR_HOOKFUNCTION(invasion_MonsterDies)
 266 {SELFPARAM();
 267         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 268         {
 269                 inv_numkilled += 1;
 270                 inv_maxcurrent -= 1;
 271                 if(teamplay) { inv_monsters_perteam[self.team] -= 1; }
 272
 273                 if(IS_PLAYER(frag_attacker))
 274                 if(SAME_TEAM(frag_attacker, self)) // in non-teamplay modes, same team = same player, so this works
 275                         PlayerScore_Add(frag_attacker, SP_KILLS, -1);
 276                 else
 277                 {
 278                         PlayerScore_Add(frag_attacker, SP_KILLS, +1);
 279                         if(teamplay)
 280                                 TeamScore_AddToTeam(frag_attacker.team, ST_INV_KILLS, +1);
 281                 }
 282         }
 283
 284         return false;
 285 }
 286
 287 MUTATOR_HOOKFUNCTION(invasion_MonsterSpawn)
 288 {SELFPARAM();
 289         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
 290                 return true;
 291
 292         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 293         {
 294                 inv_numspawned += 1;
 295                 inv_maxcurrent += 1;
 296         }
 297
 298         self.monster_skill = inv_monsterskill;
 299
 300         if((get_monsterinfo(self.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
 301                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_INVASION_SUPERMONSTER, self.monster_name);
 302
 303         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
 304
 305         return false;
 306 }
 307
 308 MUTATOR_HOOKFUNCTION(invasion_OnEntityPreSpawn)
 309 {SELFPARAM();
 310         if(startsWith(self.classname, "monster_"))
 311         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
 312                 return true;
 313
 314         return false;
 315 }
 316
 317 MUTATOR_HOOKFUNCTION(invasion_StartFrame)
 318 {
 319         monsters_total = inv_maxspawned; // TODO: make sure numspawned never exceeds maxspawned
 320         monsters_killed = inv_numkilled;
 321
 322         return false;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(invasion_PlayerRegen)
 326 {
 327         // no regeneration in invasion
 328         return true;
 329 }
 330
 331 MUTATOR_HOOKFUNCTION(invasion_PlayerSpawn)
 332 {SELFPARAM();
 333         self.bot_attack = false;
 334         return false;
 335 }
 336
 337 MUTATOR_HOOKFUNCTION(invasion_PlayerDamage)
 338 {
 339         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target) && frag_attacker != frag_target)
 340         {
 341                 frag_damage = 0;
 342                 frag_force = '0 0 0';
 343         }
 344
 345         return false;
 346 }
 347
 348 MUTATOR_HOOKFUNCTION(invasion_PlayerCommand)
 349 {SELFPARAM();
 350         if(MUTATOR_RETURNVALUE) // command was already handled?
 351                 return false;
 352
 353         if(cmd_name == "debuginvasion")
 354         {
 355                 sprint(self, strcat("inv_maxspawned = ", ftos(inv_maxspawned), "\n"));
 356                 sprint(self, strcat("inv_numspawned = ", ftos(inv_numspawned), "\n"));
 357                 sprint(self, strcat("inv_numkilled = ", ftos(inv_numkilled), "\n"));
 358                 sprint(self, strcat("inv_roundcnt = ", ftos(inv_roundcnt), "\n"));
 359                 sprint(self, strcat("monsters_total = ", ftos(monsters_total), "\n"));
 360                 sprint(self, strcat("monsters_killed = ", ftos(monsters_killed), "\n"));
 361                 sprint(self, strcat("inv_monsterskill = ", ftos(inv_monsterskill), "\n"));
 362
 363                 return true;
 364         }
 365
 366         return false;
 367 }
 368
 369 MUTATOR_HOOKFUNCTION(invasion_BotShouldAttack)
 370 {
 371         if(!IS_MONSTER(checkentity))
 372                 return true;
 373
 374         return false;
 375 }
 376
 377 MUTATOR_HOOKFUNCTION(invasion_SetStartItems)
 378 {
 379         start_health = 200;
 380         start_armorvalue = 200;
 381
 382         return false;
 383 }
 384
 385 MUTATOR_HOOKFUNCTION(invasion_AccuracyTargetValid)
 386 {
 387         if(IS_MONSTER(frag_target))
 388                 return MUT_ACCADD_INVALID;
 389         return MUT_ACCADD_INDIFFERENT;
 390 }
 391
 392 MUTATOR_HOOKFUNCTION(invasion_AllowMobSpawning)
 393 {
 394         // monster spawning disabled during an invasion
 395         return true;
 396 }
 397
 398 MUTATOR_HOOKFUNCTION(invasion_GetTeamCount)
 399 {
 400         ret_float = invasion_teams;
 401         return false;
 402 }
 403
 404 void invasion_ScoreRules(float inv_teams)
 405 {
 406         if(inv_teams) { CheckAllowedTeams(world); }
 407         ScoreRules_basics(inv_teams, 0, 0, false);
 408         if(inv_teams) ScoreInfo_SetLabel_TeamScore(ST_INV_KILLS, "frags", SFL_SORT_PRIO_PRIMARY);
 409         ScoreInfo_SetLabel_PlayerScore(SP_KILLS, "frags", ((inv_teams) ? SFL_SORT_PRIO_SECONDARY : SFL_SORT_PRIO_PRIMARY));
 410         ScoreRules_basics_end();
 411 }
 412
 413 void invasion_DelayedInit() // Do this check with a delay so we can wait for teams to be set up.
 414 {
 415         if(autocvar_g_invasion_teams)
 416                 invasion_teams = bound(2, autocvar_g_invasion_teams, 4);
 417         else
 418                 invasion_teams = 0;
 419
 420         independent_players = 1; // to disable extra useless scores
 421
 422         invasion_ScoreRules(invasion_teams);
 423
 424         independent_players = 0;
 425
 426         round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
 427         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 428
 429         inv_roundcnt = 0;
 430         inv_maxrounds = 15; // 15?
 431 }
 432
 433 void invasion_Initialize()
 434 {
 435         if(autocvar_g_invasion_zombies_only) {
 436                 Monster mon = MON_ZOMBIE;
 437                 mon.mr_precache(mon);
 438         } else
 439         {
 440                 float i;
 441                 entity mon;
 442                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 443                 {
 444                         mon = get_monsterinfo(i);
 445                         if((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM))
 446                                 continue; // flying/swimming monsters not yet supported
 447
 448                         mon.mr_precache(mon);
 449                 }
 450         }
 451
 452         InitializeEntity(world, invasion_DelayedInit, INITPRIO_GAMETYPE);
 453 }
 454
 455 MUTATOR_DEFINITION(gamemode_invasion)
 456 {
 457         MUTATOR_HOOK(MonsterDies, invasion_MonsterDies, CBC_ORDER_ANY);
 458         MUTATOR_HOOK(MonsterSpawn, invasion_MonsterSpawn, CBC_ORDER_ANY);
 459         MUTATOR_HOOK(OnEntityPreSpawn, invasion_OnEntityPreSpawn, CBC_ORDER_ANY);
 460         MUTATOR_HOOK(SV_StartFrame, invasion_StartFrame, CBC_ORDER_ANY);
 461         MUTATOR_HOOK(PlayerRegen, invasion_PlayerRegen, CBC_ORDER_ANY);
 462         MUTATOR_HOOK(PlayerSpawn, invasion_PlayerSpawn, CBC_ORDER_ANY);
 463         MUTATOR_HOOK(PlayerDamage_Calculate, invasion_PlayerDamage, CBC_ORDER_ANY);
 464         MUTATOR_HOOK(SV_ParseClientCommand, invasion_PlayerCommand, CBC_ORDER_ANY);
 465         MUTATOR_HOOK(BotShouldAttack, invasion_BotShouldAttack, CBC_ORDER_ANY);
 466         MUTATOR_HOOK(SetStartItems, invasion_SetStartItems, CBC_ORDER_ANY);
 467         MUTATOR_HOOK(AccuracyTargetValid, invasion_AccuracyTargetValid, CBC_ORDER_ANY);
 468         MUTATOR_HOOK(AllowMobSpawning, invasion_AllowMobSpawning, CBC_ORDER_ANY);
 469         MUTATOR_HOOK(GetTeamCount, invasion_GetTeamCount, CBC_ORDER_ANY);
 470
 471         MUTATOR_ONADD
 472         {
 473                 if(time > 1) // game loads at time 1
 474                         error("This is a game type and it cannot be added at runtime.");
 475                 invasion_Initialize();
 476
 477                 cvar_settemp("g_monsters", "1");
 478         }
 479
 480         MUTATOR_ONROLLBACK_OR_REMOVE
 481         {
 482                 // we actually cannot roll back invasion_Initialize here
 483                 // BUT: we don't need to! If this gets called, adding always
 484                 // succeeds.
 485         }
 486
 487         MUTATOR_ONREMOVE
 488         {
 489                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
 490                 return -1;
 491         }
 492
 493         return 0;
 494 }