CA: Reset .team when a player chooses to spectate; remove ForbidPlayerScore_Clear...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator / gamemode_ca.qc
1 #include "gamemode_ca.qh"
2
3 float autocvar_g_ca_damage2score_multiplier;
4 bool autocvar_g_ca_spectate_enemies;
5
6 void CA_count_alive_players()
7 {
8         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
9         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
10                 switch(it.team)
11                 {
12                         case NUM_TEAM_1: ++total_players; if(!IS_DEAD(it)) ++redalive; break;
13                         case NUM_TEAM_2: ++total_players; if(!IS_DEAD(it)) ++bluealive; break;
14                         case NUM_TEAM_3: ++total_players; if(!IS_DEAD(it)) ++yellowalive; break;
15                         case NUM_TEAM_4: ++total_players; if(!IS_DEAD(it)) ++pinkalive; break;
16                 }
17         ));
18         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
19                 it.redalive_stat = redalive;
20                 it.bluealive_stat = bluealive;
21                 it.yellowalive_stat = yellowalive;
22                 it.pinkalive_stat = pinkalive;
23         ));
24 }
25
26 float CA_GetWinnerTeam()
27 {
28         float winner_team = 0;
29         if(redalive >= 1)
30                 winner_team = NUM_TEAM_1;
31         if(bluealive >= 1)
32         {
33                 if(winner_team) return 0;
34                 winner_team = NUM_TEAM_2;
35         }
36         if(yellowalive >= 1)
37         {
38                 if(winner_team) return 0;
39                 winner_team = NUM_TEAM_3;
40         }
41         if(pinkalive >= 1)
42         {
43                 if(winner_team) return 0;
44                 winner_team = NUM_TEAM_4;
45         }
46         if(winner_team)
47                 return winner_team;
48         return -1; // no player left
49 }
50
51 void nades_Clear(entity player);
52
53 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
54 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == NumTeams(ca_teams))
55 float CA_CheckWinner()
56 {
57         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
58         {
59                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
60                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
61                 allowed_to_spawn = false;
62                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
63                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
64                 return 1;
65         }
66
67         CA_count_alive_players();
68         if(CA_ALIVE_TEAMS() > 1)
69                 return 0;
70
71         int winner_team = CA_GetWinnerTeam();
72         if(winner_team > 0)
73         {
74                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
75                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
76                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
77         }
78         else if(winner_team == -1)
79         {
80                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
81                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
82         }
83
84         allowed_to_spawn = false;
85         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
86
87         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
88
89         return 1;
90 }
91
92 void CA_RoundStart()
93 {
94     allowed_to_spawn = boolean(warmup_stage);
95 }
96
97 bool CA_CheckTeams()
98 {
99         static int prev_missing_teams_mask;
100         allowed_to_spawn = true;
101         CA_count_alive_players();
102         if(CA_ALIVE_TEAMS_OK())
103         {
104                 if(prev_missing_teams_mask > 0)
105                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
106                 prev_missing_teams_mask = -1;
107                 return true;
108         }
109         if(total_players == 0)
110         {
111                 if(prev_missing_teams_mask > 0)
112                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
113                 prev_missing_teams_mask = -1;
114                 return false;
115         }
116         int missing_teams_mask = 0;
117         if(ca_teams & BIT(0))
118                 missing_teams_mask += (!redalive) * 1;
119         if(ca_teams & BIT(1))
120                 missing_teams_mask += (!bluealive) * 2;
121         if(ca_teams & BIT(2))
122                 missing_teams_mask += (!yellowalive) * 4;
123         if(ca_teams & BIT(3))
124                 missing_teams_mask += (!pinkalive) * 8;
125         if(prev_missing_teams_mask != missing_teams_mask)
126         {
127                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
128                 prev_missing_teams_mask = missing_teams_mask;
129         }
130         return false;
131 }
132
133 bool ca_isEliminated(entity e)
134 {
135         if(e.caplayer == 1 && (IS_DEAD(e) || e.frags == FRAGS_LMS_LOSER))
136                 return true;
137         if(e.caplayer == 0.5)
138                 return true;
139         return false;
140 }
141
142 /** Returns next available player to spectate if g_ca_spectate_enemies == 0 */
143 entity CA_SpectateNext(entity player, entity start)
144 {
145         if (SAME_TEAM(start, player)) return start;
146         // continue from current player
147         for (entity e = start; (e = find(e, classname, STR_PLAYER)); )
148         {
149                 if (SAME_TEAM(player, e)) return e;
150         }
151         // restart from begining
152         for (entity e = NULL; (e = find(e, classname, STR_PLAYER)); )
153         {
154                 if (SAME_TEAM(player, e)) return e;
155         }
156         return start;
157 }
158
159
160 MUTATOR_HOOKFUNCTION(ca, PlayerSpawn)
161 {
162     entity player = M_ARGV(0, entity);
163
164         player.caplayer = 1;
165         if (!warmup_stage)
166                 eliminatedPlayers.SendFlags |= 1;
167 }
168
169 MUTATOR_HOOKFUNCTION(ca, ForbidSpawn)
170 {
171         entity player = M_ARGV(0, entity);
172
173         // spectators / observers that weren't playing can join; they are
174         // immediately forced to observe in the PutClientInServer hook
175         // this way they are put in a team and can play in the next round
176         if (!allowed_to_spawn && player.caplayer)
177                 return true;
178         return false;
179 }
180
181 MUTATOR_HOOKFUNCTION(ca, PutClientInServer)
182 {
183         entity player = M_ARGV(0, entity);
184
185         if (!allowed_to_spawn && IS_PLAYER(player)) // this is true even when player is trying to join
186         {
187                 TRANSMUTE(Observer, player);
188                 if (player.jointime != time && !player.caplayer) // not when connecting
189                 {
190                         player.caplayer = 0.5;
191                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_JOIN_LATE);
192                 }
193         }
194 }
195
196 MUTATOR_HOOKFUNCTION(ca, reset_map_players)
197 {
198         FOREACH_CLIENT(true, {
199                 it.killcount = 0;
200                 if (!it.caplayer && IS_BOT_CLIENT(it))
201                 {
202                         it.team = -1;
203                         it.caplayer = 1;
204                 }
205                 if (it.caplayer)
206                 {
207                         TRANSMUTE(Player, it);
208                         it.caplayer = 1;
209                         PutClientInServer(it);
210                 }
211         });
212         return true;
213 }
214
215 MUTATOR_HOOKFUNCTION(ca, ClientConnect)
216 {
217     entity player = M_ARGV(0, entity);
218
219         TRANSMUTE(Observer, player);
220         return true;
221 }
222
223 MUTATOR_HOOKFUNCTION(ca, reset_map_global)
224 {
225         allowed_to_spawn = true;
226         return true;
227 }
228
229 MUTATOR_HOOKFUNCTION(ca, GetTeamCount, CBC_ORDER_EXCLUSIVE)
230 {
231         M_ARGV(0, float) = ca_teams;
232 }
233
234 entity ca_LastPlayerForTeam(entity this)
235 {
236         entity last_pl = NULL;
237         FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
238                 if (!IS_DEAD(it))
239                 if (SAME_TEAM(this, it))
240                 if (!last_pl)
241                         last_pl = it;
242                 else
243                         return NULL;
244         });
245         return last_pl;
246 }
247
248 void ca_LastPlayerForTeam_Notify(entity this)
249 {
250         if (round_handler_IsActive())
251         if (round_handler_IsRoundStarted())
252         {
253                 entity pl = ca_LastPlayerForTeam(this);
254                 if (pl)
255                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
256         }
257 }
258
259 MUTATOR_HOOKFUNCTION(ca, PlayerDies)
260 {
261         entity frag_target = M_ARGV(2, entity);
262
263         ca_LastPlayerForTeam_Notify(frag_target);
264         if (!allowed_to_spawn)
265                 frag_target.respawn_flags =  RESPAWN_SILENT;
266         if (!warmup_stage)
267                 eliminatedPlayers.SendFlags |= 1;
268         return true;
269 }
270
271 MUTATOR_HOOKFUNCTION(ca, ClientDisconnect)
272 {
273     entity player = M_ARGV(0, entity);
274
275         if (player.caplayer == 1)
276                 ca_LastPlayerForTeam_Notify(player);
277         return true;
278 }
279
280 MUTATOR_HOOKFUNCTION(ca, MakePlayerObserver)
281 {
282     entity player = M_ARGV(0, entity);
283
284         if (!IS_DEAD(player))
285                 ca_LastPlayerForTeam_Notify(player);
286         if (player.killindicator_teamchange == -2) // player wants to spectate
287                 player.caplayer = 0;
288         if (player.caplayer)
289                 player.frags = FRAGS_LMS_LOSER;
290         if (!warmup_stage)
291                 eliminatedPlayers.SendFlags |= 1;
292         if (!player.caplayer)
293                 return false;  // allow team reset
294         return true;  // prevent team reset
295 }
296
297 MUTATOR_HOOKFUNCTION(ca, ForbidThrowCurrentWeapon)
298 {
299         return true;
300 }
301
302 MUTATOR_HOOKFUNCTION(ca, GiveFragsForKill, CBC_ORDER_FIRST)
303 {
304         M_ARGV(2, float) = 0; // score will be given to the winner team when the round ends
305         return true;
306 }
307
308 MUTATOR_HOOKFUNCTION(ca, SetStartItems)
309 {
310         start_items       &= ~IT_UNLIMITED_AMMO;
311         start_health       = warmup_start_health       = cvar("g_lms_start_health");
312         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
313         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
314         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
315         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
316         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
317         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
318         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
319 }
320
321 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_Calculate)
322 {
323         entity frag_attacker = M_ARGV(1, entity);
324         entity frag_target = M_ARGV(2, entity);
325         float frag_deathtype = M_ARGV(3, float);
326         float frag_damage = M_ARGV(4, float);
327         float frag_mirrordamage = M_ARGV(5, float);
328
329         if (IS_PLAYER(frag_target))
330         if (!IS_DEAD(frag_target))
331         if (frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL.m_id)
332                 frag_damage = 0;
333
334         frag_mirrordamage = 0;
335
336         M_ARGV(4, float) = frag_damage;
337         M_ARGV(5, float) = frag_mirrordamage;
338 }
339
340 MUTATOR_HOOKFUNCTION(ca, FilterItem)
341 {
342     entity item = M_ARGV(0, entity);
343
344         if (autocvar_g_powerups <= 0)
345         if (item.flags & FL_POWERUP)
346                 return true;
347
348         if (autocvar_g_pickup_items <= 0)
349                 return true;
350 }
351
352 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_SplitHealthArmor)
353 {
354         entity frag_attacker = M_ARGV(1, entity);
355         entity frag_target = M_ARGV(2, entity);
356         float frag_damage = M_ARGV(7, float);
357         float damage_take = M_ARGV(4, float);
358         float damage_save = M_ARGV(5, float);
359
360         float excess = max(0, frag_damage - damage_take - damage_save);
361
362         if (frag_target != frag_attacker && IS_PLAYER(frag_attacker))
363                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
364 }
365
366 MUTATOR_HOOKFUNCTION(ca, PlayerRegen)
367 {
368         // no regeneration in CA
369         return true;
370 }
371
372 MUTATOR_HOOKFUNCTION(ca, Scores_CountFragsRemaining)
373 {
374         // announce remaining frags
375         return true;
376 }
377
378 MUTATOR_HOOKFUNCTION(ca, SpectateSet)
379 {
380     entity client = M_ARGV(0, entity);
381     entity targ = M_ARGV(1, entity);
382
383         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
384         if (DIFF_TEAM(targ, client))
385                 return true;
386 }
387
388 MUTATOR_HOOKFUNCTION(ca, SpectateNext)
389 {
390     entity client = M_ARGV(0, entity);
391
392         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
393         {
394                 entity targ = M_ARGV(1, entity);
395                 M_ARGV(1, entity) = CA_SpectateNext(client, targ);
396                 return true;
397         }
398 }
399
400 MUTATOR_HOOKFUNCTION(ca, SpectatePrev)
401 {
402     entity client = M_ARGV(0, entity);
403     entity targ = M_ARGV(1, entity);
404     entity first = M_ARGV(2, entity);
405
406         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
407         {
408                 do { targ = targ.chain; }
409                 while(targ && DIFF_TEAM(targ, client));
410
411                 if (!targ)
412                 {
413                         for (targ = first; targ && DIFF_TEAM(targ, client); targ = targ.chain);
414
415                         if (targ == client.enemy)
416                                 return MUT_SPECPREV_RETURN;
417                 }
418         }
419
420         M_ARGV(1, entity) = targ;
421
422         return MUT_SPECPREV_FOUND;
423 }
424
425 MUTATOR_HOOKFUNCTION(ca, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
426 {
427         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
428                 if (IS_PLAYER(it) || it.caplayer == 1)
429                         ++M_ARGV(0, int);
430                 ++M_ARGV(1, int);
431         });
432         return true;
433 }
434
435 MUTATOR_HOOKFUNCTION(ca, ClientCommand_Spectate)
436 {
437     entity player = M_ARGV(0, entity);
438
439         if (player.caplayer)
440         {
441                 // they're going to spec, we can do other checks
442                 if (autocvar_sv_spectate && (IS_SPEC(player) || IS_OBSERVER(player)))
443                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_LEAVE);
444                 return MUT_SPECCMD_FORCE;
445         }
446
447         return MUT_SPECCMD_CONTINUE;
448 }
449
450 MUTATOR_HOOKFUNCTION(ca, WantWeapon)
451 {
452         M_ARGV(2, bool) = true; // all weapons
453 }
454
455 MUTATOR_HOOKFUNCTION(ca, GetPlayerStatus)
456 {
457         entity player = M_ARGV(0, entity);
458
459         return player.caplayer == 1;
460 }
461
462 MUTATOR_HOOKFUNCTION(ca, SetWeaponArena)
463 {
464         // most weapons arena
465         if (M_ARGV(0, string) == "0" || M_ARGV(0, string) == "") M_ARGV(0, string) = "most";
466 }