qcsrc/server/mutators/mutator/gamemode_ca.qc

   1 #include "gamemode_ca.qh"
   2
   3 float autocvar_g_ca_damage2score_multiplier;
   4 bool autocvar_g_ca_spectate_enemies;
   5
   6 void CA_count_alive_players()
   7 {
   8         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
   9         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  10                 switch(it.team)
  11                 {
  12                         case NUM_TEAM_1: ++total_players; if(!IS_DEAD(it)) ++redalive; break;
  13                         case NUM_TEAM_2: ++total_players; if(!IS_DEAD(it)) ++bluealive; break;
  14                         case NUM_TEAM_3: ++total_players; if(!IS_DEAD(it)) ++yellowalive; break;
  15                         case NUM_TEAM_4: ++total_players; if(!IS_DEAD(it)) ++pinkalive; break;
  16                 }
  17         ));
  18         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  19                 it.redalive_stat = redalive;
  20                 it.bluealive_stat = bluealive;
  21                 it.yellowalive_stat = yellowalive;
  22                 it.pinkalive_stat = pinkalive;
  23         ));
  24 }
  25
  26 float CA_GetWinnerTeam()
  27 {
  28         float winner_team = 0;
  29         if(redalive >= 1)
  30                 winner_team = NUM_TEAM_1;
  31         if(bluealive >= 1)
  32         {
  33                 if(winner_team) return 0;
  34                 winner_team = NUM_TEAM_2;
  35         }
  36         if(yellowalive >= 1)
  37         {
  38                 if(winner_team) return 0;
  39                 winner_team = NUM_TEAM_3;
  40         }
  41         if(pinkalive >= 1)
  42         {
  43                 if(winner_team) return 0;
  44                 winner_team = NUM_TEAM_4;
  45         }
  46         if(winner_team)
  47                 return winner_team;
  48         return -1; // no player left
  49 }
  50
  51 void nades_Clear(entity player);
  52
  53 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  54 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == NumTeams(ca_teams))
  55 float CA_CheckWinner()
  56 {
  57         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  58         {
  59                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
  60                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
  61                 allowed_to_spawn = false;
  62                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  63                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
  64                 return 1;
  65         }
  66
  67         CA_count_alive_players();
  68         if(CA_ALIVE_TEAMS() > 1)
  69                 return 0;
  70
  71         int winner_team = CA_GetWinnerTeam();
  72         if(winner_team > 0)
  73         {
  74                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
  75                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
  76                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
  77         }
  78         else if(winner_team == -1)
  79         {
  80                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
  81                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
  82         }
  83
  84         allowed_to_spawn = false;
  85         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  86
  87         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
  88
  89         return 1;
  90 }
  91
  92 void CA_RoundStart()
  93 {
  94     allowed_to_spawn = boolean(warmup_stage);
  95 }
  96
  97 bool CA_CheckTeams()
  98 {
  99         static int prev_missing_teams_mask;
 100         allowed_to_spawn = true;
 101         CA_count_alive_players();
 102         if(CA_ALIVE_TEAMS_OK())
 103         {
 104                 if(prev_missing_teams_mask > 0)
 105                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 106                 prev_missing_teams_mask = -1;
 107                 return true;
 108         }
 109         if(total_players == 0)
 110         {
 111                 if(prev_missing_teams_mask > 0)
 112                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 113                 prev_missing_teams_mask = -1;
 114                 return false;
 115         }
 116         int missing_teams_mask = 0;
 117         if(ca_teams & BIT(0))
 118                 missing_teams_mask += (!redalive) * 1;
 119         if(ca_teams & BIT(1))
 120                 missing_teams_mask += (!bluealive) * 2;
 121         if(ca_teams & BIT(2))
 122                 missing_teams_mask += (!yellowalive) * 4;
 123         if(ca_teams & BIT(3))
 124                 missing_teams_mask += (!pinkalive) * 8;
 125         if(prev_missing_teams_mask != missing_teams_mask)
 126         {
 127                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 128                 prev_missing_teams_mask = missing_teams_mask;
 129         }
 130         return false;
 131 }
 132
 133 bool ca_isEliminated(entity e)
 134 {
 135         if(e.caplayer == 1 && (IS_DEAD(e) || e.frags == FRAGS_LMS_LOSER))
 136                 return true;
 137         if(e.caplayer == 0.5)
 138                 return true;
 139         return false;
 140 }
 141
 142 /** Returns next available player to spectate if g_ca_spectate_enemies == 0 */
 143 entity CA_SpectateNext(entity player, entity start)
 144 {
 145         if (SAME_TEAM(start, player)) return start;
 146         // continue from current player
 147         for (entity e = start; (e = find(e, classname, STR_PLAYER)); )
 148         {
 149                 if (SAME_TEAM(player, e)) return e;
 150         }
 151         // restart from begining
 152         for (entity e = NULL; (e = find(e, classname, STR_PLAYER)); )
 153         {
 154                 if (SAME_TEAM(player, e)) return e;
 155         }
 156         return start;
 157 }
 158
 159
 160 MUTATOR_HOOKFUNCTION(ca, PlayerSpawn)
 161 {
 162     entity player = M_ARGV(0, entity);
 163
 164         player.caplayer = 1;
 165         if (!warmup_stage)
 166                 eliminatedPlayers.SendFlags |= 1;
 167 }
 168
 169 MUTATOR_HOOKFUNCTION(ca, ForbidSpawn)
 170 {
 171         entity player = M_ARGV(0, entity);
 172
 173         // spectators / observers that weren't playing can join; they are
 174         // immediately forced to observe in the PutClientInServer hook
 175         // this way they are put in a team and can play in the next round
 176         if (!allowed_to_spawn && player.caplayer)
 177                 return true;
 178         return false;
 179 }
 180
 181 MUTATOR_HOOKFUNCTION(ca, PutClientInServer)
 182 {
 183         entity player = M_ARGV(0, entity);
 184
 185         if (!allowed_to_spawn && IS_PLAYER(player)) // this is true even when player is trying to join
 186         {
 187                 TRANSMUTE(Observer, player);
 188                 if (player.jointime != time && !player.caplayer) // not when connecting
 189                 {
 190                         player.caplayer = 0.5;
 191                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_JOIN_LATE);
 192                 }
 193         }
 194 }
 195
 196 MUTATOR_HOOKFUNCTION(ca, reset_map_players)
 197 {
 198         FOREACH_CLIENT(true, {
 199                 it.killcount = 0;
 200                 if (!it.caplayer && IS_BOT_CLIENT(it))
 201                 {
 202                         it.team = -1;
 203                         it.caplayer = 1;
 204                 }
 205                 if (it.caplayer)
 206                 {
 207                         TRANSMUTE(Player, it);
 208                         it.caplayer = 1;
 209                         PutClientInServer(it);
 210                 }
 211         });
 212         bot_relinkplayerlist();
 213         return true;
 214 }
 215
 216 MUTATOR_HOOKFUNCTION(ca, ClientConnect)
 217 {
 218     entity player = M_ARGV(0, entity);
 219
 220         TRANSMUTE(Observer, player);
 221         return true;
 222 }
 223
 224 MUTATOR_HOOKFUNCTION(ca, reset_map_global)
 225 {
 226         allowed_to_spawn = true;
 227         return true;
 228 }
 229
 230 MUTATOR_HOOKFUNCTION(ca, CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 231 {
 232         M_ARGV(0, float) = ca_teams;
 233 }
 234
 235 entity ca_LastPlayerForTeam(entity this)
 236 {
 237         entity last_pl = NULL;
 238         FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 239                 if (!IS_DEAD(it))
 240                 if (SAME_TEAM(this, it))
 241                 if (!last_pl)
 242                         last_pl = it;
 243                 else
 244                         return NULL;
 245         });
 246         return last_pl;
 247 }
 248
 249 void ca_LastPlayerForTeam_Notify(entity this)
 250 {
 251         if (round_handler_IsActive())
 252         if (round_handler_IsRoundStarted())
 253         {
 254                 entity pl = ca_LastPlayerForTeam(this);
 255                 if (pl)
 256                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 257         }
 258 }
 259
 260 MUTATOR_HOOKFUNCTION(ca, PlayerDies)
 261 {
 262         entity frag_target = M_ARGV(2, entity);
 263
 264         ca_LastPlayerForTeam_Notify(frag_target);
 265         if (!allowed_to_spawn)
 266                 frag_target.respawn_flags =  RESPAWN_SILENT;
 267         if (!warmup_stage)
 268                 eliminatedPlayers.SendFlags |= 1;
 269         if(IS_BOT_CLIENT(frag_target))
 270                 bot_clear(frag_target);
 271         return true;
 272 }
 273
 274 MUTATOR_HOOKFUNCTION(ca, ClientDisconnect)
 275 {
 276     entity player = M_ARGV(0, entity);
 277
 278         if (player.caplayer == 1)
 279                 ca_LastPlayerForTeam_Notify(player);
 280         return true;
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(ca, MakePlayerObserver)
 284 {
 285     entity player = M_ARGV(0, entity);
 286
 287         if (!IS_DEAD(player))
 288                 ca_LastPlayerForTeam_Notify(player);
 289         if (player.killindicator_teamchange == -2) // player wants to spectate
 290                 player.caplayer = 0;
 291         if (player.caplayer)
 292                 player.frags = FRAGS_LMS_LOSER;
 293         if (!warmup_stage)
 294                 eliminatedPlayers.SendFlags |= 1;
 295         if (!player.caplayer)
 296                 return false;  // allow team reset
 297         return true;  // prevent team reset
 298 }
 299
 300 MUTATOR_HOOKFUNCTION(ca, ForbidThrowCurrentWeapon)
 301 {
 302         return true;
 303 }
 304
 305 MUTATOR_HOOKFUNCTION(ca, GiveFragsForKill, CBC_ORDER_FIRST)
 306 {
 307         M_ARGV(2, float) = 0; // score will be given to the winner team when the round ends
 308         return true;
 309 }
 310
 311 MUTATOR_HOOKFUNCTION(ca, SetStartItems)
 312 {
 313         start_items       &= ~IT_UNLIMITED_AMMO;
 314         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 315         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 316         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 317         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 318         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 319         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 320         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 321         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 322 }
 323
 324 MUTATOR_HOOKFUNCTION(ca, Damage_Calculate)
 325 {
 326         entity frag_attacker = M_ARGV(1, entity);
 327         entity frag_target = M_ARGV(2, entity);
 328         float frag_deathtype = M_ARGV(3, float);
 329         float frag_damage = M_ARGV(4, float);
 330         float frag_mirrordamage = M_ARGV(5, float);
 331
 332         if (IS_PLAYER(frag_target))
 333         if (!IS_DEAD(frag_target))
 334         if (frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL.m_id)
 335                 frag_damage = 0;
 336
 337         frag_mirrordamage = 0;
 338
 339         M_ARGV(4, float) = frag_damage;
 340         M_ARGV(5, float) = frag_mirrordamage;
 341 }
 342
 343 MUTATOR_HOOKFUNCTION(ca, FilterItem)
 344 {
 345     entity item = M_ARGV(0, entity);
 346
 347         if (autocvar_g_powerups <= 0)
 348         if (item.flags & FL_POWERUP)
 349                 return true;
 350
 351         if (autocvar_g_pickup_items <= 0)
 352                 return true;
 353 }
 354
 355 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_SplitHealthArmor)
 356 {
 357         entity frag_attacker = M_ARGV(1, entity);
 358         entity frag_target = M_ARGV(2, entity);
 359         float frag_damage = M_ARGV(7, float);
 360         float damage_take = M_ARGV(4, float);
 361         float damage_save = M_ARGV(5, float);
 362
 363         float excess = max(0, frag_damage - damage_take - damage_save);
 364
 365         if (frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 366                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 367 }
 368
 369 MUTATOR_HOOKFUNCTION(ca, PlayerRegen)
 370 {
 371         // no regeneration in CA
 372         return true;
 373 }
 374
 375 MUTATOR_HOOKFUNCTION(ca, Scores_CountFragsRemaining)
 376 {
 377         // announce remaining frags
 378         return true;
 379 }
 380
 381 MUTATOR_HOOKFUNCTION(ca, SpectateSet)
 382 {
 383     entity client = M_ARGV(0, entity);
 384     entity targ = M_ARGV(1, entity);
 385
 386         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
 387         if (DIFF_TEAM(targ, client))
 388                 return true;
 389 }
 390
 391 MUTATOR_HOOKFUNCTION(ca, SpectateNext)
 392 {
 393     entity client = M_ARGV(0, entity);
 394
 395         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
 396         {
 397                 entity targ = M_ARGV(1, entity);
 398                 M_ARGV(1, entity) = CA_SpectateNext(client, targ);
 399                 return true;
 400         }
 401 }
 402
 403 MUTATOR_HOOKFUNCTION(ca, SpectatePrev)
 404 {
 405     entity client = M_ARGV(0, entity);
 406     entity targ = M_ARGV(1, entity);
 407     entity first = M_ARGV(2, entity);
 408
 409         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
 410         {
 411                 do { targ = targ.chain; }
 412                 while(targ && DIFF_TEAM(targ, client));
 413
 414                 if (!targ)
 415                 {
 416                         for (targ = first; targ && DIFF_TEAM(targ, client); targ = targ.chain);
 417
 418                         if (targ == client.enemy)
 419                                 return MUT_SPECPREV_RETURN;
 420                 }
 421         }
 422
 423         M_ARGV(1, entity) = targ;
 424
 425         return MUT_SPECPREV_FOUND;
 426 }
 427
 428 MUTATOR_HOOKFUNCTION(ca, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 429 {
 430         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 431                 if (IS_PLAYER(it) || it.caplayer == 1)
 432                         ++M_ARGV(0, int);
 433                 ++M_ARGV(1, int);
 434         });
 435         return true;
 436 }
 437
 438 MUTATOR_HOOKFUNCTION(ca, ClientCommand_Spectate)
 439 {
 440     entity player = M_ARGV(0, entity);
 441
 442         if (player.caplayer)
 443         {
 444                 // they're going to spec, we can do other checks
 445                 if (autocvar_sv_spectate && (IS_SPEC(player) || IS_OBSERVER(player)))
 446                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_LEAVE);
 447                 return MUT_SPECCMD_FORCE;
 448         }
 449
 450         return MUT_SPECCMD_CONTINUE;
 451 }
 452
 453 MUTATOR_HOOKFUNCTION(ca, WantWeapon)
 454 {
 455         M_ARGV(2, bool) = true; // all weapons
 456 }
 457
 458 MUTATOR_HOOKFUNCTION(ca, GetPlayerStatus)
 459 {
 460         entity player = M_ARGV(0, entity);
 461
 462         return player.caplayer == 1;
 463 }
 464
 465 MUTATOR_HOOKFUNCTION(ca, SetWeaponArena)
 466 {
 467         // most weapons arena
 468         if (M_ARGV(0, string) == "0" || M_ARGV(0, string) == "") M_ARGV(0, string) = "most";
 469 }