qcsrc/server/mutators/mutator/gamemode_ca.qc

   1 #include "gamemode_ca.qh"
   2 #ifndef GAMEMODE_CA_H
   3 #define GAMEMODE_CA_H
   4
   5 int autocvar_g_ca_point_limit;
   6 int autocvar_g_ca_point_leadlimit;
   7 float autocvar_g_ca_round_timelimit;
   8 bool autocvar_g_ca_team_spawns;
   9 int autocvar_g_ca_teams;
  10 int autocvar_g_ca_teams_override;
  11 float autocvar_g_ca_warmup;
  12
  13
  14 int ca_teams;
  15 bool allowed_to_spawn;
  16
  17 const int ST_CA_ROUNDS = 1;
  18
  19 bool CA_CheckTeams();
  20 bool CA_CheckWinner();
  21 void CA_RoundStart();
  22 bool ca_isEliminated(entity e);
  23
  24 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override);
  25
  26 REGISTER_MUTATOR(ca, false)
  27 {
  28         MUTATOR_ONADD
  29         {
  30                 // game loads at time 1
  31                 if (time > 1) error("This is a game type and it cannot be added at runtime.");
  32
  33                 allowed_to_spawn = true;
  34
  35                 ca_teams = autocvar_g_ca_teams_override;
  36                 if (ca_teams < 2) ca_teams = autocvar_g_ca_teams;
  37                 ca_teams = bound(2, ca_teams, 4);
  38                 ret_float = ca_teams;
  39
  40         ScoreRules_basics(ca_teams, SFL_SORT_PRIO_PRIMARY, 0, true);
  41         ScoreInfo_SetLabel_TeamScore(ST_CA_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
  42         ScoreRules_basics_end();
  43
  44                 round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
  45                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  46
  47                 EliminatedPlayers_Init(ca_isEliminated);
  48
  49                 ActivateTeamplay();
  50                 SetLimits(autocvar_g_ca_point_limit, autocvar_g_ca_point_leadlimit, -1, -1);
  51
  52                 if (autocvar_g_ca_team_spawns)
  53                         have_team_spawns = -1; // request team spawns
  54         }
  55
  56         MUTATOR_ONREMOVE
  57         {
  58                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  59                 return -1;
  60         }
  61
  62         return 0;
  63 }
  64
  65 // should be removed in the future, as other code should not have to care
  66 .float caplayer; // 0.5 if scheduled to join the next round
  67 #endif
  68
  69 #ifdef IMPLEMENTATION
  70 float autocvar_g_ca_damage2score_multiplier;
  71 bool autocvar_g_ca_spectate_enemies;
  72
  73 void CA_count_alive_players()
  74 {
  75         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  76         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  77                 switch(it.team)
  78                 {
  79                         case NUM_TEAM_1: ++total_players; if(!IS_DEAD(it)) ++redalive; break;
  80                         case NUM_TEAM_2: ++total_players; if(!IS_DEAD(it)) ++bluealive; break;
  81                         case NUM_TEAM_3: ++total_players; if(!IS_DEAD(it)) ++yellowalive; break;
  82                         case NUM_TEAM_4: ++total_players; if(!IS_DEAD(it)) ++pinkalive; break;
  83                 }
  84         ));
  85         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  86                 it.redalive_stat = redalive;
  87                 it.bluealive_stat = bluealive;
  88                 it.yellowalive_stat = yellowalive;
  89                 it.pinkalive_stat = pinkalive;
  90         ));
  91 }
  92
  93 float CA_GetWinnerTeam()
  94 {
  95         float winner_team = 0;
  96         if(redalive >= 1)
  97                 winner_team = NUM_TEAM_1;
  98         if(bluealive >= 1)
  99         {
 100                 if(winner_team) return 0;
 101                 winner_team = NUM_TEAM_2;
 102         }
 103         if(yellowalive >= 1)
 104         {
 105                 if(winner_team) return 0;
 106                 winner_team = NUM_TEAM_3;
 107         }
 108         if(pinkalive >= 1)
 109         {
 110                 if(winner_team) return 0;
 111                 winner_team = NUM_TEAM_4;
 112         }
 113         if(winner_team)
 114                 return winner_team;
 115         return -1; // no player left
 116 }
 117
 118 void nades_Clear(entity player);
 119
 120 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
 121 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
 122 float CA_CheckWinner()
 123 {
 124         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 125         {
 126                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
 127                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
 128                 allowed_to_spawn = false;
 129                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 130                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
 131                 return 1;
 132         }
 133
 134         CA_count_alive_players();
 135         if(CA_ALIVE_TEAMS() > 1)
 136                 return 0;
 137
 138         int winner_team = CA_GetWinnerTeam();
 139         if(winner_team > 0)
 140         {
 141                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 142                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 143                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
 144         }
 145         else if(winner_team == -1)
 146         {
 147                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
 148                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
 149         }
 150
 151         allowed_to_spawn = false;
 152         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 153
 154         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
 155
 156         return 1;
 157 }
 158
 159 void CA_RoundStart()
 160 {
 161     allowed_to_spawn = boolean(warmup_stage);
 162 }
 163
 164 bool CA_CheckTeams()
 165 {
 166         static int prev_missing_teams_mask;
 167         allowed_to_spawn = true;
 168         CA_count_alive_players();
 169         if(CA_ALIVE_TEAMS_OK())
 170         {
 171                 if(prev_missing_teams_mask > 0)
 172                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 173                 prev_missing_teams_mask = -1;
 174                 return true;
 175         }
 176         if(total_players == 0)
 177         {
 178                 if(prev_missing_teams_mask > 0)
 179                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 180                 prev_missing_teams_mask = -1;
 181                 return false;
 182         }
 183         int missing_teams_mask = (!redalive) + (!bluealive) * 2;
 184         if(ca_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 185         if(ca_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 186         if(prev_missing_teams_mask != missing_teams_mask)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 189                 prev_missing_teams_mask = missing_teams_mask;
 190         }
 191         return false;
 192 }
 193
 194 bool ca_isEliminated(entity e)
 195 {
 196         if(e.caplayer == 1 && (IS_DEAD(e) || e.frags == FRAGS_LMS_LOSER))
 197                 return true;
 198         if(e.caplayer == 0.5)
 199                 return true;
 200         return false;
 201 }
 202
 203 /** Returns next available player to spectate if g_ca_spectate_enemies == 0 */
 204 entity CA_SpectateNext(entity player, entity start)
 205 {
 206         if (SAME_TEAM(start, player)) return start;
 207         // continue from current player
 208         for (entity e = start; (e = find(e, classname, STR_PLAYER)); )
 209         {
 210                 if (SAME_TEAM(player, e)) return e;
 211         }
 212         // restart from begining
 213         for (entity e = NULL; (e = find(e, classname, STR_PLAYER)); )
 214         {
 215                 if (SAME_TEAM(player, e)) return e;
 216         }
 217         return start;
 218 }
 219
 220
 221 MUTATOR_HOOKFUNCTION(ca, PlayerSpawn)
 222 {
 223     SELFPARAM();
 224         this.caplayer = 1;
 225         if (!warmup_stage)
 226                 eliminatedPlayers.SendFlags |= 1;
 227 }
 228
 229 MUTATOR_HOOKFUNCTION(ca, PutClientInServer)
 230 {
 231     SELFPARAM();
 232         if (!allowed_to_spawn && IS_PLAYER(this)) // this is true even when player is trying to join
 233         {
 234                 this.classname = STR_OBSERVER;
 235                 if (this.jointime != time && !this.caplayer) // not when connecting
 236                 {
 237                         this.caplayer = 0.5;
 238                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CA_JOIN_LATE);
 239                 }
 240         }
 241 }
 242
 243 MUTATOR_HOOKFUNCTION(ca, reset_map_players)
 244 {
 245         FOREACH_CLIENT(true, {
 246                 it.killcount = 0;
 247                 if (!it.caplayer && IS_BOT_CLIENT(it))
 248                 {
 249                         it.team = -1;
 250                         it.caplayer = 1;
 251                 }
 252                 if (it.caplayer)
 253                 {
 254                         it.classname = STR_PLAYER;
 255                         it.caplayer = 1;
 256                         WITH(entity, self, it, PutClientInServer());
 257                 }
 258         });
 259         return true;
 260 }
 261
 262 MUTATOR_HOOKFUNCTION(ca, ClientConnect)
 263 {
 264     SELFPARAM();
 265         this.classname = STR_OBSERVER;
 266         return true;
 267 }
 268
 269 MUTATOR_HOOKFUNCTION(ca, reset_map_global)
 270 {
 271         allowed_to_spawn = true;
 272         return true;
 273 }
 274
 275 MUTATOR_HOOKFUNCTION(ca, GetTeamCount, CBC_ORDER_EXCLUSIVE)
 276 {
 277         ret_float = ca_teams;
 278         return false;
 279 }
 280
 281 entity ca_LastPlayerForTeam()
 282 {
 283     SELFPARAM();
 284         entity last_pl = NULL;
 285         FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 286                 if (!IS_DEAD(it))
 287                 if (SAME_TEAM(this, it))
 288                 if (!last_pl)
 289                         last_pl = it;
 290                 else
 291                         return NULL;
 292         });
 293         return last_pl;
 294 }
 295
 296 void ca_LastPlayerForTeam_Notify()
 297 {
 298         if (round_handler_IsActive())
 299         if (round_handler_IsRoundStarted())
 300         {
 301                 entity pl = ca_LastPlayerForTeam();
 302                 if (pl)
 303                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 304         }
 305 }
 306
 307 MUTATOR_HOOKFUNCTION(ca, PlayerDies)
 308 {
 309         ca_LastPlayerForTeam_Notify();
 310         if (!allowed_to_spawn)
 311                 frag_target.respawn_flags =  RESPAWN_SILENT;
 312         if (!warmup_stage)
 313                 eliminatedPlayers.SendFlags |= 1;
 314         return 1;
 315 }
 316
 317 MUTATOR_HOOKFUNCTION(ca, ClientDisconnect)
 318 {
 319     SELFPARAM();
 320         if (this.caplayer == 1)
 321                 ca_LastPlayerForTeam_Notify();
 322         return 1;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(ca, ForbidPlayerScore_Clear)
 326 {
 327         return 1;
 328 }
 329
 330 MUTATOR_HOOKFUNCTION(ca, MakePlayerObserver)
 331 {
 332     SELFPARAM();
 333         if (this.caplayer == 1)
 334                 ca_LastPlayerForTeam_Notify();
 335         if (this.killindicator_teamchange == -2)
 336                 this.caplayer = 0;
 337         if (this.caplayer)
 338                 this.frags = FRAGS_LMS_LOSER;
 339         if (!warmup_stage)
 340                 eliminatedPlayers.SendFlags |= 1;
 341         return true;  // prevent team reset
 342 }
 343
 344 MUTATOR_HOOKFUNCTION(ca, ForbidThrowCurrentWeapon)
 345 {
 346         return 1;
 347 }
 348
 349 MUTATOR_HOOKFUNCTION(ca, GiveFragsForKill, CBC_ORDER_FIRST)
 350 {
 351         frag_score = 0; // score will be given to the winner team when the round ends
 352         return 1;
 353 }
 354
 355 MUTATOR_HOOKFUNCTION(ca, SetStartItems)
 356 {
 357         start_items       &= ~IT_UNLIMITED_AMMO;
 358         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 359         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 360         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 361         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 362         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 363         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 364         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 365         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 366
 367         return 0;
 368 }
 369
 370 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_Calculate)
 371 {
 372         if (IS_PLAYER(frag_target))
 373         if (!IS_DEAD(frag_target))
 374         if (frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL.m_id)
 375                 frag_damage = 0;
 376
 377         frag_mirrordamage = 0;
 378
 379         return false;
 380 }
 381
 382 MUTATOR_HOOKFUNCTION(ca, FilterItem)
 383 {
 384     SELFPARAM();
 385         if (autocvar_g_powerups <= 0)
 386         if (this.flags & FL_POWERUP)
 387                 return true;
 388
 389         if (autocvar_g_pickup_items <= 0)
 390                 return true;
 391
 392         return false;
 393 }
 394
 395 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_SplitHealthArmor)
 396 {
 397         float excess = max(0, frag_damage - damage_take - damage_save);
 398
 399         if (frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 400                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 401
 402         return false;
 403 }
 404
 405 MUTATOR_HOOKFUNCTION(ca, PlayerRegen)
 406 {
 407         // no regeneration in CA
 408         return true;
 409 }
 410
 411 MUTATOR_HOOKFUNCTION(ca, Scores_CountFragsRemaining)
 412 {
 413         // announce remaining frags
 414         return true;
 415 }
 416
 417 MUTATOR_HOOKFUNCTION(ca, SpectateSet)
 418 {
 419     SELFPARAM();
 420         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 421         if (DIFF_TEAM(spec_player, this))
 422                 return true;
 423         return false;
 424 }
 425
 426 MUTATOR_HOOKFUNCTION(ca, SpectateNext)
 427 {
 428     SELFPARAM();
 429         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 430         {
 431                 spec_player = CA_SpectateNext(this, spec_player);
 432                 return true;
 433         }
 434         return false;
 435 }
 436
 437 MUTATOR_HOOKFUNCTION(ca, SpectatePrev)
 438 {
 439     SELFPARAM();
 440         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 441         {
 442                 do { spec_player = spec_player.chain; }
 443                 while(spec_player && DIFF_TEAM(spec_player, this));
 444
 445                 if (!spec_player)
 446                 {
 447                         for (spec_player = spec_first; spec_player && DIFF_TEAM(spec_player, this); spec_player = spec_player.chain);
 448
 449                         if (spec_player == this.enemy)
 450                                 return MUT_SPECPREV_RETURN;
 451                 }
 452         }
 453
 454         return MUT_SPECPREV_FOUND;
 455 }
 456
 457 MUTATOR_HOOKFUNCTION(ca, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 458 {
 459         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 460                 if (IS_PLAYER(it) || it.caplayer == 1)
 461                         ++bot_activerealplayers;
 462                 ++bot_realplayers;
 463         });
 464         return true;
 465 }
 466
 467 MUTATOR_HOOKFUNCTION(ca, ClientCommand_Spectate)
 468 {
 469     SELFPARAM();
 470         if (this.caplayer)
 471         {
 472                 // they're going to spec, we can do other checks
 473                 if (autocvar_sv_spectate && (IS_SPEC(this) || IS_OBSERVER(this)))
 474                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CA_LEAVE);
 475                 return MUT_SPECCMD_FORCE;
 476         }
 477
 478         return MUT_SPECCMD_CONTINUE;
 479 }
 480
 481 MUTATOR_HOOKFUNCTION(ca, WantWeapon)
 482 {
 483         want_allguns = true;
 484         return false;
 485 }
 486
 487 MUTATOR_HOOKFUNCTION(ca, GetPlayerStatus)
 488 {
 489         return set_player.caplayer == 1;
 490 }
 491
 492 MUTATOR_HOOKFUNCTION(ca, SetWeaponArena)
 493 {
 494         // most weapons arena
 495         if (ret_string == "0" || ret_string == "") ret_string = "most";
 496 }
 497
 498 #endif