qcsrc/server/mutators/mutator/gamemode_domination.qc

   1 #include "gamemode_domination.qh"
   2 #ifndef GAMEMODE_DOMINATION_H
   3 #define GAMEMODE_DOMINATION_H
   4
   5 #define autocvar_g_domination_point_limit cvar("g_domination_point_limit")
   6 bool autocvar_g_domination_roundbased;
   7 int autocvar_g_domination_roundbased_point_limit;
   8 int autocvar_g_domination_point_leadlimit;
   9
  10 void dom_Initialize();
  11
  12 REGISTER_MUTATOR(dom, false)
  13 {
  14         MUTATOR_ONADD
  15         {
  16                 if (time > 1) // game loads at time 1
  17                         error("This is a game type and it cannot be added at runtime.");
  18                 dom_Initialize();
  19
  20                 int fraglimit_override = autocvar_g_domination_point_limit;
  21                 if (autocvar_g_domination_roundbased && autocvar_g_domination_roundbased_point_limit)
  22                         fraglimit_override = autocvar_g_domination_roundbased_point_limit;
  23
  24                 ActivateTeamplay();
  25                 SetLimits(fraglimit_override, autocvar_g_domination_point_leadlimit, autocvar_timelimit_override, -1);
  26                 have_team_spawns = -1; // request team spawns
  27         }
  28
  29         MUTATOR_ONREMOVE
  30         {
  31                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  32                 return -1;
  33         }
  34
  35         return 0;
  36 }
  37
  38 // score rule declarations
  39 const float ST_DOM_TICKS = 1;
  40 const float SP_DOM_TICKS = 4;
  41 const float SP_DOM_TAKES = 5;
  42 const float ST_DOM_CAPS = 1;
  43 const float SP_DOM_CAPS = 4;
  44
  45 // pps: points per second
  46 .float dom_total_pps = _STAT(DOM_TOTAL_PPS);
  47 .float dom_pps_red = _STAT(DOM_PPS_RED);
  48 .float dom_pps_blue = _STAT(DOM_PPS_BLUE);
  49 .float dom_pps_yellow = _STAT(DOM_PPS_YELLOW);
  50 .float dom_pps_pink = _STAT(DOM_PPS_PINK);
  51 float total_pps;
  52 float pps_red;
  53 float pps_blue;
  54 float pps_yellow;
  55 float pps_pink;
  56
  57 // capture declarations
  58 .float enemy_playerid;
  59 .entity sprite;
  60 .float captime;
  61
  62 // misc globals
  63 float domination_roundbased;
  64 float domination_teams;
  65 #endif
  66
  67 #ifdef IMPLEMENTATION
  68
  69 #include <server/teamplay.qh>
  70
  71 bool g_domination;
  72
  73 int autocvar_g_domination_default_teams;
  74 bool autocvar_g_domination_disable_frags;
  75 int autocvar_g_domination_point_amt;
  76 bool autocvar_g_domination_point_fullbright;
  77 float autocvar_g_domination_round_timelimit;
  78 float autocvar_g_domination_warmup;
  79 float autocvar_g_domination_point_rate;
  80 int autocvar_g_domination_teams_override;
  81
  82 void dom_EventLog(string mode, float team_before, entity actor) // use an alias for easy changing and quick editing later
  83 {
  84         if(autocvar_sv_eventlog)
  85                 GameLogEcho(strcat(":dom:", mode, ":", ftos(team_before), ((actor != world) ? (strcat(":", ftos(actor.playerid))) : "")));
  86 }
  87
  88 void set_dom_state(entity e)
  89 {
  90         e.dom_total_pps = total_pps;
  91         e.dom_pps_red = pps_red;
  92         e.dom_pps_blue = pps_blue;
  93         if(domination_teams >= 3)
  94                 e.dom_pps_yellow = pps_yellow;
  95         if(domination_teams >= 4)
  96                 e.dom_pps_pink = pps_pink;
  97 }
  98
  99 void dompoint_captured(entity this)
 100 {
 101         float old_delay, old_team, real_team;
 102
 103         // now that the delay has expired, switch to the latest team to lay claim to this point
 104         entity head = this.owner;
 105
 106         real_team = this.cnt;
 107         this.cnt = -1;
 108
 109         dom_EventLog("taken", this.team, this.dmg_inflictor);
 110         this.dmg_inflictor = world;
 111
 112         this.goalentity = head;
 113         this.model = head.mdl;
 114         this.modelindex = head.dmg;
 115         this.skin = head.skin;
 116
 117         float points, wait_time;
 118         if (autocvar_g_domination_point_amt)
 119                 points = autocvar_g_domination_point_amt;
 120         else
 121                 points = this.frags;
 122         if (autocvar_g_domination_point_rate)
 123                 wait_time = autocvar_g_domination_point_rate;
 124         else
 125                 wait_time = this.wait;
 126
 127         if(domination_roundbased)
 128                 bprint(sprintf("^3%s^3%s\n", head.netname, this.message));
 129         else
 130                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_DOMINATION_CAPTURE_TIME, head.netname, this.message, points, wait_time);
 131
 132         if(this.enemy.playerid == this.enemy_playerid)
 133                 PlayerScore_Add(this.enemy, SP_DOM_TAKES, 1);
 134         else
 135                 this.enemy = world;
 136
 137         if (head.noise != "")
 138                 if(this.enemy)
 139                         _sound(this.enemy, CH_TRIGGER, head.noise, VOL_BASE, ATTEN_NORM);
 140                 else
 141                         _sound(this, CH_TRIGGER, head.noise, VOL_BASE, ATTEN_NORM);
 142         if (head.noise1 != "")
 143                 play2all(head.noise1);
 144
 145         this.delay = time + wait_time;
 146
 147         // do trigger work
 148         old_delay = this.delay;
 149         old_team = this.team;
 150         this.team = real_team;
 151         this.delay = 0;
 152         SUB_UseTargets (this, this, NULL);
 153         this.delay = old_delay;
 154         this.team = old_team;
 155
 156         entity msg = WP_DomNeut;
 157         switch(this.team)
 158         {
 159                 case NUM_TEAM_1: msg = WP_DomRed; break;
 160                 case NUM_TEAM_2: msg = WP_DomBlue; break;
 161                 case NUM_TEAM_3: msg = WP_DomYellow; break;
 162                 case NUM_TEAM_4: msg = WP_DomPink; break;
 163         }
 164
 165         WaypointSprite_UpdateSprites(this.sprite, msg, WP_Null, WP_Null);
 166
 167         total_pps = 0, pps_red = 0, pps_blue = 0, pps_yellow = 0, pps_pink = 0;
 168         for(head = world; (head = find(head, classname, "dom_controlpoint")) != world; )
 169         FOREACH_ENTITY_CLASS("dom_controlpoint", true, LAMBDA(
 170                 if (autocvar_g_domination_point_amt)
 171                         points = autocvar_g_domination_point_amt;
 172                 else
 173                         points = it.frags;
 174                 if (autocvar_g_domination_point_rate)
 175                         wait_time = autocvar_g_domination_point_rate;
 176                 else
 177                         wait_time = it.wait;
 178                 switch(it.goalentity.team)
 179                 {
 180                         case NUM_TEAM_1: pps_red += points/wait_time; break;
 181                         case NUM_TEAM_2: pps_blue += points/wait_time; break;
 182                         case NUM_TEAM_3: pps_yellow += points/wait_time; break;
 183                         case NUM_TEAM_4: pps_pink += points/wait_time; break;
 184                 }
 185                 total_pps += points/wait_time;
 186         ));
 187
 188         WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DOMPOINT, colormapPaletteColor(this.goalentity.team - 1, 0));
 189         WaypointSprite_Ping(this.sprite);
 190
 191         this.captime = time;
 192
 193         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(set_dom_state(it)));
 194 }
 195
 196 void AnimateDomPoint(entity this)
 197 {
 198         if(this.pain_finished > time)
 199                 return;
 200         this.pain_finished = time + this.t_width;
 201         if(this.nextthink > this.pain_finished)
 202                 this.nextthink = this.pain_finished;
 203
 204         this.frame = this.frame + 1;
 205         if(this.frame > this.t_length)
 206                 this.frame = 0;
 207 }
 208
 209 void dompointthink(entity this)
 210 {
 211         float fragamt;
 212
 213         this.nextthink = time + 0.1;
 214
 215         //this.frame = this.frame + 1;
 216         //if(this.frame > 119)
 217         //      this.frame = 0;
 218         AnimateDomPoint(this);
 219
 220         // give points
 221
 222         if (gameover || this.delay > time || time < game_starttime)     // game has ended, don't keep giving points
 223                 return;
 224
 225         if(autocvar_g_domination_point_rate)
 226                 this.delay = time + autocvar_g_domination_point_rate;
 227         else
 228                 this.delay = time + this.wait;
 229
 230         // give credit to the team
 231         // NOTE: this defaults to 0
 232         if (!domination_roundbased)
 233         if (this.goalentity.netname != "")
 234         {
 235                 if(autocvar_g_domination_point_amt)
 236                         fragamt = autocvar_g_domination_point_amt;
 237                 else
 238                         fragamt = this.frags;
 239                 TeamScore_AddToTeam(this.goalentity.team, ST_SCORE, fragamt);
 240                 TeamScore_AddToTeam(this.goalentity.team, ST_DOM_TICKS, fragamt);
 241
 242                 // give credit to the individual player, if he is still there
 243                 if (this.enemy.playerid == this.enemy_playerid)
 244                 {
 245                         PlayerScore_Add(this.enemy, SP_SCORE, fragamt);
 246                         PlayerScore_Add(this.enemy, SP_DOM_TICKS, fragamt);
 247                 }
 248                 else
 249                         this.enemy = world;
 250         }
 251 }
 252
 253 void dompointtouch(entity this)
 254 {
 255         if (!IS_PLAYER(other))
 256                 return;
 257         if (other.health < 1)
 258                 return;
 259
 260         if(round_handler_IsActive() && !round_handler_IsRoundStarted())
 261                 return;
 262
 263         if(time < this.captime + 0.3)
 264                 return;
 265
 266         // only valid teams can claim it
 267         entity head = find(world, classname, "dom_team");
 268         while (head && head.team != other.team)
 269                 head = find(head, classname, "dom_team");
 270         if (!head || head.netname == "" || head == this.goalentity)
 271                 return;
 272
 273         // delay capture
 274
 275         this.team = this.goalentity.team; // this stores the PREVIOUS team!
 276
 277         this.cnt = other.team;
 278         this.owner = head; // team to switch to after the delay
 279         this.dmg_inflictor = other;
 280
 281         // this.state = 1;
 282         // this.delay = time + cvar("g_domination_point_capturetime");
 283         //this.nextthink = time + cvar("g_domination_point_capturetime");
 284         //this.think = dompoint_captured;
 285
 286         // go to neutral team in the mean time
 287         head = find(world, classname, "dom_team");
 288         while (head && head.netname != "")
 289                 head = find(head, classname, "dom_team");
 290         if(head == world)
 291                 return;
 292
 293         WaypointSprite_UpdateSprites(this.sprite, WP_DomNeut, WP_Null, WP_Null);
 294         WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DOMPOINT, '0 1 1');
 295         WaypointSprite_Ping(this.sprite);
 296
 297         this.goalentity = head;
 298         this.model = head.mdl;
 299         this.modelindex = head.dmg;
 300         this.skin = head.skin;
 301
 302         this.enemy = other; // individual player scoring
 303         this.enemy_playerid = other.playerid;
 304         dompoint_captured(this);
 305 }
 306
 307 void dom_controlpoint_setup(entity this)
 308 {
 309         entity head;
 310         // find the spawnfunc_dom_team representing unclaimed points
 311         head = find(world, classname, "dom_team");
 312         while(head && head.netname != "")
 313                 head = find(head, classname, "dom_team");
 314         if (!head)
 315                 objerror(this, "no spawnfunc_dom_team with netname \"\" found\n");
 316
 317         // copy important properties from spawnfunc_dom_team entity
 318         this.goalentity = head;
 319         _setmodel(this, head.mdl); // precision already set
 320         this.skin = head.skin;
 321
 322         this.cnt = -1;
 323
 324         if(this.message == "")
 325                 this.message = " has captured a control point";
 326
 327         if(this.frags <= 0)
 328                 this.frags = 1;
 329         if(this.wait <= 0)
 330                 this.wait = 5;
 331
 332         float points, waittime;
 333         if (autocvar_g_domination_point_amt)
 334                 points = autocvar_g_domination_point_amt;
 335         else
 336                 points = this.frags;
 337         if (autocvar_g_domination_point_rate)
 338                 waittime = autocvar_g_domination_point_rate;
 339         else
 340                 waittime = this.wait;
 341
 342         total_pps += points/waittime;
 343
 344         if(!this.t_width)
 345                 this.t_width = 0.02; // frame animation rate
 346         if(!this.t_length)
 347                 this.t_length = 239; // maximum frame
 348
 349         setthink(this, dompointthink);
 350         this.nextthink = time;
 351         settouch(this, dompointtouch);
 352         this.solid = SOLID_TRIGGER;
 353         this.flags = FL_ITEM;
 354         setsize(this, '-32 -32 -32', '32 32 32');
 355         setorigin(this, this.origin + '0 0 20');
 356         droptofloor(this);
 357
 358         waypoint_spawnforitem(this);
 359         WaypointSprite_SpawnFixed(WP_DomNeut, this.origin + '0 0 32', this, sprite, RADARICON_DOMPOINT);
 360 }
 361
 362 float total_controlpoints;
 363 void Domination_count_controlpoints()
 364 {
 365         entity e;
 366         total_controlpoints = redowned = blueowned = yellowowned = pinkowned = 0;
 367         for(e = world; (e = find(e, classname, "dom_controlpoint")) != world; )
 368         {
 369                 ++total_controlpoints;
 370                 redowned += (e.goalentity.team == NUM_TEAM_1);
 371                 blueowned += (e.goalentity.team == NUM_TEAM_2);
 372                 yellowowned += (e.goalentity.team == NUM_TEAM_3);
 373                 pinkowned += (e.goalentity.team == NUM_TEAM_4);
 374         }
 375 }
 376
 377 float Domination_GetWinnerTeam()
 378 {
 379         float winner_team = 0;
 380         if(redowned == total_controlpoints)
 381                 winner_team = NUM_TEAM_1;
 382         if(blueowned == total_controlpoints)
 383         {
 384                 if(winner_team) return 0;
 385                 winner_team = NUM_TEAM_2;
 386         }
 387         if(yellowowned == total_controlpoints)
 388         {
 389                 if(winner_team) return 0;
 390                 winner_team = NUM_TEAM_3;
 391         }
 392         if(pinkowned == total_controlpoints)
 393         {
 394                 if(winner_team) return 0;
 395                 winner_team = NUM_TEAM_4;
 396         }
 397         if(winner_team)
 398                 return winner_team;
 399         return -1; // no control points left?
 400 }
 401
 402 #define DOM_OWNED_CONTROLPOINTS() ((redowned > 0) + (blueowned > 0) + (yellowowned > 0) + (pinkowned > 0))
 403 #define DOM_OWNED_CONTROLPOINTS_OK() (DOM_OWNED_CONTROLPOINTS() < total_controlpoints)
 404 float Domination_CheckWinner()
 405 {
 406         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 407         {
 408                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
 409                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
 410                 round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 411                 return 1;
 412         }
 413
 414         Domination_count_controlpoints();
 415
 416         float winner_team = Domination_GetWinnerTeam();
 417
 418         if(winner_team == -1)
 419                 return 0;
 420
 421         if(winner_team > 0)
 422         {
 423                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 424                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 425                 TeamScore_AddToTeam(winner_team, ST_DOM_CAPS, +1);
 426         }
 427         else if(winner_team == -1)
 428         {
 429                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
 430                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
 431         }
 432
 433         round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 434
 435         return 1;
 436 }
 437
 438 float Domination_CheckPlayers()
 439 {
 440         return 1;
 441 }
 442
 443 void Domination_RoundStart()
 444 {
 445         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.player_blocked = false));
 446 }
 447
 448 //go to best items, or control points you don't own
 449 void havocbot_role_dom(entity this)
 450 {
 451         if(IS_DEAD(this))
 452                 return;
 453
 454         if (this.bot_strategytime < time)
 455         {
 456                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 457                 navigation_goalrating_start(this);
 458                 havocbot_goalrating_controlpoints(this, 10000, this.origin, 15000);
 459                 havocbot_goalrating_items(this, 8000, this.origin, 8000);
 460                 //havocbot_goalrating_enemyplayers(this, 3000, this.origin, 2000);
 461                 //havocbot_goalrating_waypoints(1, this.origin, 1000);
 462                 navigation_goalrating_end(this);
 463         }
 464 }
 465
 466 MUTATOR_HOOKFUNCTION(dom, GetTeamCount)
 467 {
 468         // fallback?
 469         M_ARGV(0, float) = domination_teams;
 470         string ret_string = "dom_team";
 471
 472         entity head = find(world, classname, ret_string);
 473         while(head)
 474         {
 475                 if(head.netname != "")
 476                 {
 477                         switch(head.team)
 478                         {
 479                                 case NUM_TEAM_1: c1 = 0; break;
 480                                 case NUM_TEAM_2: c2 = 0; break;
 481                                 case NUM_TEAM_3: c3 = 0; break;
 482                                 case NUM_TEAM_4: c4 = 0; break;
 483                         }
 484                 }
 485
 486                 head = find(head, classname, ret_string);
 487         }
 488
 489         M_ARGV(1, string) = string_null;
 490
 491         return true;
 492 }
 493
 494 MUTATOR_HOOKFUNCTION(dom, reset_map_players)
 495 {
 496         total_pps = 0, pps_red = 0, pps_blue = 0, pps_yellow = 0, pps_pink = 0;
 497         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 498                 WITHSELF(it, PutClientInServer());
 499                 if(domination_roundbased)
 500                         it.player_blocked = 1;
 501                 if(IS_REAL_CLIENT(it))
 502                         set_dom_state(it);
 503         ));
 504         return true;
 505 }
 506
 507 MUTATOR_HOOKFUNCTION(dom, PlayerSpawn)
 508 {
 509         entity player = M_ARGV(0, entity);
 510
 511         if(domination_roundbased)
 512         if(!round_handler_IsRoundStarted())
 513                 player.player_blocked = 1;
 514         else
 515                 player.player_blocked = 0;
 516 }
 517
 518 MUTATOR_HOOKFUNCTION(dom, ClientConnect)
 519 {
 520         entity player = M_ARGV(0, entity);
 521
 522         set_dom_state(player);
 523 }
 524
 525 MUTATOR_HOOKFUNCTION(dom, HavocBot_ChooseRole)
 526 {
 527         entity bot = M_ARGV(0, entity);
 528
 529         bot.havocbot_role = havocbot_role_dom;
 530         return true;
 531 }
 532
 533 /*QUAKED spawnfunc_dom_controlpoint (0 .5 .8) (-16 -16 -24) (16 16 32)
 534 Control point for Domination gameplay.
 535 */
 536 spawnfunc(dom_controlpoint)
 537 {
 538         if(!g_domination)
 539         {
 540                 remove(this);
 541                 return;
 542         }
 543         setthink(this, dom_controlpoint_setup);
 544         this.nextthink = time + 0.1;
 545         this.reset = dom_controlpoint_setup;
 546
 547         if(!this.scale)
 548                 this.scale = 0.6;
 549
 550         this.effects = this.effects | EF_LOWPRECISION;
 551         if (autocvar_g_domination_point_fullbright)
 552                 this.effects |= EF_FULLBRIGHT;
 553 }
 554
 555 /*QUAKED spawnfunc_dom_team (0 .5 .8) (-32 -32 -24) (32 32 32)
 556 Team declaration for Domination gameplay, this allows you to decide what team
 557 names and control point models are used in your map.
 558
 559 Note: If you use spawnfunc_dom_team entities you must define at least 3 and only two
 560 can have netname set!  The nameless team owns all control points at start.
 561
 562 Keys:
 563 "netname"
 564  Name of the team (for example Red Team, Blue Team, Green Team, Yellow Team, Life, Death, etc)
 565 "cnt"
 566  Scoreboard color of the team (for example 4 is red and 13 is blue)
 567 "model"
 568  Model to use for control points owned by this team (for example
 569  "progs/b_g_key.mdl" is a gold keycard, and "progs/b_s_key.mdl" is a silver
 570  keycard)
 571 "skin"
 572  Skin of the model to use (for team skins on a single model)
 573 "noise"
 574  Sound to play when this team captures a point.
 575  (this is a localized sound, like a small alarm or other effect)
 576 "noise1"
 577  Narrator speech to play when this team captures a point.
 578  (this is a global sound, like "Red team has captured a control point")
 579 */
 580
 581 spawnfunc(dom_team)
 582 {
 583         if(!g_domination || autocvar_g_domination_teams_override >= 2)
 584         {
 585                 remove(this);
 586                 return;
 587         }
 588         precache_model(this.model);
 589         if (this.noise != "")
 590                 precache_sound(this.noise);
 591         if (this.noise1 != "")
 592                 precache_sound(this.noise1);
 593         this.classname = "dom_team";
 594         _setmodel(this, this.model); // precision not needed
 595         this.mdl = this.model;
 596         this.dmg = this.modelindex;
 597         this.model = "";
 598         this.modelindex = 0;
 599         // this would have to be changed if used in quakeworld
 600         if(this.cnt)
 601                 this.team = this.cnt + 1; // WHY are these different anyway?
 602 }
 603
 604 // scoreboard setup
 605 void ScoreRules_dom(float teams)
 606 {
 607         if(domination_roundbased)
 608         {
 609                 ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, 0, true);
 610                 ScoreInfo_SetLabel_TeamScore  (ST_DOM_CAPS, "caps", SFL_SORT_PRIO_PRIMARY);
 611                 ScoreInfo_SetLabel_PlayerScore(SP_DOM_TAKES, "takes", 0);
 612                 ScoreRules_basics_end();
 613         }
 614         else
 615         {
 616                 float sp_domticks, sp_score;
 617                 sp_score = sp_domticks = 0;
 618                 if(autocvar_g_domination_disable_frags)
 619                         sp_domticks = SFL_SORT_PRIO_PRIMARY;
 620                 else
 621                         sp_score = SFL_SORT_PRIO_PRIMARY;
 622                 ScoreRules_basics(teams, sp_score, sp_score, true);
 623                 ScoreInfo_SetLabel_TeamScore  (ST_DOM_TICKS,    "ticks",     sp_domticks);
 624                 ScoreInfo_SetLabel_PlayerScore(SP_DOM_TICKS,    "ticks",     sp_domticks);
 625                 ScoreInfo_SetLabel_PlayerScore(SP_DOM_TAKES,    "takes",     0);
 626                 ScoreRules_basics_end();
 627         }
 628 }
 629
 630 // code from here on is just to support maps that don't have control point and team entities
 631 void dom_spawnteam (string teamname, float teamcolor, string pointmodel, float pointskin, Sound capsound, string capnarration, string capmessage)
 632 {
 633     TC(Sound, capsound);
 634     entity e = new_pure(dom_team);
 635         e.netname = strzone(teamname);
 636         e.cnt = teamcolor;
 637         e.model = pointmodel;
 638         e.skin = pointskin;
 639         e.noise = strzone(Sound_fixpath(capsound));
 640         e.noise1 = strzone(capnarration);
 641         e.message = strzone(capmessage);
 642
 643         // this code is identical to spawnfunc_dom_team
 644         _setmodel(e, e.model); // precision not needed
 645         e.mdl = e.model;
 646         e.dmg = e.modelindex;
 647         e.model = "";
 648         e.modelindex = 0;
 649         // this would have to be changed if used in quakeworld
 650         e.team = e.cnt + 1;
 651
 652         //eprint(e);
 653 }
 654
 655 void dom_spawnpoint(vector org)
 656 {
 657         entity e = spawn();
 658         e.classname = "dom_controlpoint";
 659         setthink(e, spawnfunc_dom_controlpoint);
 660         e.nextthink = time;
 661         setorigin(e, org);
 662         spawnfunc_dom_controlpoint(e);
 663 }
 664
 665 // spawn some default teams if the map is not set up for domination
 666 void dom_spawnteams(int teams)
 667 {
 668     TC(int, teams);
 669         dom_spawnteam(Team_ColoredFullName(NUM_TEAM_1), NUM_TEAM_1-1, "models/domination/dom_red.md3", 0, SND_DOM_CLAIM, "", "Red team has captured a control point");
 670         dom_spawnteam(Team_ColoredFullName(NUM_TEAM_2), NUM_TEAM_2-1, "models/domination/dom_blue.md3", 0, SND_DOM_CLAIM, "", "Blue team has captured a control point");
 671         if(teams >= 3)
 672                 dom_spawnteam(Team_ColoredFullName(NUM_TEAM_3), NUM_TEAM_3-1, "models/domination/dom_yellow.md3", 0, SND_DOM_CLAIM, "", "Yellow team has captured a control point");
 673         if(teams >= 4)
 674                 dom_spawnteam(Team_ColoredFullName(NUM_TEAM_4), NUM_TEAM_4-1, "models/domination/dom_pink.md3", 0, SND_DOM_CLAIM, "", "Pink team has captured a control point");
 675         dom_spawnteam("", 0, "models/domination/dom_unclaimed.md3", 0, SND_Null, "", "");
 676 }
 677
 678 void dom_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up.
 679 {
 680         // if no teams are found, spawn defaults
 681         if(find(world, classname, "dom_team") == world || autocvar_g_domination_teams_override >= 2)
 682         {
 683                 LOG_TRACE("No \"dom_team\" entities found on this map, creating them anyway.\n");
 684                 domination_teams = bound(2, ((autocvar_g_domination_teams_override < 2) ? autocvar_g_domination_default_teams : autocvar_g_domination_teams_override), 4);
 685                 dom_spawnteams(domination_teams);
 686         }
 687
 688         CheckAllowedTeams(world);
 689         domination_teams = ((c4>=0) ? 4 : (c3>=0) ? 3 : 2);
 690
 691         domination_roundbased = autocvar_g_domination_roundbased;
 692
 693         ScoreRules_dom(domination_teams);
 694
 695         if(domination_roundbased)
 696         {
 697                 round_handler_Spawn(Domination_CheckPlayers, Domination_CheckWinner, Domination_RoundStart);
 698                 round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 699         }
 700 }
 701
 702 void dom_Initialize()
 703 {
 704         g_domination = true;
 705         InitializeEntity(world, dom_DelayedInit, INITPRIO_GAMETYPE);
 706 }
 707
 708 #endif