qcsrc/server/mutators/gamemode_keyhunt.qc

   1 #include "gamemode_keyhunt.qh"
   2 #include "../_all.qh"
   3
   4 #include "gamemode.qh"
   5
   6
   7 // #define KH_PLAYER_USE_ATTACHMENT
   8 // #define KH_PLAYER_USE_CARRIEDMODEL
   9
  10 #ifdef KH_PLAYER_USE_ATTACHMENT
  11 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  12 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  13 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  14 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  15 const string KH_PLAYER_ATTACHMENT_BONE = "";
  16 #else
  17 const float KH_KEY_ZSHIFT = 22;
  18 const float KH_KEY_XYDIST = 24;
  19 const float KH_KEY_XYSPEED = 45;
  20 #endif
  21 const float KH_KEY_WP_ZSHIFT = 20;
  22
  23 const vector KH_KEY_MIN = '-10 -10 -46';
  24 const vector KH_KEY_MAX = '10 10 3';
  25 const float KH_KEY_BRIGHTNESS = 2;
  26
  27 float kh_no_radar_circles;
  28
  29 // kh_state
  30 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  31 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  32 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  33 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  34 .float kh_state;
  35 .float siren_time;  //  time delay the siren
  36 //.float stuff_time;  //  time delay to stuffcmd a cvar
  37
  38 float kh_keystatus[17];
  39 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
  40 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  41 //for(i = 0; i < maxplayers; ++i)
  42 //      kh_keystatus[i] = "0";
  43
  44 float kh_Team_ByID(float t)
  45 {
  46         if(t == 0) return NUM_TEAM_1;
  47         if(t == 1) return NUM_TEAM_2;
  48         if(t == 2) return NUM_TEAM_3;
  49         if(t == 3) return NUM_TEAM_4;
  50         return 0;
  51 }
  52
  53 //entity kh_worldkeylist;
  54 .entity kh_worldkeynext;
  55 entity kh_controller;
  56 //float kh_tracking_enabled;
  57 float kh_teams;
  58 float kh_interferemsg_time, kh_interferemsg_team;
  59 .entity kh_next, kh_prev; // linked list
  60 .float kh_droptime;
  61 .float kh_dropperteam;
  62 .entity kh_previous_owner;
  63 .float kh_previous_owner_playerid;
  64 .float kh_cp_duration;
  65
  66 string kh_sound_capture = "kh/capture.wav";
  67 string kh_sound_destroy = "kh/destroy.wav";
  68 string kh_sound_drop = "kh/drop.wav";
  69 string kh_sound_collect = "kh/collect.wav";
  70 string kh_sound_alarm = "kh/alarm.wav";  // the new siren/alarm
  71
  72 float kh_key_dropped, kh_key_carried;
  73
  74 const float ST_KH_CAPS = 1;
  75 const float SP_KH_CAPS = 4;
  76 const float SP_KH_PUSHES = 5;
  77 const float SP_KH_DESTROYS = 6;
  78 const float SP_KH_PICKUPS = 7;
  79 const float SP_KH_KCKILLS = 8;
  80 const float SP_KH_LOSSES = 9;
  81 void kh_ScoreRules(float teams)
  82 {
  83         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, true);
  84         ScoreInfo_SetLabel_TeamScore(  ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  85         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  86         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSHES,    "pushes",    0);
  87         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYS,  "destroyed", SFL_LOWER_IS_BETTER);
  88         ScoreInfo_SetLabel_PlayerScore(SP_KH_PICKUPS,   "pickups",   0);
  89         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCKILLS,   "kckills",   0);
  90         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSSES,    "losses",    SFL_LOWER_IS_BETTER);
  91         ScoreRules_basics_end();
  92 }
  93
  94 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
  95 {
  96         if(!IS_PLAYER(e) || self.team != e.team)
  97                 if(!kh_tracking_enabled)
  98                         return false;
  99
 100         return true;
 101 }
 102
 103 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
 104 {
 105         if(!kh_tracking_enabled)
 106                 return false;
 107         if(!self.owner)
 108                 return true;
 109         if(!self.owner.owner)
 110                 return true;
 111         return false;  // draw only when key is not owned
 112 }
 113
 114 void kh_update_state()
 115 {
 116         entity player;
 117         entity key;
 118         float s;
 119         float f;
 120
 121         s = 0;
 122         FOR_EACH_KH_KEY(key)
 123         {
 124                 if(key.owner)
 125                         f = key.team;
 126                 else
 127                         f = 30;
 128                 s |= pow(32, key.count) * f;
 129         }
 130
 131         FOR_EACH_CLIENT(player)
 132         {
 133                 player.kh_state = s;
 134         }
 135
 136         FOR_EACH_KH_KEY(key)
 137         {
 138                 if(key.owner)
 139                         key.owner.kh_state |= pow(32, key.count) * 31;
 140         }
 141         //print(ftos((nextent(world)).kh_state), "\n");
 142 }
 143
 144
 145
 146
 147 var kh_Think_t kh_Controller_Thinkfunc;
 148 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 149 {
 150         kh_Controller_Thinkfunc = func;
 151         kh_controller.cnt = ceil(t);
 152         if(t == 0)
 153                 kh_controller.nextthink = time; // force
 154 }
 155 void kh_WaitForPlayers();
 156 void kh_Controller_Think()  // called a lot
 157 {
 158         if(intermission_running)
 159                 return;
 160         if(self.cnt > 0)
 161         { if(self.think != kh_WaitForPlayers) { self.cnt -= 1; } }
 162         else if(self.cnt == 0)
 163         {
 164                 self.cnt -= 1;
 165                 kh_Controller_Thinkfunc();
 166         }
 167         self.nextthink = time + 1;
 168 }
 169
 170 // frags f: take from cvar * f
 171 // frags 0: no frags
 172 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 173 {
 174         string s;
 175         if(intermission_running)
 176                 return;
 177
 178         if(frags_player)
 179                 UpdateFrags(player, frags_player);
 180
 181         if(key && key.owner && frags_owner)
 182                 UpdateFrags(key.owner, frags_owner);
 183
 184         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 185                 return;
 186
 187         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 188
 189         if(key && key.owner)
 190                 s = strcat(s, ":", ftos(key.owner.playerid));
 191         else
 192                 s = strcat(s, ":0");
 193
 194         s = strcat(s, ":", ftos(frags_owner), ":");
 195
 196         if(key)
 197                 s = strcat(s, key.netname);
 198
 199         GameLogEcho(s);
 200 }
 201
 202 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 203 {
 204         if(e.tag_entity)
 205         {
 206                 makevectors(e.tag_entity.angles);
 207                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 208         }
 209         else
 210                 return e.origin;
 211 }
 212
 213 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 214 {
 215 #ifdef KH_PLAYER_USE_ATTACHMENT
 216         entity first;
 217         first = key.owner.kh_next;
 218         if(key == first)
 219         {
 220                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 221                 if(key.kh_next)
 222                 {
 223                         setattachment(key.kh_next, key, "");
 224                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 225                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 226                         key.kh_next.angles = '0 0 0';
 227                 }
 228                 else
 229                         setorigin(key, KH_PLAYER_ATTACHMENT);
 230                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 231         }
 232         else
 233         {
 234                 setattachment(key, key.kh_prev, "");
 235                 if(key.kh_next)
 236                         setattachment(key.kh_next, key, "");
 237                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 238                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 239                 key.angles = '0 0 0';
 240         }
 241 #else
 242         setattachment(key, key.owner, "");
 243         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 244         key.angles_y -= key.owner.angles.y;
 245 #endif
 246         key.flags = 0;
 247         key.solid = SOLID_NOT;
 248         key.movetype = MOVETYPE_NONE;
 249         key.team = key.owner.team;
 250         key.nextthink = time;
 251         key.damageforcescale = 0;
 252         key.takedamage = DAMAGE_NO;
 253         key.modelindex = kh_key_carried;
 254 }
 255
 256 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 257 {
 258 #ifdef KH_PLAYER_USE_ATTACHMENT
 259         entity first;
 260         first = key.owner.kh_next;
 261         if(key == first)
 262         {
 263                 if(key.kh_next)
 264                 {
 265                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 266                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 267                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 268                 }
 269         }
 270         else
 271         {
 272                 if(key.kh_next)
 273                         setattachment(key.kh_next, key.kh_prev, "");
 274                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 275         }
 276         // in any case:
 277         setattachment(key, world, "");
 278         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN.z - KH_KEY_MIN_z));
 279         key.angles = key.owner.angles;
 280 #else
 281         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 282         setattachment(key, world, "");
 283         key.angles_y += key.owner.angles.y;
 284 #endif
 285         key.flags = FL_ITEM;
 286         key.solid = SOLID_TRIGGER;
 287         key.movetype = MOVETYPE_TOSS;
 288         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 289         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 290         key.takedamage = DAMAGE_YES;
 291         // let key.team stay
 292         key.modelindex = kh_key_dropped;
 293         key.kh_previous_owner = key.owner;
 294         key.kh_previous_owner_playerid = key.owner.playerid;
 295 }
 296
 297 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 298 {
 299         entity k;
 300         float ownerteam0, ownerteam;
 301         if(key.owner == player)
 302                 return;
 303
 304         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 305
 306         if(key.owner)
 307         {
 308                 kh_Key_Detach(key);
 309
 310                 // remove from linked list
 311                 if(key.kh_next)
 312                         key.kh_next.kh_prev = key.kh_prev;
 313                 key.kh_prev.kh_next = key.kh_next;
 314                 key.kh_next = world;
 315                 key.kh_prev = world;
 316
 317                 if(key.owner.kh_next == world)
 318                 {
 319                         // No longer a key carrier
 320                         if(!kh_no_radar_circles)
 321                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 322                         WaypointSprite_DetachCarrier(key.owner);
 323                 }
 324         }
 325
 326         key.owner = player;
 327
 328         if(player)
 329         {
 330                 // insert into linked list
 331                 key.kh_next = player.kh_next;
 332                 key.kh_prev = player;
 333                 player.kh_next = key;
 334                 if(key.kh_next)
 335                         key.kh_next.kh_prev = key;
 336
 337                 float i;
 338                 i = kh_keystatus[key.owner.playerid];
 339                         if(key.netname == "^1red key")
 340                                 i += 1;
 341                         if(key.netname == "^4blue key")
 342                                 i += 2;
 343                         if(key.netname == "^3yellow key")
 344                                 i += 4;
 345                         if(key.netname == "^6pink key")
 346                                 i += 8;
 347                 kh_keystatus[key.owner.playerid] = i;
 348
 349                 kh_Key_Attach(key);
 350
 351                 if(key.kh_next == world)
 352                 {
 353                         // player is now a key carrier
 354                         WaypointSprite_AttachCarrier("", player, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 355                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 356                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 357                         if(player.team == NUM_TEAM_1)
 358                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "keycarrier-red");
 359                         else if(player.team == NUM_TEAM_2)
 360                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "keycarrier-blue");
 361                         else if(player.team == NUM_TEAM_3)
 362                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "keycarrier-yellow");
 363                         else if(player.team == NUM_TEAM_4)
 364                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "keycarrier-pink");
 365                         if(!kh_no_radar_circles)
 366                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 367                 }
 368         }
 369
 370         // moved that here, also update if there's no player
 371         kh_update_state();
 372
 373         key.pusher = world;
 374
 375         ownerteam = kh_Key_AllOwnedByWhichTeam();
 376         if(ownerteam != ownerteam0)
 377         {
 378                 if(ownerteam != -1)
 379                 {
 380                         kh_interferemsg_time = time + 0.2;
 381                         kh_interferemsg_team = player.team;
 382
 383                         // audit all key carrier sprites, update them to RUN HERE
 384                         FOR_EACH_KH_KEY(k)
 385                         {
 386                                 if(k.owner)
 387                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-finish", k.owner.waypointsprite_attachedforcarrier.model3);
 388                         }
 389                 }
 390                 else
 391                 {
 392                         kh_interferemsg_time = 0;
 393
 394                         // audit all key carrier sprites, update them to RUN HERE
 395                         FOR_EACH_KH_KEY(k)
 396                         {
 397                                 if(k.owner)
 398                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-friend", k.owner.waypointsprite_attachedforcarrier.model3);
 399                         }
 400                 }
 401         }
 402 }
 403
 404 void kh_Key_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 405 {
 406         if(self.owner)
 407                 return;
 408         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 409         {
 410                 // touching lava, or hurt trigger
 411                 // what shall we do?
 412                 // immediately return is bad
 413                 // maybe start a shorter countdown?
 414         }
 415         if(vlen(force) <= 0)
 416                 return;
 417         if(time > self.pushltime)
 418                 if(IS_PLAYER(attacker))
 419                         self.team = attacker.team;
 420 }
 421
 422 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 423 {
 424         sound(player, CH_TRIGGER, kh_sound_collect, VOL_BASE, ATTEN_NORM);
 425
 426         if(key.kh_dropperteam != player.team)
 427         {
 428                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 429                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 430         }
 431         key.kh_dropperteam = 0;
 432         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_PICKUP_), player.netname);
 433
 434         kh_Key_AssignTo(key, player); // this also updates .kh_state
 435 }
 436
 437 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 438 {
 439         if(intermission_running)
 440                 return;
 441
 442         if(self.owner) // already carried
 443                 return;
 444
 445         if(ITEM_TOUCH_NEEDKILL())
 446         {
 447                 // touching sky, or nodrop
 448                 // what shall we do?
 449                 // immediately return is bad
 450                 // maybe start a shorter countdown?
 451         }
 452
 453         if (!IS_PLAYER(other))
 454                 return;
 455         if(other.deadflag != DEAD_NO)
 456                 return;
 457         if(other == self.enemy)
 458                 if(time < self.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 459                         return;  // you just dropped it!
 460         kh_Key_Collect(self, other);
 461 }
 462
 463 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 464 {
 465         entity o;
 466         o = key.owner;
 467         kh_Key_AssignTo(key, world);
 468         if(o) // it was attached
 469                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 470         else // it was dropped
 471                 WaypointSprite_DetachCarrier(key);
 472
 473         // remove key from key list
 474         if (kh_worldkeylist == key)
 475                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 476         else
 477         {
 478                 o = kh_worldkeylist;
 479                 while (o)
 480                 {
 481                         if (o.kh_worldkeynext == key)
 482                         {
 483                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 484                                 break;
 485                         }
 486                         o = o.kh_worldkeynext;
 487                 }
 488         }
 489
 490         remove(key);
 491
 492         kh_update_state();
 493 }
 494
 495 void kh_FinishRound()  // runs when a team captures the keys
 496 {
 497         // prepare next round
 498         kh_interferemsg_time = 0;
 499         entity key;
 500
 501         kh_no_radar_circles = true;
 502         FOR_EACH_KH_KEY(key)
 503                 kh_Key_Remove(key);
 504         kh_no_radar_circles = false;
 505
 506         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 507         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 508 }
 509
 510 void kh_WinnerTeam(float teem)  // runs when a team wins // Samual: Teem?.... TEEM?!?! what the fuck is wrong with you people
 511 {
 512         // all key carriers get some points
 513         vector firstorigin, lastorigin, midpoint;
 514         float first;
 515         entity key;
 516         float score;
 517         score = (kh_teams - 1) * autocvar_g_balance_keyhunt_score_capture;
 518         DistributeEvenly_Init(score, kh_teams);
 519         // twice the score for 3 team games, three times the score for 4 team games!
 520         // note: for a win by destroying the key, this should NOT be applied
 521         FOR_EACH_KH_KEY(key)
 522         {
 523                 float f;
 524                 f = DistributeEvenly_Get(1);
 525                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 526                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 527                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 528         }
 529
 530         first = true;
 531         string keyowner = "";
 532         FOR_EACH_KH_KEY(key)
 533                 if(key.owner.kh_next == key)
 534                 {
 535                         if(!first)
 536                                 keyowner = strcat(keyowner, ", ");
 537                         keyowner = key.owner.netname;
 538                         first = false;
 539                 }
 540
 541         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(teem, INFO_KEYHUNT_CAPTURE_), keyowner);
 542
 543         first = true;
 544         midpoint = '0 0 0';
 545         firstorigin = '0 0 0';
 546         lastorigin = '0 0 0';
 547         FOR_EACH_KH_KEY(key)
 548         {
 549                 vector thisorigin;
 550
 551                 thisorigin = kh_AttachedOrigin(key);
 552                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 553                 midpoint += thisorigin;
 554
 555                 if(!first)
 556                         te_lightning2(world, lastorigin, thisorigin);
 557                 lastorigin = thisorigin;
 558                 if(first)
 559                         firstorigin = thisorigin;
 560                 first = false;
 561         }
 562         if(kh_teams > 2)
 563         {
 564                 te_lightning2(world, lastorigin, firstorigin);
 565         }
 566         midpoint = midpoint * (1 / kh_teams);
 567         te_customflash(midpoint, 1000, 1, Team_ColorRGB(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 568
 569         play2all(kh_sound_capture);
 570         kh_FinishRound();
 571 }
 572
 573 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 574 {
 575         entity player, key, attacker;
 576         float players;
 577         float keys;
 578         float f;
 579
 580         attacker = world;
 581         if(lostkey.pusher)
 582                 if(lostkey.pusher.team != teem)
 583                         if(IS_PLAYER(lostkey.pusher))
 584                                 attacker = lostkey.pusher;
 585
 586         players = keys = 0;
 587
 588         if(attacker)
 589         {
 590                 if(lostkey.kh_previous_owner)
 591                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 592                         // don't actually GIVE him the -nn points, just log
 593                 kh_Scores_Event(attacker, world, "push", autocvar_g_balance_keyhunt_score_push, 0);
 594                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 595                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 596         }
 597         else
 598         {
 599                 float of, fragsleft, i, j, thisteam;
 600                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 601
 602                 FOR_EACH_PLAYER(player)
 603                         if(player.team != teem)
 604                                 ++players;
 605
 606                 FOR_EACH_KH_KEY(key)
 607                         if(key.owner && key.team != teem)
 608                                 ++keys;
 609
 610                 if(lostkey.kh_previous_owner)
 611                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 612                         // don't actually GIVE him the -nn points, just log
 613
 614                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 615                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 616
 617                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 618
 619                 FOR_EACH_KH_KEY(key)
 620                         if(key.owner && key.team != teem)
 621                         {
 622                                 f = DistributeEvenly_Get(of);
 623                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 624                         }
 625
 626                 fragsleft = DistributeEvenly_Get(players);
 627
 628                 // Now distribute these among all other teams...
 629                 j = kh_teams - 1;
 630                 for(i = 0; i < kh_teams; ++i)
 631                 {
 632                         thisteam = kh_Team_ByID(i);
 633                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 634                                 continue;
 635
 636                         players = 0;
 637                         FOR_EACH_PLAYER(player)
 638                                 if(player.team == thisteam)
 639                                         ++players;
 640
 641                         DistributeEvenly_Init(fragsleft, j);
 642                         fragsleft = DistributeEvenly_Get(j - 1);
 643                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 644
 645                         FOR_EACH_PLAYER(player)
 646                                 if(player.team == thisteam)
 647                                 {
 648                                         f = DistributeEvenly_Get(1);
 649                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 650                                 }
 651
 652                         --j;
 653                 }
 654         }
 655
 656         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(lostkey, INFO_KEYHUNT_LOST_), lostkey.kh_previous_owner.netname);
 657
 658         play2all(kh_sound_destroy);
 659         te_tarexplosion(lostkey.origin);
 660
 661         kh_FinishRound();
 662 }
 663
 664 void kh_Key_Think()  // runs all the time
 665 {
 666         entity head;
 667         //entity player;  // needed by FOR_EACH_PLAYER
 668
 669         if(intermission_running)
 670                 return;
 671
 672         if(self.owner)
 673         {
 674 #ifndef KH_PLAYER_USE_ATTACHMENT
 675                 makevectors('0 1 0' * (self.cnt + (time % 360) * KH_KEY_XYSPEED));
 676                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin.z);
 677 #endif
 678         }
 679
 680         // if in nodrop or time over, end the round
 681         if(!self.owner)
 682                 if(time > self.pain_finished)
 683                         kh_LoserTeam(self.team, self);
 684
 685         if(self.owner)
 686         if(kh_Key_AllOwnedByWhichTeam() != -1)
 687         {
 688                 if(self.siren_time < time)
 689                 {
 690                         sound(self.owner, CH_TRIGGER, kh_sound_alarm, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 691                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 692                 }
 693
 694                 entity key;
 695                 vector p;
 696                 p = self.owner.origin;
 697                 FOR_EACH_KH_KEY(key)
 698                         if(vlen(key.owner.origin - p) > autocvar_g_balance_keyhunt_maxdist)
 699                                 goto not_winning;
 700                 kh_WinnerTeam(self.team);
 701 :not_winning
 702         }
 703
 704         if(kh_interferemsg_time && time > kh_interferemsg_time)
 705         {
 706                 kh_interferemsg_time = 0;
 707                 FOR_EACH_PLAYER(head)
 708                 {
 709                         if(head.team == kh_interferemsg_team)
 710                                 if(head.kh_next)
 711                                         Send_Notification(NOTIF_ONE, head, MSG_CENTER, CENTER_KEYHUNT_MEET);
 712                                 else
 713                                         Send_Notification(NOTIF_ONE, head, MSG_CENTER, CENTER_KEYHUNT_HELP);
 714                         else
 715                                 Send_Notification(NOTIF_ONE, head, MSG_CENTER, APP_TEAM_NUM_4(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE_));
 716                 }
 717         }
 718
 719         self.nextthink = time + 0.05;
 720 }
 721
 722 void key_reset()
 723 {
 724         kh_Key_AssignTo(self, world);
 725         kh_Key_Remove(self);
 726 }
 727
 728 const string STR_ITEM_KH_KEY = "item_kh_key";
 729 void kh_Key_Spawn(entity initial_owner, float angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 730 {
 731         entity key;
 732         key = spawn();
 733         key.count = i;
 734         key.classname = STR_ITEM_KH_KEY;
 735         key.touch = kh_Key_Touch;
 736         key.think = kh_Key_Think;
 737         key.nextthink = time;
 738         key.items = IT_KEY1 | IT_KEY2;
 739         key.cnt = angle;
 740         key.angles = '0 360 0' * random();
 741         key.event_damage = kh_Key_Damage;
 742         key.takedamage = DAMAGE_YES;
 743         key.modelindex = kh_key_dropped;
 744         key.model = "key";
 745         key.kh_dropperteam = 0;
 746         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 747         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 748         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 749         key.reset = key_reset;
 750
 751         switch(initial_owner.team)
 752         {
 753                 case NUM_TEAM_1:
 754                         key.netname = "^1red key";
 755                         break;
 756                 case NUM_TEAM_2:
 757                         key.netname = "^4blue key";
 758                         break;
 759                 case NUM_TEAM_3:
 760                         key.netname = "^3yellow key";
 761                         break;
 762                 case NUM_TEAM_4:
 763                         key.netname = "^6pink key";
 764                         break;
 765                 default:
 766                         key.netname = "NETGIER key";
 767                         break;
 768         }
 769
 770         // link into key list
 771         key.kh_worldkeynext = kh_worldkeylist;
 772         kh_worldkeylist = key;
 773
 774         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM_4(initial_owner.team, CENTER_KEYHUNT_START_));
 775
 776         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG, '0 1 1');
 777         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 778
 779         kh_Key_AssignTo(key, initial_owner);
 780 }
 781
 782 // -1 when no team completely owns all keys yet
 783 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 784 {
 785         entity key;
 786         float teem;
 787         float keys;
 788
 789         teem = -1;
 790         keys = kh_teams;
 791         FOR_EACH_KH_KEY(key)
 792         {
 793                 if(!key.owner)
 794                         return -1;
 795                 if(teem == -1)
 796                         teem = key.team;
 797                 else if(teem != key.team)
 798                         return -1;
 799                 --keys;
 800         }
 801         if(keys != 0)
 802                 return -1;
 803         return teem;
 804 }
 805
 806 void kh_Key_DropOne(entity key)
 807 {
 808         // prevent collecting this one for some time
 809         entity player;
 810         player = key.owner;
 811
 812         key.kh_droptime = time;
 813         key.enemy = player;
 814
 815         kh_Scores_Event(player, key, "dropkey", 0, 0);
 816         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 817         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_DROP_), player.netname);
 818
 819         kh_Key_AssignTo(key, world);
 820         makevectors(player.v_angle);
 821         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 822         key.pusher = world;
 823         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 824         key.kh_dropperteam = key.team;
 825
 826         sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTEN_NORM);
 827 }
 828
 829 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 830 {
 831         entity key;
 832         entity mypusher;
 833         if(player.kh_next)
 834         {
 835                 mypusher = world;
 836                 if(player.pusher)
 837                         if(time < player.pushltime)
 838                                 mypusher = player.pusher;
 839                 while((key = player.kh_next))
 840                 {
 841                         kh_Scores_Event(player, key, "losekey", 0, 0);
 842                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 843                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_LOST_), player.netname);
 844                         kh_Key_AssignTo(key, world);
 845                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 846                         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 847                         key.pusher = mypusher;
 848                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 849                         if(suicide)
 850                                 key.kh_dropperteam = player.team;
 851                 }
 852                 sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTEN_NORM);
 853         }
 854 }
 855
 856 float kh_CheckPlayers(float num)
 857 {
 858         if(num < kh_teams)
 859         {
 860                 float t_team = kh_Team_ByID(num);
 861                 float players = 0;
 862                 entity tmp_player;
 863                 FOR_EACH_PLAYER(tmp_player)
 864                         if(tmp_player.deadflag == DEAD_NO)
 865                                 if(!tmp_player.BUTTON_CHAT)
 866                                         if(tmp_player.team == t_team)
 867                                                 ++players;
 868
 869                 if (!players) { return t_team; }
 870         }
 871         return 0;
 872 }
 873
 874 #define KH_READY_TEAMS() (!p1 + !p2 + ((kh_teams >= 3) ? !p3 : p3) + ((kh_teams >= 4) ? !p4 : p4))
 875 #define KH_READY_TEAMS_OK() (KH_READY_TEAMS() == kh_teams)
 876 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 877 {
 878         if(time < game_starttime)
 879         {
 880                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 881                 return;
 882         }
 883
 884         static float prev_missing_teams_mask;
 885         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 886         if(KH_READY_TEAMS_OK())
 887         {
 888                 if(prev_missing_teams_mask > 0)
 889                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 890                 prev_missing_teams_mask = -1;
 891                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 892                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 893         }
 894         else
 895         {
 896                 if(player_count == 0)
 897                 {
 898                         if(prev_missing_teams_mask > 0)
 899                                 Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 900                         prev_missing_teams_mask = -1;
 901                 }
 902                 else
 903                 {
 904                         float missing_teams_mask = (!!p1) + (!!p2) * 2;
 905                         if(kh_teams >= 3) missing_teams_mask += (!!p3) * 4;
 906                         if(kh_teams >= 4) missing_teams_mask += (!!p4) * 8;
 907                         if(prev_missing_teams_mask != missing_teams_mask)
 908                         {
 909                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 910                                 prev_missing_teams_mask = missing_teams_mask;
 911                         }
 912                 }
 913                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 914         }
 915 }
 916
 917 void kh_EnableTrackingDevice()  // runs after each round
 918 {
 919         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT);
 920         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT_OTHER);
 921
 922         kh_tracking_enabled = true;
 923 }
 924
 925 void kh_StartRound()  // runs at the start of each round
 926 {
 927         float i, players, teem;
 928         entity player;
 929
 930         if(time < game_starttime)
 931         {
 932                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 933                 return;
 934         }
 935
 936         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 937         if(!KH_READY_TEAMS_OK())
 938         {
 939                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 940                 return;
 941         }
 942
 943         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT);
 944         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT_OTHER);
 945
 946         for(i = 0; i < kh_teams; ++i)
 947         {
 948                 teem = kh_Team_ByID(i);
 949                 players = 0;
 950                 entity my_player = world;
 951                 FOR_EACH_PLAYER(player)
 952                         if(player.deadflag == DEAD_NO)
 953                                 if(!player.BUTTON_CHAT)
 954                                         if(player.team == teem)
 955                                         {
 956                                                 ++players;
 957                                                 if(random() * players <= 1)
 958                                                         my_player = player;
 959                                         }
 960                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
 961         }
 962
 963         kh_tracking_enabled = false;
 964         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 965         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 966 }
 967
 968 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 969 {
 970         if(attacker == targ)
 971                 return f;
 972
 973         if(targ.kh_next)
 974         {
 975                 if(attacker.team == targ.team)
 976                 {
 977                         entity k;
 978                         float nk;
 979                         nk = 0;
 980                         for(k = targ.kh_next; k != world; k = k.kh_next)
 981                                 ++nk;
 982                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 983                 }
 984                 else
 985                 {
 986                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 987                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 988                         // the frag gets added later
 989                 }
 990         }
 991
 992         return f;
 993 }
 994
 995 void kh_Initialize()  // sets up th KH environment
 996 {
 997         precache_sound(kh_sound_capture);
 998         precache_sound(kh_sound_destroy);
 999         precache_sound(kh_sound_drop);
1000         precache_sound(kh_sound_collect);
1001         precache_sound(kh_sound_alarm);  // the new siren
1002
1003 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1004         precache_model("models/keyhunt/key-carried.md3");
1005 #endif
1006         precache_model("models/keyhunt/key.md3");
1007
1008         // setup variables
1009         kh_teams = autocvar_g_keyhunt_teams_override;
1010         if(kh_teams < 2)
1011                 kh_teams = autocvar_g_keyhunt_teams;
1012         kh_teams = bound(2, kh_teams, 4);
1013
1014         // make a KH entity for controlling the game
1015         kh_controller = spawn();
1016         kh_controller.think = kh_Controller_Think;
1017         kh_Controller_SetThink(0, kh_WaitForPlayers);
1018
1019         setmodel(kh_controller, "models/keyhunt/key.md3");
1020         kh_key_dropped = kh_controller.modelindex;
1021         /*
1022         dprint(vtos(kh_controller.mins));
1023         dprint(vtos(kh_controller.maxs));
1024         dprint("\n");
1025         */
1026 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1027         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
1028         kh_key_carried = kh_controller.modelindex;
1029 #else
1030         kh_key_carried = kh_key_dropped;
1031 #endif
1032
1033         kh_controller.model = "";
1034         kh_controller.modelindex = 0;
1035
1036         addstat(STAT_KH_KEYS, AS_INT, kh_state);
1037
1038         kh_ScoreRules(kh_teams);
1039 }
1040
1041 void kh_finalize()
1042 {
1043         // to be called before intermission
1044         kh_FinishRound();
1045         remove(kh_controller);
1046         kh_controller = world;
1047 }
1048
1049 // register this as a mutator
1050
1051 MUTATOR_HOOKFUNCTION(kh_Key_DropAll)
1052 {
1053         kh_Key_DropAll(self, true);
1054         return 0;
1055 }
1056
1057 MUTATOR_HOOKFUNCTION(kh_PlayerDies)
1058 {
1059         if(self == other)
1060                 kh_Key_DropAll(self, true);
1061         else if(IS_PLAYER(other))
1062                 kh_Key_DropAll(self, false);
1063         else
1064                 kh_Key_DropAll(self, true);
1065         return 0;
1066 }
1067
1068 MUTATOR_HOOKFUNCTION(kh_GiveFragsForKill)
1069 {
1070         frag_score = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1071         return 0;
1072 }
1073
1074 MUTATOR_HOOKFUNCTION(kh_finalize)
1075 {
1076         kh_finalize();
1077         return 0;
1078 }
1079
1080 MUTATOR_HOOKFUNCTION(kh_GetTeamCount)
1081 {
1082         ret_float = kh_teams;
1083         return 0;
1084 }
1085
1086 MUTATOR_HOOKFUNCTION(kh_SpectateCopy)
1087 {
1088         self.kh_state = other.kh_state;
1089         return 0;
1090 }
1091
1092 MUTATOR_HOOKFUNCTION(kh_PlayerUseKey)
1093 {
1094         if(MUTATOR_RETURNVALUE == 0)
1095         {
1096                 entity k;
1097                 k = self.kh_next;
1098                 if(k)
1099                 {
1100                         kh_Key_DropOne(k);
1101                         return 1;
1102                 }
1103         }
1104         return 0;
1105 }
1106
1107 MUTATOR_DEFINITION(gamemode_keyhunt)
1108 {
1109         MUTATOR_HOOK(MakePlayerObserver, kh_Key_DropAll, CBC_ORDER_ANY);
1110         MUTATOR_HOOK(ClientDisconnect, kh_Key_DropAll, CBC_ORDER_ANY);
1111         MUTATOR_HOOK(PlayerDies, kh_PlayerDies, CBC_ORDER_ANY);
1112         MUTATOR_HOOK(GiveFragsForKill, kh_GiveFragsForKill, CBC_ORDER_FIRST);
1113         MUTATOR_HOOK(MatchEnd, kh_finalize, CBC_ORDER_ANY);
1114         MUTATOR_HOOK(GetTeamCount, kh_GetTeamCount, CBC_ORDER_EXCLUSIVE);
1115         MUTATOR_HOOK(SpectateCopy, kh_SpectateCopy, CBC_ORDER_ANY);
1116         MUTATOR_HOOK(PlayerUseKey, kh_PlayerUseKey, CBC_ORDER_ANY);
1117
1118         MUTATOR_ONADD
1119         {
1120                 if(time > 1) // game loads at time 1
1121                         error("This is a game type and it cannot be added at runtime.");
1122                 kh_Initialize();
1123         }
1124
1125         MUTATOR_ONROLLBACK_OR_REMOVE
1126         {
1127                 // we actually cannot roll back kh_Initialize here
1128                 // BUT: we don't need to! If this gets called, adding always
1129                 // succeeds.
1130         }
1131
1132         MUTATOR_ONREMOVE
1133         {
1134                 print("This is a game type and it cannot be removed at runtime.");
1135                 return -1;
1136         }
1137
1138         return 0;
1139 }