qcsrc/server/mutators/mutator/gamemode_assault.qc

   1 #include "gamemode_assault.qh"
   2 #ifndef GAMEMODE_ASSAULT_H
   3 #define GAMEMODE_ASSAULT_H
   4
   5 void assault_ScoreRules();
   6 void ActivateTeamplay();
   7
   8 REGISTER_MUTATOR(as, false)
   9 {
  10         ActivateTeamplay();
  11         have_team_spawns = -1; // request team spawns
  12
  13         MUTATOR_ONADD
  14         {
  15                 if (time > 1) // game loads at time 1
  16                         error("This is a game type and it cannot be added at runtime.");
  17                 assault_ScoreRules();
  18         }
  19
  20         MUTATOR_ONROLLBACK_OR_REMOVE
  21         {
  22                 // we actually cannot roll back assault_Initialize here
  23                 // BUT: we don't need to! If this gets called, adding always
  24                 // succeeds.
  25         }
  26
  27         MUTATOR_ONREMOVE
  28         {
  29                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  30                 return -1;
  31         }
  32
  33         return 0;
  34 }
  35
  36 // sprites
  37 .entity assault_decreaser;
  38 .entity assault_sprite;
  39
  40 // legacy bot defs
  41 const int HAVOCBOT_AST_ROLE_NONE = 0;
  42 const int HAVOCBOT_AST_ROLE_DEFENSE = 2;
  43 const int HAVOCBOT_AST_ROLE_OFFENSE = 4;
  44
  45 .int havocbot_role_flags;
  46 .float havocbot_attack_time;
  47
  48 .void() havocbot_role;
  49 .void() havocbot_previous_role;
  50
  51 void() havocbot_role_ast_defense;
  52 void() havocbot_role_ast_offense;
  53 .entity havocbot_ast_target;
  54
  55 void(entity bot) havocbot_ast_reset_role;
  56
  57 void(float ratingscale, vector org, float sradius) havocbot_goalrating_items;
  58 void(float ratingscale, vector org, float sradius) havocbot_goalrating_enemyplayers;
  59
  60 // scoreboard stuff
  61 const float ST_ASSAULT_OBJECTIVES = 1;
  62 const float SP_ASSAULT_OBJECTIVES = 4;
  63
  64 // predefined spawnfuncs
  65 void target_objective_decrease_activate();
  66 #endif
  67
  68 #ifdef IMPLEMENTATION
  69 .entity sprite;
  70
  71 // random functions
  72 void assault_objective_use()
  73 {SELFPARAM();
  74         // activate objective
  75         self.health = 100;
  76         //print("^2Activated objective ", self.targetname, "=", etos(self), "\n");
  77         //print("Activator is ", activator.classname, "\n");
  78
  79         for (entity e = world; (e = find(e, target, this.targetname)); )
  80         {
  81                 if (e.classname == "target_objective_decrease")
  82                 {
  83                         WITH(entity, self, e, target_objective_decrease_activate());
  84                 }
  85         }
  86
  87         setself(this);
  88 }
  89
  90 vector target_objective_spawn_evalfunc(entity player, entity spot, vector current)
  91 {SELFPARAM();
  92         if(self.health < 0 || self.health >= ASSAULT_VALUE_INACTIVE)
  93                 return '-1 0 0';
  94         return current;
  95 }
  96
  97 // reset this objective. Used when spawning an objective
  98 // and when a new round starts
  99 void assault_objective_reset(entity this)
 100 {
 101         this.health = ASSAULT_VALUE_INACTIVE;
 102 }
 103
 104 // decrease the health of targeted objectives
 105 void assault_objective_decrease_use()
 106 {SELFPARAM();
 107         if(activator.team != assault_attacker_team)
 108         {
 109                 // wrong team triggered decrease
 110                 return;
 111         }
 112
 113         if(other.assault_sprite)
 114         {
 115                 WaypointSprite_Disown(other.assault_sprite, waypointsprite_deadlifetime);
 116                 if(other.classname == "func_assault_destructible")
 117                         other.sprite = world;
 118         }
 119         else
 120                 return; // already activated! cannot activate again!
 121
 122         if(self.enemy.health < ASSAULT_VALUE_INACTIVE)
 123         {
 124                 if(self.enemy.health - self.dmg > 0.5)
 125                 {
 126                         PlayerTeamScore_Add(activator, SP_SCORE, ST_SCORE, self.dmg);
 127                         self.enemy.health = self.enemy.health - self.dmg;
 128                 }
 129                 else
 130                 {
 131                         PlayerTeamScore_Add(activator, SP_SCORE, ST_SCORE, self.enemy.health);
 132                         PlayerTeamScore_Add(activator, SP_ASSAULT_OBJECTIVES, ST_ASSAULT_OBJECTIVES, 1);
 133                         self.enemy.health = -1;
 134
 135                         entity oldactivator;
 136
 137                         setself(this.enemy);
 138                         if(self.message)
 139                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(centerprint(it, self.message)));
 140
 141                         oldactivator = activator;
 142                         activator = this;
 143                         SUB_UseTargets();
 144                         activator = oldactivator;
 145                         setself(this);
 146                 }
 147         }
 148 }
 149
 150 void assault_setenemytoobjective()
 151 {SELFPARAM();
 152         entity objective;
 153         for(objective = world; (objective = find(objective, targetname, self.target)); )
 154         {
 155                 if(objective.classname == "target_objective")
 156                 {
 157                         if(self.enemy == world)
 158                                 self.enemy = objective;
 159                         else
 160                                 objerror("more than one objective as target - fix the map!");
 161                         break;
 162                 }
 163         }
 164
 165         if(self.enemy == world)
 166                 objerror("no objective as target - fix the map!");
 167 }
 168
 169 float assault_decreaser_sprite_visible(entity e)
 170 {SELFPARAM();
 171         entity decreaser;
 172
 173         decreaser = self.assault_decreaser;
 174
 175         if(decreaser.enemy.health >= ASSAULT_VALUE_INACTIVE)
 176                 return false;
 177
 178         return true;
 179 }
 180
 181 void target_objective_decrease_activate()
 182 {SELFPARAM();
 183         entity ent, spr;
 184         self.owner = world;
 185         for(ent = world; (ent = find(ent, target, self.targetname)); )
 186         {
 187                 if(ent.assault_sprite != world)
 188                 {
 189                         WaypointSprite_Disown(ent.assault_sprite, waypointsprite_deadlifetime);
 190                         if(ent.classname == "func_assault_destructible")
 191                                 ent.sprite = world;
 192                 }
 193
 194                 spr = WaypointSprite_SpawnFixed(WP_Assault, 0.5 * (ent.absmin + ent.absmax), ent, assault_sprite, RADARICON_OBJECTIVE);
 195                 spr.assault_decreaser = self;
 196                 spr.waypointsprite_visible_for_player = assault_decreaser_sprite_visible;
 197                 spr.classname = "sprite_waypoint";
 198                 WaypointSprite_UpdateRule(spr, assault_attacker_team, SPRITERULE_TEAMPLAY);
 199                 if(ent.classname == "func_assault_destructible")
 200                 {
 201                         WaypointSprite_UpdateSprites(spr, WP_AssaultDefend, WP_AssaultDestroy, WP_AssaultDestroy);
 202                         WaypointSprite_UpdateMaxHealth(spr, ent.max_health);
 203                         WaypointSprite_UpdateHealth(spr, ent.health);
 204                         ent.sprite = spr;
 205                 }
 206                 else
 207                         WaypointSprite_UpdateSprites(spr, WP_AssaultDefend, WP_AssaultPush, WP_AssaultPush);
 208         }
 209 }
 210
 211 void target_objective_decrease_findtarget()
 212 {
 213         assault_setenemytoobjective();
 214 }
 215
 216 void target_assault_roundend_reset(entity this)
 217 {
 218         //print("round end reset\n");
 219         ++this.cnt; // up round counter
 220         this.winning = false; // up round
 221 }
 222
 223 void target_assault_roundend_use()
 224 {SELFPARAM();
 225         self.winning = 1; // round has been won by attackers
 226 }
 227
 228 void assault_roundstart_use()
 229 {SELFPARAM();
 230         activator = self;
 231         SUB_UseTargets();
 232
 233         //(Re)spawn all turrets
 234         FOREACH_ENTITY_CLASS("turret_main", true, LAMBDA(
 235                 // Swap turret teams
 236                 if(it.team == NUM_TEAM_1)
 237                         it.team = NUM_TEAM_2;
 238                 else
 239                         it.team = NUM_TEAM_1;
 240
 241                 // Dubbles as teamchange
 242                 WITH(entity, self, it, turret_respawn());
 243         ));
 244 }
 245
 246 void assault_wall_think()
 247 {SELFPARAM();
 248         if(self.enemy.health < 0)
 249         {
 250                 self.model = "";
 251                 self.solid = SOLID_NOT;
 252         }
 253         else
 254         {
 255                 self.model = self.mdl;
 256                 self.solid = SOLID_BSP;
 257         }
 258
 259         self.nextthink = time + 0.2;
 260 }
 261
 262 // trigger new round
 263 // reset objectives, toggle spawnpoints, reset triggers, ...
 264 void vehicles_clearreturn(entity veh);
 265 void vehicles_spawn();
 266 void assault_new_round()
 267 {SELFPARAM();
 268         //bprint("ASSAULT: new round\n");
 269
 270         // Eject players from vehicles
 271     FOREACH_CLIENT(IS_PLAYER(it) && it.vehicle, LAMBDA(WITH(entity, self, it, vehicles_exit(VHEF_RELEASE))));
 272
 273     FOREACH_ENTITY_FLAGS(vehicle_flags, VHF_ISVEHICLE, LAMBDA(
 274         setself(it);
 275         vehicles_clearreturn(self);
 276         vehicles_spawn();
 277     ));
 278
 279     setself(this);
 280
 281         // up round counter
 282         self.winning = self.winning + 1;
 283
 284         // swap attacker/defender roles
 285         if(assault_attacker_team == NUM_TEAM_1)
 286                 assault_attacker_team = NUM_TEAM_2;
 287         else
 288                 assault_attacker_team = NUM_TEAM_1;
 289
 290         FOREACH_ENTITY(IS_NOT_A_CLIENT(it), LAMBDA(
 291                 if (it.team_saved == NUM_TEAM_1) it.team_saved = NUM_TEAM_2;
 292                 else if (it.team_saved == NUM_TEAM_2) it.team_saved = NUM_TEAM_1;
 293         ));
 294
 295         // reset the level with a countdown
 296         cvar_set("timelimit", ftos(ceil(time - game_starttime) / 60));
 297         ReadyRestart_force(); // sets game_starttime
 298 }
 299
 300 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
 301 // they win. Otherwise the defending team wins once the timelimit passes.
 302 int WinningCondition_Assault()
 303 {
 304         WinningConditionHelper(); // set worldstatus
 305
 306         int status = WINNING_NO;
 307         // as the timelimit has not yet passed just assume the defending team will win
 308         if(assault_attacker_team == NUM_TEAM_1)
 309         {
 310                 SetWinners(team, NUM_TEAM_2);
 311         }
 312         else
 313         {
 314                 SetWinners(team, NUM_TEAM_1);
 315         }
 316
 317         entity ent;
 318         ent = find(world, classname, "target_assault_roundend");
 319         if(ent)
 320         {
 321                 if(ent.winning) // round end has been triggered by attacking team
 322                 {
 323                         bprint("ASSAULT: round completed...\n");
 324                         SetWinners(team, assault_attacker_team);
 325
 326                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
 327
 328                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
 329                         {
 330                                 status = WINNING_YES;
 331                         }
 332                         else
 333                         {
 334                                 WITH(entity, self, ent, assault_new_round());
 335                         }
 336                 }
 337         }
 338
 339         return status;
 340 }
 341
 342 // spawnfuncs
 343 spawnfunc(info_player_attacker)
 344 {
 345         if (!g_assault) { remove(self); return; }
 346
 347         self.team = NUM_TEAM_1; // red, gets swapped every round
 348         spawnfunc_info_player_deathmatch(this);
 349 }
 350
 351 spawnfunc(info_player_defender)
 352 {
 353         if (!g_assault) { remove(self); return; }
 354
 355         self.team = NUM_TEAM_2; // blue, gets swapped every round
 356         spawnfunc_info_player_deathmatch(this);
 357 }
 358
 359 spawnfunc(target_objective)
 360 {
 361         if (!g_assault) { remove(this); return; }
 362
 363         this.classname = "target_objective";
 364         this.use = assault_objective_use;
 365         this.reset = assault_objective_reset;
 366         this.reset(this);
 367         this.spawn_evalfunc = target_objective_spawn_evalfunc;
 368 }
 369
 370 spawnfunc(target_objective_decrease)
 371 {
 372         if (!g_assault) { remove(self); return; }
 373
 374         self.classname = "target_objective_decrease";
 375
 376         if(!self.dmg)
 377                 self.dmg = 101;
 378
 379         self.use = assault_objective_decrease_use;
 380         self.health = ASSAULT_VALUE_INACTIVE;
 381         self.max_health = ASSAULT_VALUE_INACTIVE;
 382         self.enemy = world;
 383
 384         InitializeEntity(self, target_objective_decrease_findtarget, INITPRIO_FINDTARGET);
 385 }
 386
 387 // destructible walls that can be used to trigger target_objective_decrease
 388 spawnfunc(func_breakable);
 389 spawnfunc(func_assault_destructible)
 390 {
 391         if (!g_assault) { remove(self); return; }
 392
 393         self.spawnflags = 3;
 394         self.classname = "func_assault_destructible";
 395
 396         if(assault_attacker_team == NUM_TEAM_1)
 397                 self.team = NUM_TEAM_2;
 398         else
 399                 self.team = NUM_TEAM_1;
 400
 401         spawnfunc_func_breakable(this);
 402 }
 403
 404 spawnfunc(func_assault_wall)
 405 {
 406         if (!g_assault) { remove(self); return; }
 407
 408         self.classname = "func_assault_wall";
 409         self.mdl = self.model;
 410         _setmodel(self, self.mdl);
 411         self.solid = SOLID_BSP;
 412         self.think = assault_wall_think;
 413         self.nextthink = time;
 414         InitializeEntity(self, assault_setenemytoobjective, INITPRIO_FINDTARGET);
 415 }
 416
 417 spawnfunc(target_assault_roundend)
 418 {
 419         if (!g_assault) { remove(self); return; }
 420
 421         self.winning = 0; // round not yet won by attackers
 422         self.classname = "target_assault_roundend";
 423         self.use = target_assault_roundend_use;
 424         self.cnt = 0; // first round
 425         self.reset = target_assault_roundend_reset;
 426 }
 427
 428 spawnfunc(target_assault_roundstart)
 429 {
 430         if (!g_assault) { remove(self); return; }
 431
 432         assault_attacker_team = NUM_TEAM_1;
 433         self.classname = "target_assault_roundstart";
 434         self.use = assault_roundstart_use;
 435         self.reset2 = assault_roundstart_use;
 436         InitializeEntity(self, assault_roundstart_use, INITPRIO_FINDTARGET);
 437 }
 438
 439 // legacy bot code
 440 void havocbot_goalrating_ast_targets(float ratingscale)
 441 {SELFPARAM();
 442         entity ad, best, wp, tod;
 443         float radius, found, bestvalue;
 444         vector p;
 445
 446         ad = findchain(classname, "func_assault_destructible");
 447
 448         for (; ad; ad = ad.chain)
 449         {
 450                 if (ad.target == "")
 451                         continue;
 452
 453                 if (!ad.bot_attack)
 454                         continue;
 455
 456                 found = false;
 457                 for(tod = world; (tod = find(tod, targetname, ad.target)); )
 458                 {
 459                         if(tod.classname == "target_objective_decrease")
 460                         {
 461                                 if(tod.enemy.health > 0 && tod.enemy.health < ASSAULT_VALUE_INACTIVE)
 462                                 {
 463                                 //      dprint(etos(ad),"\n");
 464                                         found = true;
 465                                         break;
 466                                 }
 467                         }
 468                 }
 469
 470                 if(!found)
 471                 {
 472                 ///     dprint("target not found\n");
 473                         continue;
 474                 }
 475                 /// dprint("target #", etos(ad), " found\n");
 476
 477
 478                 p = 0.5 * (ad.absmin + ad.absmax);
 479         //      dprint(vtos(ad.origin), " ", vtos(ad.absmin), " ", vtos(ad.absmax),"\n");
 480         //      te_knightspike(p);
 481         //      te_lightning2(world, '0 0 0', p);
 482
 483                 // Find and rate waypoints around it
 484                 found = false;
 485                 best = world;
 486                 bestvalue = 99999999999;
 487                 for(radius=0; radius<1500 && !found; radius+=500)
 488                 {
 489                         for(wp=findradius(p, radius); wp; wp=wp.chain)
 490                         {
 491                                 if(!(wp.wpflags & WAYPOINTFLAG_GENERATED))
 492                                 if(wp.classname=="waypoint")
 493                                 if(checkpvs(wp.origin, ad))
 494                                 {
 495                                         found = true;
 496                                         if(wp.cnt<bestvalue)
 497                                         {
 498                                                 best = wp;
 499                                                 bestvalue = wp.cnt;
 500                                         }
 501                                 }
 502                         }
 503                 }
 504
 505                 if(best)
 506                 {
 507                 ///     dprint("waypoints around target were found\n");
 508                 //      te_lightning2(world, '0 0 0', best.origin);
 509                 //      te_knightspike(best.origin);
 510
 511                         navigation_routerating(best, ratingscale, 4000);
 512                         best.cnt += 1;
 513
 514                         self.havocbot_attack_time = 0;
 515
 516                         if(checkpvs(self.view_ofs,ad))
 517                         if(checkpvs(self.view_ofs,best))
 518                         {
 519                         //      dprint("increasing attack time for this target\n");
 520                                 self.havocbot_attack_time = time + 2;
 521                         }
 522                 }
 523         }
 524 }
 525
 526 void havocbot_role_ast_offense()
 527 {SELFPARAM();
 528         if(IS_DEAD(self))
 529         {
 530                 self.havocbot_attack_time = 0;
 531                 havocbot_ast_reset_role(self);
 532                 return;
 533         }
 534
 535         // Set the role timeout if necessary
 536         if (!self.havocbot_role_timeout)
 537                 self.havocbot_role_timeout = time + 120;
 538
 539         if (time > self.havocbot_role_timeout)
 540         {
 541                 havocbot_ast_reset_role(self);
 542                 return;
 543         }
 544
 545         if(self.havocbot_attack_time>time)
 546                 return;
 547
 548         if (self.bot_strategytime < time)
 549         {
 550                 navigation_goalrating_start();
 551                 havocbot_goalrating_enemyplayers(20000, self.origin, 650);
 552                 havocbot_goalrating_ast_targets(20000);
 553                 havocbot_goalrating_items(15000, self.origin, 10000);
 554                 navigation_goalrating_end();
 555
 556                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 557         }
 558 }
 559
 560 void havocbot_role_ast_defense()
 561 {SELFPARAM();
 562         if(IS_DEAD(self))
 563         {
 564                 self.havocbot_attack_time = 0;
 565                 havocbot_ast_reset_role(self);
 566                 return;
 567         }
 568
 569         // Set the role timeout if necessary
 570         if (!self.havocbot_role_timeout)
 571                 self.havocbot_role_timeout = time + 120;
 572
 573         if (time > self.havocbot_role_timeout)
 574         {
 575                 havocbot_ast_reset_role(self);
 576                 return;
 577         }
 578
 579         if(self.havocbot_attack_time>time)
 580                 return;
 581
 582         if (self.bot_strategytime < time)
 583         {
 584                 navigation_goalrating_start();
 585                 havocbot_goalrating_enemyplayers(20000, self.origin, 3000);
 586                 havocbot_goalrating_ast_targets(20000);
 587                 havocbot_goalrating_items(15000, self.origin, 10000);
 588                 navigation_goalrating_end();
 589
 590                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 591         }
 592 }
 593
 594 void havocbot_role_ast_setrole(entity bot, float role)
 595 {
 596         switch(role)
 597         {
 598                 case HAVOCBOT_AST_ROLE_DEFENSE:
 599                         bot.havocbot_role = havocbot_role_ast_defense;
 600                         bot.havocbot_role_flags = HAVOCBOT_AST_ROLE_DEFENSE;
 601                         bot.havocbot_role_timeout = 0;
 602                         break;
 603                 case HAVOCBOT_AST_ROLE_OFFENSE:
 604                         bot.havocbot_role = havocbot_role_ast_offense;
 605                         bot.havocbot_role_flags = HAVOCBOT_AST_ROLE_OFFENSE;
 606                         bot.havocbot_role_timeout = 0;
 607                         break;
 608         }
 609 }
 610
 611 void havocbot_ast_reset_role(entity bot)
 612 {SELFPARAM();
 613         if(IS_DEAD(self))
 614                 return;
 615
 616         if(bot.team == assault_attacker_team)
 617                 havocbot_role_ast_setrole(bot, HAVOCBOT_AST_ROLE_OFFENSE);
 618         else
 619                 havocbot_role_ast_setrole(bot, HAVOCBOT_AST_ROLE_DEFENSE);
 620 }
 621
 622 // mutator hooks
 623 MUTATOR_HOOKFUNCTION(as, PlayerSpawn)
 624 {SELFPARAM();
 625         if(self.team == assault_attacker_team)
 626                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
 627         else
 628                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
 629
 630         return false;
 631 }
 632
 633 MUTATOR_HOOKFUNCTION(as, TurretSpawn)
 634 {SELFPARAM();
 635         if(!self.team || self.team == MAX_SHOT_DISTANCE)
 636                 self.team = 5; // this gets reversed when match starts?
 637
 638         return false;
 639 }
 640
 641 MUTATOR_HOOKFUNCTION(as, VehicleSpawn)
 642 {SELFPARAM();
 643         self.nextthink = time + 0.5;
 644
 645         return false;
 646 }
 647
 648 MUTATOR_HOOKFUNCTION(as, HavocBot_ChooseRole)
 649 {SELFPARAM();
 650         havocbot_ast_reset_role(self);
 651         return true;
 652 }
 653
 654 MUTATOR_HOOKFUNCTION(as, PlayHitsound)
 655 {
 656         return (frag_victim.classname == "func_assault_destructible");
 657 }
 658
 659 MUTATOR_HOOKFUNCTION(as, GetTeamCount)
 660 {
 661         // assault always has 2 teams
 662         c1 = c2 = 0;
 663         return true;
 664 }
 665
 666 MUTATOR_HOOKFUNCTION(as, CheckRules_World)
 667 {
 668         ret_float = WinningCondition_Assault();
 669         return true;
 670 }
 671
 672 MUTATOR_HOOKFUNCTION(as, ReadLevelCvars)
 673 {
 674         // no assault warmups
 675         warmup_stage = 0;
 676         return false;
 677 }
 678
 679 MUTATOR_HOOKFUNCTION(as, OnEntityPreSpawn)
 680 {
 681         switch(self.classname)
 682         {
 683                 case "info_player_team1":
 684                 case "info_player_team2":
 685                 case "info_player_team3":
 686                 case "info_player_team4":
 687                         return true;
 688         }
 689
 690         return false;
 691 }
 692
 693 // scoreboard setup
 694 void assault_ScoreRules()
 695 {
 696         ScoreRules_basics(2, SFL_SORT_PRIO_SECONDARY, SFL_SORT_PRIO_SECONDARY, true);
 697         ScoreInfo_SetLabel_TeamScore(  ST_ASSAULT_OBJECTIVES,    "objectives",      SFL_SORT_PRIO_PRIMARY);
 698         ScoreInfo_SetLabel_PlayerScore(SP_ASSAULT_OBJECTIVES,    "objectives",      SFL_SORT_PRIO_PRIMARY);
 699         ScoreRules_basics_end();
 700 }
 701
 702 #endif