qcsrc/server/mutators/mutator/gamemode_invasion.qc

   1 #include "gamemode_invasion.qh"
   2
   3 #include <common/monsters/spawn.qh>
   4 #include <common/monsters/sv_monsters.qh>
   5
   6 #include <server/teamplay.qh>
   7
   8
   9 float autocvar_g_invasion_round_timelimit;
  10 float autocvar_g_invasion_spawnpoint_spawn_delay;
  11 float autocvar_g_invasion_warmup;
  12 int autocvar_g_invasion_monster_count;
  13 bool autocvar_g_invasion_zombies_only;
  14 float autocvar_g_invasion_spawn_delay;
  15
  16 spawnfunc(invasion_spawnpoint)
  17 {
  18         if(!g_invasion) { delete(this); return; }
  19
  20         this.classname = "invasion_spawnpoint";
  21
  22         if(autocvar_g_invasion_zombies_only) // precache only if it hasn't been already
  23         if(this.monsterid) {
  24                 Monster mon = get_monsterinfo(this.monsterid);
  25                 mon.mr_precache(mon);
  26         }
  27 }
  28
  29 float invasion_PickMonster(float supermonster_count)
  30 {
  31         if(autocvar_g_invasion_zombies_only)
  32                 return MON_ZOMBIE.monsterid;
  33
  34         float i;
  35         entity mon;
  36
  37         RandomSelection_Init();
  38
  39         for(i = MON_FIRST; i <= MON_LAST; ++i)
  40         {
  41                 mon = get_monsterinfo(i);
  42                 if((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM) || ((mon.spawnflags & MON_FLAG_SUPERMONSTER) && supermonster_count >= 1))
  43                         continue; // flying/swimming monsters not yet supported
  44
  45                 RandomSelection_Add(NULL, i, string_null, 1, 1);
  46         }
  47
  48         return RandomSelection_chosen_float;
  49 }
  50
  51 entity invasion_PickSpawn()
  52 {
  53         RandomSelection_Init();
  54
  55         FOREACH_ENTITY_CLASS("invasion_spawnpoint", true,
  56         {
  57                 RandomSelection_Add(it, 0, string_null, 1, ((time >= it.spawnshieldtime) ? 0.2 : 1)); // give recently used spawnpoints a very low rating
  58                 it.spawnshieldtime = time + autocvar_g_invasion_spawnpoint_spawn_delay;
  59         });
  60
  61         return RandomSelection_chosen_ent;
  62 }
  63
  64 void invasion_SpawnChosenMonster(float mon)
  65 {
  66         entity spawn_point, monster;
  67
  68         spawn_point = invasion_PickSpawn();
  69
  70         if(spawn_point == NULL)
  71         {
  72                 LOG_TRACE("Warning: couldn't find any invasion_spawnpoint spawnpoints, attempting to spawn monsters in random locations");
  73                 entity e = spawn();
  74                 setsize(e, (get_monsterinfo(mon)).mins, (get_monsterinfo(mon)).maxs);
  75
  76                 if(MoveToRandomMapLocation(e, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  77                         monster = spawnmonster("", mon, NULL, NULL, e.origin, false, false, 2);
  78                 else return;
  79
  80                 setthink(e, SUB_Remove);
  81                 e.nextthink = time + 0.1;
  82         }
  83         else
  84                 monster = spawnmonster("", ((spawn_point.monsterid) ? spawn_point.monsterid : mon), spawn_point, spawn_point, spawn_point.origin, false, false, 2);
  85
  86         if(spawn_point) monster.target2 = spawn_point.target2;
  87         monster.spawnshieldtime = time;
  88         if(spawn_point && spawn_point.target_range) monster.target_range = spawn_point.target_range;
  89
  90         if(teamplay)
  91         if(spawn_point && spawn_point.team && inv_monsters_perteam[spawn_point.team] > 0)
  92                 monster.team = spawn_point.team;
  93         else
  94         {
  95                 RandomSelection_Init();
  96                 if(inv_monsters_perteam[NUM_TEAM_1] > 0) RandomSelection_Add(NULL, NUM_TEAM_1, string_null, 1, 1);
  97                 if(inv_monsters_perteam[NUM_TEAM_2] > 0) RandomSelection_Add(NULL, NUM_TEAM_2, string_null, 1, 1);
  98                 if(invasion_teams >= 3) if(inv_monsters_perteam[NUM_TEAM_3] > 0) { RandomSelection_Add(NULL, NUM_TEAM_3, string_null, 1, 1); }
  99                 if(invasion_teams >= 4) if(inv_monsters_perteam[NUM_TEAM_4] > 0) { RandomSelection_Add(NULL, NUM_TEAM_4, string_null, 1, 1); }
 100
 101                 monster.team = RandomSelection_chosen_float;
 102         }
 103
 104         if(teamplay)
 105         {
 106                 monster_setupcolors(monster);
 107
 108                 if(monster.sprite)
 109                 {
 110                         WaypointSprite_UpdateTeamRadar(monster.sprite, RADARICON_DANGER, ((monster.team) ? Team_ColorRGB(monster.team) : '1 0 0'));
 111
 112                         monster.sprite.team = 0;
 113                         monster.sprite.SendFlags |= 1;
 114                 }
 115         }
 116
 117         monster.monster_attack = false; // it's the player's job to kill all the monsters
 118
 119         if(inv_roundcnt >= inv_maxrounds)
 120                 monster.spawnflags |= MONSTERFLAG_MINIBOSS; // last round spawns minibosses
 121 }
 122
 123 void invasion_SpawnMonsters(float supermonster_count)
 124 {
 125         float chosen_monster = invasion_PickMonster(supermonster_count);
 126
 127         invasion_SpawnChosenMonster(chosen_monster);
 128 }
 129
 130 float Invasion_CheckWinner()
 131 {
 132         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 133         {
 134                 IL_EACH(g_monsters, true,
 135                 {
 136                         Monster_Remove(it);
 137                 });
 138                 IL_CLEAR(g_monsters);
 139
 140                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
 141                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
 142                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 143                 return 1;
 144         }
 145
 146         float total_alive_monsters = 0, supermonster_count = 0, red_alive = 0, blue_alive = 0, yellow_alive = 0, pink_alive = 0;
 147
 148         IL_EACH(g_monsters, it.health > 0,
 149         {
 150                 if((get_monsterinfo(it.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
 151                         ++supermonster_count;
 152                 ++total_alive_monsters;
 153
 154                 if(teamplay)
 155                 switch(it.team)
 156                 {
 157                         case NUM_TEAM_1: ++red_alive; break;
 158                         case NUM_TEAM_2: ++blue_alive; break;
 159                         case NUM_TEAM_3: ++yellow_alive; break;
 160                         case NUM_TEAM_4: ++pink_alive; break;
 161                 }
 162         });
 163
 164         if((total_alive_monsters + inv_numkilled) < inv_maxspawned && inv_maxcurrent < inv_maxspawned)
 165         {
 166                 if(time >= inv_lastcheck)
 167                 {
 168                         invasion_SpawnMonsters(supermonster_count);
 169                         inv_lastcheck = time + autocvar_g_invasion_spawn_delay;
 170                 }
 171
 172                 return 0;
 173         }
 174
 175         if(inv_numspawned < 1)
 176                 return 0; // nothing has spawned yet
 177
 178         if(teamplay)
 179         {
 180                 if(((red_alive > 0) + (blue_alive > 0) + (yellow_alive > 0) + (pink_alive > 0)) > 1)
 181                         return 0;
 182         }
 183         else if(inv_numkilled < inv_maxspawned)
 184                 return 0;
 185
 186         entity winner = NULL;
 187         float winning_score = 0, winner_team = 0;
 188
 189
 190         if(teamplay)
 191         {
 192                 if(red_alive > 0) { winner_team = NUM_TEAM_1; }
 193                 if(blue_alive > 0)
 194                 if(winner_team) { winner_team = 0; }
 195                 else { winner_team = NUM_TEAM_2; }
 196                 if(yellow_alive > 0)
 197                 if(winner_team) { winner_team = 0; }
 198                 else { winner_team = NUM_TEAM_3; }
 199                 if(pink_alive > 0)
 200                 if(winner_team) { winner_team = 0; }
 201                 else { winner_team = NUM_TEAM_4; }
 202         }
 203         else
 204         {
 205                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 206                         float cs = PlayerScore_Add(it, SP_KILLS, 0);
 207                         if(cs > winning_score)
 208                         {
 209                                 winning_score = cs;
 210                                 winner = it;
 211                         }
 212                 ));
 213         }
 214
 215         IL_EACH(g_monsters, true,
 216         {
 217                 Monster_Remove(it);
 218         });
 219         IL_CLEAR(g_monsters);
 220
 221         if(teamplay)
 222         {
 223                 if(winner_team)
 224                 {
 225                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 226                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 227                 }
 228         }
 229         else if(winner)
 230         {
 231                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
 232                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
 233         }
 234
 235         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 236
 237         return 1;
 238 }
 239
 240 bool Invasion_CheckPlayers()
 241 {
 242         return true;
 243 }
 244
 245 void Invasion_RoundStart()
 246 {
 247         int numplayers = 0;
 248         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 249                 it.player_blocked = false;
 250                 ++numplayers;
 251         ));
 252
 253         if(inv_roundcnt < inv_maxrounds)
 254                 inv_roundcnt += 1; // a limiter to stop crazy counts
 255
 256         inv_monsterskill = inv_roundcnt + max(1, numplayers * 0.3);
 257
 258         inv_maxcurrent = 0;
 259         inv_numspawned = 0;
 260         inv_numkilled = 0;
 261
 262         inv_maxspawned = rint(max(autocvar_g_invasion_monster_count, autocvar_g_invasion_monster_count * (inv_roundcnt * 0.5)));
 263
 264         if(teamplay)
 265         {
 266                 DistributeEvenly_Init(inv_maxspawned, invasion_teams);
 267                 inv_monsters_perteam[NUM_TEAM_1] = DistributeEvenly_Get(1);
 268                 inv_monsters_perteam[NUM_TEAM_2] = DistributeEvenly_Get(1);
 269                 if(invasion_teams >= 3) inv_monsters_perteam[NUM_TEAM_3] = DistributeEvenly_Get(1);
 270                 if(invasion_teams >= 4) inv_monsters_perteam[NUM_TEAM_4] = DistributeEvenly_Get(1);
 271         }
 272 }
 273
 274 MUTATOR_HOOKFUNCTION(inv, MonsterDies)
 275 {
 276         entity frag_target = M_ARGV(0, entity);
 277         entity frag_attacker = M_ARGV(1, entity);
 278
 279         if(!(frag_target.spawnflags & MONSTERFLAG_RESPAWNED))
 280         {
 281                 inv_numkilled += 1;
 282                 inv_maxcurrent -= 1;
 283                 if(teamplay) { inv_monsters_perteam[frag_target.team] -= 1; }
 284
 285                 if(IS_PLAYER(frag_attacker))
 286                 if(SAME_TEAM(frag_attacker, frag_target)) // in non-teamplay modes, same team = same player, so this works
 287                         PlayerScore_Add(frag_attacker, SP_KILLS, -1);
 288                 else
 289                 {
 290                         PlayerScore_Add(frag_attacker, SP_KILLS, +1);
 291                         if(teamplay)
 292                                 TeamScore_AddToTeam(frag_attacker.team, ST_INV_KILLS, +1);
 293                 }
 294         }
 295 }
 296
 297 MUTATOR_HOOKFUNCTION(inv, MonsterSpawn)
 298 {
 299         entity mon = M_ARGV(0, entity);
 300
 301         if(!(mon.spawnflags & MONSTERFLAG_SPAWNED))
 302                 return true;
 303
 304         if(!(mon.spawnflags & MONSTERFLAG_RESPAWNED))
 305         {
 306                 inv_numspawned += 1;
 307                 inv_maxcurrent += 1;
 308         }
 309
 310         mon.monster_skill = inv_monsterskill;
 311
 312         if((get_monsterinfo(mon.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
 313                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_INVASION_SUPERMONSTER, mon.monster_name);
 314
 315         mon.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
 316 }
 317
 318 MUTATOR_HOOKFUNCTION(inv, OnEntityPreSpawn)
 319 {
 320         entity ent = M_ARGV(0, entity);
 321
 322         if(startsWith(ent.classname, "monster_"))
 323         if(!(ent.spawnflags & MONSTERFLAG_SPAWNED))
 324                 return true;
 325 }
 326
 327 MUTATOR_HOOKFUNCTION(inv, SV_StartFrame)
 328 {
 329         monsters_total = inv_maxspawned; // TODO: make sure numspawned never exceeds maxspawned
 330         monsters_killed = inv_numkilled;
 331 }
 332
 333 MUTATOR_HOOKFUNCTION(inv, PlayerRegen)
 334 {
 335         // no regeneration in invasion
 336         return true;
 337 }
 338
 339 MUTATOR_HOOKFUNCTION(inv, PlayerSpawn)
 340 {
 341         entity player = M_ARGV(0, entity);
 342
 343         player.bot_attack = false;
 344 }
 345
 346 MUTATOR_HOOKFUNCTION(inv, PlayerDamage_Calculate)
 347 {
 348         entity frag_attacker = M_ARGV(1, entity);
 349         entity frag_target = M_ARGV(2, entity);
 350         float frag_damage = M_ARGV(4, float);
 351         vector frag_force = M_ARGV(6, vector);
 352
 353         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target) && frag_attacker != frag_target)
 354         {
 355                 frag_damage = 0;
 356                 frag_force = '0 0 0';
 357
 358                 M_ARGV(4, float) = frag_damage;
 359                 M_ARGV(6, vector) = frag_force;
 360         }
 361 }
 362
 363 MUTATOR_HOOKFUNCTION(inv, SV_ParseClientCommand)
 364 {
 365         if(MUTATOR_RETURNVALUE) // command was already handled?
 366                 return;
 367
 368         entity player = M_ARGV(0, entity);
 369         string cmd_name = M_ARGV(1, string);
 370
 371         if(cmd_name == "debuginvasion")
 372         {
 373                 sprint(player, strcat("inv_maxspawned = ", ftos(inv_maxspawned), "\n"));
 374                 sprint(player, strcat("inv_numspawned = ", ftos(inv_numspawned), "\n"));
 375                 sprint(player, strcat("inv_numkilled = ", ftos(inv_numkilled), "\n"));
 376                 sprint(player, strcat("inv_roundcnt = ", ftos(inv_roundcnt), "\n"));
 377                 sprint(player, strcat("monsters_total = ", ftos(monsters_total), "\n"));
 378                 sprint(player, strcat("monsters_killed = ", ftos(monsters_killed), "\n"));
 379                 sprint(player, strcat("inv_monsterskill = ", ftos(inv_monsterskill), "\n"));
 380
 381                 return true;
 382         }
 383 }
 384
 385 MUTATOR_HOOKFUNCTION(inv, BotShouldAttack)
 386 {
 387         entity targ = M_ARGV(1, entity);
 388
 389         if(!IS_MONSTER(targ))
 390                 return true;
 391 }
 392
 393 MUTATOR_HOOKFUNCTION(inv, SetStartItems)
 394 {
 395         start_health = 200;
 396         start_armorvalue = 200;
 397 }
 398
 399 MUTATOR_HOOKFUNCTION(inv, AccuracyTargetValid)
 400 {
 401         entity frag_target = M_ARGV(1, entity);
 402
 403         if(IS_MONSTER(frag_target))
 404                 return MUT_ACCADD_INVALID;
 405         return MUT_ACCADD_INDIFFERENT;
 406 }
 407
 408 MUTATOR_HOOKFUNCTION(inv, AllowMobSpawning)
 409 {
 410         // monster spawning disabled during an invasion
 411         M_ARGV(1, string) = "You cannot spawn monsters during an invasion!";
 412         return true;
 413 }
 414
 415 MUTATOR_HOOKFUNCTION(inv, GetTeamCount, CBC_ORDER_EXCLUSIVE)
 416 {
 417         M_ARGV(0, float) = invasion_teams;
 418 }
 419
 420 MUTATOR_HOOKFUNCTION(inv, AllowMobButcher)
 421 {
 422         M_ARGV(0, string) = "This command does not work during an invasion!";
 423         return true;
 424 }
 425
 426 void invasion_ScoreRules(int inv_teams)
 427 {
 428         if(inv_teams) { CheckAllowedTeams(NULL); }
 429         ScoreRules_basics(inv_teams, 0, 0, false);
 430         if(inv_teams) ScoreInfo_SetLabel_TeamScore(ST_INV_KILLS, "frags", SFL_SORT_PRIO_PRIMARY);
 431         ScoreInfo_SetLabel_PlayerScore(SP_KILLS, "frags", ((inv_teams) ? SFL_SORT_PRIO_SECONDARY : SFL_SORT_PRIO_PRIMARY));
 432         ScoreRules_basics_end();
 433 }
 434
 435 void invasion_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up.
 436 {
 437         if(autocvar_g_invasion_teams)
 438         {
 439                 invasion_teams = bound(2, autocvar_g_invasion_teams, 4);
 440                 int teams = 0;
 441                 if(invasion_teams >= 1) teams |= BIT(0);
 442                 if(invasion_teams >= 2) teams |= BIT(1);
 443                 if(invasion_teams >= 3) teams |= BIT(2);
 444                 if(invasion_teams >= 4) teams |= BIT(3);
 445
 446                 invasion_teams = teams; // now set it?
 447         }
 448         else
 449                 invasion_teams = 0;
 450
 451         independent_players = 1; // to disable extra useless scores
 452
 453         invasion_ScoreRules(invasion_teams);
 454
 455         independent_players = 0;
 456
 457         round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
 458         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 459
 460         inv_roundcnt = 0;
 461         inv_maxrounds = 15; // 15?
 462 }
 463
 464 void invasion_Initialize()
 465 {
 466         if(autocvar_g_invasion_zombies_only) {
 467                 Monster mon = MON_ZOMBIE;
 468                 mon.mr_precache(mon);
 469         } else
 470         {
 471                 float i;
 472                 entity mon;
 473                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 474                 {
 475                         mon = get_monsterinfo(i);
 476                         if((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM))
 477                                 continue; // flying/swimming monsters not yet supported
 478
 479                         mon.mr_precache(mon);
 480                 }
 481         }
 482
 483         InitializeEntity(NULL, invasion_DelayedInit, INITPRIO_GAMETYPE);
 484 }