qcsrc/server/mutators/gamemode_lms.qc

   1 #include "gamemode_lms.qh"
   2 #include "../_all.qh"
   3
   4 #include "gamemode.qh"
   5
   6 #include "../campaign.qh"
   7 #include "../command/cmd.qh"
   8
   9 // main functions
  10 float LMS_NewPlayerLives()
  11 {
  12         float fl;
  13         fl = autocvar_fraglimit;
  14         if(fl == 0)
  15                 fl = 999;
  16
  17         // first player has left the game for dying too much? Nobody else can get in.
  18         if(lms_lowest_lives < 1)
  19                 return 0;
  20
  21         if(!autocvar_g_lms_join_anytime)
  22                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  23                         return 0;
  24
  25         return bound(1, lms_lowest_lives, fl);
  26 }
  27
  28 // mutator hooks
  29 MUTATOR_HOOKFUNCTION(lms_ResetMap)
  30 {
  31         lms_lowest_lives = 999;
  32         lms_next_place = player_count;
  33
  34         return false;
  35 }
  36
  37 MUTATOR_HOOKFUNCTION(lms_ResetPlayers)
  38 {SELFPARAM();
  39         if(restart_mapalreadyrestarted || (time < game_starttime))
  40         FOR_EACH_CLIENT(self)
  41         if(IS_PLAYER(self))
  42                 PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
  43
  44         return false;
  45 }
  46
  47 MUTATOR_HOOKFUNCTION(lms_PlayerPreSpawn)
  48 {SELFPARAM();
  49         // player is dead and becomes observer
  50         // FIXME fix LMS scoring for new system
  51         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
  52                 self.classname = "observer";
  53
  54         return false;
  55 }
  56
  57 MUTATOR_HOOKFUNCTION(lms_PlayerDies)
  58 {SELFPARAM();
  59         self.respawn_flags |= RESPAWN_FORCE;
  60
  61         return false;
  62 }
  63
  64 MUTATOR_HOOKFUNCTION(lms_RemovePlayer)
  65 {SELFPARAM();
  66         // Only if the player cannot play at all
  67         if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
  68                 self.frags = FRAGS_SPECTATOR;
  69         else
  70                 self.frags = FRAGS_LMS_LOSER;
  71
  72         if(self.killcount != -666)
  73                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
  74                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
  75                 else
  76                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
  77
  78         return false;
  79 }
  80
  81 MUTATOR_HOOKFUNCTION(lms_ClientConnect)
  82 {SELFPARAM();
  83         self.classname = "player";
  84         campaign_bots_may_start = 1;
  85
  86         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
  87         {
  88                 PlayerScore_Add(self, SP_LMS_RANK, 666);
  89                 self.frags = FRAGS_SPECTATOR;
  90         }
  91
  92         return false;
  93 }
  94
  95 MUTATOR_HOOKFUNCTION(lms_PlayerThink)
  96 {SELFPARAM();
  97         if(self.deadflag == DEAD_DYING)
  98                 self.deadflag = DEAD_RESPAWNING;
  99
 100         return false;
 101 }
 102
 103 MUTATOR_HOOKFUNCTION(lms_PlayerRegen)
 104 {
 105         if(autocvar_g_lms_regenerate)
 106                 return false;
 107         return true;
 108 }
 109
 110 MUTATOR_HOOKFUNCTION(lms_ForbidThrowing)
 111 {
 112         // forbode!
 113         return true;
 114 }
 115
 116 MUTATOR_HOOKFUNCTION(lms_GiveFragsForKill)
 117 {
 118         // remove a life
 119         float tl;
 120         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 121         if(tl < lms_lowest_lives)
 122                 lms_lowest_lives = tl;
 123         if(tl <= 0)
 124         {
 125                 if(!lms_next_place)
 126                         lms_next_place = player_count;
 127                 else
 128                         lms_next_place = min(lms_next_place, player_count);
 129                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 130                 --lms_next_place;
 131         }
 132         frag_score = 0;
 133
 134         return true;
 135 }
 136
 137 MUTATOR_HOOKFUNCTION(lms_SetStartItems)
 138 {
 139         start_items &= ~IT_UNLIMITED_AMMO;
 140         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 141         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 142         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 143         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 144         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 145         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 146         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 147         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 148
 149         return false;
 150 }
 151
 152 MUTATOR_HOOKFUNCTION(lms_KeepScore)
 153 {
 154         // don't clear player score
 155         return true;
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(lms_FilterItem)
 159 {SELFPARAM();
 160         if(autocvar_g_lms_extra_lives)
 161         if(self.itemdef == ITEM_HealthMega)
 162         {
 163                 self.max_health = 1;
 164                 return false;
 165         }
 166
 167         return true;
 168 }
 169
 170 MUTATOR_HOOKFUNCTION(lms_ItemTouch)
 171 {SELFPARAM();
 172         // give extra lives for mega health
 173         if (self.items & ITEM_HealthMega.m_itemid)
 174         {
 175                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 176                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 177         }
 178
 179         return MUT_ITEMTOUCH_CONTINUE;
 180 }
 181
 182 // scoreboard stuff
 183 void lms_ScoreRules()
 184 {
 185         ScoreRules_basics(0, 0, 0, false);
 186         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 187         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 188         ScoreRules_basics_end();
 189 }
 190
 191 void lms_Initialize()
 192 {
 193         lms_lowest_lives = 9999;
 194         lms_next_place = 0;
 195
 196         lms_ScoreRules();
 197 }
 198
 199 MUTATOR_DEFINITION(gamemode_lms)
 200 {
 201         MUTATOR_HOOK(reset_map_global, lms_ResetMap, CBC_ORDER_ANY);
 202         MUTATOR_HOOK(reset_map_players, lms_ResetPlayers, CBC_ORDER_ANY);
 203         MUTATOR_HOOK(PutClientInServer, lms_PlayerPreSpawn, CBC_ORDER_ANY);
 204         MUTATOR_HOOK(PlayerDies, lms_PlayerDies, CBC_ORDER_ANY);
 205         MUTATOR_HOOK(MakePlayerObserver, lms_RemovePlayer, CBC_ORDER_ANY);
 206         MUTATOR_HOOK(ClientConnect, lms_ClientConnect, CBC_ORDER_ANY);
 207         MUTATOR_HOOK(PlayerPreThink, lms_PlayerThink, CBC_ORDER_ANY);
 208         MUTATOR_HOOK(PlayerRegen, lms_PlayerRegen, CBC_ORDER_ANY);
 209         MUTATOR_HOOK(ForbidThrowCurrentWeapon, lms_ForbidThrowing, CBC_ORDER_ANY);
 210         MUTATOR_HOOK(GiveFragsForKill, lms_GiveFragsForKill, CBC_ORDER_ANY);
 211         MUTATOR_HOOK(SetStartItems, lms_SetStartItems, CBC_ORDER_ANY);
 212         MUTATOR_HOOK(ForbidPlayerScore_Clear, lms_KeepScore, CBC_ORDER_ANY);
 213         MUTATOR_HOOK(FilterItem, lms_FilterItem, CBC_ORDER_ANY);
 214         MUTATOR_HOOK(ItemTouch, lms_ItemTouch, CBC_ORDER_ANY);
 215
 216         MUTATOR_ONADD
 217         {
 218                 if(time > 1) // game loads at time 1
 219                         error("This is a game type and it cannot be added at runtime.");
 220                 lms_Initialize();
 221         }
 222
 223         MUTATOR_ONROLLBACK_OR_REMOVE
 224         {
 225                 // we actually cannot roll back lms_Initialize here
 226                 // BUT: we don't need to! If this gets called, adding always
 227                 // succeeds.
 228         }
 229
 230         MUTATOR_ONREMOVE
 231         {
 232                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
 233                 return -1;
 234         }
 235
 236         return 0;
 237 }