qcsrc/server/mutators/gamemode_keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5
   6 #ifdef KH_PLAYER_USE_ATTACHMENT
   7 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   8 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
   9 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  10 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  11 string KH_PLAYER_ATTACHMENT_BONE = "";
  12 #else
  13 float KH_KEY_ZSHIFT = 22;
  14 float KH_KEY_XYDIST = 24;
  15 float KH_KEY_XYSPEED = 45;
  16 #endif
  17 float KH_KEY_WP_ZSHIFT = 20;
  18
  19 vector KH_KEY_MIN = '-10 -10 -46';
  20 vector KH_KEY_MAX = '10 10 3';
  21 float KH_KEY_BRIGHTNESS = 2;
  22
  23 string kh_Controller_Waitmsg;
  24 float kh_no_radar_circles;
  25
  26 // kh_state
  27 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  28 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  29 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  30 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  31 .float kh_state;
  32 .float siren_time;  //  time delay the siren
  33 //.float stuff_time;  //  time delay to stuffcmd a cvar
  34
  35 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  36 //test[0] = status of dropped keys, test[1 - 16] = player #
  37 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  38 //for(i = 0; i < maxplayers; ++i)
  39 //      test[i] = "0";
  40
  41 float kh_Team_ByID(float t)
  42 {
  43         if(t == 0) return COLOR_TEAM1;
  44         if(t == 1) return COLOR_TEAM2;
  45         if(t == 2) return COLOR_TEAM3;
  46         if(t == 3) return COLOR_TEAM4;
  47         return 0;
  48 }
  49
  50 entity kh_worldkeylist;
  51 .entity kh_worldkeynext;
  52 entity kh_controller;
  53 float kh_tracking_enabled;
  54 float kh_teams;
  55 float kh_interferemsg_time, kh_interferemsg_team;
  56 .entity kh_next, kh_prev; // linked list
  57 .float kh_droptime;
  58 .float kh_dropperteam;
  59 .entity kh_previous_owner;
  60 .float kh_previous_owner_playerid;
  61 .float kh_cp_duration;
  62
  63 string kh_sound_capture = "kh/capture.wav";
  64 string kh_sound_destroy = "kh/destroy.wav";
  65 string kh_sound_drop = "kh/drop.wav";
  66 string kh_sound_collect = "kh/collect.wav";
  67 string kh_sound_alarm = "kh/alarm.wav";  // the new siren/alarm
  68
  69 float kh_key_dropped, kh_key_carried;
  70
  71 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
  72 {
  73         if(e.classname != "player" || self.team != e.team)
  74                 if(!kh_tracking_enabled)
  75                         return FALSE;
  76
  77         return TRUE;
  78 }
  79
  80 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
  81 {
  82         if(!kh_tracking_enabled)
  83                 return FALSE;
  84         if(!self.owner)
  85                 return TRUE;
  86         if(!self.owner.owner)
  87                 return TRUE;
  88         return FALSE;  // draw only when key is not owned
  89 }
  90
  91 void kh_update_state()
  92 {
  93         entity player;
  94         entity key;
  95         float s;
  96         float f;
  97
  98         s = 0;
  99         FOR_EACH_KH_KEY(key)
 100         {
 101                 if(key.owner)
 102                         f = key.team;
 103                 else
 104                         f = 30;
 105                 s |= pow(32, key.count) * f;
 106         }
 107
 108         FOR_EACH_CLIENT(player)
 109         {
 110                 player.kh_state = s;
 111         }
 112
 113         FOR_EACH_KH_KEY(key)
 114         {
 115                 if(key.owner)
 116                         key.owner.kh_state |= pow(32, key.count) * 31;
 117         }
 118         //print(ftos((nextent(world)).kh_state), "\n");
 119 }
 120
 121
 122
 123
 124 var kh_Think_t kh_Controller_Thinkfunc;
 125 void kh_Controller_SetThink(float t, string msg, float centerprint_duration, kh_Think_t func)  // runs occasionaly
 126 {
 127         kh_Controller_Thinkfunc = func;
 128         kh_controller.cnt = ceil(t);
 129         if(kh_Controller_Waitmsg != "")
 130                 strunzone(kh_Controller_Waitmsg);
 131         if(msg == "")
 132                 kh_Controller_Waitmsg = "";
 133         else
 134         {
 135                 kh_controller.kh_cp_duration = centerprint_duration;
 136                 kh_Controller_Waitmsg = strzone(msg);
 137         }
 138         if(t == 0)
 139                 kh_controller.nextthink = time; // force
 140 }
 141 void kh_Controller_SetThink_NoMsg(float t, kh_Think_t func)  // runs occasionaly
 142 {
 143         kh_Controller_SetThink(t, "", 0, func);
 144 }
 145
 146 void kh_Controller_Think()  // called a lot
 147 {
 148         entity e;
 149         if(intermission_running)
 150                 return;
 151         if(self.cnt > 0)
 152         {
 153                 if(kh_Controller_Waitmsg != "")
 154                 {
 155                         string s;
 156                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 157                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 158                         else
 159                                 s = kh_Controller_Waitmsg;
 160
 161                         //dprint(s, "\n");
 162
 163                         FOR_EACH_PLAYER(e)
 164                                 if(clienttype(e) == CLIENTTYPE_REAL)
 165                                         Send_CSQC_Centerprint_Generic(e, CPID_KH_MSG, s, self.kh_cp_duration, 0);
 166                 }
 167                 self.cnt -= 1;
 168         }
 169         else if(self.cnt == 0)
 170         {
 171                 self.cnt -= 1;
 172                 kh_Controller_Thinkfunc();
 173         }
 174         self.nextthink = time + 1;
 175 }
 176
 177 // frags f: take from cvar * f
 178 // frags 0: no frags
 179 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 180 {
 181         string s;
 182         if(intermission_running)
 183                 return;
 184
 185         if(frags_player)
 186                 UpdateFrags(player, frags_player);
 187
 188         if(key && key.owner && frags_owner)
 189                 UpdateFrags(key.owner, frags_owner);
 190
 191         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 192                 return;
 193
 194         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 195
 196         if(key && key.owner)
 197                 s = strcat(s, ":", ftos(key.owner.playerid));
 198         else
 199                 s = strcat(s, ":0");
 200
 201         s = strcat(s, ":", ftos(frags_owner), ":");
 202
 203         if(key)
 204                 s = strcat(s, key.netname);
 205
 206         GameLogEcho(s);
 207 }
 208
 209 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 210 {
 211         if(e.tag_entity)
 212         {
 213                 makevectors(e.tag_entity.angles);
 214                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 215         }
 216         else
 217                 return e.origin;
 218 }
 219
 220 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 221 {
 222 #ifdef KH_PLAYER_USE_ATTACHMENT
 223         entity first;
 224         first = key.owner.kh_next;
 225         if(key == first)
 226         {
 227                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 228                 if(key.kh_next)
 229                 {
 230                         setattachment(key.kh_next, key, "");
 231                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 232                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 233                         key.kh_next.angles = '0 0 0';
 234                 }
 235                 else
 236                         setorigin(key, KH_PLAYER_ATTACHMENT);
 237                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 238         }
 239         else
 240         {
 241                 setattachment(key, key.kh_prev, "");
 242                 if(key.kh_next)
 243                         setattachment(key.kh_next, key, "");
 244                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 245                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 246                 key.angles = '0 0 0';
 247         }
 248 #else
 249         setattachment(key, key.owner, "");
 250         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 251         key.angles_y -= key.owner.angles_y;
 252 #endif
 253         key.flags = 0;
 254         key.solid = SOLID_NOT;
 255         key.movetype = MOVETYPE_NONE;
 256         key.team = key.owner.team;
 257         key.nextthink = time;
 258         key.damageforcescale = 0;
 259         key.takedamage = DAMAGE_NO;
 260         key.modelindex = kh_key_carried;
 261 }
 262
 263 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 264 {
 265 #ifdef KH_PLAYER_USE_ATTACHMENT
 266         entity first;
 267         first = key.owner.kh_next;
 268         if(key == first)
 269         {
 270                 if(key.kh_next)
 271                 {
 272                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 273                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 274                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 275                 }
 276         }
 277         else
 278         {
 279                 if(key.kh_next)
 280                         setattachment(key.kh_next, key.kh_prev, "");
 281                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 282         }
 283         // in any case:
 284         setattachment(key, world, "");
 285         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 286         key.angles = key.owner.angles;
 287 #else
 288         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 289         setattachment(key, world, "");
 290         key.angles_y += key.owner.angles_y;
 291 #endif
 292         key.flags = FL_ITEM;
 293         key.solid = SOLID_TRIGGER;
 294         key.movetype = MOVETYPE_TOSS;
 295         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 296         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 297         key.takedamage = DAMAGE_YES;
 298         // let key.team stay
 299         key.modelindex = kh_key_dropped;
 300         key.kh_previous_owner = key.owner;
 301         key.kh_previous_owner_playerid = key.owner.playerid;
 302 }
 303
 304 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 305 {
 306         entity k;
 307         float ownerteam0, ownerteam;
 308         if(key.owner == player)
 309                 return;
 310
 311         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 312
 313         if(key.owner)
 314         {
 315                 kh_Key_Detach(key);
 316
 317                 // remove from linked list
 318                 if(key.kh_next)
 319                         key.kh_next.kh_prev = key.kh_prev;
 320                 key.kh_prev.kh_next = key.kh_next;
 321                 key.kh_next = world;
 322                 key.kh_prev = world;
 323
 324                 if(key.owner.kh_next == world)
 325                 {
 326                         // No longer a key carrier
 327                         if(!kh_no_radar_circles)
 328                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 329                         WaypointSprite_DetachCarrier(key.owner);
 330                 }
 331         }
 332
 333         key.owner = player;
 334
 335         if(player)
 336         {
 337                 // insert into linked list
 338                 key.kh_next = player.kh_next;
 339                 key.kh_prev = player;
 340                 player.kh_next = key;
 341                 if(key.kh_next)
 342                         key.kh_next.kh_prev = key;
 343
 344                 float i;
 345                 i = test[key.owner.playerid];
 346                         if(key.netname == "^1red key")
 347                                 i += 1;
 348                         if(key.netname == "^4blue key")
 349                                 i += 2;
 350                         if(key.netname == "^3yellow key")
 351                                 i += 4;
 352                         if(key.netname == "^6pink key")
 353                                 i += 8;
 354                 test[key.owner.playerid] = i;
 355
 356                 kh_Key_Attach(key);
 357
 358                 if(key.kh_next == world)
 359                 {
 360                         // player is now a key carrier
 361                         WaypointSprite_AttachCarrier("", player, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 362                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 363                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 364                         if(player.team == COLOR_TEAM1)
 365                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "keycarrier-red");
 366                         else if(player.team == COLOR_TEAM2)
 367                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "keycarrier-blue");
 368                         else if(player.team == COLOR_TEAM3)
 369                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "keycarrier-yellow");
 370                         else if(player.team == COLOR_TEAM4)
 371                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "keycarrier-pink");
 372                         if(!kh_no_radar_circles)
 373                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 374                 }
 375         }
 376
 377         // moved that here, also update if there's no player
 378         kh_update_state();
 379
 380         key.pusher = world;
 381
 382         ownerteam = kh_Key_AllOwnedByWhichTeam();
 383         if(ownerteam != ownerteam0)
 384         {
 385                 if(ownerteam != -1)
 386                 {
 387                         kh_interferemsg_time = time + 0.2;
 388                         kh_interferemsg_team = player.team;
 389
 390                         // audit all key carrier sprites, update them to RUN HERE
 391                         FOR_EACH_KH_KEY(k)
 392                         {
 393                                 if(k.owner)
 394                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-finish", k.owner.waypointsprite_attachedforcarrier.model3);
 395                         }
 396                 }
 397                 else
 398                 {
 399                         kh_interferemsg_time = 0;
 400
 401                         // audit all key carrier sprites, update them to RUN HERE
 402                         FOR_EACH_KH_KEY(k)
 403                         {
 404                                 if(k.owner)
 405                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-friend", k.owner.waypointsprite_attachedforcarrier.model3);
 406                         }
 407                 }
 408         }
 409 }
 410
 411 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 412 {
 413         if(self.owner)
 414                 return;
 415         if(vlen(force) <= 0)
 416                 return;
 417         if(time > self.pushltime)
 418                 if(attacker.classname == "player")
 419                         self.team = attacker.team;
 420 }
 421
 422 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 423 {
 424         sound(player, CH_TRIGGER, kh_sound_collect, VOL_BASE, ATTN_NORM);
 425
 426         if(key.kh_dropperteam != player.team)
 427         {
 428                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 429                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 430         }
 431         key.kh_dropperteam = 0;
 432         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 433
 434         kh_Key_AssignTo(key, player); // this also updates .kh_state
 435 }
 436
 437 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 438 {
 439         if(intermission_running)
 440                 return;
 441
 442         if(self.owner) // already carried
 443                 return;
 444         if(other.classname != "player")
 445                 return;
 446         if(other.deadflag != DEAD_NO)
 447                 return;
 448         if(other == self.enemy)
 449                 if(time < self.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 450                         return;  // you just dropped it!
 451         kh_Key_Collect(self, other);
 452 }
 453
 454 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 455 {
 456         entity o;
 457         o = key.owner;
 458         kh_Key_AssignTo(key, world);
 459         if(o) // it was attached
 460                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 461         else // it was dropped
 462                 WaypointSprite_DetachCarrier(key);
 463
 464         // remove key from key list
 465         if (kh_worldkeylist == key)
 466                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 467         else
 468         {
 469                 o = kh_worldkeylist;
 470                 while (o)
 471                 {
 472                         if (o.kh_worldkeynext == key)
 473                         {
 474                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 475                                 break;
 476                         }
 477                         o = o.kh_worldkeynext;
 478                 }
 479         }
 480
 481         remove(key);
 482
 483         kh_update_state();
 484 }
 485
 486 void kh_FinishRound()  // runs when a team captures the keys
 487 {
 488         // prepare next round
 489         kh_interferemsg_time = 0;
 490         entity key;
 491
 492         kh_no_radar_circles = TRUE;
 493         FOR_EACH_KH_KEY(key)
 494                 kh_Key_Remove(key);
 495         kh_no_radar_circles = FALSE;
 496
 497         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, "Round starts in ", 1, kh_StartRound);
 498 }
 499
 500 void kh_WinnerTeam(float teem)  // runs when a team wins
 501 {
 502         // all key carriers get some points
 503         vector firstorigin, lastorigin, midpoint;
 504         float first;
 505         entity key;
 506         float score;
 507         score = (kh_teams - 1) * autocvar_g_balance_keyhunt_score_capture;
 508         DistributeEvenly_Init(score, kh_teams);
 509         // twice the score for 3 team games, three times the score for 4 team games!
 510         // note: for a win by destroying the key, this should NOT be applied
 511         FOR_EACH_KH_KEY(key)
 512         {
 513                 float f;
 514                 f = DistributeEvenly_Get(1);
 515                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 516                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 517         }
 518
 519         first = TRUE;
 520         FOR_EACH_KH_KEY(key)
 521                 if(key.owner.kh_next == key)
 522                 {
 523                         if(!first)
 524                                 bprint("^7, ");
 525                         bprint(key.owner.netname);
 526                         first = FALSE;
 527                 }
 528         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 529
 530         first = TRUE;
 531         midpoint = '0 0 0';
 532         FOR_EACH_KH_KEY(key)
 533         {
 534                 vector thisorigin;
 535
 536                 thisorigin = kh_AttachedOrigin(key);
 537                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 538                 midpoint += thisorigin;
 539
 540                 if(!first)
 541                         te_lightning2(world, lastorigin, thisorigin);
 542                 lastorigin = thisorigin;
 543                 if(first)
 544                         firstorigin = thisorigin;
 545                 first = FALSE;
 546         }
 547         if(kh_teams > 2)
 548         {
 549                 te_lightning2(world, lastorigin, firstorigin);
 550         }
 551         midpoint = midpoint * (1 / kh_teams);
 552         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 553
 554         play2all(kh_sound_capture);
 555         kh_FinishRound();
 556 }
 557
 558 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 559 {
 560         entity player, key, attacker;
 561         float players;
 562         float keys;
 563         float f;
 564
 565         attacker = world;
 566         if(lostkey.pusher)
 567                 if(lostkey.pusher.team != teem)
 568                         if(lostkey.pusher.classname == "player")
 569                                 attacker = lostkey.pusher;
 570
 571         players = keys = 0;
 572
 573         if(attacker)
 574         {
 575                 if(lostkey.kh_previous_owner)
 576                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 577                         // don't actually GIVE him the -nn points, just log
 578                 kh_Scores_Event(attacker, world, "push", autocvar_g_balance_keyhunt_score_push, 0);
 579                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 580                 centerprint(attacker, "Your push is the best!");
 581                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 582         }
 583         else
 584         {
 585                 float of, fragsleft, i, j, thisteam;
 586                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 587
 588                 FOR_EACH_PLAYER(player)
 589                         if(player.team != teem)
 590                                 ++players;
 591
 592                 FOR_EACH_KH_KEY(key)
 593                         if(key.owner && key.team != teem)
 594                                 ++keys;
 595
 596                 if(lostkey.kh_previous_owner)
 597                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 598                         // don't actually GIVE him the -nn points, just log
 599
 600                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 601                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 602
 603                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 604
 605                 FOR_EACH_KH_KEY(key)
 606                         if(key.owner && key.team != teem)
 607                         {
 608                                 f = DistributeEvenly_Get(of);
 609                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 610                         }
 611
 612                 fragsleft = DistributeEvenly_Get(players);
 613
 614                 // Now distribute these among all other teams...
 615                 j = kh_teams - 1;
 616                 for(i = 0; i < kh_teams; ++i)
 617                 {
 618                         thisteam = kh_Team_ByID(i);
 619                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 620                                 continue;
 621
 622                         players = 0;
 623                         FOR_EACH_PLAYER(player)
 624                                 if(player.team == thisteam)
 625                                         ++players;
 626
 627                         DistributeEvenly_Init(fragsleft, j);
 628                         fragsleft = DistributeEvenly_Get(j - 1);
 629                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 630
 631                         FOR_EACH_PLAYER(player)
 632                                 if(player.team == thisteam)
 633                                 {
 634                                         f = DistributeEvenly_Get(1);
 635                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 636                                 }
 637
 638                         --j;
 639                 }
 640
 641                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 642         }
 643         play2all(kh_sound_destroy);
 644         te_tarexplosion(lostkey.origin);
 645
 646         kh_FinishRound();
 647 }
 648
 649 void kh_Key_Think()  // runs all the time
 650 {
 651         entity head;
 652         //entity player;  // needed by FOR_EACH_PLAYER
 653
 654         if(intermission_running)
 655                 return;
 656
 657         if(self.owner)
 658         {
 659 #ifndef KH_PLAYER_USE_ATTACHMENT
 660                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 661                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 662 #endif
 663         }
 664
 665         // if in nodrop or time over, end the round
 666         if(!self.owner)
 667                 if(time > self.pain_finished)
 668                         kh_LoserTeam(self.team, self);
 669
 670         if(self.owner)
 671         if(kh_Key_AllOwnedByWhichTeam() != -1)
 672         {
 673                 if(self.siren_time < time)
 674                 {
 675                         sound(self.owner, CH_TRIGGER, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 676                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 677                 }
 678
 679                 entity key;
 680                 vector p;
 681                 p = self.owner.origin;
 682                 FOR_EACH_KH_KEY(key)
 683                         if(vlen(key.owner.origin - p) > autocvar_g_balance_keyhunt_maxdist)
 684                                 goto not_winning;
 685                 kh_WinnerTeam(self.team);
 686 :not_winning
 687         }
 688
 689         if(kh_interferemsg_time && time > kh_interferemsg_time)
 690         {
 691                 kh_interferemsg_time = 0;
 692                 FOR_EACH_PLAYER(head)
 693                 {
 694                         if(head.team == kh_interferemsg_team)
 695                                 if(head.kh_next)
 696                                         Send_CSQC_Centerprint_Generic(head, CPID_KH_MSG, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!", 0, 0);
 697                                 else
 698                                         Send_CSQC_Centerprint_Generic(head, CPID_KH_MSG, "All keys are in your team's hands!\n\nHelp the key carriers to meet!", 0, 0);
 699                         else
 700                                 Send_CSQC_Centerprint_Generic(head, CPID_KH_MSG, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!"), 0, 0);
 701                 }
 702         }
 703
 704         self.nextthink = time + 0.05;
 705 }
 706
 707 void key_reset()
 708 {
 709         kh_Key_AssignTo(self, world);
 710         kh_Key_Remove(self);
 711 }
 712
 713 string STR_ITEM_KH_KEY = "item_kh_key";
 714 void kh_Key_Spawn(entity initial_owner, float angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 715 {
 716         entity key;
 717         key = spawn();
 718         key.count = i;
 719         key.classname = STR_ITEM_KH_KEY;
 720         key.touch = kh_Key_Touch;
 721         key.think = kh_Key_Think;
 722         key.nextthink = time;
 723         key.items = IT_KEY1 | IT_KEY2;
 724         key.cnt = angle;
 725         key.angles = '0 360 0' * random();
 726         key.event_damage = kh_Key_Damage;
 727         key.takedamage = DAMAGE_YES;
 728         key.modelindex = kh_key_dropped;
 729         key.model = "key";
 730         key.kh_dropperteam = 0;
 731         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 732         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 733         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 734         key.reset = key_reset;
 735
 736         switch(initial_owner.team)
 737         {
 738                 case COLOR_TEAM1:
 739                         key.netname = "^1red key";
 740                         break;
 741                 case COLOR_TEAM2:
 742                         key.netname = "^4blue key";
 743                         break;
 744                 case COLOR_TEAM3:
 745                         key.netname = "^3yellow key";
 746                         break;
 747                 case COLOR_TEAM4:
 748                         key.netname = "^6pink key";
 749                         break;
 750                 default:
 751                         key.netname = "NETGIER key";
 752                         break;
 753         }
 754
 755         // link into key list
 756         key.kh_worldkeynext = kh_worldkeylist;
 757         kh_worldkeylist = key;
 758
 759         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 760
 761         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE, RADARICON_FLAG, '0 1 1');
 762         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 763
 764         kh_Key_AssignTo(key, initial_owner);
 765 }
 766
 767 // -1 when no team completely owns all keys yet
 768 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 769 {
 770         entity key;
 771         float teem;
 772         float keys;
 773
 774         teem = -1;
 775         keys = kh_teams;
 776         FOR_EACH_KH_KEY(key)
 777         {
 778                 if(!key.owner)
 779                         return -1;
 780                 if(teem == -1)
 781                         teem = key.team;
 782                 else if(teem != key.team)
 783                         return -1;
 784                 --keys;
 785         }
 786         if(keys != 0)
 787                 return -1;
 788         return teem;
 789 }
 790
 791 void kh_Key_DropOne(entity key)
 792 {
 793         // prevent collecting this one for some time
 794         entity player;
 795         player = key.owner;
 796
 797         key.kh_droptime = time;
 798         key.enemy = player;
 799
 800         kh_Scores_Event(player, key, "dropkey", 0, 0);
 801         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 802         bprint(player.netname, "^7 dropped the ", key.netname, "\n");
 803         kh_Key_AssignTo(key, world);
 804         makevectors(player.v_angle);
 805         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, FALSE);
 806         key.pusher = world;
 807         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 808         key.kh_dropperteam = key.team;
 809
 810         sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 811 }
 812
 813 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 814 {
 815         entity key;
 816         entity mypusher;
 817         if(player.kh_next)
 818         {
 819                 mypusher = world;
 820                 if(player.pusher)
 821                         if(time < player.pushltime)
 822                                 mypusher = player.pusher;
 823                 while((key = player.kh_next))
 824                 {
 825                         kh_Scores_Event(player, key, "losekey", 0, 0);
 826                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 827                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 828                         kh_Key_AssignTo(key, world);
 829                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 830                         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, FALSE);
 831                         key.pusher = mypusher;
 832                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 833                         if(suicide)
 834                                 key.kh_dropperteam = player.team;
 835                 }
 836                 sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 837         }
 838 }
 839
 840 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 841 {
 842         float i, players, teem;
 843         entity player;
 844         string result;
 845         result = "";
 846
 847         // find a random player per team
 848         for(i = 0; i < kh_teams; ++i)
 849         {
 850                 teem = kh_Team_ByID(i);
 851                 players = 0;
 852                 FOR_EACH_PLAYER(player)
 853                         if(player.deadflag == DEAD_NO)
 854                                 if(!player.BUTTON_CHAT)
 855                                         if(player.team == teem)
 856                                                 ++players;
 857                 if(players == 0)
 858                 {
 859                         if(result != "")
 860                                 result = strcat(result, ", ");
 861                         result = strcat(result, ColoredTeamName(teem));
 862                 }
 863         }
 864         return result;
 865 }
 866
 867 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 868 {
 869         string teams_missing;
 870
 871         if(time < game_starttime)
 872         {
 873                 kh_Controller_SetThink_NoMsg(game_starttime - time + 0.1, kh_WaitForPlayers);
 874                 return;
 875         }
 876
 877         teams_missing = kh_CheckEnoughPlayers();
 878         if(teams_missing == "")
 879                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, "Round starts in ", 1, kh_StartRound);
 880         else
 881                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, kh_WaitForPlayers);
 882 }
 883
 884 void kh_EnableTrackingDevice()  // runs after each round
 885 {
 886         entity player;
 887
 888         FOR_EACH_PLAYER(player)
 889                 if(clienttype(player) == CLIENTTYPE_REAL)
 890                         Send_CSQC_Centerprint_Generic_Expire(player, CPID_KH_MSG);
 891
 892         kh_tracking_enabled = TRUE;
 893 }
 894
 895 void kh_StartRound()  // runs at the start of each round
 896 {
 897         string teams_missing;
 898         float i, players, teem;
 899         entity player;
 900
 901         if(time < game_starttime)
 902         {
 903                 kh_Controller_SetThink_NoMsg(game_starttime - time + 0.1, kh_WaitForPlayers);
 904                 return;
 905         }
 906
 907         teams_missing = kh_CheckEnoughPlayers();
 908         if(teams_missing != "")
 909         {
 910                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, kh_WaitForPlayers);
 911                 return;
 912         }
 913
 914         FOR_EACH_PLAYER(player)
 915                 if(clienttype(player) == CLIENTTYPE_REAL)
 916                         Send_CSQC_Centerprint_Generic_Expire(player, CPID_KH_MSG);
 917
 918         for(i = 0; i < kh_teams; ++i)
 919         {
 920                 teem = kh_Team_ByID(i);
 921                 players = 0;
 922                 entity my_player;
 923                 FOR_EACH_PLAYER(player)
 924                         if(player.deadflag == DEAD_NO)
 925                                 if(!player.BUTTON_CHAT)
 926                                         if(player.team == teem)
 927                                         {
 928                                                 ++players;
 929                                                 if(random() * players <= 1)
 930                                                         my_player = player;
 931                                         }
 932                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
 933         }
 934
 935         kh_tracking_enabled = FALSE;
 936         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, "Scanning frequency range...", -1, kh_EnableTrackingDevice);
 937 }
 938
 939 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 940 {
 941         if(attacker == targ)
 942                 return f;
 943
 944         if(targ.kh_next)
 945         {
 946                 if(attacker.team == targ.team)
 947                 {
 948                         entity k;
 949                         float nk;
 950                         nk = 0;
 951                         for(k = targ.kh_next; k != world; k = k.kh_next)
 952                                 ++nk;
 953                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 954                 }
 955                 else
 956                 {
 957                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 958                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 959                         // the frag gets added later
 960                 }
 961         }
 962
 963         return f;
 964 }
 965
 966 void kh_Initialize()  // sets up th KH environment
 967 {
 968         precache_sound(kh_sound_capture);
 969         precache_sound(kh_sound_destroy);
 970         precache_sound(kh_sound_drop);
 971         precache_sound(kh_sound_collect);
 972         precache_sound(kh_sound_alarm);  // the new siren
 973
 974 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 975         precache_model("models/keyhunt/key-carried.md3");
 976 #endif
 977         precache_model("models/keyhunt/key.md3");
 978
 979         // setup variables
 980         kh_teams = autocvar_g_keyhunt_teams_override;
 981         if(kh_teams < 2)
 982                 kh_teams = autocvar_g_keyhunt_teams;
 983         kh_teams = bound(2, kh_teams, 4);
 984
 985         // make a KH entity for controlling the game
 986         kh_controller = spawn();
 987         kh_controller.think = kh_Controller_Think;
 988         kh_Controller_SetThink_NoMsg(0, kh_WaitForPlayers);
 989
 990         setmodel(kh_controller, "models/keyhunt/key.md3");
 991         kh_key_dropped = kh_controller.modelindex;
 992         /*
 993         dprint(vtos(kh_controller.mins));
 994         dprint(vtos(kh_controller.maxs));
 995         dprint("\n");
 996         */
 997 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 998         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 999         kh_key_carried = kh_controller.modelindex;
1000 #else
1001         kh_key_carried = kh_key_dropped;
1002 #endif
1003
1004         kh_controller.model = "";
1005         kh_controller.modelindex = 0;
1006
1007         addstat(STAT_KH_KEYS, AS_INT, kh_state);
1008
1009         ScoreRules_kh(kh_teams);
1010 }
1011
1012 void kh_finalize()
1013 {
1014         // to be called before intermission
1015         kh_FinishRound();
1016         remove(kh_controller);
1017         kh_controller = world;
1018 }
1019
1020 // register this as a mutator
1021
1022 MUTATOR_HOOKFUNCTION(kh_Key_DropAll)
1023 {
1024         kh_Key_DropAll(self, TRUE);
1025         return 0;
1026 }
1027
1028 MUTATOR_HOOKFUNCTION(kh_PlayerDies)
1029 {
1030         if(self == other)
1031                 kh_Key_DropAll(self, TRUE);
1032         else if(other.classname == "player")
1033                 kh_Key_DropAll(self, FALSE);
1034         else
1035                 kh_Key_DropAll(self, TRUE);
1036         return 0;
1037 }
1038
1039 MUTATOR_HOOKFUNCTION(kh_GiveFragsForKill)
1040 {
1041         frag_score = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1042         return 0;
1043 }
1044
1045 MUTATOR_HOOKFUNCTION(kh_finalize)
1046 {
1047         kh_finalize();
1048         return 0;
1049 }
1050
1051 MUTATOR_HOOKFUNCTION(kh_GetTeamCount)
1052 {
1053         ret_float = kh_teams;
1054         return 0;
1055 }
1056
1057 MUTATOR_HOOKFUNCTION(kh_SpectateCopy)
1058 {
1059         self.kh_state = other.kh_state;
1060         return 0;
1061 }
1062
1063 MUTATOR_HOOKFUNCTION(kh_PlayerUseKey)
1064 {
1065         if(MUTATOR_RETURNVALUE == 0)
1066         {
1067                 entity k;
1068                 k = self.kh_next;
1069                 if(k)
1070                 {
1071                         kh_Key_DropOne(k);
1072                         return 1;
1073                 }
1074         }
1075         return 0;
1076 }
1077
1078 MUTATOR_DEFINITION(gamemode_keyhunt)
1079 {
1080         MUTATOR_HOOK(MakePlayerObserver, kh_Key_DropAll, CBC_ORDER_ANY);
1081         MUTATOR_HOOK(ClientDisconnect, kh_Key_DropAll, CBC_ORDER_ANY);
1082         MUTATOR_HOOK(PlayerDies, kh_PlayerDies, CBC_ORDER_ANY);
1083         MUTATOR_HOOK(GiveFragsForKill, kh_GiveFragsForKill, CBC_ORDER_FIRST);
1084         MUTATOR_HOOK(MatchEnd, kh_finalize, CBC_ORDER_ANY);
1085         MUTATOR_HOOK(GetTeamCount, kh_GetTeamCount, CBC_ORDER_EXCLUSIVE);
1086         MUTATOR_HOOK(SpectateCopy, kh_SpectateCopy, CBC_ORDER_ANY);
1087         MUTATOR_HOOK(PlayerUseKey, kh_PlayerUseKey, CBC_ORDER_ANY);
1088
1089         MUTATOR_ONADD
1090         {
1091                 if(time > 1) // game loads at time 1
1092                         error("This is a game type and it cannot be added at runtime.");
1093                 g_keyhunt = 1;
1094                 kh_Initialize();
1095         }
1096
1097         MUTATOR_ONREMOVE
1098         {
1099                 g_keyhunt = 0;
1100                 error("This is a game type and it cannot be removed at runtime.");
1101         }
1102
1103         return 0;
1104 }