qcsrc/server/mutators/mutator/gamemode_ca.qc

   1 #include "gamemode_ca.qh"
   2 #ifndef GAMEMODE_CA_H
   3 #define GAMEMODE_CA_H
   4
   5 int autocvar_g_ca_point_limit;
   6 int autocvar_g_ca_point_leadlimit;
   7 float autocvar_g_ca_round_timelimit;
   8 bool autocvar_g_ca_team_spawns;
   9 int autocvar_g_ca_teams;
  10 int autocvar_g_ca_teams_override;
  11 float autocvar_g_ca_warmup;
  12
  13
  14 int ca_teams;
  15 bool allowed_to_spawn;
  16
  17 const int ST_CA_ROUNDS = 1;
  18
  19 bool CA_CheckTeams();
  20 bool CA_CheckWinner();
  21 void CA_RoundStart();
  22 bool ca_isEliminated(entity e);
  23
  24 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override);
  25
  26 REGISTER_MUTATOR(ca, false)
  27 {
  28         MUTATOR_ONADD
  29         {
  30                 // game loads at time 1
  31                 if (time > 1) error("This is a game type and it cannot be added at runtime.");
  32
  33                 allowed_to_spawn = true;
  34
  35                 ca_teams = autocvar_g_ca_teams_override;
  36                 if (ca_teams < 2) ca_teams = autocvar_g_ca_teams;
  37                 ca_teams = bound(2, ca_teams, 4);
  38                 ret_float = ca_teams;
  39
  40         ScoreRules_basics(ca_teams, SFL_SORT_PRIO_PRIMARY, 0, true);
  41         ScoreInfo_SetLabel_TeamScore(ST_CA_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
  42         ScoreRules_basics_end();
  43
  44                 round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
  45                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  46
  47                 EliminatedPlayers_Init(ca_isEliminated);
  48
  49                 ActivateTeamplay();
  50                 SetLimits(autocvar_g_ca_point_limit, autocvar_g_ca_point_leadlimit, autocvar_timelimit_override, -1);
  51
  52                 if (autocvar_g_ca_team_spawns)
  53                         have_team_spawns = -1; // request team spawns
  54         }
  55
  56         MUTATOR_ONREMOVE
  57         {
  58                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  59                 return -1;
  60         }
  61
  62         return 0;
  63 }
  64
  65 // should be removed in the future, as other code should not have to care
  66 .float caplayer; // 0.5 if scheduled to join the next round
  67 #endif
  68
  69 #ifdef IMPLEMENTATION
  70 float autocvar_g_ca_damage2score_multiplier;
  71 bool autocvar_g_ca_spectate_enemies;
  72
  73 void CA_count_alive_players()
  74 {
  75         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  76         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  77                 switch(it.team)
  78                 {
  79                         case NUM_TEAM_1: ++total_players; if(!IS_DEAD(it)) ++redalive; break;
  80                         case NUM_TEAM_2: ++total_players; if(!IS_DEAD(it)) ++bluealive; break;
  81                         case NUM_TEAM_3: ++total_players; if(!IS_DEAD(it)) ++yellowalive; break;
  82                         case NUM_TEAM_4: ++total_players; if(!IS_DEAD(it)) ++pinkalive; break;
  83                 }
  84         ));
  85         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  86                 it.redalive_stat = redalive;
  87                 it.bluealive_stat = bluealive;
  88                 it.yellowalive_stat = yellowalive;
  89                 it.pinkalive_stat = pinkalive;
  90         ));
  91 }
  92
  93 float CA_GetWinnerTeam()
  94 {
  95         float winner_team = 0;
  96         if(redalive >= 1)
  97                 winner_team = NUM_TEAM_1;
  98         if(bluealive >= 1)
  99         {
 100                 if(winner_team) return 0;
 101                 winner_team = NUM_TEAM_2;
 102         }
 103         if(yellowalive >= 1)
 104         {
 105                 if(winner_team) return 0;
 106                 winner_team = NUM_TEAM_3;
 107         }
 108         if(pinkalive >= 1)
 109         {
 110                 if(winner_team) return 0;
 111                 winner_team = NUM_TEAM_4;
 112         }
 113         if(winner_team)
 114                 return winner_team;
 115         return -1; // no player left
 116 }
 117
 118 void nades_Clear(entity player);
 119
 120 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
 121 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
 122 float CA_CheckWinner()
 123 {
 124         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 125         {
 126                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
 127                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
 128                 allowed_to_spawn = false;
 129                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 130                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
 131                 return 1;
 132         }
 133
 134         CA_count_alive_players();
 135         if(CA_ALIVE_TEAMS() > 1)
 136                 return 0;
 137
 138         int winner_team = CA_GetWinnerTeam();
 139         if(winner_team > 0)
 140         {
 141                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 142                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 143                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
 144         }
 145         else if(winner_team == -1)
 146         {
 147                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
 148                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
 149         }
 150
 151         allowed_to_spawn = false;
 152         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 153
 154         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
 155
 156         return 1;
 157 }
 158
 159 void CA_RoundStart()
 160 {
 161     allowed_to_spawn = boolean(warmup_stage);
 162 }
 163
 164 bool CA_CheckTeams()
 165 {
 166         static int prev_missing_teams_mask;
 167         allowed_to_spawn = true;
 168         CA_count_alive_players();
 169         if(CA_ALIVE_TEAMS_OK())
 170         {
 171                 if(prev_missing_teams_mask > 0)
 172                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 173                 prev_missing_teams_mask = -1;
 174                 return true;
 175         }
 176         if(total_players == 0)
 177         {
 178                 if(prev_missing_teams_mask > 0)
 179                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 180                 prev_missing_teams_mask = -1;
 181                 return false;
 182         }
 183         int missing_teams_mask = (!redalive) + (!bluealive) * 2;
 184         if(ca_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 185         if(ca_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 186         if(prev_missing_teams_mask != missing_teams_mask)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 189                 prev_missing_teams_mask = missing_teams_mask;
 190         }
 191         return false;
 192 }
 193
 194 bool ca_isEliminated(entity e)
 195 {
 196         if(e.caplayer == 1 && (IS_DEAD(e) || e.frags == FRAGS_LMS_LOSER))
 197                 return true;
 198         if(e.caplayer == 0.5)
 199                 return true;
 200         return false;
 201 }
 202
 203 /** Returns next available player to spectate if g_ca_spectate_enemies == 0 */
 204 entity CA_SpectateNext(entity player, entity start)
 205 {
 206         if (SAME_TEAM(start, player)) return start;
 207         // continue from current player
 208         for (entity e = start; (e = find(e, classname, STR_PLAYER)); )
 209         {
 210                 if (SAME_TEAM(player, e)) return e;
 211         }
 212         // restart from begining
 213         for (entity e = NULL; (e = find(e, classname, STR_PLAYER)); )
 214         {
 215                 if (SAME_TEAM(player, e)) return e;
 216         }
 217         return start;
 218 }
 219
 220
 221 MUTATOR_HOOKFUNCTION(ca, PlayerSpawn)
 222 {
 223     SELFPARAM();
 224         this.caplayer = 1;
 225         if (!warmup_stage)
 226                 eliminatedPlayers.SendFlags |= 1;
 227 }
 228
 229 MUTATOR_HOOKFUNCTION(ca, PutClientInServer)
 230 {
 231     SELFPARAM();
 232         if (!allowed_to_spawn && IS_PLAYER(this)) // this is true even when player is trying to join
 233         {
 234                 TRANSMUTE(Observer, this);
 235                 if (this.jointime != time && !this.caplayer) // not when connecting
 236                 {
 237                         this.caplayer = 0.5;
 238                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CA_JOIN_LATE);
 239                 }
 240         }
 241 }
 242
 243 MUTATOR_HOOKFUNCTION(ca, reset_map_players)
 244 {
 245     SELFPARAM();
 246         FOREACH_CLIENT(true, {
 247                 it.killcount = 0;
 248                 if (!it.caplayer && IS_BOT_CLIENT(it))
 249                 {
 250                         it.team = -1;
 251                         it.caplayer = 1;
 252                 }
 253                 if (it.caplayer)
 254                 {
 255                         TRANSMUTE(Player, it);
 256                         it.caplayer = 1;
 257                         WITHSELF(it, PutClientInServer());
 258                 }
 259         });
 260         return true;
 261 }
 262
 263 MUTATOR_HOOKFUNCTION(ca, ClientConnect)
 264 {
 265     SELFPARAM();
 266         TRANSMUTE(Observer, this);
 267         return true;
 268 }
 269
 270 MUTATOR_HOOKFUNCTION(ca, reset_map_global)
 271 {
 272         allowed_to_spawn = true;
 273         return true;
 274 }
 275
 276 MUTATOR_HOOKFUNCTION(ca, GetTeamCount, CBC_ORDER_EXCLUSIVE)
 277 {
 278         ret_float = ca_teams;
 279         return false;
 280 }
 281
 282 entity ca_LastPlayerForTeam()
 283 {
 284     SELFPARAM();
 285         entity last_pl = NULL;
 286         FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 287                 if (!IS_DEAD(it))
 288                 if (SAME_TEAM(this, it))
 289                 if (!last_pl)
 290                         last_pl = it;
 291                 else
 292                         return NULL;
 293         });
 294         return last_pl;
 295 }
 296
 297 void ca_LastPlayerForTeam_Notify()
 298 {
 299         if (round_handler_IsActive())
 300         if (round_handler_IsRoundStarted())
 301         {
 302                 entity pl = ca_LastPlayerForTeam();
 303                 if (pl)
 304                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 305         }
 306 }
 307
 308 MUTATOR_HOOKFUNCTION(ca, PlayerDies)
 309 {
 310         ca_LastPlayerForTeam_Notify();
 311         if (!allowed_to_spawn)
 312                 frag_target.respawn_flags =  RESPAWN_SILENT;
 313         if (!warmup_stage)
 314                 eliminatedPlayers.SendFlags |= 1;
 315         return 1;
 316 }
 317
 318 MUTATOR_HOOKFUNCTION(ca, ClientDisconnect)
 319 {
 320     SELFPARAM();
 321         if (this.caplayer == 1)
 322                 ca_LastPlayerForTeam_Notify();
 323         return 1;
 324 }
 325
 326 MUTATOR_HOOKFUNCTION(ca, ForbidPlayerScore_Clear)
 327 {
 328         return 1;
 329 }
 330
 331 MUTATOR_HOOKFUNCTION(ca, MakePlayerObserver)
 332 {
 333     SELFPARAM();
 334         if (!IS_DEAD(this))
 335                 ca_LastPlayerForTeam_Notify();
 336         if (this.killindicator_teamchange == -2)
 337                 this.caplayer = 0;
 338         if (this.caplayer)
 339                 this.frags = FRAGS_LMS_LOSER;
 340         if (!warmup_stage)
 341                 eliminatedPlayers.SendFlags |= 1;
 342         return true;  // prevent team reset
 343 }
 344
 345 MUTATOR_HOOKFUNCTION(ca, ForbidThrowCurrentWeapon)
 346 {
 347         return 1;
 348 }
 349
 350 MUTATOR_HOOKFUNCTION(ca, GiveFragsForKill, CBC_ORDER_FIRST)
 351 {
 352         frag_score = 0; // score will be given to the winner team when the round ends
 353         return 1;
 354 }
 355
 356 MUTATOR_HOOKFUNCTION(ca, SetStartItems)
 357 {
 358         start_items       &= ~IT_UNLIMITED_AMMO;
 359         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 360         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 361         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 362         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 363         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 364         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 365         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 366         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 367
 368         return 0;
 369 }
 370
 371 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_Calculate)
 372 {
 373         if (IS_PLAYER(frag_target))
 374         if (!IS_DEAD(frag_target))
 375         if (frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL.m_id)
 376                 frag_damage = 0;
 377
 378         frag_mirrordamage = 0;
 379
 380         return false;
 381 }
 382
 383 MUTATOR_HOOKFUNCTION(ca, FilterItem)
 384 {
 385     SELFPARAM();
 386         if (autocvar_g_powerups <= 0)
 387         if (this.flags & FL_POWERUP)
 388                 return true;
 389
 390         if (autocvar_g_pickup_items <= 0)
 391                 return true;
 392
 393         return false;
 394 }
 395
 396 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_SplitHealthArmor)
 397 {
 398         float excess = max(0, frag_damage - damage_take - damage_save);
 399
 400         if (frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 401                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 402
 403         return false;
 404 }
 405
 406 MUTATOR_HOOKFUNCTION(ca, PlayerRegen)
 407 {
 408         // no regeneration in CA
 409         return true;
 410 }
 411
 412 MUTATOR_HOOKFUNCTION(ca, Scores_CountFragsRemaining)
 413 {
 414         // announce remaining frags
 415         return true;
 416 }
 417
 418 MUTATOR_HOOKFUNCTION(ca, SpectateSet)
 419 {
 420     SELFPARAM();
 421         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 422         if (DIFF_TEAM(spec_player, this))
 423                 return true;
 424         return false;
 425 }
 426
 427 MUTATOR_HOOKFUNCTION(ca, SpectateNext)
 428 {
 429     SELFPARAM();
 430         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 431         {
 432                 spec_player = CA_SpectateNext(this, spec_player);
 433                 return true;
 434         }
 435         return false;
 436 }
 437
 438 MUTATOR_HOOKFUNCTION(ca, SpectatePrev)
 439 {
 440     SELFPARAM();
 441         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 442         {
 443                 do { spec_player = spec_player.chain; }
 444                 while(spec_player && DIFF_TEAM(spec_player, this));
 445
 446                 if (!spec_player)
 447                 {
 448                         for (spec_player = spec_first; spec_player && DIFF_TEAM(spec_player, this); spec_player = spec_player.chain);
 449
 450                         if (spec_player == this.enemy)
 451                                 return MUT_SPECPREV_RETURN;
 452                 }
 453         }
 454
 455         return MUT_SPECPREV_FOUND;
 456 }
 457
 458 MUTATOR_HOOKFUNCTION(ca, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 459 {
 460         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 461                 if (IS_PLAYER(it) || it.caplayer == 1)
 462                         ++bot_activerealplayers;
 463                 ++bot_realplayers;
 464         });
 465         return true;
 466 }
 467
 468 MUTATOR_HOOKFUNCTION(ca, ClientCommand_Spectate)
 469 {
 470     SELFPARAM();
 471         if (this.caplayer)
 472         {
 473                 // they're going to spec, we can do other checks
 474                 if (autocvar_sv_spectate && (IS_SPEC(this) || IS_OBSERVER(this)))
 475                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CA_LEAVE);
 476                 return MUT_SPECCMD_FORCE;
 477         }
 478
 479         return MUT_SPECCMD_CONTINUE;
 480 }
 481
 482 MUTATOR_HOOKFUNCTION(ca, WantWeapon)
 483 {
 484         want_allguns = true;
 485         return false;
 486 }
 487
 488 MUTATOR_HOOKFUNCTION(ca, GetPlayerStatus)
 489 {
 490         return set_player.caplayer == 1;
 491 }
 492
 493 MUTATOR_HOOKFUNCTION(ca, SetWeaponArena)
 494 {
 495         // most weapons arena
 496         if (ret_string == "0" || ret_string == "") ret_string = "most";
 497 }
 498
 499 #endif