qcsrc/server/mutators/gamemode_keepaway.qc

   1 // ===========================================================
   2 //  Keepaway game mode coding, written by Samual and Diabolik
   3 //  Last updated: September, 2012
   4 // ===========================================================
   5
   6 float ka_ballcarrier_waypointsprite_visible_for_player(entity e) // runs on waypoints which are attached to ballcarriers, updates once per frame
   7 {
   8         if(e.ballcarried)
   9                 if(IS_SPEC(other))
  10                         return FALSE; // we don't want spectators of the ballcarrier to see the attached waypoint on the top of their screen
  11
  12         // TODO: Make the ballcarrier lack a waypointsprite whenever they have the invisibility powerup
  13
  14         return TRUE;
  15 }
  16
  17 void ka_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  18 {
  19         if(autocvar_sv_eventlog)
  20                 GameLogEcho(strcat(":ka:", mode, ((actor != world) ? (strcat(":", ftos(actor.playerid))) : "")));
  21 }
  22
  23 void ka_RespawnBall() // runs whenever the ball needs to be relocated
  24 {
  25         if(gameover) { return; }
  26         vector oldballorigin = self.origin;
  27
  28         if(!MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  29         {
  30                 entity spot = SelectSpawnPoint(TRUE);
  31                 setorigin(self, spot.origin);
  32                 self.angles = spot.angles;
  33         }
  34
  35         makevectors(self.angles);
  36         self.movetype = MOVETYPE_BOUNCE;
  37         self.velocity = '0 0 200';
  38         self.angles = '0 0 0';
  39         self.effects = autocvar_g_keepawayball_effects;
  40         self.think = ka_RespawnBall;
  41         self.nextthink = time + autocvar_g_keepawayball_respawntime;
  42
  43         pointparticles(particleeffectnum("electro_combo"), oldballorigin, '0 0 0', 1);
  44         pointparticles(particleeffectnum("electro_combo"), self.origin, '0 0 0', 1);
  45
  46         WaypointSprite_Spawn("ka-ball", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attachedforcarrier, FALSE, RADARICON_FLAGCARRIER, '0 1 1');
  47         WaypointSprite_Ping(self.waypointsprite_attachedforcarrier);
  48
  49         sound(self, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
  50 }
  51
  52 void ka_TimeScoring()
  53 {
  54         if(self.owner.ballcarried)
  55         { // add points for holding the ball after a certain amount of time
  56                 if(autocvar_g_keepaway_score_timepoints)
  57                         PlayerScore_Add(self.owner, SP_SCORE, autocvar_g_keepaway_score_timepoints);
  58
  59                 PlayerScore_Add(self.owner, SP_KEEPAWAY_BCTIME, (autocvar_g_keepaway_score_timeinterval / 1)); // interval is divided by 1 so that time always shows "seconds"
  60                 self.nextthink = time + autocvar_g_keepaway_score_timeinterval;
  61         }
  62 }
  63
  64 void ka_TouchEvent() // runs any time that the ball comes in contact with something
  65 {
  66         if(gameover) { return; }
  67         if(!self) { return; }
  68         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  69         { // The ball fell off the map, respawn it since players can't get to it
  70                 ka_RespawnBall();
  71                 return;
  72         }
  73         if(other.deadflag != DEAD_NO) { return; }
  74         if (!IS_PLAYER(other))
  75         {  // The ball just touched an object, most likely the world
  76                 pointparticles(particleeffectnum("kaball_sparks"), self.origin, '0 0 0', 1);
  77                 sound(self, CH_TRIGGER, "keepaway/touch.wav", VOL_BASE, ATTEN_NORM);
  78                 return;
  79         }
  80         else if(self.wait > time) { return; }
  81
  82         // attach the ball to the player
  83         self.owner = other;
  84         other.ballcarried = self;
  85         setattachment(self, other, "");
  86         setorigin(self, '0 0 0');
  87
  88         // make the ball invisible/unable to do anything/set up time scoring
  89         self.velocity = '0 0 0';
  90         self.movetype = MOVETYPE_NONE;
  91         self.effects |= EF_NODRAW;
  92         self.touch = func_null;
  93         self.think = ka_TimeScoring;
  94         self.nextthink = time + autocvar_g_keepaway_score_timeinterval;
  95         self.takedamage = DAMAGE_NO;
  96
  97         // apply effects to player
  98         other.glow_color = autocvar_g_keepawayball_trail_color;
  99         other.glow_trail = TRUE;
 100         other.effects |= autocvar_g_keepaway_ballcarrier_effects;
 101
 102         // messages and sounds
 103         ka_EventLog("pickup", other);
 104         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_KEEPAWAY_PICKUP, other.netname);
 105         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_CENTER, CENTER_KEEPAWAY_PICKUP, other.netname);
 106         Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_KEEPAWAY_PICKUP_SELF);
 107         sound(self.owner, CH_TRIGGER, "keepaway/pickedup.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 108
 109         // scoring
 110         PlayerScore_Add(other, SP_KEEPAWAY_PICKUPS, 1);
 111
 112         // waypoints
 113         WaypointSprite_AttachCarrier("ka-ballcarrier", other, RADARICON_FLAGCARRIER, '1 0 0');
 114         other.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = ka_ballcarrier_waypointsprite_visible_for_player;
 115         WaypointSprite_UpdateRule(other.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 116         WaypointSprite_Ping(other.waypointsprite_attachedforcarrier);
 117         WaypointSprite_Kill(self.waypointsprite_attachedforcarrier);
 118 }
 119
 120 void ka_DropEvent(entity plyr) // runs any time that a player is supposed to lose the ball
 121 {
 122         entity ball;
 123         ball = plyr.ballcarried;
 124
 125         if(!ball) { return; }
 126
 127         // reset the ball
 128         setattachment(ball, world, "");
 129         ball.movetype = MOVETYPE_BOUNCE;
 130         ball.wait = time + 1;
 131         ball.touch = ka_TouchEvent;
 132         ball.think = ka_RespawnBall;
 133         ball.nextthink = time + autocvar_g_keepawayball_respawntime;
 134         ball.takedamage = DAMAGE_YES;
 135         ball.effects &= ~EF_NODRAW;
 136         setorigin(ball, plyr.origin + '0 0 10');
 137         ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
 138         ball.owner.ballcarried = world; // I hope nothing checks to see if the world has the ball in the rest of my code :P
 139         ball.owner = world;
 140
 141         // reset the player effects
 142         plyr.glow_trail = FALSE;
 143         plyr.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 144
 145         // messages and sounds
 146         ka_EventLog("dropped", plyr);
 147         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_KEEPAWAY_DROPPED, plyr.netname);
 148         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEEPAWAY_DROPPED, plyr.netname);
 149         sound(other, CH_TRIGGER, "keepaway/dropped.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 150
 151         // scoring
 152         // PlayerScore_Add(plyr, SP_KEEPAWAY_DROPS, 1); Not anymore, this is 100% the same as pickups and is useless.
 153
 154         // waypoints
 155         WaypointSprite_Spawn("ka-ball", 0, 0, ball, '0 0 64', world, ball.team, ball, waypointsprite_attachedforcarrier, FALSE, RADARICON_FLAGCARRIER, '0 1 1');
 156         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 157         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 158         WaypointSprite_Kill(plyr.waypointsprite_attachedforcarrier);
 159 }
 160
 161 void ka_Reset() // used to clear the ballcarrier whenever the match switches from warmup to normal
 162 {
 163         if((self.owner) && (IS_PLAYER(self.owner)))
 164                 ka_DropEvent(self.owner);
 165
 166         ka_RespawnBall();
 167 }
 168
 169
 170 // ================
 171 // Bot player logic
 172 // ================
 173
 174 void havocbot_goalrating_ball(float ratingscale, vector org)
 175 {
 176         float t;
 177         entity ball_owner;
 178         ball_owner = ka_ball.owner;
 179
 180         if (ball_owner == self)
 181                 return;
 182
 183         // If ball is carried by player then hunt them down.
 184         if (ball_owner)
 185         {
 186                 t = (self.health + self.armorvalue) / (ball_owner.health + ball_owner.armorvalue);
 187                 navigation_routerating(ball_owner, t * ratingscale, 2000);
 188         }
 189
 190         // Ball has been dropped so collect.
 191         navigation_routerating(ka_ball, ratingscale, 2000);
 192 }
 193
 194 void havocbot_role_ka_carrier()
 195 {
 196         if (self.deadflag != DEAD_NO)
 197                 return;
 198
 199         if (time > self.bot_strategytime)
 200         {
 201                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 202
 203                 navigation_goalrating_start();
 204                 havocbot_goalrating_items(10000, self.origin, 10000);
 205                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 206                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 207                 navigation_goalrating_end();
 208         }
 209
 210         if (!self.ballcarried)
 211         {
 212                 self.havocbot_role = havocbot_role_ka_collector;
 213                 self.bot_strategytime = 0;
 214         }
 215 }
 216
 217 void havocbot_role_ka_collector()
 218 {
 219         if (self.deadflag != DEAD_NO)
 220                 return;
 221
 222         if (time > self.bot_strategytime)
 223         {
 224                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 225
 226                 navigation_goalrating_start();
 227                 havocbot_goalrating_items(10000, self.origin, 10000);
 228                 havocbot_goalrating_enemyplayers(1000, self.origin, 10000);
 229                 havocbot_goalrating_ball(20000, self.origin);
 230                 navigation_goalrating_end();
 231         }
 232
 233         if (self.ballcarried)
 234         {
 235                 self.havocbot_role = havocbot_role_ka_carrier;
 236                 self.bot_strategytime = 0;
 237         }
 238 }
 239
 240
 241 // ==============
 242 // Hook Functions
 243 // ==============
 244
 245 MUTATOR_HOOKFUNCTION(ka_Scoring)
 246 {
 247         if((frag_attacker != frag_target) && (IS_PLAYER(frag_attacker)))
 248         {
 249                 if(frag_target.ballcarried) { // add to amount of times killing carrier
 250                         PlayerScore_Add(frag_attacker, SP_KEEPAWAY_CARRIERKILLS, 1);
 251                         if(autocvar_g_keepaway_score_bckill) // add bckills to the score
 252                                 PlayerScore_Add(frag_attacker, SP_SCORE, autocvar_g_keepaway_score_bckill);
 253                 }
 254                 else if(!frag_attacker.ballcarried)
 255                         if(autocvar_g_keepaway_noncarrier_warn)
 256                                 Send_Notification(NOTIF_ONE_ONLY, frag_attacker, MSG_CENTER, CENTER_KEEPAWAY_WARN);
 257
 258                 if(frag_attacker.ballcarried) // add to amount of kills while ballcarrier
 259                         PlayerScore_Add(frag_attacker, SP_SCORE, autocvar_g_keepaway_score_killac);
 260         }
 261
 262         if(self.ballcarried) { ka_DropEvent(self); } // a player with the ball has died, drop it
 263         return 0;
 264 }
 265
 266 MUTATOR_HOOKFUNCTION(ka_GiveFragsForKill)
 267 {
 268         frag_score = 0; // no frags counted in keepaway
 269         return 1; // you deceptive little bugger ;3 This needs to be true in order for this function to even count.
 270 }
 271
 272 MUTATOR_HOOKFUNCTION(ka_PlayerPreThink)
 273 {
 274         // clear the item used for the ball in keepaway
 275         self.items &= ~IT_KEY1;
 276
 277         // if the player has the ball, make sure they have the item for it (Used for HUD primarily)
 278         if(self.ballcarried)
 279                 self.items |= IT_KEY1;
 280
 281         return 0;
 282 }
 283
 284 MUTATOR_HOOKFUNCTION(ka_PlayerUseKey)
 285 {
 286         if(MUTATOR_RETURNVALUE == 0)
 287         if(self.ballcarried)
 288         {
 289                 ka_DropEvent(self);
 290                 return 1;
 291         }
 292         return 0;
 293 }
 294
 295 MUTATOR_HOOKFUNCTION(ka_PlayerDamage) // for changing damage and force values that are applied to players in g_damage.qc
 296 {
 297         if(frag_attacker.ballcarried) // if the attacker is a ballcarrier
 298         {
 299                 if(frag_target == frag_attacker) // damage done to yourself
 300                 {
 301                         frag_damage *= autocvar_g_keepaway_ballcarrier_selfdamage;
 302                         frag_force *= autocvar_g_keepaway_ballcarrier_selfforce;
 303                 }
 304                 else // damage done to noncarriers
 305                 {
 306                         frag_damage *= autocvar_g_keepaway_ballcarrier_damage;
 307                         frag_force *= autocvar_g_keepaway_ballcarrier_force;
 308                 }
 309         }
 310         else if (!frag_target.ballcarried) // if the target is a noncarrier
 311         {
 312                 if(frag_target == frag_attacker) // damage done to yourself
 313                 {
 314                         frag_damage *= autocvar_g_keepaway_noncarrier_selfdamage;
 315                         frag_force *= autocvar_g_keepaway_noncarrier_selfforce;
 316                 }
 317                 else // damage done to other noncarriers
 318                 {
 319                         frag_damage *= autocvar_g_keepaway_noncarrier_damage;
 320                         frag_force *= autocvar_g_keepaway_noncarrier_force;
 321                 }
 322         }
 323         return 0;
 324 }
 325
 326 MUTATOR_HOOKFUNCTION(ka_RemovePlayer)
 327 {
 328         if(self.ballcarried) { ka_DropEvent(self); } // a player with the ball has left the match, drop it
 329         return 0;
 330 }
 331
 332 MUTATOR_HOOKFUNCTION(ka_PlayerPowerups)
 333 {
 334         // In the future this hook is supposed to allow me to do some extra stuff with waypointsprites and invisibility powerup
 335         // So bare with me until I can fix a certain bug with ka_ballcarrier_waypointsprite_visible_for_player()
 336
 337         self.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 338
 339         if(self.ballcarried)
 340                 self.effects |= autocvar_g_keepaway_ballcarrier_effects;
 341
 342         return 0;
 343 }
 344
 345 MUTATOR_HOOKFUNCTION(ka_BotRoles)
 346 {
 347         if (self.ballcarried)
 348                 self.havocbot_role = havocbot_role_ka_carrier;
 349         else
 350                 self.havocbot_role = havocbot_role_ka_collector;
 351         return TRUE;
 352 }
 353
 354
 355 // ==============
 356 // Initialization
 357 // ==============
 358
 359 void ka_SpawnBall() // loads various values for the ball, runs only once at start of match
 360 {
 361         if(!g_keepaway) { return; }
 362
 363         entity e;
 364         e = spawn();
 365         e.model = "models/orbs/orbblue.md3";
 366         precache_model(e.model);
 367         setmodel(e, e.model);
 368         setsize(e, '-16 -16 -20', '16 16 20'); // 20 20 20 was too big, player is only 16 16 24... gotta cheat with the Z (20) axis so that the particle isn't cut off
 369         e.classname = "keepawayball";
 370         e.damageforcescale = autocvar_g_keepawayball_damageforcescale;
 371         e.takedamage = DAMAGE_YES;
 372         e.solid = SOLID_TRIGGER;
 373         e.movetype = MOVETYPE_BOUNCE;
 374         e.glow_color = autocvar_g_keepawayball_trail_color;
 375         e.glow_trail = TRUE;
 376         e.flags = FL_ITEM;
 377         e.reset = ka_Reset;
 378         e.touch = ka_TouchEvent;
 379         e.owner = world;
 380         ka_ball = e;
 381
 382         InitializeEntity(e, ka_RespawnBall, INITPRIO_SETLOCATION); // is this the right priority? Neh, I have no idea.. Well-- it works! So.
 383 }
 384
 385 void ka_ScoreRules()
 386 {
 387         ScoreRules_basics(0, SFL_SORT_PRIO_PRIMARY, 0, TRUE); // SFL_SORT_PRIO_PRIMARY
 388         ScoreInfo_SetLabel_PlayerScore(SP_KEEPAWAY_PICKUPS,                     "pickups",              0);
 389         ScoreInfo_SetLabel_PlayerScore(SP_KEEPAWAY_CARRIERKILLS,        "bckills",              0);
 390         ScoreInfo_SetLabel_PlayerScore(SP_KEEPAWAY_BCTIME,                      "bctime",               SFL_SORT_PRIO_SECONDARY);
 391         ScoreRules_basics_end();
 392 }
 393
 394 void ka_Initialize() // run at the start of a match, initiates game mode
 395 {
 396         if(!g_keepaway)
 397                 return;
 398
 399         precache_sound("keepaway/pickedup.wav");
 400         precache_sound("keepaway/dropped.wav");
 401         precache_sound("keepaway/respawn.wav");
 402         precache_sound("keepaway/touch.wav");
 403
 404         ka_ScoreRules();
 405         ka_SpawnBall();
 406 }
 407
 408
 409 MUTATOR_DEFINITION(gamemode_keepaway)
 410 {
 411         MUTATOR_HOOK(MakePlayerObserver, ka_RemovePlayer, CBC_ORDER_ANY);
 412         MUTATOR_HOOK(ClientDisconnect, ka_RemovePlayer, CBC_ORDER_ANY);
 413         MUTATOR_HOOK(PlayerDies, ka_Scoring, CBC_ORDER_ANY);
 414         MUTATOR_HOOK(GiveFragsForKill, ka_GiveFragsForKill, CBC_ORDER_ANY);
 415         MUTATOR_HOOK(PlayerPreThink, ka_PlayerPreThink, CBC_ORDER_ANY);
 416         MUTATOR_HOOK(PlayerDamage_Calculate, ka_PlayerDamage, CBC_ORDER_ANY);
 417         MUTATOR_HOOK(PlayerPowerups, ka_PlayerPowerups, CBC_ORDER_ANY);
 418         MUTATOR_HOOK(PlayerUseKey, ka_PlayerUseKey, CBC_ORDER_ANY);
 419         MUTATOR_HOOK(HavocBot_ChooseRole, ka_BotRoles, CBC_ORDER_ANY);
 420
 421         MUTATOR_ONADD
 422         {
 423                 if(time > 1) // game loads at time 1
 424                         error("This is a game type and it cannot be added at runtime.");
 425                 ka_Initialize();
 426         }
 427
 428         MUTATOR_ONROLLBACK_OR_REMOVE
 429         {
 430                 // we actually cannot roll back ka_Initialize here
 431                 // BUT: we don't need to! If this gets called, adding always
 432                 // succeeds.
 433         }
 434
 435         MUTATOR_ONREMOVE
 436         {
 437                 print("This is a game type and it cannot be removed at runtime.");
 438                 return -1;
 439         }
 440
 441         return 0;
 442 }