qcsrc/server/mutators/gamemode_lms.qc

   1 // main functions
   2 float LMS_NewPlayerLives()
   3 {
   4         float fl;
   5         fl = autocvar_fraglimit;
   6         if(fl == 0)
   7                 fl = 999;
   8
   9         // first player has left the game for dying too much? Nobody else can get in.
  10         if(lms_lowest_lives < 1)
  11                 return 0;
  12
  13         if(!autocvar_g_lms_join_anytime)
  14                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  15                         return 0;
  16
  17         return bound(1, lms_lowest_lives, fl);
  18 }
  19
  20 // mutator hooks
  21 MUTATOR_HOOKFUNCTION(lms_RemovePlayer)
  22 {
  23         // Only if the player cannot play at all
  24         if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
  25                 self.frags = FRAGS_SPECTATOR;
  26         else
  27                 self.frags = FRAGS_LMS_LOSER;
  28
  29         return FALSE;
  30 }
  31
  32 MUTATOR_HOOKFUNCTION(lms_PlayerSpawn)
  33 {
  34         // player is dead and becomes observer
  35         // FIXME fix LMS scoring for new system
  36         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
  37                 self.classname = "observer";
  38
  39         return FALSE;
  40 }
  41
  42 MUTATOR_HOOKFUNCTION(lms_ClientConnect)
  43 {
  44         self.classname = "player";
  45         campaign_bots_may_start = 1;
  46
  47         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
  48         {
  49                 PlayerScore_Add(self, SP_LMS_RANK, 666);
  50                 self.frags = FRAGS_SPECTATOR;
  51         }
  52
  53         return FALSE;
  54 }
  55
  56 MUTATOR_HOOKFUNCTION(lms_PlayerThink)
  57 {
  58         if(self.deadflag == DEAD_DYING)
  59                 self.deadflag = DEAD_RESPAWNING;
  60
  61         return FALSE;
  62 }
  63
  64 MUTATOR_HOOKFUNCTION(lms_ForbidThrowing)
  65 {
  66         // forbode!
  67         return TRUE;
  68 }
  69
  70 MUTATOR_HOOKFUNCTION(lms_GiveFragsForKill)
  71 {
  72         // remove a life
  73         float tl;
  74         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
  75         if(tl < lms_lowest_lives)
  76                 lms_lowest_lives = tl;
  77         if(tl <= 0)
  78         {
  79                 if(!lms_next_place)
  80                         lms_next_place = player_count;
  81                 else
  82                         lms_next_place = min(lms_next_place, player_count);
  83                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
  84                 --lms_next_place;
  85         }
  86         frag_score = 0;
  87
  88         return TRUE;
  89 }
  90
  91 MUTATOR_HOOKFUNCTION(lms_SetStartItems)
  92 {
  93         start_items &~= IT_UNLIMITED_AMMO;
  94         start_ammo_shells = cvar("g_lms_start_ammo_shells");
  95         start_ammo_nails = cvar("g_lms_start_ammo_nails");
  96         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
  97         start_ammo_cells = cvar("g_lms_start_ammo_cells");
  98         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
  99         start_health = cvar("g_lms_start_health");
 100         start_armorvalue = cvar("g_lms_start_armor");
 101
 102         return FALSE;
 103 }
 104
 105 MUTATOR_HOOKFUNCTION(lms_KeepScore)
 106 {
 107         // don't clear player score
 108         return TRUE;
 109 }
 110
 111 MUTATOR_HOOKFUNCTION(lms_FilterItem)
 112 {
 113         // no items in LMS
 114         return TRUE;
 115 }
 116
 117 MUTATOR_HOOKFUNCTION(lms_BotSpawn)
 118 {
 119         // temporary hack to give bots lives
 120         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 121         {
 122                 PlayerScore_Add(self, SP_LMS_RANK, 666);
 123                 self.frags = FRAGS_SPECTATOR;
 124         }
 125
 126         return FALSE;
 127 }
 128
 129 // scoreboard stuff
 130 void lms_ScoreRules()
 131 {
 132         ScoreRules_basics(0, 0, 0, FALSE);
 133         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 134         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 135         ScoreRules_basics_end();
 136 }
 137
 138 void lms_Initialize()
 139 {
 140         lms_lowest_lives = 9999;
 141         lms_next_place = 0;
 142
 143         lms_ScoreRules();
 144 }
 145
 146 MUTATOR_DEFINITION(gamemode_lms)
 147 {
 148         MUTATOR_HOOK(MakePlayerObserver, lms_RemovePlayer, CBC_ORDER_ANY);
 149         MUTATOR_HOOK(PlayerSpawn, lms_PlayerSpawn, CBC_ORDER_ANY);
 150         MUTATOR_HOOK(ClientConnect, lms_ClientConnect, CBC_ORDER_ANY);
 151         MUTATOR_HOOK(PlayerPreThink, lms_PlayerThink, CBC_ORDER_ANY);
 152         MUTATOR_HOOK(ForbidThrowCurrentWeapon, lms_ForbidThrowing, CBC_ORDER_ANY);
 153         MUTATOR_HOOK(GiveFragsForKill, lms_GiveFragsForKill, CBC_ORDER_ANY);
 154         MUTATOR_HOOK(SetStartItems, lms_SetStartItems, CBC_ORDER_ANY);
 155         MUTATOR_HOOK(PlayerClearScore, lms_KeepScore, CBC_ORDER_ANY);
 156         MUTATOR_HOOK(FilterItem, lms_FilterItem, CBC_ORDER_ANY);
 157         MUTATOR_HOOK(HavocBot_ChooseRule, lms_BotSpawn, CBC_ORDER_ANY);
 158
 159         MUTATOR_ONADD
 160         {
 161                 if(time > 1) // game loads at time 1
 162                         error("This is a game type and it cannot be added at runtime.");
 163                 lms_Initialize();
 164         }
 165
 166         MUTATOR_ONROLLBACK_OR_REMOVE
 167         {
 168                 // we actually cannot roll back lms_Initialize here
 169                 // BUT: we don't need to! If this gets called, adding always
 170                 // succeeds.
 171         }
 172
 173         MUTATOR_ONREMOVE
 174         {
 175                 print("This is a game type and it cannot be removed at runtime.");
 176                 return -1;
 177         }
 178
 179         return 0;
 180 }