qcsrc/server/mutators/mutator/gamemode_keyhunt.qc

   1 #ifndef GAMEMODE_KEYHUNT_H
   2 #define GAMEMODE_KEYHUNT_H
   3
   4 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   5
   6 // ALL OF THESE should be removed in the future, as other code should not have to care
   7
   8 // used by bots:
   9 float kh_tracking_enabled;
  10 .entity kh_next;
  11 float kh_Key_AllOwnedByWhichTeam();
  12
  13 typedef void(void) kh_Think_t;
  14 void kh_StartRound();
  15 void kh_Controller_SetThink(float t, kh_Think_t func);
  16
  17 entity kh_worldkeylist;
  18 .entity kh_worldkeynext;
  19 #endif
  20
  21 #ifdef IMPLEMENTATION
  22
  23 float autocvar_g_balance_keyhunt_damageforcescale;
  24 float autocvar_g_balance_keyhunt_delay_collect;
  25 float autocvar_g_balance_keyhunt_delay_return;
  26 float autocvar_g_balance_keyhunt_delay_round;
  27 float autocvar_g_balance_keyhunt_delay_tracking;
  28 float autocvar_g_balance_keyhunt_dropvelocity;
  29 float autocvar_g_balance_keyhunt_maxdist;
  30 float autocvar_g_balance_keyhunt_protecttime;
  31
  32 int autocvar_g_balance_keyhunt_score_capture;
  33 int autocvar_g_balance_keyhunt_score_carrierfrag;
  34 int autocvar_g_balance_keyhunt_score_collect;
  35 int autocvar_g_balance_keyhunt_score_destroyed;
  36 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  37 int autocvar_g_balance_keyhunt_score_push;
  38 float autocvar_g_balance_keyhunt_throwvelocity;
  39
  40 int autocvar_g_keyhunt_point_leadlimit;
  41 bool autocvar_g_keyhunt_team_spawns;
  42 #define autocvar_g_keyhunt_point_limit cvar("g_keyhunt_point_limit")
  43 int autocvar_g_keyhunt_teams;
  44 int autocvar_g_keyhunt_teams_override;
  45
  46 // #define KH_PLAYER_USE_ATTACHMENT
  47 // #define KH_PLAYER_USE_CARRIEDMODEL
  48
  49 #ifdef KH_PLAYER_USE_ATTACHMENT
  50 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  51 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  52 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  53 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  54 const string KH_PLAYER_ATTACHMENT_BONE = "";
  55 #else
  56 const float KH_KEY_ZSHIFT = 22;
  57 const float KH_KEY_XYDIST = 24;
  58 const float KH_KEY_XYSPEED = 45;
  59 #endif
  60 const float KH_KEY_WP_ZSHIFT = 20;
  61
  62 const vector KH_KEY_MIN = '-10 -10 -46';
  63 const vector KH_KEY_MAX = '10 10 3';
  64 const float KH_KEY_BRIGHTNESS = 2;
  65
  66 float kh_no_radar_circles;
  67
  68 // kh_state
  69 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  70 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  71 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  72 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  73 .float kh_state;
  74 .float siren_time;  //  time delay the siren
  75 //.float stuff_time;  //  time delay to stuffcmd a cvar
  76
  77 float kh_keystatus[17];
  78 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
  79 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  80 //for(i = 0; i < maxplayers; ++i)
  81 //      kh_keystatus[i] = "0";
  82
  83 float kh_Team_ByID(float t)
  84 {
  85         if(t == 0) return NUM_TEAM_1;
  86         if(t == 1) return NUM_TEAM_2;
  87         if(t == 2) return NUM_TEAM_3;
  88         if(t == 3) return NUM_TEAM_4;
  89         return 0;
  90 }
  91
  92 //entity kh_worldkeylist;
  93 .entity kh_worldkeynext;
  94 entity kh_controller;
  95 //float kh_tracking_enabled;
  96 float kh_teams;
  97 float kh_interferemsg_time, kh_interferemsg_team;
  98 .entity kh_next, kh_prev; // linked list
  99 .float kh_droptime;
 100 .float kh_dropperteam;
 101 .entity kh_previous_owner;
 102 .float kh_previous_owner_playerid;
 103 .float kh_cp_duration;
 104
 105 float kh_key_dropped, kh_key_carried;
 106
 107 const float ST_KH_CAPS = 1;
 108 const float SP_KH_CAPS = 4;
 109 const float SP_KH_PUSHES = 5;
 110 const float SP_KH_DESTROYS = 6;
 111 const float SP_KH_PICKUPS = 7;
 112 const float SP_KH_KCKILLS = 8;
 113 const float SP_KH_LOSSES = 9;
 114 void kh_ScoreRules(float teams)
 115 {
 116         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, true);
 117         ScoreInfo_SetLabel_TeamScore(  ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
 118         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
 119         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSHES,    "pushes",    0);
 120         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYS,  "destroyed", SFL_LOWER_IS_BETTER);
 121         ScoreInfo_SetLabel_PlayerScore(SP_KH_PICKUPS,   "pickups",   0);
 122         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCKILLS,   "kckills",   0);
 123         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSSES,    "losses",    SFL_LOWER_IS_BETTER);
 124         ScoreRules_basics_end();
 125 }
 126
 127 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
 128 {SELFPARAM();
 129         if(!IS_PLAYER(e) || self.team != e.team)
 130                 if(!kh_tracking_enabled)
 131                         return false;
 132
 133         return true;
 134 }
 135
 136 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
 137 {SELFPARAM();
 138         if(!kh_tracking_enabled)
 139                 return false;
 140         if(!self.owner)
 141                 return true;
 142         if(!self.owner.owner)
 143                 return true;
 144         return false;  // draw only when key is not owned
 145 }
 146
 147 void kh_update_state()
 148 {
 149         entity player;
 150         entity key;
 151         float s;
 152         float f;
 153
 154         s = 0;
 155         FOR_EACH_KH_KEY(key)
 156         {
 157                 if(key.owner)
 158                         f = key.team;
 159                 else
 160                         f = 30;
 161                 s |= pow(32, key.count) * f;
 162         }
 163
 164         FOR_EACH_CLIENT(player)
 165         {
 166                 player.kh_state = s;
 167         }
 168
 169         FOR_EACH_KH_KEY(key)
 170         {
 171                 if(key.owner)
 172                         key.owner.kh_state |= pow(32, key.count) * 31;
 173         }
 174         //print(ftos((nextent(world)).kh_state), "\n");
 175 }
 176
 177
 178
 179
 180 var kh_Think_t kh_Controller_Thinkfunc;
 181 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 182 {
 183         kh_Controller_Thinkfunc = func;
 184         kh_controller.cnt = ceil(t);
 185         if(t == 0)
 186                 kh_controller.nextthink = time; // force
 187 }
 188 void kh_WaitForPlayers();
 189 void kh_Controller_Think()  // called a lot
 190 {SELFPARAM();
 191         if(intermission_running)
 192                 return;
 193         if(self.cnt > 0)
 194         { if(self.think != kh_WaitForPlayers) { self.cnt -= 1; } }
 195         else if(self.cnt == 0)
 196         {
 197                 self.cnt -= 1;
 198                 kh_Controller_Thinkfunc();
 199         }
 200         self.nextthink = time + 1;
 201 }
 202
 203 // frags f: take from cvar * f
 204 // frags 0: no frags
 205 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 206 {
 207         string s;
 208         if(intermission_running)
 209                 return;
 210
 211         if(frags_player)
 212                 UpdateFrags(player, frags_player);
 213
 214         if(key && key.owner && frags_owner)
 215                 UpdateFrags(key.owner, frags_owner);
 216
 217         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 218                 return;
 219
 220         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 221
 222         if(key && key.owner)
 223                 s = strcat(s, ":", ftos(key.owner.playerid));
 224         else
 225                 s = strcat(s, ":0");
 226
 227         s = strcat(s, ":", ftos(frags_owner), ":");
 228
 229         if(key)
 230                 s = strcat(s, key.netname);
 231
 232         GameLogEcho(s);
 233 }
 234
 235 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 236 {
 237         if(e.tag_entity)
 238         {
 239                 makevectors(e.tag_entity.angles);
 240                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 241         }
 242         else
 243                 return e.origin;
 244 }
 245
 246 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 247 {
 248 #ifdef KH_PLAYER_USE_ATTACHMENT
 249         entity first;
 250         first = key.owner.kh_next;
 251         if(key == first)
 252         {
 253                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 254                 if(key.kh_next)
 255                 {
 256                         setattachment(key.kh_next, key, "");
 257                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 258                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 259                         key.kh_next.angles = '0 0 0';
 260                 }
 261                 else
 262                         setorigin(key, KH_PLAYER_ATTACHMENT);
 263                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 264         }
 265         else
 266         {
 267                 setattachment(key, key.kh_prev, "");
 268                 if(key.kh_next)
 269                         setattachment(key.kh_next, key, "");
 270                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 271                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 272                 key.angles = '0 0 0';
 273         }
 274 #else
 275         setattachment(key, key.owner, "");
 276         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 277         key.angles_y -= key.owner.angles.y;
 278 #endif
 279         key.flags = 0;
 280         key.solid = SOLID_NOT;
 281         key.movetype = MOVETYPE_NONE;
 282         key.team = key.owner.team;
 283         key.nextthink = time;
 284         key.damageforcescale = 0;
 285         key.takedamage = DAMAGE_NO;
 286         key.modelindex = kh_key_carried;
 287 }
 288
 289 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 290 {
 291 #ifdef KH_PLAYER_USE_ATTACHMENT
 292         entity first;
 293         first = key.owner.kh_next;
 294         if(key == first)
 295         {
 296                 if(key.kh_next)
 297                 {
 298                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 299                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 300                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 301                 }
 302         }
 303         else
 304         {
 305                 if(key.kh_next)
 306                         setattachment(key.kh_next, key.kh_prev, "");
 307                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 308         }
 309         // in any case:
 310         setattachment(key, world, "");
 311         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN.z - KH_KEY_MIN_z));
 312         key.angles = key.owner.angles;
 313 #else
 314         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 315         setattachment(key, world, "");
 316         key.angles_y += key.owner.angles.y;
 317 #endif
 318         key.flags = FL_ITEM;
 319         key.solid = SOLID_TRIGGER;
 320         key.movetype = MOVETYPE_TOSS;
 321         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 322         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 323         key.takedamage = DAMAGE_YES;
 324         // let key.team stay
 325         key.modelindex = kh_key_dropped;
 326         key.kh_previous_owner = key.owner;
 327         key.kh_previous_owner_playerid = key.owner.playerid;
 328 }
 329
 330 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 331 {
 332         entity k;
 333         float ownerteam0, ownerteam;
 334         if(key.owner == player)
 335                 return;
 336
 337         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 338
 339         if(key.owner)
 340         {
 341                 kh_Key_Detach(key);
 342
 343                 // remove from linked list
 344                 if(key.kh_next)
 345                         key.kh_next.kh_prev = key.kh_prev;
 346                 key.kh_prev.kh_next = key.kh_next;
 347                 key.kh_next = world;
 348                 key.kh_prev = world;
 349
 350                 if(key.owner.kh_next == world)
 351                 {
 352                         // No longer a key carrier
 353                         if(!kh_no_radar_circles)
 354                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 355                         WaypointSprite_DetachCarrier(key.owner);
 356                 }
 357         }
 358
 359         key.owner = player;
 360
 361         if(player)
 362         {
 363                 // insert into linked list
 364                 key.kh_next = player.kh_next;
 365                 key.kh_prev = player;
 366                 player.kh_next = key;
 367                 if(key.kh_next)
 368                         key.kh_next.kh_prev = key;
 369
 370                 float i;
 371                 i = kh_keystatus[key.owner.playerid];
 372                         if(key.netname == "^1red key")
 373                                 i += 1;
 374                         if(key.netname == "^4blue key")
 375                                 i += 2;
 376                         if(key.netname == "^3yellow key")
 377                                 i += 4;
 378                         if(key.netname == "^6pink key")
 379                                 i += 8;
 380                 kh_keystatus[key.owner.playerid] = i;
 381
 382                 kh_Key_Attach(key);
 383
 384                 if(key.kh_next == world)
 385                 {
 386                         // player is now a key carrier
 387                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 388                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 389                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 390                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 391                         if(player.team == NUM_TEAM_1)
 392                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 393                         else if(player.team == NUM_TEAM_2)
 394                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 395                         else if(player.team == NUM_TEAM_3)
 396                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 397                         else if(player.team == NUM_TEAM_4)
 398                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 399                         if(!kh_no_radar_circles)
 400                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 401                 }
 402         }
 403
 404         // moved that here, also update if there's no player
 405         kh_update_state();
 406
 407         key.pusher = world;
 408
 409         ownerteam = kh_Key_AllOwnedByWhichTeam();
 410         if(ownerteam != ownerteam0)
 411         {
 412                 if(ownerteam != -1)
 413                 {
 414                         kh_interferemsg_time = time + 0.2;
 415                         kh_interferemsg_team = player.team;
 416
 417                         // audit all key carrier sprites, update them to RUN HERE
 418                         FOR_EACH_KH_KEY(k)
 419                         {
 420                                 if (!k.owner) continue;
 421                                 entity first = WP_Null;
 422                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 423                                 entity third = WP_Null;
 424                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 425                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 426                         }
 427                 }
 428                 else
 429                 {
 430                         kh_interferemsg_time = 0;
 431
 432                         // audit all key carrier sprites, update them to RUN HERE
 433                         FOR_EACH_KH_KEY(k)
 434                         {
 435                                 if (!k.owner) continue;
 436                                 entity first = WP_Null;
 437                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 438                                 entity third = WP_Null;
 439                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 440                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 441                         }
 442                 }
 443         }
 444 }
 445
 446 void kh_Key_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 447 {SELFPARAM();
 448         if(self.owner)
 449                 return;
 450         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 451         {
 452                 // touching lava, or hurt trigger
 453                 // what shall we do?
 454                 // immediately return is bad
 455                 // maybe start a shorter countdown?
 456         }
 457         if(vlen(force) <= 0)
 458                 return;
 459         if(time > self.pushltime)
 460                 if(IS_PLAYER(attacker))
 461                         self.team = attacker.team;
 462 }
 463
 464 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 465 {
 466         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 467
 468         if(key.kh_dropperteam != player.team)
 469         {
 470                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 471                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 472         }
 473         key.kh_dropperteam = 0;
 474         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_PICKUP_), player.netname);
 475
 476         kh_Key_AssignTo(key, player); // this also updates .kh_state
 477 }
 478
 479 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 480 {SELFPARAM();
 481         if(intermission_running)
 482                 return;
 483
 484         if(self.owner) // already carried
 485                 return;
 486
 487         if(ITEM_TOUCH_NEEDKILL())
 488         {
 489                 // touching sky, or nodrop
 490                 // what shall we do?
 491                 // immediately return is bad
 492                 // maybe start a shorter countdown?
 493         }
 494
 495         if (!IS_PLAYER(other))
 496                 return;
 497         if(other.deadflag != DEAD_NO)
 498                 return;
 499         if(other == self.enemy)
 500                 if(time < self.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 501                         return;  // you just dropped it!
 502         kh_Key_Collect(self, other);
 503 }
 504
 505 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 506 {
 507         entity o;
 508         o = key.owner;
 509         kh_Key_AssignTo(key, world);
 510         if(o) // it was attached
 511                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 512         else // it was dropped
 513                 WaypointSprite_DetachCarrier(key);
 514
 515         // remove key from key list
 516         if (kh_worldkeylist == key)
 517                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 518         else
 519         {
 520                 o = kh_worldkeylist;
 521                 while (o)
 522                 {
 523                         if (o.kh_worldkeynext == key)
 524                         {
 525                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 526                                 break;
 527                         }
 528                         o = o.kh_worldkeynext;
 529                 }
 530         }
 531
 532         remove(key);
 533
 534         kh_update_state();
 535 }
 536
 537 void kh_FinishRound()  // runs when a team captures the keys
 538 {
 539         // prepare next round
 540         kh_interferemsg_time = 0;
 541         entity key;
 542
 543         kh_no_radar_circles = true;
 544         FOR_EACH_KH_KEY(key)
 545                 kh_Key_Remove(key);
 546         kh_no_radar_circles = false;
 547
 548         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 549         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 550 }
 551
 552 void kh_WinnerTeam(float teem)  // runs when a team wins // Samual: Teem?.... TEEM?!?! what the fuck is wrong with you people
 553 {
 554         // all key carriers get some points
 555         vector firstorigin, lastorigin, midpoint;
 556         float first;
 557         entity key;
 558         float score;
 559         score = (kh_teams - 1) * autocvar_g_balance_keyhunt_score_capture;
 560         DistributeEvenly_Init(score, kh_teams);
 561         // twice the score for 3 team games, three times the score for 4 team games!
 562         // note: for a win by destroying the key, this should NOT be applied
 563         FOR_EACH_KH_KEY(key)
 564         {
 565                 float f;
 566                 f = DistributeEvenly_Get(1);
 567                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 568                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 569                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 570         }
 571
 572         first = true;
 573         string keyowner = "";
 574         FOR_EACH_KH_KEY(key)
 575                 if(key.owner.kh_next == key)
 576                 {
 577                         if(!first)
 578                                 keyowner = strcat(keyowner, ", ");
 579                         keyowner = key.owner.netname;
 580                         first = false;
 581                 }
 582
 583         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(teem, INFO_KEYHUNT_CAPTURE_), keyowner);
 584
 585         first = true;
 586         midpoint = '0 0 0';
 587         firstorigin = '0 0 0';
 588         lastorigin = '0 0 0';
 589         FOR_EACH_KH_KEY(key)
 590         {
 591                 vector thisorigin;
 592
 593                 thisorigin = kh_AttachedOrigin(key);
 594                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 595                 midpoint += thisorigin;
 596
 597                 if(!first)
 598                         te_lightning2(world, lastorigin, thisorigin);
 599                 lastorigin = thisorigin;
 600                 if(first)
 601                         firstorigin = thisorigin;
 602                 first = false;
 603         }
 604         if(kh_teams > 2)
 605         {
 606                 te_lightning2(world, lastorigin, firstorigin);
 607         }
 608         midpoint = midpoint * (1 / kh_teams);
 609         te_customflash(midpoint, 1000, 1, Team_ColorRGB(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 610
 611         play2all(SND(KH_CAPTURE));
 612         kh_FinishRound();
 613 }
 614
 615 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 616 {
 617         entity player, key, attacker;
 618         float players;
 619         float keys;
 620         float f;
 621
 622         attacker = world;
 623         if(lostkey.pusher)
 624                 if(lostkey.pusher.team != teem)
 625                         if(IS_PLAYER(lostkey.pusher))
 626                                 attacker = lostkey.pusher;
 627
 628         players = keys = 0;
 629
 630         if(attacker)
 631         {
 632                 if(lostkey.kh_previous_owner)
 633                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 634                         // don't actually GIVE him the -nn points, just log
 635                 kh_Scores_Event(attacker, world, "push", autocvar_g_balance_keyhunt_score_push, 0);
 636                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 637                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 638         }
 639         else
 640         {
 641                 float of, fragsleft, i, j, thisteam;
 642                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 643
 644                 FOR_EACH_PLAYER(player)
 645                         if(player.team != teem)
 646                                 ++players;
 647
 648                 FOR_EACH_KH_KEY(key)
 649                         if(key.owner && key.team != teem)
 650                                 ++keys;
 651
 652                 if(lostkey.kh_previous_owner)
 653                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 654                         // don't actually GIVE him the -nn points, just log
 655
 656                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 657                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 658
 659                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 660
 661                 FOR_EACH_KH_KEY(key)
 662                         if(key.owner && key.team != teem)
 663                         {
 664                                 f = DistributeEvenly_Get(of);
 665                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 666                         }
 667
 668                 fragsleft = DistributeEvenly_Get(players);
 669
 670                 // Now distribute these among all other teams...
 671                 j = kh_teams - 1;
 672                 for(i = 0; i < kh_teams; ++i)
 673                 {
 674                         thisteam = kh_Team_ByID(i);
 675                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 676                                 continue;
 677
 678                         players = 0;
 679                         FOR_EACH_PLAYER(player)
 680                                 if(player.team == thisteam)
 681                                         ++players;
 682
 683                         DistributeEvenly_Init(fragsleft, j);
 684                         fragsleft = DistributeEvenly_Get(j - 1);
 685                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 686
 687                         FOR_EACH_PLAYER(player)
 688                                 if(player.team == thisteam)
 689                                 {
 690                                         f = DistributeEvenly_Get(1);
 691                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 692                                 }
 693
 694                         --j;
 695                 }
 696         }
 697
 698         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(lostkey, INFO_KEYHUNT_LOST_), lostkey.kh_previous_owner.netname);
 699
 700         play2all(SND(KH_DESTROY));
 701         te_tarexplosion(lostkey.origin);
 702
 703         kh_FinishRound();
 704 }
 705
 706 void kh_Key_Think()  // runs all the time
 707 {SELFPARAM();
 708         entity head;
 709         //entity player;  // needed by FOR_EACH_PLAYER
 710
 711         if(intermission_running)
 712                 return;
 713
 714         if(self.owner)
 715         {
 716 #ifndef KH_PLAYER_USE_ATTACHMENT
 717                 makevectors('0 1 0' * (self.cnt + (time % 360) * KH_KEY_XYSPEED));
 718                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin.z);
 719 #endif
 720         }
 721
 722         // if in nodrop or time over, end the round
 723         if(!self.owner)
 724                 if(time > self.pain_finished)
 725                         kh_LoserTeam(self.team, self);
 726
 727         if(self.owner)
 728         if(kh_Key_AllOwnedByWhichTeam() != -1)
 729         {
 730                 if(self.siren_time < time)
 731                 {
 732                         sound(self.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 733                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 734                 }
 735
 736                 entity key;
 737                 vector p;
 738                 p = self.owner.origin;
 739                 FOR_EACH_KH_KEY(key)
 740                         if(vlen(key.owner.origin - p) > autocvar_g_balance_keyhunt_maxdist)
 741                                 goto not_winning;
 742                 kh_WinnerTeam(self.team);
 743 :not_winning
 744         }
 745
 746         if(kh_interferemsg_time && time > kh_interferemsg_time)
 747         {
 748                 kh_interferemsg_time = 0;
 749                 FOR_EACH_PLAYER(head)
 750                 {
 751                         if(head.team == kh_interferemsg_team)
 752                                 if(head.kh_next)
 753                                         Send_Notification(NOTIF_ONE, head, MSG_CENTER, CENTER_KEYHUNT_MEET);
 754                                 else
 755                                         Send_Notification(NOTIF_ONE, head, MSG_CENTER, CENTER_KEYHUNT_HELP);
 756                         else
 757                                 Send_Notification(NOTIF_ONE, head, MSG_CENTER, APP_TEAM_NUM_4(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE_));
 758                 }
 759         }
 760
 761         self.nextthink = time + 0.05;
 762 }
 763
 764 void key_reset()
 765 {SELFPARAM();
 766         kh_Key_AssignTo(self, world);
 767         kh_Key_Remove(self);
 768 }
 769
 770 const string STR_ITEM_KH_KEY = "item_kh_key";
 771 void kh_Key_Spawn(entity initial_owner, float angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 772 {
 773         entity key;
 774         key = spawn();
 775         key.count = i;
 776         key.classname = STR_ITEM_KH_KEY;
 777         key.touch = kh_Key_Touch;
 778         key.think = kh_Key_Think;
 779         key.nextthink = time;
 780         key.items = IT_KEY1 | IT_KEY2;
 781         key.cnt = angle;
 782         key.angles = '0 360 0' * random();
 783         key.event_damage = kh_Key_Damage;
 784         key.takedamage = DAMAGE_YES;
 785         key.modelindex = kh_key_dropped;
 786         key.model = "key";
 787         key.kh_dropperteam = 0;
 788         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 789         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 790         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 791         key.reset = key_reset;
 792
 793         switch(initial_owner.team)
 794         {
 795                 case NUM_TEAM_1:
 796                         key.netname = "^1red key";
 797                         break;
 798                 case NUM_TEAM_2:
 799                         key.netname = "^4blue key";
 800                         break;
 801                 case NUM_TEAM_3:
 802                         key.netname = "^3yellow key";
 803                         break;
 804                 case NUM_TEAM_4:
 805                         key.netname = "^6pink key";
 806                         break;
 807                 default:
 808                         key.netname = "NETGIER key";
 809                         break;
 810         }
 811
 812         // link into key list
 813         key.kh_worldkeynext = kh_worldkeylist;
 814         kh_worldkeylist = key;
 815
 816         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM_4(initial_owner.team, CENTER_KEYHUNT_START_));
 817
 818         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 819         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 820
 821         kh_Key_AssignTo(key, initial_owner);
 822 }
 823
 824 // -1 when no team completely owns all keys yet
 825 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 826 {
 827         entity key;
 828         float teem;
 829         float keys;
 830
 831         teem = -1;
 832         keys = kh_teams;
 833         FOR_EACH_KH_KEY(key)
 834         {
 835                 if(!key.owner)
 836                         return -1;
 837                 if(teem == -1)
 838                         teem = key.team;
 839                 else if(teem != key.team)
 840                         return -1;
 841                 --keys;
 842         }
 843         if(keys != 0)
 844                 return -1;
 845         return teem;
 846 }
 847
 848 void kh_Key_DropOne(entity key)
 849 {
 850         // prevent collecting this one for some time
 851         entity player;
 852         player = key.owner;
 853
 854         key.kh_droptime = time;
 855         key.enemy = player;
 856
 857         kh_Scores_Event(player, key, "dropkey", 0, 0);
 858         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 859         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_DROP_), player.netname);
 860
 861         kh_Key_AssignTo(key, world);
 862         makevectors(player.v_angle);
 863         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 864         key.pusher = world;
 865         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 866         key.kh_dropperteam = key.team;
 867
 868         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 869 }
 870
 871 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 872 {
 873         entity key;
 874         entity mypusher;
 875         if(player.kh_next)
 876         {
 877                 mypusher = world;
 878                 if(player.pusher)
 879                         if(time < player.pushltime)
 880                                 mypusher = player.pusher;
 881                 while((key = player.kh_next))
 882                 {
 883                         kh_Scores_Event(player, key, "losekey", 0, 0);
 884                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 885                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(key, INFO_KEYHUNT_LOST_), player.netname);
 886                         kh_Key_AssignTo(key, world);
 887                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 888                         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 889                         key.pusher = mypusher;
 890                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 891                         if(suicide)
 892                                 key.kh_dropperteam = player.team;
 893                 }
 894                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 895         }
 896 }
 897
 898 float kh_CheckPlayers(float num)
 899 {
 900         if(num < kh_teams)
 901         {
 902                 float t_team = kh_Team_ByID(num);
 903                 float players = 0;
 904                 entity tmp_player;
 905                 FOR_EACH_PLAYER(tmp_player)
 906                         if(tmp_player.deadflag == DEAD_NO)
 907                                 if(!tmp_player.BUTTON_CHAT)
 908                                         if(tmp_player.team == t_team)
 909                                                 ++players;
 910
 911                 if (!players) { return t_team; }
 912         }
 913         return 0;
 914 }
 915
 916 #define KH_READY_TEAMS() (!p1 + !p2 + ((kh_teams >= 3) ? !p3 : p3) + ((kh_teams >= 4) ? !p4 : p4))
 917 #define KH_READY_TEAMS_OK() (KH_READY_TEAMS() == kh_teams)
 918 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 919 {
 920         if(time < game_starttime)
 921         {
 922                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 923                 return;
 924         }
 925
 926         static float prev_missing_teams_mask;
 927         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 928         if(KH_READY_TEAMS_OK())
 929         {
 930                 if(prev_missing_teams_mask > 0)
 931                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 932                 prev_missing_teams_mask = -1;
 933                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 934                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 935         }
 936         else
 937         {
 938                 if(player_count == 0)
 939                 {
 940                         if(prev_missing_teams_mask > 0)
 941                                 Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_MISSING_TEAMS);
 942                         prev_missing_teams_mask = -1;
 943                 }
 944                 else
 945                 {
 946                         float missing_teams_mask = (!!p1) + (!!p2) * 2;
 947                         if(kh_teams >= 3) missing_teams_mask += (!!p3) * 4;
 948                         if(kh_teams >= 4) missing_teams_mask += (!!p4) * 8;
 949                         if(prev_missing_teams_mask != missing_teams_mask)
 950                         {
 951                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 952                                 prev_missing_teams_mask = missing_teams_mask;
 953                         }
 954                 }
 955                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 956         }
 957 }
 958
 959 void kh_EnableTrackingDevice()  // runs after each round
 960 {
 961         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT);
 962         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT_OTHER);
 963
 964         kh_tracking_enabled = true;
 965 }
 966
 967 void kh_StartRound()  // runs at the start of each round
 968 {
 969         float i, players, teem;
 970         entity player;
 971
 972         if(time < game_starttime)
 973         {
 974                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 975                 return;
 976         }
 977
 978         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 979         if(!KH_READY_TEAMS_OK())
 980         {
 981                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 982                 return;
 983         }
 984
 985         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT);
 986         Kill_Notification(NOTIF_ALL, world, MSG_CENTER_CPID, CPID_KEYHUNT_OTHER);
 987
 988         for(i = 0; i < kh_teams; ++i)
 989         {
 990                 teem = kh_Team_ByID(i);
 991                 players = 0;
 992                 entity my_player = world;
 993                 FOR_EACH_PLAYER(player)
 994                         if(player.deadflag == DEAD_NO)
 995                                 if(!player.BUTTON_CHAT)
 996                                         if(player.team == teem)
 997                                         {
 998                                                 ++players;
 999                                                 if(random() * players <= 1)
1000                                                         my_player = player;
1001                                         }
1002                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
1003         }
1004
1005         kh_tracking_enabled = false;
1006         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
1007         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
1008 }
1009
1010 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
1011 {
1012         if(attacker == targ)
1013                 return f;
1014
1015         if(targ.kh_next)
1016         {
1017                 if(attacker.team == targ.team)
1018                 {
1019                         entity k;
1020                         float nk;
1021                         nk = 0;
1022                         for(k = targ.kh_next; k != world; k = k.kh_next)
1023                                 ++nk;
1024                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
1025                 }
1026                 else
1027                 {
1028                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
1029                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
1030                         // the frag gets added later
1031                 }
1032         }
1033
1034         return f;
1035 }
1036
1037 void kh_Initialize()  // sets up th KH environment
1038 {
1039         // setup variables
1040         kh_teams = autocvar_g_keyhunt_teams_override;
1041         if(kh_teams < 2)
1042                 kh_teams = autocvar_g_keyhunt_teams;
1043         kh_teams = bound(2, kh_teams, 4);
1044
1045         // make a KH entity for controlling the game
1046         kh_controller = spawn();
1047         kh_controller.think = kh_Controller_Think;
1048         kh_Controller_SetThink(0, kh_WaitForPlayers);
1049
1050         setmodel(kh_controller, MDL_KH_KEY);
1051         kh_key_dropped = kh_controller.modelindex;
1052         /*
1053         dprint(vtos(kh_controller.mins));
1054         dprint(vtos(kh_controller.maxs));
1055         dprint("\n");
1056         */
1057 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1058         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
1059         kh_key_carried = kh_controller.modelindex;
1060 #else
1061         kh_key_carried = kh_key_dropped;
1062 #endif
1063
1064         kh_controller.model = "";
1065         kh_controller.modelindex = 0;
1066
1067         addstat(STAT_KH_KEYS, AS_INT, kh_state);
1068
1069         kh_ScoreRules(kh_teams);
1070 }
1071
1072 void kh_finalize()
1073 {
1074         // to be called before intermission
1075         kh_FinishRound();
1076         remove(kh_controller);
1077         kh_controller = world;
1078 }
1079
1080 // legacy bot role
1081
1082 void() havocbot_role_kh_carrier;
1083 void() havocbot_role_kh_defense;
1084 void() havocbot_role_kh_offense;
1085 void() havocbot_role_kh_freelancer;
1086
1087
1088 void havocbot_goalrating_kh(float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1089 {SELFPARAM();
1090         entity head;
1091         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1092         {
1093                 if(head.owner == self)
1094                         continue;
1095                 if(!kh_tracking_enabled)
1096                 {
1097                         // if it's carried by our team we know about it
1098                         // otherwise we have to see it to know about it
1099                         if(!head.owner || head.team != self.team)
1100                         {
1101                                 traceline(self.origin + self.view_ofs, head.origin, MOVE_NOMONSTERS, self);
1102                                 if (trace_fraction < 1 && trace_ent != head)
1103                                         continue; // skip what I can't see
1104                         }
1105                 }
1106                 if(!head.owner)
1107                         navigation_routerating(head, ratingscale_dropped * BOT_PICKUP_RATING_HIGH, 100000);
1108                 else if(head.team == self.team)
1109                         navigation_routerating(head.owner, ratingscale_team * BOT_PICKUP_RATING_HIGH, 100000);
1110                 else
1111                         navigation_routerating(head.owner, ratingscale_enemy * BOT_PICKUP_RATING_HIGH, 100000);
1112         }
1113
1114         havocbot_goalrating_items(1, self.origin, 10000);
1115 }
1116
1117 void havocbot_role_kh_carrier()
1118 {SELFPARAM();
1119         if(self.deadflag != DEAD_NO)
1120                 return;
1121
1122         if (!(self.kh_next))
1123         {
1124                 LOG_TRACE("changing role to freelancer\n");
1125                 self.havocbot_role = havocbot_role_kh_freelancer;
1126                 self.havocbot_role_timeout = 0;
1127                 return;
1128         }
1129
1130         if (self.bot_strategytime < time)
1131         {
1132                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1133                 navigation_goalrating_start();
1134
1135                 if(kh_Key_AllOwnedByWhichTeam() == self.team)
1136                         havocbot_goalrating_kh(10, 0.1, 0.1); // bring home
1137                 else
1138                         havocbot_goalrating_kh(4, 4, 1); // play defensively
1139
1140                 navigation_goalrating_end();
1141         }
1142 }
1143
1144 void havocbot_role_kh_defense()
1145 {SELFPARAM();
1146         if(self.deadflag != DEAD_NO)
1147                 return;
1148
1149         if (self.kh_next)
1150         {
1151                 LOG_TRACE("changing role to carrier\n");
1152                 self.havocbot_role = havocbot_role_kh_carrier;
1153                 self.havocbot_role_timeout = 0;
1154                 return;
1155         }
1156
1157         if (!self.havocbot_role_timeout)
1158                 self.havocbot_role_timeout = time + random() * 10 + 20;
1159         if (time > self.havocbot_role_timeout)
1160         {
1161                 LOG_TRACE("changing role to freelancer\n");
1162                 self.havocbot_role = havocbot_role_kh_freelancer;
1163                 self.havocbot_role_timeout = 0;
1164                 return;
1165         }
1166
1167         if (self.bot_strategytime < time)
1168         {
1169                 float key_owner_team;
1170                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1171                 navigation_goalrating_start();
1172
1173                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1174                 if(key_owner_team == self.team)
1175                         havocbot_goalrating_kh(10, 0.1, 0.1); // defend key carriers
1176                 else if(key_owner_team == -1)
1177                         havocbot_goalrating_kh(4, 1, 0.1); // play defensively
1178                 else
1179                         havocbot_goalrating_kh(0.1, 0.1, 10); // ATTACK ANYWAY
1180
1181                 navigation_goalrating_end();
1182         }
1183 }
1184
1185 void havocbot_role_kh_offense()
1186 {SELFPARAM();
1187         if(self.deadflag != DEAD_NO)
1188                 return;
1189
1190         if (self.kh_next)
1191         {
1192                 LOG_TRACE("changing role to carrier\n");
1193                 self.havocbot_role = havocbot_role_kh_carrier;
1194                 self.havocbot_role_timeout = 0;
1195                 return;
1196         }
1197
1198         if (!self.havocbot_role_timeout)
1199                 self.havocbot_role_timeout = time + random() * 10 + 20;
1200         if (time > self.havocbot_role_timeout)
1201         {
1202                 LOG_TRACE("changing role to freelancer\n");
1203                 self.havocbot_role = havocbot_role_kh_freelancer;
1204                 self.havocbot_role_timeout = 0;
1205                 return;
1206         }
1207
1208         if (self.bot_strategytime < time)
1209         {
1210                 float key_owner_team;
1211
1212                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1213                 navigation_goalrating_start();
1214
1215                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1216                 if(key_owner_team == self.team)
1217                         havocbot_goalrating_kh(10, 0.1, 0.1); // defend anyway
1218                 else if(key_owner_team == -1)
1219                         havocbot_goalrating_kh(0.1, 1, 4); // play offensively
1220                 else
1221                         havocbot_goalrating_kh(0.1, 0.1, 10); // ATTACK! EMERGENCY!
1222
1223                 navigation_goalrating_end();
1224         }
1225 }
1226
1227 void havocbot_role_kh_freelancer()
1228 {SELFPARAM();
1229         if(self.deadflag != DEAD_NO)
1230                 return;
1231
1232         if (self.kh_next)
1233         {
1234                 LOG_TRACE("changing role to carrier\n");
1235                 self.havocbot_role = havocbot_role_kh_carrier;
1236                 self.havocbot_role_timeout = 0;
1237                 return;
1238         }
1239
1240         if (!self.havocbot_role_timeout)
1241                 self.havocbot_role_timeout = time + random() * 10 + 10;
1242         if (time > self.havocbot_role_timeout)
1243         {
1244                 if (random() < 0.5)
1245                 {
1246                         LOG_TRACE("changing role to offense\n");
1247                         self.havocbot_role = havocbot_role_kh_offense;
1248                 }
1249                 else
1250                 {
1251                         LOG_TRACE("changing role to defense\n");
1252                         self.havocbot_role = havocbot_role_kh_defense;
1253                 }
1254                 self.havocbot_role_timeout = 0;
1255                 return;
1256         }
1257
1258         if (self.bot_strategytime < time)
1259         {
1260                 float key_owner_team;
1261
1262                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1263                 navigation_goalrating_start();
1264
1265                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1266                 if(key_owner_team == self.team)
1267                         havocbot_goalrating_kh(10, 0.1, 0.1); // defend anyway
1268                 else if(key_owner_team == -1)
1269                         havocbot_goalrating_kh(1, 10, 4); // prefer dropped keys
1270                 else
1271                         havocbot_goalrating_kh(0.1, 0.1, 10); // ATTACK ANYWAY
1272
1273                 navigation_goalrating_end();
1274         }
1275 }
1276
1277
1278 // register this as a mutator
1279
1280 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1281 {SELFPARAM();
1282         kh_Key_DropAll(self, true);
1283         return 0;
1284 }
1285
1286 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1287 {SELFPARAM();
1288         kh_Key_DropAll(self, true);
1289         return 0;
1290 }
1291
1292 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1293 {SELFPARAM();
1294         if(self == other)
1295                 kh_Key_DropAll(self, true);
1296         else if(IS_PLAYER(other))
1297                 kh_Key_DropAll(self, false);
1298         else
1299                 kh_Key_DropAll(self, true);
1300         return 0;
1301 }
1302
1303 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1304 {
1305         frag_score = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1306         return 0;
1307 }
1308
1309 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1310 {
1311         kh_finalize();
1312         return 0;
1313 }
1314
1315 MUTATOR_HOOKFUNCTION(kh, GetTeamCount, CBC_ORDER_EXCLUSIVE)
1316 {
1317         ret_float = kh_teams;
1318         return false;
1319 }
1320
1321 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1322 {SELFPARAM();
1323         self.kh_state = other.kh_state;
1324         return 0;
1325 }
1326
1327 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1328 {SELFPARAM();
1329         if(MUTATOR_RETURNVALUE == 0)
1330         {
1331                 entity k;
1332                 k = self.kh_next;
1333                 if(k)
1334                 {
1335                         kh_Key_DropOne(k);
1336                         return 1;
1337                 }
1338         }
1339         return 0;
1340 }
1341
1342 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1343 {
1344         if(self.deadflag != DEAD_NO)
1345                 return true;
1346
1347         float r = random() * 3;
1348         if (r < 1)
1349                 self.havocbot_role = havocbot_role_kh_offense;
1350         else if (r < 2)
1351                 self.havocbot_role = havocbot_role_kh_defense;
1352         else
1353                 self.havocbot_role = havocbot_role_kh_freelancer;
1354
1355         return true;
1356 }
1357
1358 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1359 {
1360         kh_Key_DropAll(frag_target, false);
1361         return false;
1362 }
1363
1364 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1365 {
1366         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
1367         return false;
1368 }
1369
1370 REGISTER_MUTATOR(kh, IS_GAMETYPE(KEYHUNT))
1371 {
1372         ActivateTeamplay();
1373         SetLimits(autocvar_g_keyhunt_point_limit, autocvar_g_keyhunt_point_leadlimit, -1, -1);
1374         if(autocvar_g_keyhunt_team_spawns)
1375                 have_team_spawns = -1; // request team spawns
1376
1377         MUTATOR_ONADD
1378         {
1379                 if(time > 1) // game loads at time 1
1380                         error("This is a game type and it cannot be added at runtime.");
1381                 kh_Initialize();
1382         }
1383
1384         MUTATOR_ONROLLBACK_OR_REMOVE
1385         {
1386                 // we actually cannot roll back kh_Initialize here
1387                 // BUT: we don't need to! If this gets called, adding always
1388                 // succeeds.
1389         }
1390
1391         MUTATOR_ONREMOVE
1392         {
1393                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
1394                 return -1;
1395         }
1396
1397         return 0;
1398 }
1399 #endif