Merge branch 'Mario/teams_bitflag' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator / gamemode_invasion.qc
1 #include "gamemode_invasion.qh"
2 #ifndef GAMEMODE_INVASION_H
3 #define GAMEMODE_INVASION_H
4
5 #define autocvar_g_invasion_point_limit cvar("g_invasion_point_limit")
6 int autocvar_g_invasion_teams;
7 bool autocvar_g_invasion_team_spawns;
8 bool g_invasion;
9 void invasion_Initialize();
10
11 REGISTER_MUTATOR(inv, false)
12 {
13         MUTATOR_ONADD
14         {
15                 if (time > 1) // game loads at time 1
16                         error("This is a game type and it cannot be added at runtime.");
17                 g_invasion = true;
18                 invasion_Initialize();
19
20                 cvar_settemp("g_monsters", "1");
21
22                 SetLimits(autocvar_g_invasion_point_limit, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
23                 if (autocvar_g_invasion_teams >= 2)
24                 {
25                         ActivateTeamplay();
26                         if (autocvar_g_invasion_team_spawns)
27                                 have_team_spawns = -1; // request team spawns
28                 }
29         }
30
31         MUTATOR_ONROLLBACK_OR_REMOVE
32         {
33                 // we actually cannot roll back invasion_Initialize here
34                 // BUT: we don't need to! If this gets called, adding always
35                 // succeeds.
36         }
37
38         MUTATOR_ONREMOVE
39         {
40                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
41                 return -1;
42         }
43
44         return 0;
45 }
46
47 float inv_numspawned;
48 float inv_maxspawned;
49 float inv_roundcnt;
50 float inv_maxrounds;
51 float inv_numkilled;
52 float inv_lastcheck;
53 float inv_maxcurrent;
54
55 float invasion_teams;
56 float inv_monsters_perteam[17];
57
58 float inv_monsterskill;
59
60 const float ST_INV_KILLS = 1;
61 #endif
62
63 #ifdef IMPLEMENTATION
64
65 #include <common/monsters/spawn.qh>
66 #include <common/monsters/sv_monsters.qh>
67
68 #include <server/teamplay.qh>
69
70
71 float autocvar_g_invasion_round_timelimit;
72 float autocvar_g_invasion_spawnpoint_spawn_delay;
73 float autocvar_g_invasion_warmup;
74 int autocvar_g_invasion_monster_count;
75 bool autocvar_g_invasion_zombies_only;
76 float autocvar_g_invasion_spawn_delay;
77
78 spawnfunc(invasion_spawnpoint)
79 {
80         if(!g_invasion) { remove(this); return; }
81
82         this.classname = "invasion_spawnpoint";
83
84         if(autocvar_g_invasion_zombies_only) // precache only if it hasn't been already
85         if(this.monsterid) {
86                 Monster mon = get_monsterinfo(this.monsterid);
87                 mon.mr_precache(mon);
88         }
89 }
90
91 float invasion_PickMonster(float supermonster_count)
92 {
93         if(autocvar_g_invasion_zombies_only)
94                 return MON_ZOMBIE.monsterid;
95
96         float i;
97         entity mon;
98
99         RandomSelection_Init();
100
101         for(i = MON_FIRST; i <= MON_LAST; ++i)
102         {
103                 mon = get_monsterinfo(i);
104                 if((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM) || ((mon.spawnflags & MON_FLAG_SUPERMONSTER) && supermonster_count >= 1))
105                         continue; // flying/swimming monsters not yet supported
106
107                 RandomSelection_Add(NULL, i, string_null, 1, 1);
108         }
109
110         return RandomSelection_chosen_float;
111 }
112
113 entity invasion_PickSpawn()
114 {
115         RandomSelection_Init();
116
117         FOREACH_ENTITY_CLASS("invasion_spawnpoint", true,
118         {
119                 RandomSelection_Add(it, 0, string_null, 1, ((time >= it.spawnshieldtime) ? 0.2 : 1)); // give recently used spawnpoints a very low rating
120                 it.spawnshieldtime = time + autocvar_g_invasion_spawnpoint_spawn_delay;
121         });
122
123         return RandomSelection_chosen_ent;
124 }
125
126 void invasion_SpawnChosenMonster(float mon)
127 {
128         entity spawn_point, monster;
129
130         spawn_point = invasion_PickSpawn();
131
132         if(spawn_point == NULL)
133         {
134                 LOG_TRACE("Warning: couldn't find any invasion_spawnpoint spawnpoints, attempting to spawn monsters in random locations\n");
135                 entity e = spawn();
136                 setsize(e, (get_monsterinfo(mon)).mins, (get_monsterinfo(mon)).maxs);
137
138                 if(MoveToRandomMapLocation(e, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
139                         monster = spawnmonster("", mon, NULL, NULL, e.origin, false, false, 2);
140                 else return;
141
142                 setthink(e, SUB_Remove);
143                 e.nextthink = time + 0.1;
144         }
145         else
146                 monster = spawnmonster("", ((spawn_point.monsterid) ? spawn_point.monsterid : mon), spawn_point, spawn_point, spawn_point.origin, false, false, 2);
147
148         if(spawn_point) monster.target2 = spawn_point.target2;
149         monster.spawnshieldtime = time;
150         if(spawn_point && spawn_point.target_range) monster.target_range = spawn_point.target_range;
151
152         if(teamplay)
153         if(spawn_point && spawn_point.team && inv_monsters_perteam[spawn_point.team] > 0)
154                 monster.team = spawn_point.team;
155         else
156         {
157                 RandomSelection_Init();
158                 if(inv_monsters_perteam[NUM_TEAM_1] > 0) RandomSelection_Add(NULL, NUM_TEAM_1, string_null, 1, 1);
159                 if(inv_monsters_perteam[NUM_TEAM_2] > 0) RandomSelection_Add(NULL, NUM_TEAM_2, string_null, 1, 1);
160                 if(invasion_teams >= 3) if(inv_monsters_perteam[NUM_TEAM_3] > 0) { RandomSelection_Add(NULL, NUM_TEAM_3, string_null, 1, 1); }
161                 if(invasion_teams >= 4) if(inv_monsters_perteam[NUM_TEAM_4] > 0) { RandomSelection_Add(NULL, NUM_TEAM_4, string_null, 1, 1); }
162
163                 monster.team = RandomSelection_chosen_float;
164         }
165
166         if(teamplay)
167         {
168                 monster_setupcolors(monster);
169
170                 if(monster.sprite)
171                 {
172                         WaypointSprite_UpdateTeamRadar(monster.sprite, RADARICON_DANGER, ((monster.team) ? Team_ColorRGB(monster.team) : '1 0 0'));
173
174                         monster.sprite.team = 0;
175                         monster.sprite.SendFlags |= 1;
176                 }
177         }
178
179         monster.monster_attack = false; // it's the player's job to kill all the monsters
180
181         if(inv_roundcnt >= inv_maxrounds)
182                 monster.spawnflags |= MONSTERFLAG_MINIBOSS; // last round spawns minibosses
183 }
184
185 void invasion_SpawnMonsters(float supermonster_count)
186 {
187         float chosen_monster = invasion_PickMonster(supermonster_count);
188
189         invasion_SpawnChosenMonster(chosen_monster);
190 }
191
192 float Invasion_CheckWinner()
193 {
194         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
195         {
196                 IL_EACH(g_monsters, true,
197                 {
198                         Monster_Remove(it);
199                 });
200                 IL_CLEAR(g_monsters);
201
202                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
203                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
204                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
205                 return 1;
206         }
207
208         float total_alive_monsters = 0, supermonster_count = 0, red_alive = 0, blue_alive = 0, yellow_alive = 0, pink_alive = 0;
209
210         IL_EACH(g_monsters, it.health > 0,
211         {
212                 if((get_monsterinfo(it.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
213                         ++supermonster_count;
214                 ++total_alive_monsters;
215
216                 if(teamplay)
217                 switch(it.team)
218                 {
219                         case NUM_TEAM_1: ++red_alive; break;
220                         case NUM_TEAM_2: ++blue_alive; break;
221                         case NUM_TEAM_3: ++yellow_alive; break;
222                         case NUM_TEAM_4: ++pink_alive; break;
223                 }
224         });
225
226         if((total_alive_monsters + inv_numkilled) < inv_maxspawned && inv_maxcurrent < inv_maxspawned)
227         {
228                 if(time >= inv_lastcheck)
229                 {
230                         invasion_SpawnMonsters(supermonster_count);
231                         inv_lastcheck = time + autocvar_g_invasion_spawn_delay;
232                 }
233
234                 return 0;
235         }
236
237         if(inv_numspawned < 1)
238                 return 0; // nothing has spawned yet
239
240         if(teamplay)
241         {
242                 if(((red_alive > 0) + (blue_alive > 0) + (yellow_alive > 0) + (pink_alive > 0)) > 1)
243                         return 0;
244         }
245         else if(inv_numkilled < inv_maxspawned)
246                 return 0;
247
248         entity winner = NULL;
249         float winning_score = 0, winner_team = 0;
250
251
252         if(teamplay)
253         {
254                 if(red_alive > 0) { winner_team = NUM_TEAM_1; }
255                 if(blue_alive > 0)
256                 if(winner_team) { winner_team = 0; }
257                 else { winner_team = NUM_TEAM_2; }
258                 if(yellow_alive > 0)
259                 if(winner_team) { winner_team = 0; }
260                 else { winner_team = NUM_TEAM_3; }
261                 if(pink_alive > 0)
262                 if(winner_team) { winner_team = 0; }
263                 else { winner_team = NUM_TEAM_4; }
264         }
265         else
266         {
267                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
268                         float cs = PlayerScore_Add(it, SP_KILLS, 0);
269                         if(cs > winning_score)
270                         {
271                                 winning_score = cs;
272                                 winner = it;
273                         }
274                 ));
275         }
276
277         IL_EACH(g_monsters, true,
278         {
279                 Monster_Remove(it);
280         });
281         IL_CLEAR(g_monsters);
282
283         if(teamplay)
284         {
285                 if(winner_team)
286                 {
287                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
288                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
289                 }
290         }
291         else if(winner)
292         {
293                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
294                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
295         }
296
297         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
298
299         return 1;
300 }
301
302 bool Invasion_CheckPlayers()
303 {
304         return true;
305 }
306
307 void Invasion_RoundStart()
308 {
309         int numplayers = 0;
310         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
311                 it.player_blocked = false;
312                 ++numplayers;
313         ));
314
315         if(inv_roundcnt < inv_maxrounds)
316                 inv_roundcnt += 1; // a limiter to stop crazy counts
317
318         inv_monsterskill = inv_roundcnt + max(1, numplayers * 0.3);
319
320         inv_maxcurrent = 0;
321         inv_numspawned = 0;
322         inv_numkilled = 0;
323
324         inv_maxspawned = rint(max(autocvar_g_invasion_monster_count, autocvar_g_invasion_monster_count * (inv_roundcnt * 0.5)));
325
326         if(teamplay)
327         {
328                 DistributeEvenly_Init(inv_maxspawned, invasion_teams);
329                 inv_monsters_perteam[NUM_TEAM_1] = DistributeEvenly_Get(1);
330                 inv_monsters_perteam[NUM_TEAM_2] = DistributeEvenly_Get(1);
331                 if(invasion_teams >= 3) inv_monsters_perteam[NUM_TEAM_3] = DistributeEvenly_Get(1);
332                 if(invasion_teams >= 4) inv_monsters_perteam[NUM_TEAM_4] = DistributeEvenly_Get(1);
333         }
334 }
335
336 MUTATOR_HOOKFUNCTION(inv, MonsterDies)
337 {
338         entity frag_target = M_ARGV(0, entity);
339         entity frag_attacker = M_ARGV(1, entity);
340
341         if(!(frag_target.spawnflags & MONSTERFLAG_RESPAWNED))
342         {
343                 inv_numkilled += 1;
344                 inv_maxcurrent -= 1;
345                 if(teamplay) { inv_monsters_perteam[frag_target.team] -= 1; }
346
347                 if(IS_PLAYER(frag_attacker))
348                 if(SAME_TEAM(frag_attacker, frag_target)) // in non-teamplay modes, same team = same player, so this works
349                         PlayerScore_Add(frag_attacker, SP_KILLS, -1);
350                 else
351                 {
352                         PlayerScore_Add(frag_attacker, SP_KILLS, +1);
353                         if(teamplay)
354                                 TeamScore_AddToTeam(frag_attacker.team, ST_INV_KILLS, +1);
355                 }
356         }
357 }
358
359 MUTATOR_HOOKFUNCTION(inv, MonsterSpawn)
360 {
361         entity mon = M_ARGV(0, entity);
362
363         if(!(mon.spawnflags & MONSTERFLAG_SPAWNED))
364                 return true;
365
366         if(!(mon.spawnflags & MONSTERFLAG_RESPAWNED))
367         {
368                 inv_numspawned += 1;
369                 inv_maxcurrent += 1;
370         }
371
372         mon.monster_skill = inv_monsterskill;
373
374         if((get_monsterinfo(mon.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
375                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_INVASION_SUPERMONSTER, mon.monster_name);
376
377         mon.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
378 }
379
380 MUTATOR_HOOKFUNCTION(inv, OnEntityPreSpawn)
381 {
382         entity ent = M_ARGV(0, entity);
383
384         if(startsWith(ent.classname, "monster_"))
385         if(!(ent.spawnflags & MONSTERFLAG_SPAWNED))
386                 return true;
387 }
388
389 MUTATOR_HOOKFUNCTION(inv, SV_StartFrame)
390 {
391         monsters_total = inv_maxspawned; // TODO: make sure numspawned never exceeds maxspawned
392         monsters_killed = inv_numkilled;
393 }
394
395 MUTATOR_HOOKFUNCTION(inv, PlayerRegen)
396 {
397         // no regeneration in invasion
398         return true;
399 }
400
401 MUTATOR_HOOKFUNCTION(inv, PlayerSpawn)
402 {
403         entity player = M_ARGV(0, entity);
404
405         player.bot_attack = false;
406 }
407
408 MUTATOR_HOOKFUNCTION(inv, PlayerDamage_Calculate)
409 {
410         entity frag_attacker = M_ARGV(1, entity);
411         entity frag_target = M_ARGV(2, entity);
412         float frag_damage = M_ARGV(4, float);
413         vector frag_force = M_ARGV(6, vector);
414
415         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target) && frag_attacker != frag_target)
416         {
417                 frag_damage = 0;
418                 frag_force = '0 0 0';
419
420                 M_ARGV(4, float) = frag_damage;
421                 M_ARGV(6, vector) = frag_force;
422         }
423 }
424
425 MUTATOR_HOOKFUNCTION(inv, SV_ParseClientCommand)
426 {
427         if(MUTATOR_RETURNVALUE) // command was already handled?
428                 return;
429
430         entity player = M_ARGV(0, entity);
431         string cmd_name = M_ARGV(1, string);
432
433         if(cmd_name == "debuginvasion")
434         {
435                 sprint(player, strcat("inv_maxspawned = ", ftos(inv_maxspawned), "\n"));
436                 sprint(player, strcat("inv_numspawned = ", ftos(inv_numspawned), "\n"));
437                 sprint(player, strcat("inv_numkilled = ", ftos(inv_numkilled), "\n"));
438                 sprint(player, strcat("inv_roundcnt = ", ftos(inv_roundcnt), "\n"));
439                 sprint(player, strcat("monsters_total = ", ftos(monsters_total), "\n"));
440                 sprint(player, strcat("monsters_killed = ", ftos(monsters_killed), "\n"));
441                 sprint(player, strcat("inv_monsterskill = ", ftos(inv_monsterskill), "\n"));
442
443                 return true;
444         }
445 }
446
447 MUTATOR_HOOKFUNCTION(inv, BotShouldAttack)
448 {
449         entity targ = M_ARGV(1, entity);
450
451         if(!IS_MONSTER(targ))
452                 return true;
453 }
454
455 MUTATOR_HOOKFUNCTION(inv, SetStartItems)
456 {
457         start_health = 200;
458         start_armorvalue = 200;
459 }
460
461 MUTATOR_HOOKFUNCTION(inv, AccuracyTargetValid)
462 {
463         entity frag_target = M_ARGV(1, entity);
464
465         if(IS_MONSTER(frag_target))
466                 return MUT_ACCADD_INVALID;
467         return MUT_ACCADD_INDIFFERENT;
468 }
469
470 MUTATOR_HOOKFUNCTION(inv, AllowMobSpawning)
471 {
472         // monster spawning disabled during an invasion
473         M_ARGV(1, string) = "You cannot spawn monsters during an invasion!";
474         return true;
475 }
476
477 MUTATOR_HOOKFUNCTION(inv, GetTeamCount, CBC_ORDER_EXCLUSIVE)
478 {
479         M_ARGV(0, float) = invasion_teams;
480 }
481
482 MUTATOR_HOOKFUNCTION(inv, AllowMobButcher)
483 {
484         M_ARGV(0, string) = "This command does not work during an invasion!";
485         return true;
486 }
487
488 void invasion_ScoreRules(int inv_teams)
489 {
490         if(inv_teams) { CheckAllowedTeams(NULL); }
491         ScoreRules_basics(inv_teams, 0, 0, false);
492         if(inv_teams) ScoreInfo_SetLabel_TeamScore(ST_INV_KILLS, "frags", SFL_SORT_PRIO_PRIMARY);
493         ScoreInfo_SetLabel_PlayerScore(SP_KILLS, "frags", ((inv_teams) ? SFL_SORT_PRIO_SECONDARY : SFL_SORT_PRIO_PRIMARY));
494         ScoreRules_basics_end();
495 }
496
497 void invasion_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up.
498 {
499         if(autocvar_g_invasion_teams)
500         {
501                 invasion_teams = bound(2, autocvar_g_invasion_teams, 4);
502                 int teams = 0;
503                 if(invasion_teams >= 1) teams |= BIT(0);
504                 if(invasion_teams >= 2) teams |= BIT(1);
505                 if(invasion_teams >= 3) teams |= BIT(2);
506                 if(invasion_teams >= 4) teams |= BIT(3);
507
508                 invasion_teams = teams; // now set it?
509         }
510         else
511                 invasion_teams = 0;
512
513         independent_players = 1; // to disable extra useless scores
514
515         invasion_ScoreRules(invasion_teams);
516
517         independent_players = 0;
518
519         round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
520         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
521
522         inv_roundcnt = 0;
523         inv_maxrounds = 15; // 15?
524 }
525
526 void invasion_Initialize()
527 {
528         if(autocvar_g_invasion_zombies_only) {
529                 Monster mon = MON_ZOMBIE;
530                 mon.mr_precache(mon);
531         } else
532         {
533                 float i;
534                 entity mon;
535                 for(i = MON_FIRST; i <= MON_LAST; ++i)
536                 {
537                         mon = get_monsterinfo(i);
538                         if((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM))
539                                 continue; // flying/swimming monsters not yet supported
540
541                         mon.mr_precache(mon);
542                 }
543         }
544
545         InitializeEntity(NULL, invasion_DelayedInit, INITPRIO_GAMETYPE);
546 }
547
548 #endif