qcsrc/server/mutators/gamemode_lms.qc

   1 // main functions
   2 float LMS_NewPlayerLives()
   3 {
   4         float fl;
   5         fl = autocvar_fraglimit;
   6         if(fl == 0)
   7                 fl = 999;
   8
   9         // first player has left the game for dying too much? Nobody else can get in.
  10         if(lms_lowest_lives < 1)
  11                 return 0;
  12
  13         if(!autocvar_g_lms_join_anytime)
  14                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  15                         return 0;
  16
  17         return bound(1, lms_lowest_lives, fl);
  18 }
  19
  20 // mutator hooks
  21 MUTATOR_HOOKFUNCTION(lms_ResetMap)
  22 {
  23         lms_lowest_lives = 999;
  24         lms_next_place = player_count;
  25
  26         return FALSE;
  27 }
  28
  29 MUTATOR_HOOKFUNCTION(lms_ResetPlayers)
  30 {
  31         if(restart_mapalreadyrestarted || (time < game_starttime))
  32         FOR_EACH_CLIENT(self)
  33         if(IS_PLAYER(self))
  34                 PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
  35
  36         return FALSE;
  37 }
  38
  39 MUTATOR_HOOKFUNCTION(lms_PlayerPreSpawn)
  40 {
  41         // player is dead and becomes observer
  42         // FIXME fix LMS scoring for new system
  43         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
  44                 self.classname = "observer";
  45
  46         return FALSE;
  47 }
  48
  49 MUTATOR_HOOKFUNCTION(lms_PlayerDies)
  50 {
  51         self.respawn_flags |= RESPAWN_FORCE;
  52
  53         return FALSE;
  54 }
  55
  56 MUTATOR_HOOKFUNCTION(lms_RemovePlayer)
  57 {
  58         // Only if the player cannot play at all
  59         if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
  60                 self.frags = FRAGS_SPECTATOR;
  61         else
  62                 self.frags = FRAGS_LMS_LOSER;
  63
  64         if(self.killcount != -666)
  65                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
  66                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
  67                 else
  68                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
  69
  70         return FALSE;
  71 }
  72
  73 MUTATOR_HOOKFUNCTION(lms_ClientConnect)
  74 {
  75         self.classname = "player";
  76         campaign_bots_may_start = 1;
  77
  78         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
  79         {
  80                 PlayerScore_Add(self, SP_LMS_RANK, 666);
  81                 self.frags = FRAGS_SPECTATOR;
  82         }
  83
  84         return FALSE;
  85 }
  86
  87 MUTATOR_HOOKFUNCTION(lms_PlayerThink)
  88 {
  89         if(self.deadflag == DEAD_DYING)
  90                 self.deadflag = DEAD_RESPAWNING;
  91
  92         return FALSE;
  93 }
  94
  95 MUTATOR_HOOKFUNCTION(lms_PlayerRegen)
  96 {
  97         if(autocvar_g_lms_regenerate)
  98                 return FALSE;
  99         return TRUE;
 100 }
 101
 102 MUTATOR_HOOKFUNCTION(lms_ForbidThrowing)
 103 {
 104         // forbode!
 105         return TRUE;
 106 }
 107
 108 MUTATOR_HOOKFUNCTION(lms_GiveFragsForKill)
 109 {
 110         // remove a life
 111         float tl;
 112         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 113         if(tl < lms_lowest_lives)
 114                 lms_lowest_lives = tl;
 115         if(tl <= 0)
 116         {
 117                 if(!lms_next_place)
 118                         lms_next_place = player_count;
 119                 else
 120                         lms_next_place = min(lms_next_place, player_count);
 121                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 122                 --lms_next_place;
 123         }
 124         frag_score = 0;
 125
 126         return TRUE;
 127 }
 128
 129 MUTATOR_HOOKFUNCTION(lms_SetStartItems)
 130 {
 131         start_items &= ~IT_UNLIMITED_AMMO;
 132         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 133         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 134         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 135         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 136         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 137         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 138         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 139
 140         return FALSE;
 141 }
 142
 143 MUTATOR_HOOKFUNCTION(lms_KeepScore)
 144 {
 145         // don't clear player score
 146         return TRUE;
 147 }
 148
 149 MUTATOR_HOOKFUNCTION(lms_FilterItem)
 150 {
 151         if(autocvar_g_lms_extra_lives)
 152         if(self.classname == "item_health_mega")
 153         {
 154                 self.max_health = 1;
 155                 return FALSE;
 156         }
 157
 158         return TRUE;
 159 }
 160
 161 MUTATOR_HOOKFUNCTION(lms_ItemTouch)
 162 {
 163         // give extra lives for mega health
 164         if(self.items & IT_HEALTH)
 165         {
 166                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 167                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 168         }
 169
 170         return MUT_ITEMTOUCH_CONTINUE;
 171 }
 172
 173 // scoreboard stuff
 174 void lms_ScoreRules()
 175 {
 176         ScoreRules_basics(0, 0, 0, FALSE);
 177         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 178         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 179         ScoreRules_basics_end();
 180 }
 181
 182 void lms_Initialize()
 183 {
 184         lms_lowest_lives = 9999;
 185         lms_next_place = 0;
 186
 187         lms_ScoreRules();
 188 }
 189
 190 MUTATOR_DEFINITION(gamemode_lms)
 191 {
 192         MUTATOR_HOOK(reset_map_global, lms_ResetMap, CBC_ORDER_ANY);
 193         MUTATOR_HOOK(reset_map_players, lms_ResetPlayers, CBC_ORDER_ANY);
 194         MUTATOR_HOOK(PutClientInServer, lms_PlayerPreSpawn, CBC_ORDER_ANY);
 195         MUTATOR_HOOK(PlayerDies, lms_PlayerDies, CBC_ORDER_ANY);
 196         MUTATOR_HOOK(MakePlayerObserver, lms_RemovePlayer, CBC_ORDER_ANY);
 197         MUTATOR_HOOK(ClientConnect, lms_ClientConnect, CBC_ORDER_ANY);
 198         MUTATOR_HOOK(PlayerPreThink, lms_PlayerThink, CBC_ORDER_ANY);
 199         MUTATOR_HOOK(PlayerRegen, lms_PlayerRegen, CBC_ORDER_ANY);
 200         MUTATOR_HOOK(ForbidThrowCurrentWeapon, lms_ForbidThrowing, CBC_ORDER_ANY);
 201         MUTATOR_HOOK(GiveFragsForKill, lms_GiveFragsForKill, CBC_ORDER_ANY);
 202         MUTATOR_HOOK(SetStartItems, lms_SetStartItems, CBC_ORDER_ANY);
 203         MUTATOR_HOOK(ForbidPlayerScore_Clear, lms_KeepScore, CBC_ORDER_ANY);
 204         MUTATOR_HOOK(FilterItem, lms_FilterItem, CBC_ORDER_ANY);
 205         MUTATOR_HOOK(ItemTouch, lms_ItemTouch, CBC_ORDER_ANY);
 206
 207         MUTATOR_ONADD
 208         {
 209                 if(time > 1) // game loads at time 1
 210                         error("This is a game type and it cannot be added at runtime.");
 211                 lms_Initialize();
 212         }
 213
 214         MUTATOR_ONROLLBACK_OR_REMOVE
 215         {
 216                 // we actually cannot roll back lms_Initialize here
 217                 // BUT: we don't need to! If this gets called, adding always
 218                 // succeeds.
 219         }
 220
 221         MUTATOR_ONREMOVE
 222         {
 223                 print("This is a game type and it cannot be removed at runtime.");
 224                 return -1;
 225         }
 226
 227         return 0;
 228 }