]> de.git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/server/mutators/mutator/gamemode_ca.qc
Merge remote-tracking branch 'origin/terencehill/bot_waypoints' into terencehill...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator / gamemode_ca.qc
1 #include "gamemode_ca.qh"
2
3 float autocvar_g_ca_damage2score_multiplier;
4 bool autocvar_g_ca_spectate_enemies;
5
6 void CA_count_alive_players()
7 {
8         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
9         FOREACH_CLIENT(IS_PLAYER(it), {
10                 switch(it.team)
11                 {
12                         case NUM_TEAM_1: ++total_players; if(!IS_DEAD(it)) ++redalive; break;
13                         case NUM_TEAM_2: ++total_players; if(!IS_DEAD(it)) ++bluealive; break;
14                         case NUM_TEAM_3: ++total_players; if(!IS_DEAD(it)) ++yellowalive; break;
15                         case NUM_TEAM_4: ++total_players; if(!IS_DEAD(it)) ++pinkalive; break;
16                 }
17         });
18         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
19                 it.redalive_stat = redalive;
20                 it.bluealive_stat = bluealive;
21                 it.yellowalive_stat = yellowalive;
22                 it.pinkalive_stat = pinkalive;
23         });
24 }
25
26 float CA_GetWinnerTeam()
27 {
28         float winner_team = 0;
29         if(redalive >= 1)
30                 winner_team = NUM_TEAM_1;
31         if(bluealive >= 1)
32         {
33                 if(winner_team) return 0;
34                 winner_team = NUM_TEAM_2;
35         }
36         if(yellowalive >= 1)
37         {
38                 if(winner_team) return 0;
39                 winner_team = NUM_TEAM_3;
40         }
41         if(pinkalive >= 1)
42         {
43                 if(winner_team) return 0;
44                 winner_team = NUM_TEAM_4;
45         }
46         if(winner_team)
47                 return winner_team;
48         return -1; // no player left
49 }
50
51 void nades_Clear(entity player);
52
53 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
54 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == NumTeams(ca_teams))
55 float CA_CheckWinner()
56 {
57         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
58         {
59                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
60                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
61                 FOREACH_CLIENT(IS_PLAYER(it), { nades_Clear(it); });
62
63                 allowed_to_spawn = false;
64                 game_stopped = true;
65                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
66                 return 1;
67         }
68
69         CA_count_alive_players();
70         if(CA_ALIVE_TEAMS() > 1)
71                 return 0;
72
73         int winner_team = CA_GetWinnerTeam();
74         if(winner_team > 0)
75         {
76                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
77                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
78                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
79         }
80         else if(winner_team == -1)
81         {
82                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
83                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
84         }
85
86         allowed_to_spawn = false;
87         game_stopped = true;
88         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
89
90         FOREACH_CLIENT(IS_PLAYER(it), { nades_Clear(it); });
91
92         return 1;
93 }
94
95 void CA_RoundStart()
96 {
97     allowed_to_spawn = boolean(warmup_stage);
98 }
99
100 bool CA_CheckTeams()
101 {
102         static int prev_missing_teams_mask;
103         allowed_to_spawn = true;
104         CA_count_alive_players();
105         if(CA_ALIVE_TEAMS_OK())
106         {
107                 if(prev_missing_teams_mask > 0)
108                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
109                 prev_missing_teams_mask = -1;
110                 return true;
111         }
112         if(total_players == 0)
113         {
114                 if(prev_missing_teams_mask > 0)
115                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
116                 prev_missing_teams_mask = -1;
117                 return false;
118         }
119         int missing_teams_mask = 0;
120         if(ca_teams & BIT(0))
121                 missing_teams_mask += (!redalive) * 1;
122         if(ca_teams & BIT(1))
123                 missing_teams_mask += (!bluealive) * 2;
124         if(ca_teams & BIT(2))
125                 missing_teams_mask += (!yellowalive) * 4;
126         if(ca_teams & BIT(3))
127                 missing_teams_mask += (!pinkalive) * 8;
128         if(prev_missing_teams_mask != missing_teams_mask)
129         {
130                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
131                 prev_missing_teams_mask = missing_teams_mask;
132         }
133         return false;
134 }
135
136 bool ca_isEliminated(entity e)
137 {
138         if(e.caplayer == 1 && (IS_DEAD(e) || e.frags == FRAGS_LMS_LOSER))
139                 return true;
140         if(e.caplayer == 0.5)
141                 return true;
142         return false;
143 }
144
145 /** Returns next available player to spectate if g_ca_spectate_enemies == 0 */
146 entity CA_SpectateNext(entity player, entity start)
147 {
148         if (SAME_TEAM(start, player)) return start;
149         // continue from current player
150         for (entity e = start; (e = find(e, classname, STR_PLAYER)); )
151         {
152                 if (SAME_TEAM(player, e)) return e;
153         }
154         // restart from begining
155         for (entity e = NULL; (e = find(e, classname, STR_PLAYER)); )
156         {
157                 if (SAME_TEAM(player, e)) return e;
158         }
159         return start;
160 }
161
162
163 MUTATOR_HOOKFUNCTION(ca, PlayerSpawn)
164 {
165     entity player = M_ARGV(0, entity);
166
167         player.caplayer = 1;
168         if (!warmup_stage)
169                 eliminatedPlayers.SendFlags |= 1;
170 }
171
172 MUTATOR_HOOKFUNCTION(ca, ForbidSpawn)
173 {
174         entity player = M_ARGV(0, entity);
175
176         // spectators / observers that weren't playing can join; they are
177         // immediately forced to observe in the PutClientInServer hook
178         // this way they are put in a team and can play in the next round
179         if (!allowed_to_spawn && player.caplayer)
180                 return true;
181         return false;
182 }
183
184 MUTATOR_HOOKFUNCTION(ca, PutClientInServer)
185 {
186         entity player = M_ARGV(0, entity);
187
188         if (!allowed_to_spawn && IS_PLAYER(player)) // this is true even when player is trying to join
189         {
190                 TRANSMUTE(Observer, player);
191                 if (CS(player).jointime != time && !player.caplayer) // not when connecting
192                 {
193                         player.caplayer = 0.5;
194                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_JOIN_LATE);
195                 }
196         }
197 }
198
199 MUTATOR_HOOKFUNCTION(ca, reset_map_players)
200 {
201         FOREACH_CLIENT(true, {
202                 CS(it).killcount = 0;
203                 if (!it.caplayer && IS_BOT_CLIENT(it))
204                 {
205                         it.team = -1;
206                         it.caplayer = 1;
207                 }
208                 if (it.caplayer)
209                 {
210                         TRANSMUTE(Player, it);
211                         it.caplayer = 1;
212                         PutClientInServer(it);
213                 }
214         });
215         bot_relinkplayerlist();
216         return true;
217 }
218
219 MUTATOR_HOOKFUNCTION(ca, ClientConnect)
220 {
221     entity player = M_ARGV(0, entity);
222
223         TRANSMUTE(Observer, player);
224         return true;
225 }
226
227 MUTATOR_HOOKFUNCTION(ca, reset_map_global)
228 {
229         allowed_to_spawn = true;
230         return true;
231 }
232
233 MUTATOR_HOOKFUNCTION(ca, CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
234 {
235         M_ARGV(0, float) = ca_teams;
236 }
237
238 entity ca_LastPlayerForTeam(entity this)
239 {
240         entity last_pl = NULL;
241         FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
242                 if (!IS_DEAD(it))
243                 if (SAME_TEAM(this, it))
244                 if (!last_pl)
245                         last_pl = it;
246                 else
247                         return NULL;
248         });
249         return last_pl;
250 }
251
252 void ca_LastPlayerForTeam_Notify(entity this)
253 {
254         if (round_handler_IsActive())
255         if (round_handler_IsRoundStarted())
256         {
257                 entity pl = ca_LastPlayerForTeam(this);
258                 if (pl)
259                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
260         }
261 }
262
263 MUTATOR_HOOKFUNCTION(ca, PlayerDies)
264 {
265         entity frag_target = M_ARGV(2, entity);
266
267         ca_LastPlayerForTeam_Notify(frag_target);
268         if (!allowed_to_spawn)
269         {
270                 frag_target.respawn_flags = RESPAWN_SILENT;
271                 // prevent unwanted sudden rejoin as spectator and move of spectator camera
272                 frag_target.respawn_time = time + 2;
273         }
274         if (!warmup_stage)
275                 eliminatedPlayers.SendFlags |= 1;
276         if(IS_BOT_CLIENT(frag_target))
277                 bot_clear(frag_target);
278         return true;
279 }
280
281 MUTATOR_HOOKFUNCTION(ca, ClientDisconnect)
282 {
283     entity player = M_ARGV(0, entity);
284
285         if (player.caplayer == 1)
286                 ca_LastPlayerForTeam_Notify(player);
287         return true;
288 }
289
290 MUTATOR_HOOKFUNCTION(ca, MakePlayerObserver)
291 {
292     entity player = M_ARGV(0, entity);
293
294         if (!IS_DEAD(player))
295                 ca_LastPlayerForTeam_Notify(player);
296         if (player.killindicator_teamchange == -2) // player wants to spectate
297                 player.caplayer = 0;
298         if (player.caplayer)
299                 player.frags = FRAGS_LMS_LOSER;
300         if (!warmup_stage)
301                 eliminatedPlayers.SendFlags |= 1;
302         if (!player.caplayer)
303                 return false;  // allow team reset
304         return true;  // prevent team reset
305 }
306
307 MUTATOR_HOOKFUNCTION(ca, ForbidThrowCurrentWeapon)
308 {
309         return true;
310 }
311
312 MUTATOR_HOOKFUNCTION(ca, GiveFragsForKill, CBC_ORDER_FIRST)
313 {
314         M_ARGV(2, float) = 0; // score will be given to the winner team when the round ends
315         return true;
316 }
317
318 MUTATOR_HOOKFUNCTION(ca, SetStartItems)
319 {
320         start_items       &= ~IT_UNLIMITED_AMMO;
321         start_health       = warmup_start_health       = cvar("g_lms_start_health");
322         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
323         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
324         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
325         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
326         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
327         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
328         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
329 }
330
331 MUTATOR_HOOKFUNCTION(ca, Damage_Calculate)
332 {
333         entity frag_attacker = M_ARGV(1, entity);
334         entity frag_target = M_ARGV(2, entity);
335         float frag_deathtype = M_ARGV(3, float);
336         float frag_damage = M_ARGV(4, float);
337         float frag_mirrordamage = M_ARGV(5, float);
338
339         if (IS_PLAYER(frag_target))
340         if (!IS_DEAD(frag_target))
341         if (frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL.m_id)
342                 frag_damage = 0;
343
344         frag_mirrordamage = 0;
345
346         M_ARGV(4, float) = frag_damage;
347         M_ARGV(5, float) = frag_mirrordamage;
348 }
349
350 MUTATOR_HOOKFUNCTION(ca, FilterItem)
351 {
352     entity item = M_ARGV(0, entity);
353
354         if (autocvar_g_powerups <= 0)
355         if (item.flags & FL_POWERUP)
356                 return true;
357
358         if (autocvar_g_pickup_items <= 0)
359                 return true;
360 }
361
362 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_SplitHealthArmor)
363 {
364         entity frag_attacker = M_ARGV(1, entity);
365         entity frag_target = M_ARGV(2, entity);
366         float frag_damage = M_ARGV(7, float);
367         float damage_take = M_ARGV(4, float);
368         float damage_save = M_ARGV(5, float);
369
370         float excess = max(0, frag_damage - damage_take - damage_save);
371
372         if (frag_target != frag_attacker && IS_PLAYER(frag_attacker))
373                 GameRules_scoring_add_team(frag_attacker, SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
374 }
375
376 MUTATOR_HOOKFUNCTION(ca, PlayerRegen)
377 {
378         // no regeneration in CA
379         return true;
380 }
381
382 MUTATOR_HOOKFUNCTION(ca, Scores_CountFragsRemaining)
383 {
384         // announce remaining frags
385         return true;
386 }
387
388 MUTATOR_HOOKFUNCTION(ca, SpectateSet)
389 {
390     entity client = M_ARGV(0, entity);
391     entity targ = M_ARGV(1, entity);
392
393         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
394         if (DIFF_TEAM(targ, client))
395                 return true;
396 }
397
398 MUTATOR_HOOKFUNCTION(ca, SpectateNext)
399 {
400     entity client = M_ARGV(0, entity);
401
402         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
403         {
404                 entity targ = M_ARGV(1, entity);
405                 M_ARGV(1, entity) = CA_SpectateNext(client, targ);
406                 return true;
407         }
408 }
409
410 MUTATOR_HOOKFUNCTION(ca, SpectatePrev)
411 {
412     entity client = M_ARGV(0, entity);
413     entity targ = M_ARGV(1, entity);
414     entity first = M_ARGV(2, entity);
415
416         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
417         {
418                 do { targ = targ.chain; }
419                 while(targ && DIFF_TEAM(targ, client));
420
421                 if (!targ)
422                 {
423                         for (targ = first; targ && DIFF_TEAM(targ, client); targ = targ.chain);
424
425                         if (targ == client.enemy)
426                                 return MUT_SPECPREV_RETURN;
427                 }
428         }
429
430         M_ARGV(1, entity) = targ;
431
432         return MUT_SPECPREV_FOUND;
433 }
434
435 MUTATOR_HOOKFUNCTION(ca, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
436 {
437         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
438                 if (IS_PLAYER(it) || it.caplayer == 1)
439                         ++M_ARGV(0, int);
440                 ++M_ARGV(1, int);
441         });
442         return true;
443 }
444
445 MUTATOR_HOOKFUNCTION(ca, ClientCommand_Spectate)
446 {
447     entity player = M_ARGV(0, entity);
448
449         if (player.caplayer)
450         {
451                 // they're going to spec, we can do other checks
452                 if (autocvar_sv_spectate && (IS_SPEC(player) || IS_OBSERVER(player)))
453                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_LEAVE);
454                 return MUT_SPECCMD_FORCE;
455         }
456
457         return MUT_SPECCMD_CONTINUE;
458 }
459
460 MUTATOR_HOOKFUNCTION(ca, WantWeapon)
461 {
462         M_ARGV(2, bool) = true; // all weapons
463 }
464
465 MUTATOR_HOOKFUNCTION(ca, HideTeamNagger)
466 {
467         return true; // doesn't work well with the whole spectator as player thing
468 }
469
470 MUTATOR_HOOKFUNCTION(ca, GetPlayerStatus)
471 {
472         entity player = M_ARGV(0, entity);
473
474         return player.caplayer == 1;
475 }
476
477 MUTATOR_HOOKFUNCTION(ca, SetWeaponArena)
478 {
479         // most weapons arena
480         if (M_ARGV(0, string) == "0" || M_ARGV(0, string) == "") M_ARGV(0, string) = "most";
481 }