qcsrc/server/mutators/mutator/gamemode_freezetag.qc

   1 #include "gamemode_freezetag.qh"
   2 #ifndef GAMEMODE_FREEZETAG_H
   3 #define GAMEMODE_FREEZETAG_H
   4
   5 int autocvar_g_freezetag_point_limit;
   6 int autocvar_g_freezetag_point_leadlimit;
   7 bool autocvar_g_freezetag_team_spawns;
   8 void freezetag_Initialize();
   9
  10 REGISTER_MUTATOR(ft, false)
  11 {
  12         MUTATOR_ONADD
  13         {
  14                 if (time > 1) // game loads at time 1
  15                         error("This is a game type and it cannot be added at runtime.");
  16                 freezetag_Initialize();
  17
  18                 ActivateTeamplay();
  19                 SetLimits(autocvar_g_freezetag_point_limit, autocvar_g_freezetag_point_leadlimit, -1, -1);
  20
  21                 if (autocvar_g_freezetag_team_spawns)
  22                         have_team_spawns = -1; // request team spawns
  23         }
  24
  25         MUTATOR_ONROLLBACK_OR_REMOVE
  26         {
  27                 // we actually cannot roll back freezetag_Initialize here
  28                 // BUT: we don't need to! If this gets called, adding always
  29                 // succeeds.
  30         }
  31
  32         MUTATOR_ONREMOVE
  33         {
  34                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  35                 return -1;
  36         }
  37
  38         return 0;
  39 }
  40
  41 .float freezetag_frozen_time;
  42 .float freezetag_frozen_timeout;
  43 const float ICE_MAX_ALPHA = 1;
  44 const float ICE_MIN_ALPHA = 0.1;
  45 float freezetag_teams;
  46
  47 .float reviving; // temp var
  48
  49 float autocvar_g_freezetag_revive_extra_size;
  50 float autocvar_g_freezetag_revive_speed;
  51 bool autocvar_g_freezetag_revive_nade;
  52 float autocvar_g_freezetag_revive_nade_health;
  53
  54 #endif
  55 #ifdef IMPLEMENTATION
  56
  57 float autocvar_g_freezetag_frozen_maxtime;
  58 float autocvar_g_freezetag_revive_clearspeed;
  59 float autocvar_g_freezetag_round_timelimit;
  60 int autocvar_g_freezetag_teams;
  61 int autocvar_g_freezetag_teams_override;
  62 float autocvar_g_freezetag_warmup;
  63
  64 const float SP_FREEZETAG_REVIVALS = 4;
  65 void freezetag_ScoreRules(float teams)
  66 {
  67         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, true); // SFL_SORT_PRIO_PRIMARY
  68         ScoreInfo_SetLabel_PlayerScore(SP_FREEZETAG_REVIVALS, "revivals", 0);
  69         ScoreRules_basics_end();
  70 }
  71
  72 void freezetag_count_alive_players()
  73 {
  74         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  75         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  76                 switch(it.team)
  77                 {
  78                         case NUM_TEAM_1: ++total_players; if(it.health >= 1 && STAT(FROZEN, it) != 1) ++redalive; break;
  79                         case NUM_TEAM_2: ++total_players; if(it.health >= 1 && STAT(FROZEN, it) != 1) ++bluealive; break;
  80                         case NUM_TEAM_3: ++total_players; if(it.health >= 1 && STAT(FROZEN, it) != 1) ++yellowalive; break;
  81                         case NUM_TEAM_4: ++total_players; if(it.health >= 1 && STAT(FROZEN, it) != 1) ++pinkalive; break;
  82                 }
  83         ));
  84         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  85                 it.redalive_stat = redalive;
  86                 it.bluealive_stat = bluealive;
  87                 it.yellowalive_stat = yellowalive;
  88                 it.pinkalive_stat = pinkalive;
  89         ));
  90
  91         eliminatedPlayers.SendFlags |= 1;
  92 }
  93 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  94 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  95
  96 float freezetag_CheckTeams()
  97 {
  98         static float prev_missing_teams_mask;
  99         if(FREEZETAG_ALIVE_TEAMS_OK())
 100         {
 101                 if(prev_missing_teams_mask > 0)
 102                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 103                 prev_missing_teams_mask = -1;
 104                 return 1;
 105         }
 106         if(total_players == 0)
 107         {
 108                 if(prev_missing_teams_mask > 0)
 109                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 110                 prev_missing_teams_mask = -1;
 111                 return 0;
 112         }
 113         float missing_teams_mask = (!redalive) + (!bluealive) * 2;
 114         if(freezetag_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 115         if(freezetag_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 116         if(prev_missing_teams_mask != missing_teams_mask)
 117         {
 118                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 119                 prev_missing_teams_mask = missing_teams_mask;
 120         }
 121         return 0;
 122 }
 123
 124 float freezetag_getWinnerTeam()
 125 {
 126         float winner_team = 0;
 127         if(redalive >= 1)
 128                 winner_team = NUM_TEAM_1;
 129         if(bluealive >= 1)
 130         {
 131                 if(winner_team) return 0;
 132                 winner_team = NUM_TEAM_2;
 133         }
 134         if(yellowalive >= 1)
 135         {
 136                 if(winner_team) return 0;
 137                 winner_team = NUM_TEAM_3;
 138         }
 139         if(pinkalive >= 1)
 140         {
 141                 if(winner_team) return 0;
 142                 winner_team = NUM_TEAM_4;
 143         }
 144         if(winner_team)
 145                 return winner_team;
 146         return -1; // no player left
 147 }
 148
 149 float freezetag_CheckWinner()
 150 {
 151         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 152         {
 153                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
 154                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
 155                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 156                         it.freezetag_frozen_timeout = 0;
 157                         nades_Clear(it);
 158                 ));
 159                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 160                 return 1;
 161         }
 162
 163         if(FREEZETAG_ALIVE_TEAMS() > 1)
 164                 return 0;
 165
 166         int winner_team = freezetag_getWinnerTeam();
 167         if(winner_team > 0)
 168         {
 169                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 170                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 171                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 172         }
 173         else if(winner_team == -1)
 174         {
 175                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
 176                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
 177         }
 178
 179         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 180                 it.freezetag_frozen_timeout = 0;
 181                 nades_Clear(it);
 182         ));
 183         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 184         return 1;
 185 }
 186
 187 entity freezetag_LastPlayerForTeam()
 188 {SELFPARAM();
 189         entity last_pl = world;
 190         FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(
 191                 if(it.health >= 1)
 192                 if(!STAT(FROZEN, it))
 193                 if(SAME_TEAM(it, self))
 194                 if(!last_pl)
 195                         last_pl = it;
 196                 else
 197                         return world;
 198         ));
 199         return last_pl;
 200 }
 201
 202 void freezetag_LastPlayerForTeam_Notify()
 203 {
 204         if(round_handler_IsActive())
 205         if(round_handler_IsRoundStarted())
 206         {
 207                 entity pl = freezetag_LastPlayerForTeam();
 208                 if(pl)
 209                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 210         }
 211 }
 212
 213 void freezetag_Add_Score(entity attacker)
 214 {SELFPARAM();
 215         if(attacker == self)
 216         {
 217                 // you froze your own dumb self
 218                 // counted as "suicide" already
 219                 PlayerScore_Add(self, SP_SCORE, -1);
 220         }
 221         else if(IS_PLAYER(attacker))
 222         {
 223                 // got frozen by an enemy
 224                 // counted as "kill" and "death" already
 225                 PlayerScore_Add(self, SP_SCORE, -1);
 226                 PlayerScore_Add(attacker, SP_SCORE, +1);
 227         }
 228         // else nothing - got frozen by the game type rules themselves
 229 }
 230
 231 void freezetag_Freeze(entity attacker)
 232 {SELFPARAM();
 233         if(STAT(FROZEN, self))
 234                 return;
 235
 236         if(autocvar_g_freezetag_frozen_maxtime > 0)
 237                 self.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 238
 239         Freeze(self, 0, 1, true);
 240
 241         freezetag_count_alive_players();
 242
 243         freezetag_Add_Score(attacker);
 244 }
 245
 246 void freezetag_Unfreeze(entity attacker)
 247 {SELFPARAM();
 248         self.freezetag_frozen_time = 0;
 249         self.freezetag_frozen_timeout = 0;
 250
 251         Unfreeze(self);
 252 }
 253
 254 float freezetag_isEliminated(entity e)
 255 {
 256         if(IS_PLAYER(e) && (STAT(FROZEN, e) == 1 || IS_DEAD(e)))
 257                 return true;
 258         return false;
 259 }
 260
 261
 262 // ================
 263 // Bot player logic
 264 // ================
 265
 266 void(entity this) havocbot_role_ft_freeing;
 267 void(entity this) havocbot_role_ft_offense;
 268
 269 void havocbot_goalrating_freeplayers(entity this, float ratingscale, vector org, float sradius)
 270 {
 271         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), LAMBDA(
 272                 if (STAT(FROZEN, it) == 1)
 273                 {
 274                         if(vdist(it.origin - org, >, sradius))
 275                                 continue;
 276                         navigation_routerating(this, it, ratingscale, 2000);
 277                 }
 278                 else
 279                 {
 280                         // If teamate is not frozen still seek them out as fight better
 281                         // in a group.
 282                         navigation_routerating(this, it, ratingscale/3, 2000);
 283                 }
 284         ));
 285 }
 286
 287 void havocbot_role_ft_offense(entity this)
 288 {
 289         if(IS_DEAD(this))
 290                 return;
 291
 292         if (!this.havocbot_role_timeout)
 293                 this.havocbot_role_timeout = time + random() * 10 + 20;
 294
 295         // Count how many players on team are unfrozen.
 296         int unfrozen = 0;
 297         FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, this) && !(STAT(FROZEN, it) != 1), LAMBDA(unfrozen++));
 298
 299         // If only one left on team or if role has timed out then start trying to free players.
 300         if (((unfrozen == 0) && (!STAT(FROZEN, this))) || (time > this.havocbot_role_timeout))
 301         {
 302                 LOG_TRACE("changing role to freeing\n");
 303                 this.havocbot_role = havocbot_role_ft_freeing;
 304                 this.havocbot_role_timeout = 0;
 305                 return;
 306         }
 307
 308         if (time > this.bot_strategytime)
 309         {
 310                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 311
 312                 navigation_goalrating_start(this);
 313                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 314                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
 315                 havocbot_goalrating_freeplayers(this, 9000, this.origin, 10000);
 316                 //havocbot_goalrating_waypoints(1, this.origin, 1000);
 317                 navigation_goalrating_end(this);
 318         }
 319 }
 320
 321 void havocbot_role_ft_freeing(entity this)
 322 {
 323         if(IS_DEAD(this))
 324                 return;
 325
 326         if (!this.havocbot_role_timeout)
 327                 this.havocbot_role_timeout = time + random() * 10 + 20;
 328
 329         if (time > this.havocbot_role_timeout)
 330         {
 331                 LOG_TRACE("changing role to offense\n");
 332                 this.havocbot_role = havocbot_role_ft_offense;
 333                 this.havocbot_role_timeout = 0;
 334                 return;
 335         }
 336
 337         if (time > this.bot_strategytime)
 338         {
 339                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 340
 341                 navigation_goalrating_start(this);
 342                 havocbot_goalrating_items(this, 8000, this.origin, 10000);
 343                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 344                 havocbot_goalrating_freeplayers(this, 20000, this.origin, 10000);
 345                 //havocbot_goalrating_waypoints(1, this.origin, 1000);
 346                 navigation_goalrating_end(this);
 347         }
 348 }
 349
 350
 351 // ==============
 352 // Hook Functions
 353 // ==============
 354
 355 void ft_RemovePlayer()
 356 {SELFPARAM();
 357         self.health = 0; // neccessary to update correctly alive stats
 358         if(!STAT(FROZEN, self))
 359                 freezetag_LastPlayerForTeam_Notify();
 360         freezetag_Unfreeze(world);
 361         freezetag_count_alive_players();
 362 }
 363
 364 MUTATOR_HOOKFUNCTION(ft, ClientDisconnect)
 365 {
 366         ft_RemovePlayer();
 367         return 1;
 368 }
 369
 370 MUTATOR_HOOKFUNCTION(ft, MakePlayerObserver)
 371 {
 372         ft_RemovePlayer();
 373         return false;
 374 }
 375
 376 MUTATOR_HOOKFUNCTION(ft, PlayerDies)
 377 {
 378     SELFPARAM();
 379         if(round_handler_IsActive())
 380         if(round_handler_CountdownRunning())
 381         {
 382                 if(STAT(FROZEN, frag_target))
 383                         WITH(entity, self, frag_target, freezetag_Unfreeze(world));
 384                 freezetag_count_alive_players();
 385                 return 1; // let the player die so that he can respawn whenever he wants
 386         }
 387
 388         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 389         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 390         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 391                 || frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
 392         {
 393                 // let the player die, he will be automatically frozen when he respawns
 394                 if(STAT(FROZEN, frag_target) != 1)
 395                 {
 396                         freezetag_Add_Score(frag_attacker);
 397                         freezetag_count_alive_players();
 398                         freezetag_LastPlayerForTeam_Notify();
 399                 }
 400                 else
 401                         WITH(entity, self, frag_target, freezetag_Unfreeze(world)); // remove ice
 402                 frag_target.health = 0; // Unfreeze resets health
 403                 frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
 404                 return 1;
 405         }
 406
 407         if(STAT(FROZEN, frag_target))
 408                 return 1;
 409
 410         WITH(entity, self, frag_target, freezetag_Freeze(frag_attacker));
 411         freezetag_LastPlayerForTeam_Notify();
 412
 413         if(frag_attacker == frag_target || frag_attacker == world)
 414         {
 415                 if(IS_PLAYER(frag_target))
 416                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 417                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 418         }
 419         else
 420         {
 421                 if(IS_PLAYER(frag_target))
 422                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_FROZEN, frag_attacker.netname);
 423                 if(IS_PLAYER(frag_attacker))
 424                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_FREEZETAG_FREEZE, frag_target.netname);
 425                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 426         }
 427
 428         return 1;
 429 }
 430
 431 MUTATOR_HOOKFUNCTION(ft, PlayerSpawn)
 432 {SELFPARAM();
 433         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 434                 return 1; // do nothing, round is starting right now
 435
 436         if(self.freezetag_frozen_timeout == -2) // player was dead
 437         {
 438                 freezetag_Freeze(world);
 439                 return 1;
 440         }
 441
 442         freezetag_count_alive_players();
 443
 444         if(round_handler_IsActive())
 445         if(round_handler_IsRoundStarted())
 446         {
 447                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 448                 freezetag_Freeze(world);
 449         }
 450
 451         return 1;
 452 }
 453
 454 MUTATOR_HOOKFUNCTION(ft, reset_map_players)
 455 {
 456         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 457                 it.killcount = 0;
 458                 it.freezetag_frozen_timeout = -1;
 459                 setself(it);
 460                 PutClientInServer();
 461                 it.freezetag_frozen_timeout = 0;
 462         ));
 463         freezetag_count_alive_players();
 464         return 1;
 465 }
 466
 467 MUTATOR_HOOKFUNCTION(ft, GiveFragsForKill, CBC_ORDER_FIRST)
 468 {
 469         frag_score = 0; // no frags counted in Freeze Tag
 470         return 1;
 471 }
 472
 473 MUTATOR_HOOKFUNCTION(ft, PlayerPreThink, CBC_ORDER_FIRST)
 474 {SELFPARAM();
 475         if(gameover)
 476                 return 1;
 477
 478         if(STAT(FROZEN, self) == 1)
 479         {
 480                 // keep health = 1
 481                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 482         }
 483
 484         if(round_handler_IsActive())
 485         if(!round_handler_IsRoundStarted())
 486                 return 1;
 487
 488         int n;
 489
 490         entity o;
 491         o = world;
 492         //if(STAT(FROZEN, self))
 493         //if(self.freezetag_frozen_timeout > 0 && time < self.freezetag_frozen_timeout)
 494                 //self.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (self.freezetag_frozen_timeout - time) / (self.freezetag_frozen_timeout - self.freezetag_frozen_time);
 495
 496         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 497                 n = -1;
 498         else
 499         {
 500                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 501                 n = 0;
 502                 FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(
 503                         if(STAT(FROZEN, it) == 0)
 504                         if(!IS_DEAD(it))
 505                         if(SAME_TEAM(it, self))
 506                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, it.absmin, it.absmax))
 507                         {
 508                                 if(!o)
 509                                         o = it;
 510                                 if(STAT(FROZEN, self) == 1)
 511                                         it.reviving = true;
 512                                 ++n;
 513                         }
 514                 ));
 515
 516         }
 517
 518         if(n && STAT(FROZEN, self) == 1) // OK, there is at least one teammate reviving us
 519         {
 520                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
 521                 self.health = max(1, self.revive_progress * ((warmup_stage) ? warmup_start_health : start_health));
 522
 523                 if(self.revive_progress >= 1)
 524                 {
 525                         freezetag_Unfreeze(self);
 526                         freezetag_count_alive_players();
 527
 528                         if(n == -1)
 529                         {
 530                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, autocvar_g_freezetag_frozen_maxtime);
 531                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, self.netname, autocvar_g_freezetag_frozen_maxtime);
 532                                 return 1;
 533                         }
 534
 535                         // EVERY team mate nearby gets a point (even if multiple!)
 536                         FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, LAMBDA(
 537                                 PlayerScore_Add(it, SP_FREEZETAG_REVIVALS, +1);
 538                                 PlayerScore_Add(it, SP_SCORE, +1);
 539                                 nades_GiveBonus(it,autocvar_g_nades_bonus_score_low);
 540                         ));
 541
 542                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
 543                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
 544                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED, self.netname, o.netname);
 545                 }
 546
 547                 FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, LAMBDA(
 548                         it.revive_progress = self.revive_progress;
 549                         it.reviving = false;
 550                 ));
 551         }
 552         else if(!n && STAT(FROZEN, self) == 1) // only if no teammate is nearby will we reset
 553         {
 554                 self.revive_progress = bound(0, self.revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 555                 self.health = max(1, self.revive_progress * ((warmup_stage) ? warmup_start_health : start_health));
 556         }
 557         else if(!n && !STAT(FROZEN, self))
 558         {
 559                 self.revive_progress = 0; // thawing nobody
 560         }
 561
 562         return 1;
 563 }
 564
 565 MUTATOR_HOOKFUNCTION(ft, SetStartItems)
 566 {
 567         start_items &= ~IT_UNLIMITED_AMMO;
 568         //start_health       = warmup_start_health       = cvar("g_lms_start_health");
 569         //start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 570         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 571         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 572         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 573         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 574         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 575         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 576
 577         return 0;
 578 }
 579
 580 MUTATOR_HOOKFUNCTION(ft, HavocBot_ChooseRole)
 581 {SELFPARAM();
 582         if (!IS_DEAD(self))
 583         {
 584                 if (random() < 0.5)
 585                         self.havocbot_role = havocbot_role_ft_freeing;
 586                 else
 587                         self.havocbot_role = havocbot_role_ft_offense;
 588         }
 589
 590         return true;
 591 }
 592
 593 MUTATOR_HOOKFUNCTION(ft, GetTeamCount, CBC_ORDER_EXCLUSIVE)
 594 {
 595         ret_float = freezetag_teams;
 596         return false;
 597 }
 598
 599 MUTATOR_HOOKFUNCTION(ft, SetWeaponArena)
 600 {
 601         // most weapons arena
 602         if(ret_string == "0" || ret_string == "")
 603                 ret_string = "most";
 604         return false;
 605 }
 606
 607 void freezetag_Initialize()
 608 {
 609         freezetag_teams = autocvar_g_freezetag_teams_override;
 610         if(freezetag_teams < 2)
 611                 freezetag_teams = autocvar_g_freezetag_teams;
 612         freezetag_teams = bound(2, freezetag_teams, 4);
 613         freezetag_ScoreRules(freezetag_teams);
 614
 615         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 616         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 617
 618         EliminatedPlayers_Init(freezetag_isEliminated);
 619 }
 620
 621 #endif