qcsrc/server/mutators/mutator/gamemode_keyhunt.qc

   1 #include "gamemode_keyhunt.qh"
   2 #ifndef GAMEMODE_KEYHUNT_H
   3 #define GAMEMODE_KEYHUNT_H
   4
   5 #define autocvar_g_keyhunt_point_limit cvar("g_keyhunt_point_limit")
   6 int autocvar_g_keyhunt_point_leadlimit;
   7 bool autocvar_g_keyhunt_team_spawns;
   8 void kh_Initialize();
   9
  10 REGISTER_MUTATOR(kh, false)
  11 {
  12         MUTATOR_ONADD
  13         {
  14                 if (time > 1) // game loads at time 1
  15                         error("This is a game type and it cannot be added at runtime.");
  16                 kh_Initialize();
  17
  18                 ActivateTeamplay();
  19                 SetLimits(autocvar_g_keyhunt_point_limit, autocvar_g_keyhunt_point_leadlimit, autocvar_timelimit_override, -1);
  20                 if (autocvar_g_keyhunt_team_spawns)
  21                         have_team_spawns = -1; // request team spawns
  22         }
  23
  24         MUTATOR_ONROLLBACK_OR_REMOVE
  25         {
  26                 // we actually cannot roll back kh_Initialize here
  27                 // BUT: we don't need to! If this gets called, adding always
  28                 // succeeds.
  29         }
  30
  31         MUTATOR_ONREMOVE
  32         {
  33                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  34                 return -1;
  35         }
  36
  37         return 0;
  38 }
  39
  40 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
  41
  42 // ALL OF THESE should be removed in the future, as other code should not have to care
  43
  44 // used by bots:
  45 float kh_tracking_enabled;
  46 .entity kh_next;
  47 float kh_Key_AllOwnedByWhichTeam();
  48
  49 USING(kh_Think_t, void());
  50 void kh_StartRound();
  51 void kh_Controller_SetThink(float t, kh_Think_t func);
  52
  53 #endif
  54
  55 #ifdef IMPLEMENTATION
  56
  57 float autocvar_g_balance_keyhunt_damageforcescale;
  58 float autocvar_g_balance_keyhunt_delay_collect;
  59 float autocvar_g_balance_keyhunt_delay_return;
  60 float autocvar_g_balance_keyhunt_delay_round;
  61 float autocvar_g_balance_keyhunt_delay_tracking;
  62 float autocvar_g_balance_keyhunt_dropvelocity;
  63 float autocvar_g_balance_keyhunt_maxdist;
  64 float autocvar_g_balance_keyhunt_protecttime;
  65
  66 int autocvar_g_balance_keyhunt_score_capture;
  67 int autocvar_g_balance_keyhunt_score_carrierfrag;
  68 int autocvar_g_balance_keyhunt_score_collect;
  69 int autocvar_g_balance_keyhunt_score_destroyed;
  70 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  71 int autocvar_g_balance_keyhunt_score_push;
  72 float autocvar_g_balance_keyhunt_throwvelocity;
  73
  74 int autocvar_g_keyhunt_teams;
  75 int autocvar_g_keyhunt_teams_override;
  76
  77 // #define KH_PLAYER_USE_ATTACHMENT
  78 // #define KH_PLAYER_USE_CARRIEDMODEL
  79
  80 #ifdef KH_PLAYER_USE_ATTACHMENT
  81 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  82 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  83 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  84 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  85 const string KH_PLAYER_ATTACHMENT_BONE = "";
  86 #else
  87 const float KH_KEY_ZSHIFT = 22;
  88 const float KH_KEY_XYDIST = 24;
  89 const float KH_KEY_XYSPEED = 45;
  90 #endif
  91 const float KH_KEY_WP_ZSHIFT = 20;
  92
  93 const vector KH_KEY_MIN = '-10 -10 -46';
  94 const vector KH_KEY_MAX = '10 10 3';
  95 const float KH_KEY_BRIGHTNESS = 2;
  96
  97 float kh_no_radar_circles;
  98
  99 // kh_state
 100 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
 101 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
 102 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
 103 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
 104 .float kh_state = _STAT(KH_KEYS);
 105 .float siren_time;  //  time delay the siren
 106 //.float stuff_time;  //  time delay to stuffcmd a cvar
 107
 108 float kh_keystatus[17];
 109 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
 110 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
 111 //for(i = 0; i < maxplayers; ++i)
 112 //      kh_keystatus[i] = "0";
 113
 114 float kh_Team_ByID(float t)
 115 {
 116         if(t == 0) return NUM_TEAM_1;
 117         if(t == 1) return NUM_TEAM_2;
 118         if(t == 2) return NUM_TEAM_3;
 119         if(t == 3) return NUM_TEAM_4;
 120         return 0;
 121 }
 122
 123 //entity kh_worldkeylist;
 124 .entity kh_worldkeynext;
 125 entity kh_controller;
 126 //float kh_tracking_enabled;
 127 float kh_teams;
 128 float kh_interferemsg_time, kh_interferemsg_team;
 129 .entity kh_next, kh_prev; // linked list
 130 .float kh_droptime;
 131 .float kh_dropperteam;
 132 .entity kh_previous_owner;
 133 .float kh_previous_owner_playerid;
 134 .float kh_cp_duration;
 135
 136 float kh_key_dropped, kh_key_carried;
 137
 138 const float ST_KH_CAPS = 1;
 139 void kh_ScoreRules(int teams)
 140 {
 141         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, true);
 142         ScoreInfo_SetLabel_TeamScore(  ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
 143         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
 144         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSHES,    "pushes",    0);
 145         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYS,  "destroyed", SFL_LOWER_IS_BETTER);
 146         ScoreInfo_SetLabel_PlayerScore(SP_KH_PICKUPS,   "pickups",   0);
 147         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCKILLS,   "kckills",   0);
 148         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSSES,    "losses",    SFL_LOWER_IS_BETTER);
 149         ScoreRules_basics_end();
 150 }
 151
 152 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
 153 {
 154         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
 155                 if(!kh_tracking_enabled)
 156                         return false;
 157
 158         return true;
 159 }
 160
 161 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 162 {
 163         if(!kh_tracking_enabled)
 164                 return false;
 165         if(!this.owner)
 166                 return true;
 167         if(!this.owner.owner)
 168                 return true;
 169         return false;  // draw only when key is not owned
 170 }
 171
 172 void kh_update_state()
 173 {
 174         entity key;
 175         float s;
 176         float f;
 177
 178         s = 0;
 179         FOR_EACH_KH_KEY(key)
 180         {
 181                 if(key.owner)
 182                         f = key.team;
 183                 else
 184                         f = 30;
 185                 s |= pow(32, key.count) * f;
 186         }
 187
 188         FOREACH_CLIENT(true, LAMBDA(it.kh_state = s));
 189
 190         FOR_EACH_KH_KEY(key)
 191         {
 192                 if(key.owner)
 193                         key.owner.kh_state |= pow(32, key.count) * 31;
 194         }
 195         //print(ftos((nextent(NULL)).kh_state), "\n");
 196 }
 197
 198
 199
 200
 201 var kh_Think_t kh_Controller_Thinkfunc;
 202 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 203 {
 204         kh_Controller_Thinkfunc = func;
 205         kh_controller.cnt = ceil(t);
 206         if(t == 0)
 207                 kh_controller.nextthink = time; // force
 208 }
 209 void kh_WaitForPlayers();
 210 void kh_Controller_Think(entity this)  // called a lot
 211 {
 212         if(intermission_running)
 213                 return;
 214         if(this.cnt > 0)
 215         { if(getthink(this) != kh_WaitForPlayers) { this.cnt -= 1; } }
 216         else if(this.cnt == 0)
 217         {
 218                 this.cnt -= 1;
 219                 kh_Controller_Thinkfunc();
 220         }
 221         this.nextthink = time + 1;
 222 }
 223
 224 // frags f: take from cvar * f
 225 // frags 0: no frags
 226 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 227 {
 228         string s;
 229         if(intermission_running)
 230                 return;
 231
 232         if(frags_player)
 233                 UpdateFrags(player, frags_player);
 234
 235         if(key && key.owner && frags_owner)
 236                 UpdateFrags(key.owner, frags_owner);
 237
 238         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 239                 return;
 240
 241         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 242
 243         if(key && key.owner)
 244                 s = strcat(s, ":", ftos(key.owner.playerid));
 245         else
 246                 s = strcat(s, ":0");
 247
 248         s = strcat(s, ":", ftos(frags_owner), ":");
 249
 250         if(key)
 251                 s = strcat(s, key.netname);
 252
 253         GameLogEcho(s);
 254 }
 255
 256 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 257 {
 258         if(e.tag_entity)
 259         {
 260                 makevectors(e.tag_entity.angles);
 261                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 262         }
 263         else
 264                 return e.origin;
 265 }
 266
 267 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 268 {
 269 #ifdef KH_PLAYER_USE_ATTACHMENT
 270         entity first;
 271         first = key.owner.kh_next;
 272         if(key == first)
 273         {
 274                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 275                 if(key.kh_next)
 276                 {
 277                         setattachment(key.kh_next, key, "");
 278                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 279                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 280                         key.kh_next.angles = '0 0 0';
 281                 }
 282                 else
 283                         setorigin(key, KH_PLAYER_ATTACHMENT);
 284                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 285         }
 286         else
 287         {
 288                 setattachment(key, key.kh_prev, "");
 289                 if(key.kh_next)
 290                         setattachment(key.kh_next, key, "");
 291                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 292                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 293                 key.angles = '0 0 0';
 294         }
 295 #else
 296         setattachment(key, key.owner, "");
 297         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 298         key.angles_y -= key.owner.angles.y;
 299 #endif
 300         key.flags = 0;
 301         key.solid = SOLID_NOT;
 302         set_movetype(key, MOVETYPE_NONE);
 303         key.team = key.owner.team;
 304         key.nextthink = time;
 305         key.damageforcescale = 0;
 306         key.takedamage = DAMAGE_NO;
 307         key.modelindex = kh_key_carried;
 308 }
 309
 310 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 311 {
 312 #ifdef KH_PLAYER_USE_ATTACHMENT
 313         entity first;
 314         first = key.owner.kh_next;
 315         if(key == first)
 316         {
 317                 if(key.kh_next)
 318                 {
 319                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 320                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 321                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 322                 }
 323         }
 324         else
 325         {
 326                 if(key.kh_next)
 327                         setattachment(key.kh_next, key.kh_prev, "");
 328                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 329         }
 330         // in any case:
 331         setattachment(key, NULL, "");
 332         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, NULL).z - KH_KEY_MIN_z));
 333         key.angles = key.owner.angles;
 334 #else
 335         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 336         setattachment(key, NULL, "");
 337         key.angles_y += key.owner.angles.y;
 338 #endif
 339         key.flags = FL_ITEM;
 340         key.solid = SOLID_TRIGGER;
 341         set_movetype(key, MOVETYPE_TOSS);
 342         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 343         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 344         key.takedamage = DAMAGE_YES;
 345         // let key.team stay
 346         key.modelindex = kh_key_dropped;
 347         key.kh_previous_owner = key.owner;
 348         key.kh_previous_owner_playerid = key.owner.playerid;
 349 }
 350
 351 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 352 {
 353         entity k;
 354         float ownerteam0, ownerteam;
 355         if(key.owner == player)
 356                 return;
 357
 358         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 359
 360         if(key.owner)
 361         {
 362                 kh_Key_Detach(key);
 363
 364                 // remove from linked list
 365                 if(key.kh_next)
 366                         key.kh_next.kh_prev = key.kh_prev;
 367                 key.kh_prev.kh_next = key.kh_next;
 368                 key.kh_next = NULL;
 369                 key.kh_prev = NULL;
 370
 371                 if(key.owner.kh_next == NULL)
 372                 {
 373                         // No longer a key carrier
 374                         if(!kh_no_radar_circles)
 375                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 376                         WaypointSprite_DetachCarrier(key.owner);
 377                 }
 378         }
 379
 380         key.owner = player;
 381
 382         if(player)
 383         {
 384                 // insert into linked list
 385                 key.kh_next = player.kh_next;
 386                 key.kh_prev = player;
 387                 player.kh_next = key;
 388                 if(key.kh_next)
 389                         key.kh_next.kh_prev = key;
 390
 391                 float i;
 392                 i = kh_keystatus[key.owner.playerid];
 393                         if(key.netname == "^1red key")
 394                                 i += 1;
 395                         if(key.netname == "^4blue key")
 396                                 i += 2;
 397                         if(key.netname == "^3yellow key")
 398                                 i += 4;
 399                         if(key.netname == "^6pink key")
 400                                 i += 8;
 401                 kh_keystatus[key.owner.playerid] = i;
 402
 403                 kh_Key_Attach(key);
 404
 405                 if(key.kh_next == NULL)
 406                 {
 407                         // player is now a key carrier
 408                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 409                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 410                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 411                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 412                         if(player.team == NUM_TEAM_1)
 413                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 414                         else if(player.team == NUM_TEAM_2)
 415                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 416                         else if(player.team == NUM_TEAM_3)
 417                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 418                         else if(player.team == NUM_TEAM_4)
 419                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 420                         if(!kh_no_radar_circles)
 421                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 422                 }
 423         }
 424
 425         // moved that here, also update if there's no player
 426         kh_update_state();
 427
 428         key.pusher = NULL;
 429
 430         ownerteam = kh_Key_AllOwnedByWhichTeam();
 431         if(ownerteam != ownerteam0)
 432         {
 433                 if(ownerteam != -1)
 434                 {
 435                         kh_interferemsg_time = time + 0.2;
 436                         kh_interferemsg_team = player.team;
 437
 438                         // audit all key carrier sprites, update them to RUN HERE
 439                         FOR_EACH_KH_KEY(k)
 440                         {
 441                                 if (!k.owner) continue;
 442                                 entity first = WP_Null;
 443                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 444                                 entity third = WP_Null;
 445                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 446                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 447                         }
 448                 }
 449                 else
 450                 {
 451                         kh_interferemsg_time = 0;
 452
 453                         // audit all key carrier sprites, update them to RUN HERE
 454                         FOR_EACH_KH_KEY(k)
 455                         {
 456                                 if (!k.owner) continue;
 457                                 entity first = WP_Null;
 458                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 459                                 entity third = WP_Null;
 460                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 461                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 462                         }
 463                 }
 464         }
 465 }
 466
 467 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 468 {
 469         if(this.owner)
 470                 return;
 471         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 472         {
 473                 // touching lava, or hurt trigger
 474                 // what shall we do?
 475                 // immediately return is bad
 476                 // maybe start a shorter countdown?
 477         }
 478         if(vlen(force) <= 0)
 479                 return;
 480         if(time > this.pushltime)
 481                 if(IS_PLAYER(attacker))
 482                         this.team = attacker.team;
 483 }
 484
 485 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 486 {
 487         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 488
 489         if(key.kh_dropperteam != player.team)
 490         {
 491                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 492                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 493         }
 494         key.kh_dropperteam = 0;
 495         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_ENT(key, INFO_KEYHUNT_PICKUP), player.netname);
 496
 497         kh_Key_AssignTo(key, player); // this also updates .kh_state
 498 }
 499
 500 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 501 {
 502         if(intermission_running)
 503                 return;
 504
 505         if(this.owner) // already carried
 506                 return;
 507
 508         if(ITEM_TOUCH_NEEDKILL())
 509         {
 510                 // touching sky, or nodrop
 511                 // what shall we do?
 512                 // immediately return is bad
 513                 // maybe start a shorter countdown?
 514         }
 515
 516         if (!IS_PLAYER(toucher))
 517                 return;
 518         if(IS_DEAD(toucher))
 519                 return;
 520         if(toucher == this.enemy)
 521                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 522                         return;  // you just dropped it!
 523         kh_Key_Collect(this, toucher);
 524 }
 525
 526 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 527 {
 528         entity o;
 529         o = key.owner;
 530         kh_Key_AssignTo(key, NULL);
 531         if(o) // it was attached
 532                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 533         else // it was dropped
 534                 WaypointSprite_DetachCarrier(key);
 535
 536         // remove key from key list
 537         if (kh_worldkeylist == key)
 538                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 539         else
 540         {
 541                 o = kh_worldkeylist;
 542                 while (o)
 543                 {
 544                         if (o.kh_worldkeynext == key)
 545                         {
 546                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 547                                 break;
 548                         }
 549                         o = o.kh_worldkeynext;
 550                 }
 551         }
 552
 553         delete(key);
 554
 555         kh_update_state();
 556 }
 557
 558 void kh_FinishRound()  // runs when a team captures the keys
 559 {
 560         // prepare next round
 561         kh_interferemsg_time = 0;
 562         entity key;
 563
 564         kh_no_radar_circles = true;
 565         FOR_EACH_KH_KEY(key)
 566                 kh_Key_Remove(key);
 567         kh_no_radar_circles = false;
 568
 569         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 570         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 571 }
 572
 573 void kh_WinnerTeam(float teem)  // runs when a team wins // Samual: Teem?.... TEEM?!?! what the fuck is wrong with you people
 574 {
 575         // all key carriers get some points
 576         vector firstorigin, lastorigin, midpoint;
 577         float first;
 578         entity key;
 579         float score;
 580         score = (kh_teams - 1) * autocvar_g_balance_keyhunt_score_capture;
 581         DistributeEvenly_Init(score, kh_teams);
 582         // twice the score for 3 team games, three times the score for 4 team games!
 583         // note: for a win by destroying the key, this should NOT be applied
 584         FOR_EACH_KH_KEY(key)
 585         {
 586                 float f;
 587                 f = DistributeEvenly_Get(1);
 588                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 589                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 590                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 591         }
 592
 593         first = true;
 594         string keyowner = "";
 595         FOR_EACH_KH_KEY(key)
 596                 if(key.owner.kh_next == key)
 597                 {
 598                         if(!first)
 599                                 keyowner = strcat(keyowner, ", ");
 600                         keyowner = key.owner.netname;
 601                         first = false;
 602                 }
 603
 604         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(teem, INFO_KEYHUNT_CAPTURE), keyowner);
 605
 606         first = true;
 607         midpoint = '0 0 0';
 608         firstorigin = '0 0 0';
 609         lastorigin = '0 0 0';
 610         FOR_EACH_KH_KEY(key)
 611         {
 612                 vector thisorigin;
 613
 614                 thisorigin = kh_AttachedOrigin(key);
 615                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 616                 midpoint += thisorigin;
 617
 618                 if(!first)
 619                         te_lightning2(NULL, lastorigin, thisorigin);
 620                 lastorigin = thisorigin;
 621                 if(first)
 622                         firstorigin = thisorigin;
 623                 first = false;
 624         }
 625         if(kh_teams > 2)
 626         {
 627                 te_lightning2(NULL, lastorigin, firstorigin);
 628         }
 629         midpoint = midpoint * (1 / kh_teams);
 630         te_customflash(midpoint, 1000, 1, Team_ColorRGB(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 631
 632         play2all(SND(KH_CAPTURE));
 633         kh_FinishRound();
 634 }
 635
 636 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 637 {
 638         entity key, attacker;
 639         float players;
 640         float keys;
 641         float f;
 642
 643         attacker = NULL;
 644         if(lostkey.pusher)
 645                 if(lostkey.pusher.team != teem)
 646                         if(IS_PLAYER(lostkey.pusher))
 647                                 attacker = lostkey.pusher;
 648
 649         players = keys = 0;
 650
 651         if(attacker)
 652         {
 653                 if(lostkey.kh_previous_owner)
 654                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 655                         // don't actually GIVE him the -nn points, just log
 656                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 657                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 658                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 659         }
 660         else
 661         {
 662                 float of, fragsleft, i, j, thisteam;
 663                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 664
 665                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != teem, LAMBDA(++players));
 666
 667                 FOR_EACH_KH_KEY(key)
 668                         if(key.owner && key.team != teem)
 669                                 ++keys;
 670
 671                 if(lostkey.kh_previous_owner)
 672                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 673                         // don't actually GIVE him the -nn points, just log
 674
 675                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 676                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 677
 678                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 679
 680                 FOR_EACH_KH_KEY(key)
 681                         if(key.owner && key.team != teem)
 682                         {
 683                                 f = DistributeEvenly_Get(of);
 684                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 685                         }
 686
 687                 fragsleft = DistributeEvenly_Get(players);
 688
 689                 // Now distribute these among all other teams...
 690                 j = kh_teams - 1;
 691                 for(i = 0; i < kh_teams; ++i)
 692                 {
 693                         thisteam = kh_Team_ByID(i);
 694                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 695                                 continue;
 696
 697                         players = 0;
 698                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(++players));
 699
 700                         DistributeEvenly_Init(fragsleft, j);
 701                         fragsleft = DistributeEvenly_Get(j - 1);
 702                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 703
 704                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(
 705                                 f = DistributeEvenly_Get(1);
 706                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 707                         ));
 708
 709                         --j;
 710                 }
 711         }
 712
 713         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_ENT(lostkey, INFO_KEYHUNT_LOST), lostkey.kh_previous_owner.netname);
 714
 715         play2all(SND(KH_DESTROY));
 716         te_tarexplosion(lostkey.origin);
 717
 718         kh_FinishRound();
 719 }
 720
 721 void kh_Key_Think(entity this)  // runs all the time
 722 {
 723         if(intermission_running)
 724                 return;
 725
 726         if(this.owner)
 727         {
 728 #ifndef KH_PLAYER_USE_ATTACHMENT
 729                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 730                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 731 #endif
 732         }
 733
 734         // if in nodrop or time over, end the round
 735         if(!this.owner)
 736                 if(time > this.pain_finished)
 737                         kh_LoserTeam(this.team, this);
 738
 739         if(this.owner)
 740         if(kh_Key_AllOwnedByWhichTeam() != -1)
 741         {
 742                 if(this.siren_time < time)
 743                 {
 744                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 745                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 746                 }
 747
 748                 entity key;
 749                 vector p;
 750                 p = this.owner.origin;
 751                 FOR_EACH_KH_KEY(key)
 752                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 753                                 goto not_winning;
 754                 kh_WinnerTeam(this.team);
 755 LABEL(not_winning)
 756         }
 757
 758         if(kh_interferemsg_time && time > kh_interferemsg_time)
 759         {
 760                 kh_interferemsg_time = 0;
 761                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 762                         if(it.team == kh_interferemsg_team)
 763                                 if(it.kh_next)
 764                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 765                                 else
 766                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 767                         else
 768                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 769                 ));
 770         }
 771
 772         this.nextthink = time + 0.05;
 773 }
 774
 775 void key_reset(entity this)
 776 {
 777         kh_Key_AssignTo(this, NULL);
 778         kh_Key_Remove(this);
 779 }
 780
 781 const string STR_ITEM_KH_KEY = "item_kh_key";
 782 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 783 {
 784         entity key = spawn();
 785         key.count = i;
 786         key.classname = STR_ITEM_KH_KEY;
 787         settouch(key, kh_Key_Touch);
 788         setthink(key, kh_Key_Think);
 789         key.nextthink = time;
 790         key.items = IT_KEY1 | IT_KEY2;
 791         key.cnt = _angle;
 792         key.angles = '0 360 0' * random();
 793         key.event_damage = kh_Key_Damage;
 794         key.takedamage = DAMAGE_YES;
 795         key.modelindex = kh_key_dropped;
 796         key.model = "key";
 797         key.kh_dropperteam = 0;
 798         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 799         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 800         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 801         key.reset = key_reset;
 802
 803         switch(initial_owner.team)
 804         {
 805                 case NUM_TEAM_1:
 806                         key.netname = "^1red key";
 807                         break;
 808                 case NUM_TEAM_2:
 809                         key.netname = "^4blue key";
 810                         break;
 811                 case NUM_TEAM_3:
 812                         key.netname = "^3yellow key";
 813                         break;
 814                 case NUM_TEAM_4:
 815                         key.netname = "^6pink key";
 816                         break;
 817                 default:
 818                         key.netname = "NETGIER key";
 819                         break;
 820         }
 821
 822         // link into key list
 823         key.kh_worldkeynext = kh_worldkeylist;
 824         kh_worldkeylist = key;
 825
 826         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 827
 828         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 829         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 830
 831         kh_Key_AssignTo(key, initial_owner);
 832 }
 833
 834 // -1 when no team completely owns all keys yet
 835 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 836 {
 837         entity key;
 838         float teem;
 839         float keys;
 840
 841         teem = -1;
 842         keys = kh_teams;
 843         FOR_EACH_KH_KEY(key)
 844         {
 845                 if(!key.owner)
 846                         return -1;
 847                 if(teem == -1)
 848                         teem = key.team;
 849                 else if(teem != key.team)
 850                         return -1;
 851                 --keys;
 852         }
 853         if(keys != 0)
 854                 return -1;
 855         return teem;
 856 }
 857
 858 void kh_Key_DropOne(entity key)
 859 {
 860         // prevent collecting this one for some time
 861         entity player;
 862         player = key.owner;
 863
 864         key.kh_droptime = time;
 865         key.enemy = player;
 866
 867         kh_Scores_Event(player, key, "dropkey", 0, 0);
 868         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 869         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_ENT(key, INFO_KEYHUNT_DROP), player.netname);
 870
 871         kh_Key_AssignTo(key, NULL);
 872         makevectors(player.v_angle);
 873         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 874         key.pusher = NULL;
 875         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 876         key.kh_dropperteam = key.team;
 877
 878         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 879 }
 880
 881 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 882 {
 883         entity key;
 884         entity mypusher;
 885         if(player.kh_next)
 886         {
 887                 mypusher = NULL;
 888                 if(player.pusher)
 889                         if(time < player.pushltime)
 890                                 mypusher = player.pusher;
 891                 while((key = player.kh_next))
 892                 {
 893                         kh_Scores_Event(player, key, "losekey", 0, 0);
 894                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 895                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_ENT(key, INFO_KEYHUNT_LOST), player.netname);
 896                         kh_Key_AssignTo(key, NULL);
 897                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 898                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 899                         key.pusher = mypusher;
 900                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 901                         if(suicide)
 902                                 key.kh_dropperteam = player.team;
 903                 }
 904                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 905         }
 906 }
 907
 908 float kh_CheckPlayers(float num)
 909 {
 910         if(num < kh_teams)
 911         {
 912                 float t_team = kh_Team_ByID(num);
 913                 float players = 0;
 914                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 915                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == t_team)
 916                                 ++players;
 917                 ));
 918
 919                 if (!players) { return t_team; }
 920         }
 921         return 0;
 922 }
 923
 924 #define KH_READY_TEAMS() (!p1 + !p2 + ((kh_teams >= 3) ? !p3 : p3) + ((kh_teams >= 4) ? !p4 : p4))
 925 #define KH_READY_TEAMS_OK() (KH_READY_TEAMS() == kh_teams)
 926 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 927 {
 928         if(time < game_starttime)
 929         {
 930                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 931                 return;
 932         }
 933
 934         static float prev_missing_teams_mask;
 935         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 936         if(KH_READY_TEAMS_OK())
 937         {
 938                 if(prev_missing_teams_mask > 0)
 939                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 940                 prev_missing_teams_mask = -1;
 941                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 942                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 943         }
 944         else
 945         {
 946                 if(player_count == 0)
 947                 {
 948                         if(prev_missing_teams_mask > 0)
 949                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 950                         prev_missing_teams_mask = -1;
 951                 }
 952                 else
 953                 {
 954                         int missing_teams_mask = 0;
 955                         if(kh_teams & BIT(0))
 956                                 missing_teams_mask += boolean(p1) * 1;
 957                         if(kh_teams & BIT(1))
 958                                 missing_teams_mask += boolean(p2) * 2;
 959                         if(kh_teams & BIT(2))
 960                                 missing_teams_mask += boolean(p3) * 4;
 961                         if(kh_teams & BIT(3))
 962                                 missing_teams_mask += boolean(p4) * 8;
 963                         if(prev_missing_teams_mask != missing_teams_mask)
 964                         {
 965                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 966                                 prev_missing_teams_mask = missing_teams_mask;
 967                         }
 968                 }
 969                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 970         }
 971 }
 972
 973 void kh_EnableTrackingDevice()  // runs after each round
 974 {
 975         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 976         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 977
 978         kh_tracking_enabled = true;
 979 }
 980
 981 void kh_StartRound()  // runs at the start of each round
 982 {
 983         float i, players, teem;
 984
 985         if(time < game_starttime)
 986         {
 987                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 988                 return;
 989         }
 990
 991         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 992         if(!KH_READY_TEAMS_OK())
 993         {
 994                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 995                 return;
 996         }
 997
 998         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 999         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
1000
1001         for(i = 0; i < kh_teams; ++i)
1002         {
1003                 teem = kh_Team_ByID(i);
1004                 players = 0;
1005                 entity my_player = NULL;
1006                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1007                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
1008                         {
1009                                 ++players;
1010                                 if(random() * players <= 1)
1011                                         my_player = it;
1012                         }
1013                 ));
1014                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
1015         }
1016
1017         kh_tracking_enabled = false;
1018         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
1019         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
1020 }
1021
1022 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
1023 {
1024         if(attacker == targ)
1025                 return f;
1026
1027         if(targ.kh_next)
1028         {
1029                 if(attacker.team == targ.team)
1030                 {
1031                         entity k;
1032                         float nk;
1033                         nk = 0;
1034                         for(k = targ.kh_next; k != NULL; k = k.kh_next)
1035                                 ++nk;
1036                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
1037                 }
1038                 else
1039                 {
1040                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
1041                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
1042                         // the frag gets added later
1043                 }
1044         }
1045
1046         return f;
1047 }
1048
1049 void kh_Initialize()  // sets up th KH environment
1050 {
1051         // setup variables
1052         kh_teams = autocvar_g_keyhunt_teams_override;
1053         if(kh_teams < 2)
1054                 kh_teams = autocvar_g_keyhunt_teams;
1055         kh_teams = bound(2, kh_teams, 4);
1056
1057         int teams = 0;
1058         if(kh_teams >= 1) teams |= BIT(0);
1059         if(kh_teams >= 2) teams |= BIT(1);
1060         if(kh_teams >= 3) teams |= BIT(2);
1061         if(kh_teams >= 4) teams |= BIT(3);
1062
1063         kh_teams = teams; // now set it?
1064
1065         // make a KH entity for controlling the game
1066         kh_controller = spawn();
1067         setthink(kh_controller, kh_Controller_Think);
1068         kh_Controller_SetThink(0, kh_WaitForPlayers);
1069
1070         setmodel(kh_controller, MDL_KH_KEY);
1071         kh_key_dropped = kh_controller.modelindex;
1072         /*
1073         dprint(vtos(kh_controller.mins));
1074         dprint(vtos(kh_controller.maxs));
1075         dprint("\n");
1076         */
1077 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1078         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
1079         kh_key_carried = kh_controller.modelindex;
1080 #else
1081         kh_key_carried = kh_key_dropped;
1082 #endif
1083
1084         kh_controller.model = "";
1085         kh_controller.modelindex = 0;
1086
1087         kh_ScoreRules(kh_teams);
1088 }
1089
1090 void kh_finalize()
1091 {
1092         // to be called before intermission
1093         kh_FinishRound();
1094         delete(kh_controller);
1095         kh_controller = NULL;
1096 }
1097
1098 // legacy bot role
1099
1100 void(entity this) havocbot_role_kh_carrier;
1101 void(entity this) havocbot_role_kh_defense;
1102 void(entity this) havocbot_role_kh_offense;
1103 void(entity this) havocbot_role_kh_freelancer;
1104
1105
1106 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1107 {
1108         entity head;
1109         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1110         {
1111                 if(head.owner == this)
1112                         continue;
1113                 if(!kh_tracking_enabled)
1114                 {
1115                         // if it's carried by our team we know about it
1116                         // otherwise we have to see it to know about it
1117                         if(!head.owner || head.team != this.team)
1118                         {
1119                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1120                                 if (trace_fraction < 1 && trace_ent != head)
1121                                         continue; // skip what I can't see
1122                         }
1123                 }
1124                 if(!head.owner)
1125                         navigation_routerating(this, head, ratingscale_dropped * BOT_PICKUP_RATING_HIGH, 100000);
1126                 else if(head.team == this.team)
1127                         navigation_routerating(this, head.owner, ratingscale_team * BOT_PICKUP_RATING_HIGH, 100000);
1128                 else
1129                         navigation_routerating(this, head.owner, ratingscale_enemy * BOT_PICKUP_RATING_HIGH, 100000);
1130         }
1131
1132         havocbot_goalrating_items(this, 1, this.origin, 10000);
1133 }
1134
1135 void havocbot_role_kh_carrier(entity this)
1136 {
1137         if(IS_DEAD(this))
1138                 return;
1139
1140         if (!(this.kh_next))
1141         {
1142                 LOG_TRACE("changing role to freelancer");
1143                 this.havocbot_role = havocbot_role_kh_freelancer;
1144                 this.havocbot_role_timeout = 0;
1145                 return;
1146         }
1147
1148         if (this.bot_strategytime < time)
1149         {
1150                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1151                 navigation_goalrating_start(this);
1152
1153                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1154                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // bring home
1155                 else
1156                         havocbot_goalrating_kh(this, 4, 4, 1); // play defensively
1157
1158                 navigation_goalrating_end(this);
1159         }
1160 }
1161
1162 void havocbot_role_kh_defense(entity this)
1163 {
1164         if(IS_DEAD(this))
1165                 return;
1166
1167         if (this.kh_next)
1168         {
1169                 LOG_TRACE("changing role to carrier");
1170                 this.havocbot_role = havocbot_role_kh_carrier;
1171                 this.havocbot_role_timeout = 0;
1172                 return;
1173         }
1174
1175         if (!this.havocbot_role_timeout)
1176                 this.havocbot_role_timeout = time + random() * 10 + 20;
1177         if (time > this.havocbot_role_timeout)
1178         {
1179                 LOG_TRACE("changing role to freelancer");
1180                 this.havocbot_role = havocbot_role_kh_freelancer;
1181                 this.havocbot_role_timeout = 0;
1182                 return;
1183         }
1184
1185         if (this.bot_strategytime < time)
1186         {
1187                 float key_owner_team;
1188                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1189                 navigation_goalrating_start(this);
1190
1191                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1192                 if(key_owner_team == this.team)
1193                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend key carriers
1194                 else if(key_owner_team == -1)
1195                         havocbot_goalrating_kh(this, 4, 1, 0.1); // play defensively
1196                 else
1197                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1198
1199                 navigation_goalrating_end(this);
1200         }
1201 }
1202
1203 void havocbot_role_kh_offense(entity this)
1204 {
1205         if(IS_DEAD(this))
1206                 return;
1207
1208         if (this.kh_next)
1209         {
1210                 LOG_TRACE("changing role to carrier");
1211                 this.havocbot_role = havocbot_role_kh_carrier;
1212                 this.havocbot_role_timeout = 0;
1213                 return;
1214         }
1215
1216         if (!this.havocbot_role_timeout)
1217                 this.havocbot_role_timeout = time + random() * 10 + 20;
1218         if (time > this.havocbot_role_timeout)
1219         {
1220                 LOG_TRACE("changing role to freelancer");
1221                 this.havocbot_role = havocbot_role_kh_freelancer;
1222                 this.havocbot_role_timeout = 0;
1223                 return;
1224         }
1225
1226         if (this.bot_strategytime < time)
1227         {
1228                 float key_owner_team;
1229
1230                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1231                 navigation_goalrating_start(this);
1232
1233                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1234                 if(key_owner_team == this.team)
1235                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1236                 else if(key_owner_team == -1)
1237                         havocbot_goalrating_kh(this, 0.1, 1, 4); // play offensively
1238                 else
1239                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK! EMERGENCY!
1240
1241                 navigation_goalrating_end(this);
1242         }
1243 }
1244
1245 void havocbot_role_kh_freelancer(entity this)
1246 {
1247         if(IS_DEAD(this))
1248                 return;
1249
1250         if (this.kh_next)
1251         {
1252                 LOG_TRACE("changing role to carrier");
1253                 this.havocbot_role = havocbot_role_kh_carrier;
1254                 this.havocbot_role_timeout = 0;
1255                 return;
1256         }
1257
1258         if (!this.havocbot_role_timeout)
1259                 this.havocbot_role_timeout = time + random() * 10 + 10;
1260         if (time > this.havocbot_role_timeout)
1261         {
1262                 if (random() < 0.5)
1263                 {
1264                         LOG_TRACE("changing role to offense");
1265                         this.havocbot_role = havocbot_role_kh_offense;
1266                 }
1267                 else
1268                 {
1269                         LOG_TRACE("changing role to defense");
1270                         this.havocbot_role = havocbot_role_kh_defense;
1271                 }
1272                 this.havocbot_role_timeout = 0;
1273                 return;
1274         }
1275
1276         if (this.bot_strategytime < time)
1277         {
1278                 float key_owner_team;
1279
1280                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1281                 navigation_goalrating_start(this);
1282
1283                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1284                 if(key_owner_team == this.team)
1285                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1286                 else if(key_owner_team == -1)
1287                         havocbot_goalrating_kh(this, 1, 10, 4); // prefer dropped keys
1288                 else
1289                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1290
1291                 navigation_goalrating_end(this);
1292         }
1293 }
1294
1295
1296 // register this as a mutator
1297
1298 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1299 {
1300         entity player = M_ARGV(0, entity);
1301
1302         kh_Key_DropAll(player, true);
1303 }
1304
1305 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1306 {
1307         entity player = M_ARGV(0, entity);
1308
1309         kh_Key_DropAll(player, true);
1310 }
1311
1312 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1313 {
1314         entity frag_attacker = M_ARGV(1, entity);
1315         entity frag_target = M_ARGV(2, entity);
1316
1317         if(frag_target == frag_attacker)
1318                 kh_Key_DropAll(frag_target, true);
1319         else if(IS_PLAYER(frag_attacker))
1320                 kh_Key_DropAll(frag_target, false);
1321         else
1322                 kh_Key_DropAll(frag_target, true);
1323 }
1324
1325 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1326 {
1327         entity frag_attacker = M_ARGV(0, entity);
1328         entity frag_target = M_ARGV(1, entity);
1329         float frag_score = M_ARGV(2, float);
1330         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1331 }
1332
1333 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1334 {
1335         kh_finalize();
1336 }
1337
1338 MUTATOR_HOOKFUNCTION(kh, GetTeamCount, CBC_ORDER_EXCLUSIVE)
1339 {
1340         M_ARGV(0, float) = kh_teams;
1341 }
1342
1343 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1344 {
1345         entity spectatee = M_ARGV(0, entity);
1346         entity client = M_ARGV(1, entity);
1347
1348         client.kh_state = spectatee.kh_state;
1349 }
1350
1351 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1352 {
1353         entity player = M_ARGV(0, entity);
1354
1355         if(MUTATOR_RETURNVALUE == 0)
1356         {
1357                 entity k = player.kh_next;
1358                 if(k)
1359                 {
1360                         kh_Key_DropOne(k);
1361                         return true;
1362                 }
1363         }
1364 }
1365
1366 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1367 {
1368     entity bot = M_ARGV(0, entity);
1369
1370         if(IS_DEAD(bot))
1371                 return true;
1372
1373         float r = random() * 3;
1374         if (r < 1)
1375                 bot.havocbot_role = havocbot_role_kh_offense;
1376         else if (r < 2)
1377                 bot.havocbot_role = havocbot_role_kh_defense;
1378         else
1379                 bot.havocbot_role = havocbot_role_kh_freelancer;
1380
1381         return true;
1382 }
1383
1384 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1385 {
1386         entity frag_target = M_ARGV(0, entity);
1387
1388         kh_Key_DropAll(frag_target, false);
1389 }
1390
1391 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1392 {
1393         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
1394 }
1395
1396 #endif