Merge branch 'terencehill/bot_waypoints' into terencehill/bot_ai
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator / gamemode_cts.qc
1 #include "gamemode_cts.qh"
2
3 #include <server/race.qh>
4 #include <server/items.qh>
5
6 float autocvar_g_cts_finish_kill_delay;
7 bool autocvar_g_cts_selfdamage;
8
9 // legacy bot roles
10 .float race_checkpoint;
11 void havocbot_role_cts(entity this)
12 {
13         if(IS_DEAD(this))
14                 return;
15
16         if (navigation_goalrating_timeout(this))
17         {
18                 navigation_goalrating_start(this);
19
20                 bool raw_touch_check = true;
21                 int cp = this.race_checkpoint;
22
23                 LABEL(search_racecheckpoints)
24                 IL_EACH(g_racecheckpoints, true,
25                 {
26                         if(it.cnt == cp || cp == -1)
27                         {
28                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
29                                 // e.g. checkpoint in front of Stormkeep's warpzone
30                                 // the same workaround is applied in Race game mode
31                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
32                                 {
33                                         cp = race_NextCheckpoint(cp);
34                                         raw_touch_check = false;
35                                         goto search_racecheckpoints;
36                                 }
37                                 navigation_routerating(this, it, 1000000, 5000);
38                         }
39                 });
40
41                 navigation_goalrating_end(this);
42
43                 navigation_goalrating_timeout_set(this);
44         }
45 }
46
47 void cts_ScoreRules()
48 {
49     GameRules_score_enabled(false);
50     GameRules_scoring(0, 0, 0, {
51         if (g_race_qualifying) {
52             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
53         } else {
54             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
55             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
56             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
57         }
58     });
59 }
60
61 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
62 {
63         if(autocvar_sv_eventlog)
64                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
65 }
66
67 void KillIndicator_Think(entity this);
68 void CTS_ClientKill(entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
69 {
70     e.killindicator = spawn();
71     e.killindicator.owner = e;
72     setthink(e.killindicator, KillIndicator_Think);
73     e.killindicator.nextthink = time + (e.lip) * 0.05;
74     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
75     e.killindicator.health = 1; // this is used to indicate that it should be silent
76     e.lip = 0;
77 }
78
79 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
80 {
81         entity player = M_ARGV(0, entity);
82         float dt = M_ARGV(1, float);
83
84         player.race_movetime_frac += dt;
85         float f = floor(player.race_movetime_frac);
86         player.race_movetime_frac -= f;
87         player.race_movetime_count += f;
88         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
89
90 #ifdef SVQC
91         if(IS_PLAYER(player))
92         {
93                 if (player.race_penalty)
94                         if (time > player.race_penalty)
95                                 player.race_penalty = 0;
96                 if(player.race_penalty)
97                 {
98                         player.velocity = '0 0 0';
99                         set_movetype(player, MOVETYPE_NONE);
100                         player.disableclientprediction = 2;
101                 }
102         }
103 #endif
104
105         // force kbd movement for fairness
106         float wishspeed;
107         vector wishvel;
108
109         // if record times matter
110         // ensure nothing EVIL is being done (i.e. div0_evade)
111         // this hinders joystick users though
112         // but it still gives SOME analog control
113         wishvel.x = fabs(CS(player).movement.x);
114         wishvel.y = fabs(CS(player).movement.y);
115         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
116         {
117                 wishvel.z = 0;
118                 wishspeed = vlen(wishvel);
119                 if(wishvel.x >= 2 * wishvel.y)
120                 {
121                         // pure X motion
122                         if(CS(player).movement.x > 0)
123                                 CS(player).movement_x = wishspeed;
124                         else
125                                 CS(player).movement_x = -wishspeed;
126                         CS(player).movement_y = 0;
127                 }
128                 else if(wishvel.y >= 2 * wishvel.x)
129                 {
130                         // pure Y motion
131                         CS(player).movement_x = 0;
132                         if(CS(player).movement.y > 0)
133                                 CS(player).movement_y = wishspeed;
134                         else
135                                 CS(player).movement_y = -wishspeed;
136                 }
137                 else
138                 {
139                         // diagonal
140                         if(CS(player).movement.x > 0)
141                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
142                         else
143                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
144                         if(CS(player).movement.y > 0)
145                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
146                         else
147                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
148                 }
149         }
150 }
151
152 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
153 {
154         float s;
155
156         Score_NicePrint(NULL);
157
158         race_ClearRecords();
159         PlayerScore_Sort(race_place, 0, 1, 0);
160
161         FOREACH_CLIENT(true, {
162                 if(it.race_place)
163                 {
164                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
165                         if(!s)
166                                 it.race_place = 0;
167                 }
168                 cts_EventLog(ftos(it.race_place), it);
169         });
170
171         if(g_race_qualifying == 2)
172         {
173                 g_race_qualifying = 0;
174                 independent_players = 0;
175                 cvar_set("fraglimit", ftos(race_fraglimit));
176                 cvar_set("leadlimit", ftos(race_leadlimit));
177                 cvar_set("timelimit", ftos(race_timelimit));
178                 cts_ScoreRules();
179         }
180 }
181
182 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
183 {
184         entity player = M_ARGV(0, entity);
185
186         race_PreparePlayer(player);
187         player.race_checkpoint = -1;
188
189         if(IS_REAL_CLIENT(player))
190         {
191                 string rr = CTS_RECORD;
192
193                 msg_entity = player;
194                 race_send_recordtime(MSG_ONE);
195                 race_send_speedaward(MSG_ONE);
196
197                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
198                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
199                 race_send_speedaward_alltimebest(MSG_ONE);
200
201                 float i;
202                 for (i = 1; i <= RANKINGS_CNT; ++i)
203                 {
204                         race_SendRankings(i, 0, 0, MSG_ONE);
205                 }
206         }
207 }
208
209 MUTATOR_HOOKFUNCTION(cts, AbortSpeedrun)
210 {
211         entity player = M_ARGV(0, entity);
212
213         if(autocvar_g_allow_checkpoints)
214                 race_PreparePlayer(player); // nice try
215 }
216
217 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
218 {
219         entity player = M_ARGV(0, entity);
220
221         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
222                 player.frags = FRAGS_LMS_LOSER;
223         else
224                 player.frags = FRAGS_SPECTATOR;
225
226         race_PreparePlayer(player);
227         player.race_checkpoint = -1;
228 }
229
230 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
231 {
232         entity player = M_ARGV(0, entity);
233         entity spawn_spot = M_ARGV(1, entity);
234
235         if(spawn_spot.target == "")
236                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
237                 race_PreparePlayer(player);
238
239         // if we need to respawn, do it right
240         player.race_respawn_checkpoint = player.race_checkpoint;
241         player.race_respawn_spotref = spawn_spot;
242
243         player.race_place = 0;
244 }
245
246 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
247 {
248         entity player = M_ARGV(0, entity);
249
250         if(IS_PLAYER(player))
251         if(!game_stopped)
252         {
253                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
254                         race_PreparePlayer(player);
255                 else // respawn
256                         race_RetractPlayer(player);
257
258                 race_AbandonRaceCheck(player);
259         }
260 }
261
262 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
263 {
264         entity frag_target = M_ARGV(2, entity);
265
266         frag_target.respawn_flags |= RESPAWN_FORCE;
267         race_AbandonRaceCheck(frag_target);
268 }
269
270 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
271 {
272         entity bot = M_ARGV(0, entity);
273
274         bot.havocbot_role = havocbot_role_cts;
275         return true;
276 }
277
278 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
279 {
280         entity player = M_ARGV(0, entity);
281
282         if(CS(player).cvar_cl_allow_uidtracking == 1 && CS(player).cvar_cl_allow_uid2name == 1)
283         {
284                 if (!player.stored_netname)
285                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
286                 if(player.stored_netname != player.netname)
287                 {
288                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
289                         strunzone(player.stored_netname);
290                         player.stored_netname = strzone(player.netname);
291                 }
292         }
293
294         if (!IS_OBSERVER(player))
295         {
296                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
297                 {
298                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
299                         speedaward_holder = player.netname;
300                         speedaward_uid = player.crypto_idfp;
301                         speedaward_lastupdate = time;
302                 }
303                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
304                 {
305                         string rr = CTS_RECORD;
306                         race_send_speedaward(MSG_ALL);
307                         speedaward_lastsent = speedaward_speed;
308                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
309                         {
310                                 speedaward_alltimebest = speedaward_speed;
311                                 speedaward_alltimebest_holder = speedaward_holder;
312                                 speedaward_alltimebest_uid = speedaward_uid;
313                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
314                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
315                                 race_send_speedaward_alltimebest(MSG_ALL);
316                         }
317                 }
318         }
319 }
320
321 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
322 {
323         // no weapon dropping in CTS
324         return true;
325 }
326
327 MUTATOR_HOOKFUNCTION(cts, FilterItem)
328 {
329         entity item = M_ARGV(0, entity);
330
331         if (Item_IsLoot(item))
332         {
333                 return true;
334         }
335 }
336
337 MUTATOR_HOOKFUNCTION(cts, Damage_Calculate)
338 {
339         entity frag_attacker = M_ARGV(1, entity);
340         entity frag_target = M_ARGV(2, entity);
341         float frag_deathtype = M_ARGV(3, float);
342         float frag_damage = M_ARGV(4, float);
343
344         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
345         if(!autocvar_g_cts_selfdamage)
346         {
347                 frag_damage = 0;
348                 M_ARGV(4, float) = frag_damage;
349         }
350 }
351
352 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
353 {
354         return true; // in CTS, you don't lose score by observing
355 }
356
357 MUTATOR_HOOKFUNCTION(cts, GetRecords)
358 {
359         int record_page = M_ARGV(0, int);
360         string ret_string = M_ARGV(1, string);
361
362         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
363         {
364                 if(MapInfo_Get_ByID(i))
365                 {
366                         float r = race_readTime(MapInfo_Map_bspname, 1);
367
368                         if(!r)
369                                 continue;
370
371                         string h = race_readName(MapInfo_Map_bspname, 1);
372                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
373                 }
374         }
375
376         M_ARGV(1, string) = ret_string;
377 }
378
379 void ClientKill_Now(entity this);
380 MUTATOR_HOOKFUNCTION(cts, ClientKill)
381 {
382     entity player = M_ARGV(0, entity);
383
384         M_ARGV(1, float) = 0; // kill delay
385
386         if(player.killindicator && player.killindicator.health == 1) // player.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
387         {
388                 delete(player.killindicator);
389                 player.killindicator = NULL;
390
391                 ClientKill_Now(player); // allow instant kill in this case
392                 return;
393         }
394 }
395
396 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
397 {
398         entity player = M_ARGV(0, entity);
399
400         if(autocvar_g_cts_finish_kill_delay)
401                 CTS_ClientKill(player);
402 }
403
404 MUTATOR_HOOKFUNCTION(cts, HideTeamNagger)
405 {
406         return true; // doesn't work so well (but isn't cts a teamless mode?)
407 }
408
409 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
410 {
411         entity player = M_ARGV(0, entity);
412
413         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
414 }
415
416 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
417 {
418         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
419         M_ARGV(3, bool) = true; // want mutator blocked
420         return true;
421 }
422
423 MUTATOR_HOOKFUNCTION(cts, ForbidDropCurrentWeapon)
424 {
425         return true;
426 }
427
428 void cts_Initialize()
429 {
430         cts_ScoreRules();
431 }