qcsrc/server/mutators/mutator/gamemode_ca.qc

   1 #include "gamemode_ca.qh"
   2 #ifndef GAMEMODE_CA_H
   3 #define GAMEMODE_CA_H
   4
   5 int autocvar_g_ca_point_limit;
   6 int autocvar_g_ca_point_leadlimit;
   7 float autocvar_g_ca_round_timelimit;
   8 bool autocvar_g_ca_team_spawns;
   9 int autocvar_g_ca_teams;
  10 int autocvar_g_ca_teams_override;
  11 float autocvar_g_ca_warmup;
  12
  13
  14 int ca_teams;
  15 bool allowed_to_spawn;
  16
  17 const int ST_CA_ROUNDS = 1;
  18
  19 bool CA_CheckTeams();
  20 bool CA_CheckWinner();
  21 void CA_RoundStart();
  22 bool ca_isEliminated(entity e);
  23
  24 REGISTER_MUTATOR(ca, false)
  25 {
  26         MUTATOR_ONADD
  27         {
  28                 // game loads at time 1
  29                 if (time > 1) error("This is a game type and it cannot be added at runtime.");
  30
  31                 allowed_to_spawn = true;
  32
  33                 ca_teams = autocvar_g_ca_teams_override;
  34                 if (ca_teams < 2) ca_teams = autocvar_g_ca_teams;
  35                 ca_teams = bound(2, ca_teams, 4);
  36                 ret_float = ca_teams;
  37
  38         ScoreRules_basics(ca_teams, SFL_SORT_PRIO_PRIMARY, 0, true);
  39         ScoreInfo_SetLabel_TeamScore(ST_CA_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
  40         ScoreRules_basics_end();
  41
  42                 round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
  43                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  44
  45                 EliminatedPlayers_Init(ca_isEliminated);
  46
  47                 ActivateTeamplay();
  48                 SetLimits(autocvar_g_ca_point_limit, autocvar_g_ca_point_leadlimit, -1, -1);
  49
  50                 if (autocvar_g_ca_team_spawns)
  51                         have_team_spawns = -1; // request team spawns
  52         }
  53
  54         MUTATOR_ONREMOVE
  55         {
  56                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  57                 return -1;
  58         }
  59
  60         return 0;
  61 }
  62
  63 // should be removed in the future, as other code should not have to care
  64 .float caplayer; // 0.5 if scheduled to join the next round
  65 #endif
  66
  67 #ifdef IMPLEMENTATION
  68 float autocvar_g_ca_damage2score_multiplier;
  69 bool autocvar_g_ca_spectate_enemies;
  70
  71 void CA_count_alive_players()
  72 {
  73         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  74         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  75                 switch(it.team)
  76                 {
  77                         case NUM_TEAM_1: ++total_players; if(!IS_DEAD(it)) ++redalive; break;
  78                         case NUM_TEAM_2: ++total_players; if(!IS_DEAD(it)) ++bluealive; break;
  79                         case NUM_TEAM_3: ++total_players; if(!IS_DEAD(it)) ++yellowalive; break;
  80                         case NUM_TEAM_4: ++total_players; if(!IS_DEAD(it)) ++pinkalive; break;
  81                 }
  82         ));
  83         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  84                 it.redalive_stat = redalive;
  85                 it.bluealive_stat = bluealive;
  86                 it.yellowalive_stat = yellowalive;
  87                 it.pinkalive_stat = pinkalive;
  88         ));
  89 }
  90
  91 float CA_GetWinnerTeam()
  92 {
  93         float winner_team = 0;
  94         if(redalive >= 1)
  95                 winner_team = NUM_TEAM_1;
  96         if(bluealive >= 1)
  97         {
  98                 if(winner_team) return 0;
  99                 winner_team = NUM_TEAM_2;
 100         }
 101         if(yellowalive >= 1)
 102         {
 103                 if(winner_team) return 0;
 104                 winner_team = NUM_TEAM_3;
 105         }
 106         if(pinkalive >= 1)
 107         {
 108                 if(winner_team) return 0;
 109                 winner_team = NUM_TEAM_4;
 110         }
 111         if(winner_team)
 112                 return winner_team;
 113         return -1; // no player left
 114 }
 115
 116 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
 117 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
 118 float CA_CheckWinner()
 119 {
 120         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 121         {
 122                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
 123                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
 124                 allowed_to_spawn = false;
 125                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 126                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
 127                 return 1;
 128         }
 129
 130         CA_count_alive_players();
 131         if(CA_ALIVE_TEAMS() > 1)
 132                 return 0;
 133
 134         int winner_team = CA_GetWinnerTeam();
 135         if(winner_team > 0)
 136         {
 137                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 138                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 139                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
 140         }
 141         else if(winner_team == -1)
 142         {
 143                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
 144                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
 145         }
 146
 147         allowed_to_spawn = false;
 148         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 149
 150         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
 151
 152         return 1;
 153 }
 154
 155 void CA_RoundStart()
 156 {
 157     allowed_to_spawn = boolean(warmup_stage);
 158 }
 159
 160 bool CA_CheckTeams()
 161 {
 162         static int prev_missing_teams_mask;
 163         allowed_to_spawn = true;
 164         CA_count_alive_players();
 165         if(CA_ALIVE_TEAMS_OK())
 166         {
 167                 if(prev_missing_teams_mask > 0)
 168                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 169                 prev_missing_teams_mask = -1;
 170                 return true;
 171         }
 172         if(total_players == 0)
 173         {
 174                 if(prev_missing_teams_mask > 0)
 175                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 176                 prev_missing_teams_mask = -1;
 177                 return false;
 178         }
 179         int missing_teams_mask = (!redalive) + (!bluealive) * 2;
 180         if(ca_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 181         if(ca_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 182         if(prev_missing_teams_mask != missing_teams_mask)
 183         {
 184                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 185                 prev_missing_teams_mask = missing_teams_mask;
 186         }
 187         return false;
 188 }
 189
 190 bool ca_isEliminated(entity e)
 191 {
 192         if(e.caplayer == 1 && (IS_DEAD(e) || e.frags == FRAGS_LMS_LOSER))
 193                 return true;
 194         if(e.caplayer == 0.5)
 195                 return true;
 196         return false;
 197 }
 198
 199 /** Returns next available player to spectate if g_ca_spectate_enemies == 0 */
 200 entity CA_SpectateNext(entity player, entity start)
 201 {
 202         if (SAME_TEAM(start, player)) return start;
 203         // continue from current player
 204         for (entity e = start; (e = find(e, classname, STR_PLAYER)); )
 205         {
 206                 if (SAME_TEAM(player, e)) return e;
 207         }
 208         // restart from begining
 209         for (entity e = NULL; (e = find(e, classname, STR_PLAYER)); )
 210         {
 211                 if (SAME_TEAM(player, e)) return e;
 212         }
 213         return start;
 214 }
 215
 216
 217 MUTATOR_HOOKFUNCTION(ca, PlayerSpawn)
 218 {
 219     SELFPARAM();
 220         this.caplayer = 1;
 221         if (!warmup_stage)
 222                 eliminatedPlayers.SendFlags |= 1;
 223 }
 224
 225 MUTATOR_HOOKFUNCTION(ca, PutClientInServer)
 226 {
 227     SELFPARAM();
 228         if (!allowed_to_spawn && IS_PLAYER(this)) // this is true even when player is trying to join
 229         {
 230                 this.classname = STR_OBSERVER;
 231                 if (this.jointime != time && !this.caplayer) // not when connecting
 232                 {
 233                         this.caplayer = 0.5;
 234                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CA_JOIN_LATE);
 235                 }
 236         }
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(ca, reset_map_players)
 240 {
 241         FOREACH_CLIENT(true, {
 242                 it.killcount = 0;
 243                 if (!it.caplayer && IS_BOT_CLIENT(it))
 244                 {
 245                         it.team = -1;
 246                         it.caplayer = 1;
 247                 }
 248                 if (it.caplayer)
 249                 {
 250                         it.classname = STR_PLAYER;
 251                         it.caplayer = 1;
 252                         WITH(entity, self, it, PutClientInServer());
 253                 }
 254         });
 255         return true;
 256 }
 257
 258 MUTATOR_HOOKFUNCTION(ca, ClientConnect)
 259 {
 260     SELFPARAM();
 261         this.classname = STR_OBSERVER;
 262         return true;
 263 }
 264
 265 MUTATOR_HOOKFUNCTION(ca, reset_map_global)
 266 {
 267         allowed_to_spawn = true;
 268         return true;
 269 }
 270
 271 MUTATOR_HOOKFUNCTION(ca, GetTeamCount, CBC_ORDER_EXCLUSIVE)
 272 {
 273         ret_float = ca_teams;
 274         return false;
 275 }
 276
 277 entity ca_LastPlayerForTeam()
 278 {
 279     SELFPARAM();
 280         entity last_pl = NULL;
 281         FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 282                 if (!IS_DEAD(it))
 283                 if (SAME_TEAM(this, it))
 284                 if (!last_pl)
 285                         last_pl = it;
 286                 else
 287                         return NULL;
 288         });
 289         return last_pl;
 290 }
 291
 292 void ca_LastPlayerForTeam_Notify()
 293 {
 294         if (round_handler_IsActive())
 295         if (round_handler_IsRoundStarted())
 296         {
 297                 entity pl = ca_LastPlayerForTeam();
 298                 if (pl)
 299                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 300         }
 301 }
 302
 303 MUTATOR_HOOKFUNCTION(ca, PlayerDies)
 304 {
 305         ca_LastPlayerForTeam_Notify();
 306         if (!allowed_to_spawn)
 307                 frag_target.respawn_flags =  RESPAWN_SILENT;
 308         if (!warmup_stage)
 309                 eliminatedPlayers.SendFlags |= 1;
 310         return 1;
 311 }
 312
 313 MUTATOR_HOOKFUNCTION(ca, ClientDisconnect)
 314 {
 315     SELFPARAM();
 316         if (this.caplayer == 1)
 317                 ca_LastPlayerForTeam_Notify();
 318         return 1;
 319 }
 320
 321 MUTATOR_HOOKFUNCTION(ca, ForbidPlayerScore_Clear)
 322 {
 323         return 1;
 324 }
 325
 326 MUTATOR_HOOKFUNCTION(ca, MakePlayerObserver)
 327 {
 328     SELFPARAM();
 329         if (this.caplayer == 1)
 330                 ca_LastPlayerForTeam_Notify();
 331         if (this.killindicator_teamchange == -2)
 332                 this.caplayer = 0;
 333         if (this.caplayer)
 334                 this.frags = FRAGS_LMS_LOSER;
 335         if (!warmup_stage)
 336                 eliminatedPlayers.SendFlags |= 1;
 337         return true;  // prevent team reset
 338 }
 339
 340 MUTATOR_HOOKFUNCTION(ca, ForbidThrowCurrentWeapon)
 341 {
 342         return 1;
 343 }
 344
 345 MUTATOR_HOOKFUNCTION(ca, GiveFragsForKill, CBC_ORDER_FIRST)
 346 {
 347         frag_score = 0; // score will be given to the winner team when the round ends
 348         return 1;
 349 }
 350
 351 MUTATOR_HOOKFUNCTION(ca, SetStartItems)
 352 {
 353         start_items       &= ~IT_UNLIMITED_AMMO;
 354         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 355         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 356         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 357         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 358         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 359         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 360         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 361         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 362
 363         return 0;
 364 }
 365
 366 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_Calculate)
 367 {
 368         if (IS_PLAYER(frag_target))
 369         if (!IS_DEAD(frag_target))
 370         if (frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL.m_id)
 371                 frag_damage = 0;
 372
 373         frag_mirrordamage = 0;
 374
 375         return false;
 376 }
 377
 378 MUTATOR_HOOKFUNCTION(ca, FilterItem)
 379 {
 380     SELFPARAM();
 381         if (autocvar_g_powerups <= 0)
 382         if (this.flags & FL_POWERUP)
 383                 return true;
 384
 385         if (autocvar_g_pickup_items <= 0)
 386                 return true;
 387
 388         return false;
 389 }
 390
 391 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_SplitHealthArmor)
 392 {
 393         float excess = max(0, frag_damage - damage_take - damage_save);
 394
 395         if (frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 396                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 397
 398         return false;
 399 }
 400
 401 MUTATOR_HOOKFUNCTION(ca, PlayerRegen)
 402 {
 403         // no regeneration in CA
 404         return true;
 405 }
 406
 407 MUTATOR_HOOKFUNCTION(ca, Scores_CountFragsRemaining)
 408 {
 409         // announce remaining frags
 410         return true;
 411 }
 412
 413 MUTATOR_HOOKFUNCTION(ca, SpectateSet)
 414 {
 415     SELFPARAM();
 416         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 417         if (DIFF_TEAM(spec_player, this))
 418                 return true;
 419         return false;
 420 }
 421
 422 MUTATOR_HOOKFUNCTION(ca, SpectateNext)
 423 {
 424     SELFPARAM();
 425         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 426         {
 427                 spec_player = CA_SpectateNext(this, spec_player);
 428                 return true;
 429         }
 430         return false;
 431 }
 432
 433 MUTATOR_HOOKFUNCTION(ca, SpectatePrev)
 434 {
 435     SELFPARAM();
 436         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 437         {
 438                 do { spec_player = spec_player.chain; }
 439                 while(spec_player && DIFF_TEAM(spec_player, this));
 440
 441                 if (!spec_player)
 442                 {
 443                         for (spec_player = spec_first; spec_player && DIFF_TEAM(spec_player, this); spec_player = spec_player.chain);
 444
 445                         if (spec_player == this.enemy)
 446                                 return MUT_SPECPREV_RETURN;
 447                 }
 448         }
 449
 450         return MUT_SPECPREV_FOUND;
 451 }
 452
 453 MUTATOR_HOOKFUNCTION(ca, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 454 {
 455         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 456                 if (IS_PLAYER(it) || it.caplayer == 1)
 457                         ++bot_activerealplayers;
 458                 ++bot_realplayers;
 459         });
 460         return true;
 461 }
 462
 463 MUTATOR_HOOKFUNCTION(ca, ClientCommand_Spectate)
 464 {
 465     SELFPARAM();
 466         if (this.caplayer)
 467         {
 468                 // they're going to spec, we can do other checks
 469                 if (autocvar_sv_spectate && (IS_SPEC(this) || IS_OBSERVER(this)))
 470                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CA_LEAVE);
 471                 return MUT_SPECCMD_FORCE;
 472         }
 473
 474         return MUT_SPECCMD_CONTINUE;
 475 }
 476
 477 MUTATOR_HOOKFUNCTION(ca, WantWeapon)
 478 {
 479         want_allguns = true;
 480         return false;
 481 }
 482
 483 MUTATOR_HOOKFUNCTION(ca, GetPlayerStatus)
 484 {
 485         return set_player.caplayer == 1;
 486 }
 487
 488 MUTATOR_HOOKFUNCTION(ca, SetWeaponArena)
 489 {
 490         // most weapons arena
 491         if (ret_string == "0" || ret_string == "") ret_string = "most";
 492 }
 493
 494 #endif