qcsrc/server/mutators/mutator/gamemode_cts.qc

   1 #include "gamemode_cts.qh"
   2 #include <server/race.qh>
   3
   4 #ifndef GAMEMODE_CTS_H
   5 #define GAMEMODE_CTS_H
   6
   7 void cts_Initialize();
   8
   9 REGISTER_MUTATOR(cts, false)
  10 {
  11         MUTATOR_ONADD
  12         {
  13                 if (time > 1) // game loads at time 1
  14                         error("This is a game type and it cannot be added at runtime.");
  15
  16                 g_race_qualifying = true;
  17                 independent_players = 1;
  18                 SetLimits(0, 0, autocvar_timelimit_override, -1);
  19
  20                 cts_Initialize();
  21         }
  22
  23         MUTATOR_ONROLLBACK_OR_REMOVE
  24         {
  25                 // we actually cannot roll back cts_Initialize here
  26                 // BUT: we don't need to! If this gets called, adding always
  27                 // succeeds.
  28         }
  29
  30         MUTATOR_ONREMOVE
  31         {
  32                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  33                 return -1;
  34         }
  35
  36         return 0;
  37 }
  38
  39 // scores
  40 const float ST_CTS_LAPS = 1;
  41 #endif
  42
  43 #ifdef IMPLEMENTATION
  44
  45 #include <server/race.qh>
  46
  47 float autocvar_g_cts_finish_kill_delay;
  48 bool autocvar_g_cts_selfdamage;
  49
  50 // legacy bot roles
  51 .float race_checkpoint;
  52 void havocbot_role_cts(entity this)
  53 {
  54         if(IS_DEAD(this))
  55                 return;
  56
  57         if (this.bot_strategytime < time)
  58         {
  59                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  60                 navigation_goalrating_start(this);
  61
  62                 FOREACH_ENTITY_CLASS("trigger_race_checkpoint", true,
  63                 {
  64                         if(it.cnt == this.race_checkpoint)
  65                                 navigation_routerating(this, it, 1000000, 5000);
  66                         else if(this.race_checkpoint == -1)
  67                                 navigation_routerating(this, it, 1000000, 5000);
  68                 });
  69
  70                 navigation_goalrating_end(this);
  71         }
  72 }
  73
  74 void cts_ScoreRules()
  75 {
  76         ScoreRules_basics(0, 0, 0, false);
  77         if(g_race_qualifying)
  78         {
  79                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_FASTEST, "fastest",   SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  80         }
  81         else
  82         {
  83                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  84                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  85                 ScoreInfo_SetLabel_PlayerScore(SP_CTS_FASTEST, "fastest",   SFL_LOWER_IS_BETTER | SFL_TIME);
  86         }
  87         ScoreRules_basics_end();
  88 }
  89
  90 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  91 {
  92         if(autocvar_sv_eventlog)
  93                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  94 }
  95
  96 void KillIndicator_Think(entity this);
  97 void CTS_ClientKill(entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
  98 {
  99     e.killindicator = spawn();
 100     e.killindicator.owner = e;
 101     setthink(e.killindicator, KillIndicator_Think);
 102     e.killindicator.nextthink = time + (e.lip) * 0.05;
 103     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 104     e.killindicator.health = 1; // this is used to indicate that it should be silent
 105     e.lip = 0;
 106 }
 107
 108 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
 109 {
 110         entity player = M_ARGV(0, entity);
 111         float dt = M_ARGV(1, float);
 112
 113         player.race_movetime_frac += dt;
 114         float f = floor(player.race_movetime_frac);
 115         player.race_movetime_frac -= f;
 116         player.race_movetime_count += f;
 117         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
 118
 119 #ifdef SVQC
 120         if(IS_PLAYER(player))
 121         {
 122                 if (player.race_penalty)
 123                         if (time > player.race_penalty)
 124                                 player.race_penalty = 0;
 125                 if(player.race_penalty)
 126                 {
 127                         player.velocity = '0 0 0';
 128                         set_movetype(player, MOVETYPE_NONE);
 129                         player.disableclientprediction = 2;
 130                 }
 131         }
 132 #endif
 133
 134         // force kbd movement for fairness
 135         float wishspeed;
 136         vector wishvel;
 137
 138         // if record times matter
 139         // ensure nothing EVIL is being done (i.e. div0_evade)
 140         // this hinders joystick users though
 141         // but it still gives SOME analog control
 142         wishvel.x = fabs(player.movement.x);
 143         wishvel.y = fabs(player.movement.y);
 144         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 145         {
 146                 wishvel.z = 0;
 147                 wishspeed = vlen(wishvel);
 148                 if(wishvel.x >= 2 * wishvel.y)
 149                 {
 150                         // pure X motion
 151                         if(player.movement.x > 0)
 152                                 player.movement_x = wishspeed;
 153                         else
 154                                 player.movement_x = -wishspeed;
 155                         player.movement_y = 0;
 156                 }
 157                 else if(wishvel.y >= 2 * wishvel.x)
 158                 {
 159                         // pure Y motion
 160                         player.movement_x = 0;
 161                         if(player.movement.y > 0)
 162                                 player.movement_y = wishspeed;
 163                         else
 164                                 player.movement_y = -wishspeed;
 165                 }
 166                 else
 167                 {
 168                         // diagonal
 169                         if(player.movement.x > 0)
 170                                 player.movement_x = M_SQRT1_2 * wishspeed;
 171                         else
 172                                 player.movement_x = -M_SQRT1_2 * wishspeed;
 173                         if(player.movement.y > 0)
 174                                 player.movement_y = M_SQRT1_2 * wishspeed;
 175                         else
 176                                 player.movement_y = -M_SQRT1_2 * wishspeed;
 177                 }
 178         }
 179 }
 180
 181 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
 182 {
 183         float s;
 184
 185         Score_NicePrint(NULL);
 186
 187         race_ClearRecords();
 188         PlayerScore_Sort(race_place, 0, 1, 0);
 189
 190         FOREACH_CLIENT(true, LAMBDA(
 191                 if(it.race_place)
 192                 {
 193                         s = PlayerScore_Add(it, SP_RACE_FASTEST, 0);
 194                         if(!s)
 195                                 it.race_place = 0;
 196                 }
 197                 cts_EventLog(ftos(it.race_place), it);
 198         ));
 199
 200         if(g_race_qualifying == 2)
 201         {
 202                 g_race_qualifying = 0;
 203                 independent_players = 0;
 204                 cvar_set("fraglimit", ftos(race_fraglimit));
 205                 cvar_set("leadlimit", ftos(race_leadlimit));
 206                 cvar_set("timelimit", ftos(race_timelimit));
 207                 cts_ScoreRules();
 208         }
 209 }
 210
 211 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
 212 {
 213         entity player = M_ARGV(0, entity);
 214
 215         race_PreparePlayer(player);
 216         player.race_checkpoint = -1;
 217
 218         if(IS_REAL_CLIENT(player))
 219         {
 220                 string rr = CTS_RECORD;
 221
 222                 msg_entity = player;
 223                 race_send_recordtime(MSG_ONE);
 224                 race_send_speedaward(MSG_ONE);
 225
 226                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 227                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 228                 race_send_speedaward_alltimebest(MSG_ONE);
 229
 230                 float i;
 231                 for (i = 1; i <= RANKINGS_CNT; ++i)
 232                 {
 233                         race_SendRankings(i, 0, 0, MSG_ONE);
 234                 }
 235         }
 236 }
 237
 238 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
 239 {
 240         entity player = M_ARGV(0, entity);
 241
 242         if(PlayerScore_Add(player, SP_RACE_FASTEST, 0))
 243                 player.frags = FRAGS_LMS_LOSER;
 244         else
 245                 player.frags = FRAGS_SPECTATOR;
 246
 247         race_PreparePlayer(player);
 248         player.race_checkpoint = -1;
 249 }
 250
 251 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
 252 {
 253         entity player = M_ARGV(0, entity);
 254         entity spawn_spot = M_ARGV(1, entity);
 255
 256         if(spawn_spot.target == "")
 257                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 258                 race_PreparePlayer(player);
 259
 260         // if we need to respawn, do it right
 261         player.race_respawn_checkpoint = player.race_checkpoint;
 262         player.race_respawn_spotref = spawn_spot;
 263
 264         player.race_place = 0;
 265 }
 266
 267 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
 268 {
 269         entity player = M_ARGV(0, entity);
 270
 271         if(IS_PLAYER(player))
 272         if(!gameover)
 273         {
 274                 if(player.killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 275                         race_PreparePlayer(player);
 276                 else // respawn
 277                         race_RetractPlayer(player);
 278
 279                 race_AbandonRaceCheck(player);
 280         }
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
 284 {
 285         entity frag_target = M_ARGV(2, entity);
 286
 287         frag_target.respawn_flags |= RESPAWN_FORCE;
 288         race_AbandonRaceCheck(frag_target);
 289 }
 290
 291 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
 292 {
 293         entity bot = M_ARGV(0, entity);
 294
 295         bot.havocbot_role = havocbot_role_cts;
 296         return true;
 297 }
 298
 299 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
 300 {
 301         entity player = M_ARGV(0, entity);
 302
 303         if(player.cvar_cl_allow_uidtracking == 1 && player.cvar_cl_allow_uid2name == 1)
 304         {
 305                 if (!player.stored_netname)
 306                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 307                 if(player.stored_netname != player.netname)
 308                 {
 309                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 310                         strunzone(player.stored_netname);
 311                         player.stored_netname = strzone(player.netname);
 312                 }
 313         }
 314
 315         if (!IS_OBSERVER(player))
 316         {
 317                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 318                 {
 319                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 320                         speedaward_holder = player.netname;
 321                         speedaward_uid = player.crypto_idfp;
 322                         speedaward_lastupdate = time;
 323                 }
 324                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 325                 {
 326                         string rr = CTS_RECORD;
 327                         race_send_speedaward(MSG_ALL);
 328                         speedaward_lastsent = speedaward_speed;
 329                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 330                         {
 331                                 speedaward_alltimebest = speedaward_speed;
 332                                 speedaward_alltimebest_holder = speedaward_holder;
 333                                 speedaward_alltimebest_uid = speedaward_uid;
 334                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 335                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 336                                 race_send_speedaward_alltimebest(MSG_ALL);
 337                         }
 338                 }
 339         }
 340 }
 341
 342 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
 343 {
 344         // no weapon dropping in CTS
 345         return true;
 346 }
 347
 348 MUTATOR_HOOKFUNCTION(cts, FilterItem)
 349 {
 350         entity item = M_ARGV(0, entity);
 351
 352         if(item.classname == "droppedweapon")
 353                 return true;
 354 }
 355
 356 MUTATOR_HOOKFUNCTION(cts, PlayerDamage_Calculate)
 357 {
 358         entity frag_attacker = M_ARGV(1, entity);
 359         entity frag_target = M_ARGV(2, entity);
 360         float frag_deathtype = M_ARGV(3, float);
 361         float frag_damage = M_ARGV(4, float);
 362
 363         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
 364         if(!autocvar_g_cts_selfdamage)
 365         {
 366                 frag_damage = 0;
 367                 M_ARGV(4, float) = frag_damage;
 368         }
 369 }
 370
 371 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
 372 {
 373         return true; // in CTS, you don't lose score by observing
 374 }
 375
 376 MUTATOR_HOOKFUNCTION(cts, GetRecords)
 377 {
 378         int record_page = M_ARGV(0, int);
 379         string ret_string = M_ARGV(1, string);
 380
 381         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 382         {
 383                 if(MapInfo_Get_ByID(i))
 384                 {
 385                         float r = race_readTime(MapInfo_Map_bspname, 1);
 386
 387                         if(!r)
 388                                 continue;
 389
 390                         string h = race_readName(MapInfo_Map_bspname, 1);
 391                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 392                 }
 393         }
 394
 395         M_ARGV(1, string) = ret_string;
 396 }
 397
 398 void ClientKill_Now(entity this);
 399 MUTATOR_HOOKFUNCTION(cts, ClientKill)
 400 {
 401     entity player = M_ARGV(0, entity);
 402
 403         M_ARGV(1, float) = 0; // kill delay
 404
 405         if(player.killindicator && player.killindicator.health == 1) // player.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 406         {
 407                 delete(player.killindicator);
 408                 player.killindicator = NULL;
 409
 410                 ClientKill_Now(player); // allow instant kill in this case
 411                 return;
 412         }
 413 }
 414
 415 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
 416 {
 417         entity player = M_ARGV(0, entity);
 418
 419         if(autocvar_g_cts_finish_kill_delay)
 420                 CTS_ClientKill(player);
 421 }
 422
 423 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
 424 {
 425         entity player = M_ARGV(0, entity);
 426
 427         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 428 }
 429
 430 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
 431 {
 432         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
 433         M_ARGV(3, bool) = true; // want mutator blocked
 434         return true;
 435 }
 436
 437 void cts_Initialize()
 438 {
 439         cts_ScoreRules();
 440 }
 441
 442 #endif