qcsrc/server/mutators/mutator/gamemode_cts.qc

   1 #include "gamemode_cts.qh"
   2
   3 #include <server/race.qh>
   4 #include <server/items.qh>
   5
   6 float autocvar_g_cts_finish_kill_delay;
   7 bool autocvar_g_cts_selfdamage;
   8
   9 // legacy bot roles
  10 .float race_checkpoint;
  11 void havocbot_role_cts(entity this)
  12 {
  13         if(IS_DEAD(this))
  14                 return;
  15
  16         if (this.bot_strategytime < time)
  17         {
  18                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  19                 navigation_goalrating_start(this);
  20
  21                 IL_EACH(g_racecheckpoints, true,
  22                 {
  23                         if(it.cnt == this.race_checkpoint)
  24                                 navigation_routerating(this, it, 1000000, 5000);
  25                         else if(this.race_checkpoint == -1)
  26                                 navigation_routerating(this, it, 1000000, 5000);
  27                 });
  28
  29                 navigation_goalrating_end(this);
  30         }
  31 }
  32
  33 void cts_ScoreRules()
  34 {
  35     GameRules_score_enabled(false);
  36     GameRules_scoring(0, 0, 0, {
  37         if (g_race_qualifying) {
  38             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  39         } else {
  40             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  41             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  42             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  43         }
  44     });
  45 }
  46
  47 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  48 {
  49         if(autocvar_sv_eventlog)
  50                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  51 }
  52
  53 void KillIndicator_Think(entity this);
  54 void CTS_ClientKill(entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
  55 {
  56     e.killindicator = spawn();
  57     e.killindicator.owner = e;
  58     setthink(e.killindicator, KillIndicator_Think);
  59     e.killindicator.nextthink = time + (e.lip) * 0.05;
  60     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
  61     e.killindicator.health = 1; // this is used to indicate that it should be silent
  62     e.lip = 0;
  63 }
  64
  65 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
  66 {
  67         entity player = M_ARGV(0, entity);
  68         float dt = M_ARGV(1, float);
  69
  70         player.race_movetime_frac += dt;
  71         float f = floor(player.race_movetime_frac);
  72         player.race_movetime_frac -= f;
  73         player.race_movetime_count += f;
  74         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
  75
  76 #ifdef SVQC
  77         if(IS_PLAYER(player))
  78         {
  79                 if (player.race_penalty)
  80                         if (time > player.race_penalty)
  81                                 player.race_penalty = 0;
  82                 if(player.race_penalty)
  83                 {
  84                         player.velocity = '0 0 0';
  85                         set_movetype(player, MOVETYPE_NONE);
  86                         player.disableclientprediction = 2;
  87                 }
  88         }
  89 #endif
  90
  91         // force kbd movement for fairness
  92         float wishspeed;
  93         vector wishvel;
  94
  95         // if record times matter
  96         // ensure nothing EVIL is being done (i.e. div0_evade)
  97         // this hinders joystick users though
  98         // but it still gives SOME analog control
  99         wishvel.x = fabs(CS(player).movement.x);
 100         wishvel.y = fabs(CS(player).movement.y);
 101         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 102         {
 103                 wishvel.z = 0;
 104                 wishspeed = vlen(wishvel);
 105                 if(wishvel.x >= 2 * wishvel.y)
 106                 {
 107                         // pure X motion
 108                         if(CS(player).movement.x > 0)
 109                                 CS(player).movement_x = wishspeed;
 110                         else
 111                                 CS(player).movement_x = -wishspeed;
 112                         CS(player).movement_y = 0;
 113                 }
 114                 else if(wishvel.y >= 2 * wishvel.x)
 115                 {
 116                         // pure Y motion
 117                         CS(player).movement_x = 0;
 118                         if(CS(player).movement.y > 0)
 119                                 CS(player).movement_y = wishspeed;
 120                         else
 121                                 CS(player).movement_y = -wishspeed;
 122                 }
 123                 else
 124                 {
 125                         // diagonal
 126                         if(CS(player).movement.x > 0)
 127                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 128                         else
 129                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 130                         if(CS(player).movement.y > 0)
 131                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 132                         else
 133                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 134                 }
 135         }
 136 }
 137
 138 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
 139 {
 140         float s;
 141
 142         Score_NicePrint(NULL);
 143
 144         race_ClearRecords();
 145         PlayerScore_Sort(race_place, 0, 1, 0);
 146
 147         FOREACH_CLIENT(true, {
 148                 if(it.race_place)
 149                 {
 150                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 151                         if(!s)
 152                                 it.race_place = 0;
 153                 }
 154                 cts_EventLog(ftos(it.race_place), it);
 155         });
 156
 157         if(g_race_qualifying == 2)
 158         {
 159                 g_race_qualifying = 0;
 160                 independent_players = 0;
 161                 cvar_set("fraglimit", ftos(race_fraglimit));
 162                 cvar_set("leadlimit", ftos(race_leadlimit));
 163                 cvar_set("timelimit", ftos(race_timelimit));
 164                 cts_ScoreRules();
 165         }
 166 }
 167
 168 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
 169 {
 170         entity player = M_ARGV(0, entity);
 171
 172         race_PreparePlayer(player);
 173         player.race_checkpoint = -1;
 174
 175         if(IS_REAL_CLIENT(player))
 176         {
 177                 string rr = CTS_RECORD;
 178
 179                 msg_entity = player;
 180                 race_send_recordtime(MSG_ONE);
 181                 race_send_speedaward(MSG_ONE);
 182
 183                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 184                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 185                 race_send_speedaward_alltimebest(MSG_ONE);
 186
 187                 float i;
 188                 for (i = 1; i <= RANKINGS_CNT; ++i)
 189                 {
 190                         race_SendRankings(i, 0, 0, MSG_ONE);
 191                 }
 192         }
 193 }
 194
 195 MUTATOR_HOOKFUNCTION(cts, AbortSpeedrun)
 196 {
 197         entity player = M_ARGV(0, entity);
 198
 199         if(autocvar_g_allow_checkpoints)
 200                 race_PreparePlayer(player); // nice try
 201 }
 202
 203 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
 204 {
 205         entity player = M_ARGV(0, entity);
 206
 207         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 208                 player.frags = FRAGS_LMS_LOSER;
 209         else
 210                 player.frags = FRAGS_SPECTATOR;
 211
 212         race_PreparePlayer(player);
 213         player.race_checkpoint = -1;
 214 }
 215
 216 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
 217 {
 218         entity player = M_ARGV(0, entity);
 219         entity spawn_spot = M_ARGV(1, entity);
 220
 221         if(spawn_spot.target == "")
 222                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 223                 race_PreparePlayer(player);
 224
 225         // if we need to respawn, do it right
 226         player.race_respawn_checkpoint = player.race_checkpoint;
 227         player.race_respawn_spotref = spawn_spot;
 228
 229         player.race_place = 0;
 230 }
 231
 232 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
 233 {
 234         entity player = M_ARGV(0, entity);
 235
 236         if(IS_PLAYER(player))
 237         if(!game_stopped)
 238         {
 239                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 240                         race_PreparePlayer(player);
 241                 else // respawn
 242                         race_RetractPlayer(player);
 243
 244                 race_AbandonRaceCheck(player);
 245         }
 246 }
 247
 248 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
 249 {
 250         entity frag_target = M_ARGV(2, entity);
 251
 252         frag_target.respawn_flags |= RESPAWN_FORCE;
 253         race_AbandonRaceCheck(frag_target);
 254 }
 255
 256 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
 257 {
 258         entity bot = M_ARGV(0, entity);
 259
 260         bot.havocbot_role = havocbot_role_cts;
 261         return true;
 262 }
 263
 264 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
 265 {
 266         entity player = M_ARGV(0, entity);
 267
 268         if(CS(player).cvar_cl_allow_uidtracking == 1 && CS(player).cvar_cl_allow_uid2name == 1)
 269         {
 270                 if (!player.stored_netname)
 271                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 272                 if(player.stored_netname != player.netname)
 273                 {
 274                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 275                         strunzone(player.stored_netname);
 276                         player.stored_netname = strzone(player.netname);
 277                 }
 278         }
 279
 280         if (!IS_OBSERVER(player))
 281         {
 282                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 283                 {
 284                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 285                         speedaward_holder = player.netname;
 286                         speedaward_uid = player.crypto_idfp;
 287                         speedaward_lastupdate = time;
 288                 }
 289                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 290                 {
 291                         string rr = CTS_RECORD;
 292                         race_send_speedaward(MSG_ALL);
 293                         speedaward_lastsent = speedaward_speed;
 294                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 295                         {
 296                                 speedaward_alltimebest = speedaward_speed;
 297                                 speedaward_alltimebest_holder = speedaward_holder;
 298                                 speedaward_alltimebest_uid = speedaward_uid;
 299                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 300                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 301                                 race_send_speedaward_alltimebest(MSG_ALL);
 302                         }
 303                 }
 304         }
 305 }
 306
 307 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
 308 {
 309         // no weapon dropping in CTS
 310         return true;
 311 }
 312
 313 MUTATOR_HOOKFUNCTION(cts, FilterItem)
 314 {
 315         entity item = M_ARGV(0, entity);
 316
 317         if (Item_IsLoot(item))
 318         {
 319                 return true;
 320         }
 321 }
 322
 323 MUTATOR_HOOKFUNCTION(cts, Damage_Calculate)
 324 {
 325         entity frag_attacker = M_ARGV(1, entity);
 326         entity frag_target = M_ARGV(2, entity);
 327         float frag_deathtype = M_ARGV(3, float);
 328         float frag_damage = M_ARGV(4, float);
 329
 330         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
 331         if(!autocvar_g_cts_selfdamage)
 332         {
 333                 frag_damage = 0;
 334                 M_ARGV(4, float) = frag_damage;
 335         }
 336 }
 337
 338 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
 339 {
 340         return true; // in CTS, you don't lose score by observing
 341 }
 342
 343 MUTATOR_HOOKFUNCTION(cts, GetRecords)
 344 {
 345         int record_page = M_ARGV(0, int);
 346         string ret_string = M_ARGV(1, string);
 347
 348         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 349         {
 350                 if(MapInfo_Get_ByID(i))
 351                 {
 352                         float r = race_readTime(MapInfo_Map_bspname, 1);
 353
 354                         if(!r)
 355                                 continue;
 356
 357                         string h = race_readName(MapInfo_Map_bspname, 1);
 358                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 359                 }
 360         }
 361
 362         M_ARGV(1, string) = ret_string;
 363 }
 364
 365 void ClientKill_Now(entity this);
 366 MUTATOR_HOOKFUNCTION(cts, ClientKill)
 367 {
 368     entity player = M_ARGV(0, entity);
 369
 370         M_ARGV(1, float) = 0; // kill delay
 371
 372         if(player.killindicator && player.killindicator.health == 1) // player.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 373         {
 374                 delete(player.killindicator);
 375                 player.killindicator = NULL;
 376
 377                 ClientKill_Now(player); // allow instant kill in this case
 378                 return;
 379         }
 380 }
 381
 382 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
 383 {
 384         entity player = M_ARGV(0, entity);
 385
 386         if(autocvar_g_cts_finish_kill_delay)
 387                 CTS_ClientKill(player);
 388 }
 389
 390 MUTATOR_HOOKFUNCTION(cts, HideTeamNagger)
 391 {
 392         return true; // doesn't work so well (but isn't cts a teamless mode?)
 393 }
 394
 395 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
 396 {
 397         entity player = M_ARGV(0, entity);
 398
 399         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 400 }
 401
 402 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
 403 {
 404         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
 405         M_ARGV(3, bool) = true; // want mutator blocked
 406         return true;
 407 }
 408
 409 MUTATOR_HOOKFUNCTION(cts, ForbidDropCurrentWeapon)
 410 {
 411         return true;
 412 }
 413
 414 void cts_Initialize()
 415 {
 416         cts_ScoreRules();
 417 }