qcsrc/server/mutators/mutator/gamemode_keyhunt.qc

   1 #include "gamemode_keyhunt.qh"
   2
   3 float autocvar_g_balance_keyhunt_damageforcescale;
   4 float autocvar_g_balance_keyhunt_delay_collect;
   5 float autocvar_g_balance_keyhunt_delay_return;
   6 float autocvar_g_balance_keyhunt_delay_round;
   7 float autocvar_g_balance_keyhunt_delay_tracking;
   8 float autocvar_g_balance_keyhunt_dropvelocity;
   9 float autocvar_g_balance_keyhunt_maxdist;
  10 float autocvar_g_balance_keyhunt_protecttime;
  11
  12 int autocvar_g_balance_keyhunt_score_capture;
  13 int autocvar_g_balance_keyhunt_score_carrierfrag;
  14 int autocvar_g_balance_keyhunt_score_collect;
  15 int autocvar_g_balance_keyhunt_score_destroyed;
  16 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  17 int autocvar_g_balance_keyhunt_score_push;
  18 float autocvar_g_balance_keyhunt_throwvelocity;
  19
  20 int autocvar_g_keyhunt_teams;
  21 int autocvar_g_keyhunt_teams_override;
  22
  23 // #define KH_PLAYER_USE_ATTACHMENT
  24 // #define KH_PLAYER_USE_CARRIEDMODEL
  25
  26 #ifdef KH_PLAYER_USE_ATTACHMENT
  27 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  28 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  29 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  30 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  31 const string KH_PLAYER_ATTACHMENT_BONE = "";
  32 #else
  33 const float KH_KEY_ZSHIFT = 22;
  34 const float KH_KEY_XYDIST = 24;
  35 const float KH_KEY_XYSPEED = 45;
  36 #endif
  37 const float KH_KEY_WP_ZSHIFT = 20;
  38
  39 const vector KH_KEY_MIN = '-10 -10 -46';
  40 const vector KH_KEY_MAX = '10 10 3';
  41 const float KH_KEY_BRIGHTNESS = 2;
  42
  43 float kh_no_radar_circles;
  44
  45 // kh_state
  46 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  47 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  48 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  49 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  50 .float kh_state = _STAT(KH_KEYS);
  51 .float siren_time;  //  time delay the siren
  52 //.float stuff_time;  //  time delay to stuffcmd a cvar
  53
  54 float kh_keystatus[17];
  55 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
  56 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  57 //for(i = 0; i < maxplayers; ++i)
  58 //      kh_keystatus[i] = "0";
  59
  60 float kh_Team_ByID(float t)
  61 {
  62         if(t == 0) return NUM_TEAM_1;
  63         if(t == 1) return NUM_TEAM_2;
  64         if(t == 2) return NUM_TEAM_3;
  65         if(t == 3) return NUM_TEAM_4;
  66         return 0;
  67 }
  68
  69 //entity kh_worldkeylist;
  70 .entity kh_worldkeynext;
  71 entity kh_controller;
  72 //float kh_tracking_enabled;
  73 float kh_teams;
  74 float kh_interferemsg_time, kh_interferemsg_team;
  75 .entity kh_next, kh_prev; // linked list
  76 .float kh_droptime;
  77 .float kh_dropperteam;
  78 .entity kh_previous_owner;
  79 .float kh_previous_owner_playerid;
  80 .float kh_cp_duration;
  81
  82 float kh_key_dropped, kh_key_carried;
  83
  84 const float ST_KH_CAPS = 1;
  85 void kh_ScoreRules(int teams)
  86 {
  87         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, true);
  88         ScoreInfo_SetLabel_TeamScore(  ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  89         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  90         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSHES,    "pushes",    0);
  91         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYS,  "destroyed", SFL_LOWER_IS_BETTER);
  92         ScoreInfo_SetLabel_PlayerScore(SP_KH_PICKUPS,   "pickups",   0);
  93         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCKILLS,   "kckills",   0);
  94         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSSES,    "losses",    SFL_LOWER_IS_BETTER);
  95         ScoreRules_basics_end();
  96 }
  97
  98 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
  99 {
 100         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
 101                 if(!kh_tracking_enabled)
 102                         return false;
 103
 104         return true;
 105 }
 106
 107 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 108 {
 109         if(!kh_tracking_enabled)
 110                 return false;
 111         if(!this.owner)
 112                 return true;
 113         if(!this.owner.owner)
 114                 return true;
 115         return false;  // draw only when key is not owned
 116 }
 117
 118 void kh_update_state()
 119 {
 120         entity key;
 121         float s;
 122         float f;
 123
 124         s = 0;
 125         FOR_EACH_KH_KEY(key)
 126         {
 127                 if(key.owner)
 128                         f = key.team;
 129                 else
 130                         f = 30;
 131                 s |= pow(32, key.count) * f;
 132         }
 133
 134         FOREACH_CLIENT(true, LAMBDA(it.kh_state = s));
 135
 136         FOR_EACH_KH_KEY(key)
 137         {
 138                 if(key.owner)
 139                         key.owner.kh_state |= pow(32, key.count) * 31;
 140         }
 141         //print(ftos((nextent(NULL)).kh_state), "\n");
 142 }
 143
 144
 145
 146
 147 var kh_Think_t kh_Controller_Thinkfunc;
 148 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 149 {
 150         kh_Controller_Thinkfunc = func;
 151         kh_controller.cnt = ceil(t);
 152         if(t == 0)
 153                 kh_controller.nextthink = time; // force
 154 }
 155 void kh_WaitForPlayers();
 156 void kh_Controller_Think(entity this)  // called a lot
 157 {
 158         if(intermission_running)
 159                 return;
 160         if(this.cnt > 0)
 161         { if(getthink(this) != kh_WaitForPlayers) { this.cnt -= 1; } }
 162         else if(this.cnt == 0)
 163         {
 164                 this.cnt -= 1;
 165                 kh_Controller_Thinkfunc();
 166         }
 167         this.nextthink = time + 1;
 168 }
 169
 170 // frags f: take from cvar * f
 171 // frags 0: no frags
 172 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 173 {
 174         string s;
 175         if(intermission_running)
 176                 return;
 177
 178         if(frags_player)
 179                 UpdateFrags(player, frags_player);
 180
 181         if(key && key.owner && frags_owner)
 182                 UpdateFrags(key.owner, frags_owner);
 183
 184         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 185                 return;
 186
 187         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 188
 189         if(key && key.owner)
 190                 s = strcat(s, ":", ftos(key.owner.playerid));
 191         else
 192                 s = strcat(s, ":0");
 193
 194         s = strcat(s, ":", ftos(frags_owner), ":");
 195
 196         if(key)
 197                 s = strcat(s, key.netname);
 198
 199         GameLogEcho(s);
 200 }
 201
 202 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 203 {
 204         if(e.tag_entity)
 205         {
 206                 makevectors(e.tag_entity.angles);
 207                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 208         }
 209         else
 210                 return e.origin;
 211 }
 212
 213 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 214 {
 215 #ifdef KH_PLAYER_USE_ATTACHMENT
 216         entity first;
 217         first = key.owner.kh_next;
 218         if(key == first)
 219         {
 220                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 221                 if(key.kh_next)
 222                 {
 223                         setattachment(key.kh_next, key, "");
 224                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 225                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 226                         key.kh_next.angles = '0 0 0';
 227                 }
 228                 else
 229                         setorigin(key, KH_PLAYER_ATTACHMENT);
 230                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 231         }
 232         else
 233         {
 234                 setattachment(key, key.kh_prev, "");
 235                 if(key.kh_next)
 236                         setattachment(key.kh_next, key, "");
 237                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 238                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 239                 key.angles = '0 0 0';
 240         }
 241 #else
 242         setattachment(key, key.owner, "");
 243         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 244         key.angles_y -= key.owner.angles.y;
 245 #endif
 246         key.flags = 0;
 247         IL_REMOVE(g_items, key);
 248         key.solid = SOLID_NOT;
 249         set_movetype(key, MOVETYPE_NONE);
 250         key.team = key.owner.team;
 251         key.nextthink = time;
 252         key.damageforcescale = 0;
 253         key.takedamage = DAMAGE_NO;
 254         key.modelindex = kh_key_carried;
 255 }
 256
 257 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 258 {
 259 #ifdef KH_PLAYER_USE_ATTACHMENT
 260         entity first;
 261         first = key.owner.kh_next;
 262         if(key == first)
 263         {
 264                 if(key.kh_next)
 265                 {
 266                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 267                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 268                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 269                 }
 270         }
 271         else
 272         {
 273                 if(key.kh_next)
 274                         setattachment(key.kh_next, key.kh_prev, "");
 275                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 276         }
 277         // in any case:
 278         setattachment(key, NULL, "");
 279         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, NULL).z - KH_KEY_MIN_z));
 280         key.angles = key.owner.angles;
 281 #else
 282         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 283         setattachment(key, NULL, "");
 284         key.angles_y += key.owner.angles.y;
 285 #endif
 286         key.flags = FL_ITEM;
 287         IL_PUSH(g_items, key);
 288         key.solid = SOLID_TRIGGER;
 289         set_movetype(key, MOVETYPE_TOSS);
 290         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 291         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 292         key.takedamage = DAMAGE_YES;
 293         // let key.team stay
 294         key.modelindex = kh_key_dropped;
 295         key.kh_previous_owner = key.owner;
 296         key.kh_previous_owner_playerid = key.owner.playerid;
 297 }
 298
 299 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 300 {
 301         entity k;
 302         float ownerteam0, ownerteam;
 303         if(key.owner == player)
 304                 return;
 305
 306         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 307
 308         if(key.owner)
 309         {
 310                 kh_Key_Detach(key);
 311
 312                 // remove from linked list
 313                 if(key.kh_next)
 314                         key.kh_next.kh_prev = key.kh_prev;
 315                 key.kh_prev.kh_next = key.kh_next;
 316                 key.kh_next = NULL;
 317                 key.kh_prev = NULL;
 318
 319                 if(key.owner.kh_next == NULL)
 320                 {
 321                         // No longer a key carrier
 322                         if(!kh_no_radar_circles)
 323                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 324                         WaypointSprite_DetachCarrier(key.owner);
 325                 }
 326         }
 327
 328         key.owner = player;
 329
 330         if(player)
 331         {
 332                 // insert into linked list
 333                 key.kh_next = player.kh_next;
 334                 key.kh_prev = player;
 335                 player.kh_next = key;
 336                 if(key.kh_next)
 337                         key.kh_next.kh_prev = key;
 338
 339                 float i;
 340                 i = kh_keystatus[key.owner.playerid];
 341                         if(key.netname == "^1red key")
 342                                 i += 1;
 343                         if(key.netname == "^4blue key")
 344                                 i += 2;
 345                         if(key.netname == "^3yellow key")
 346                                 i += 4;
 347                         if(key.netname == "^6pink key")
 348                                 i += 8;
 349                 kh_keystatus[key.owner.playerid] = i;
 350
 351                 kh_Key_Attach(key);
 352
 353                 if(key.kh_next == NULL)
 354                 {
 355                         // player is now a key carrier
 356                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 357                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 358                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 359                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 360                         if(player.team == NUM_TEAM_1)
 361                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 362                         else if(player.team == NUM_TEAM_2)
 363                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 364                         else if(player.team == NUM_TEAM_3)
 365                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 366                         else if(player.team == NUM_TEAM_4)
 367                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 368                         if(!kh_no_radar_circles)
 369                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 370                 }
 371         }
 372
 373         // moved that here, also update if there's no player
 374         kh_update_state();
 375
 376         key.pusher = NULL;
 377
 378         ownerteam = kh_Key_AllOwnedByWhichTeam();
 379         if(ownerteam != ownerteam0)
 380         {
 381                 if(ownerteam != -1)
 382                 {
 383                         kh_interferemsg_time = time + 0.2;
 384                         kh_interferemsg_team = player.team;
 385
 386                         // audit all key carrier sprites, update them to RUN HERE
 387                         FOR_EACH_KH_KEY(k)
 388                         {
 389                                 if (!k.owner) continue;
 390                                 entity first = WP_Null;
 391                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 392                                 entity third = WP_Null;
 393                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 394                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 395                         }
 396                 }
 397                 else
 398                 {
 399                         kh_interferemsg_time = 0;
 400
 401                         // audit all key carrier sprites, update them to RUN HERE
 402                         FOR_EACH_KH_KEY(k)
 403                         {
 404                                 if (!k.owner) continue;
 405                                 entity first = WP_Null;
 406                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 407                                 entity third = WP_Null;
 408                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 409                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 410                         }
 411                 }
 412         }
 413 }
 414
 415 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 416 {
 417         if(this.owner)
 418                 return;
 419         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 420         {
 421                 // touching lava, or hurt trigger
 422                 // what shall we do?
 423                 // immediately return is bad
 424                 // maybe start a shorter countdown?
 425         }
 426         if(force == '0 0 0')
 427                 return;
 428         if(time > this.pushltime)
 429                 if(IS_PLAYER(attacker))
 430                         this.team = attacker.team;
 431 }
 432
 433 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 434 {
 435         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 436
 437         if(key.kh_dropperteam != player.team)
 438         {
 439                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 440                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 441         }
 442         key.kh_dropperteam = 0;
 443         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_ENT(key, INFO_KEYHUNT_PICKUP), player.netname);
 444
 445         kh_Key_AssignTo(key, player); // this also updates .kh_state
 446 }
 447
 448 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 449 {
 450         if(intermission_running)
 451                 return;
 452
 453         if(this.owner) // already carried
 454                 return;
 455
 456         if(ITEM_TOUCH_NEEDKILL())
 457         {
 458                 // touching sky, or nodrop
 459                 // what shall we do?
 460                 // immediately return is bad
 461                 // maybe start a shorter countdown?
 462         }
 463
 464         if (!IS_PLAYER(toucher))
 465                 return;
 466         if(IS_DEAD(toucher))
 467                 return;
 468         if(toucher == this.enemy)
 469                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 470                         return;  // you just dropped it!
 471         kh_Key_Collect(this, toucher);
 472 }
 473
 474 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 475 {
 476         entity o;
 477         o = key.owner;
 478         kh_Key_AssignTo(key, NULL);
 479         if(o) // it was attached
 480                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 481         else // it was dropped
 482                 WaypointSprite_DetachCarrier(key);
 483
 484         // remove key from key list
 485         if (kh_worldkeylist == key)
 486                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 487         else
 488         {
 489                 o = kh_worldkeylist;
 490                 while (o)
 491                 {
 492                         if (o.kh_worldkeynext == key)
 493                         {
 494                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 495                                 break;
 496                         }
 497                         o = o.kh_worldkeynext;
 498                 }
 499         }
 500
 501         delete(key);
 502
 503         kh_update_state();
 504 }
 505
 506 void kh_FinishRound()  // runs when a team captures the keys
 507 {
 508         // prepare next round
 509         kh_interferemsg_time = 0;
 510         entity key;
 511
 512         kh_no_radar_circles = true;
 513         FOR_EACH_KH_KEY(key)
 514                 kh_Key_Remove(key);
 515         kh_no_radar_circles = false;
 516
 517         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 518         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 519 }
 520
 521 void nades_GiveBonus(entity player, float score);
 522
 523 void kh_WinnerTeam(float teem)  // runs when a team wins // Samual: Teem?.... TEEM?!?! what the fuck is wrong with you people
 524 {
 525         // all key carriers get some points
 526         vector firstorigin, lastorigin, midpoint;
 527         float first;
 528         entity key;
 529         float score;
 530         score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 531         DistributeEvenly_Init(score, NumTeams(kh_teams));
 532         // twice the score for 3 team games, three times the score for 4 team games!
 533         // note: for a win by destroying the key, this should NOT be applied
 534         FOR_EACH_KH_KEY(key)
 535         {
 536                 float f;
 537                 f = DistributeEvenly_Get(1);
 538                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 539                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 540                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 541         }
 542
 543         first = true;
 544         string keyowner = "";
 545         FOR_EACH_KH_KEY(key)
 546                 if(key.owner.kh_next == key)
 547                 {
 548                         if(!first)
 549                                 keyowner = strcat(keyowner, ", ");
 550                         keyowner = key.owner.netname;
 551                         first = false;
 552                 }
 553
 554         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(teem, INFO_KEYHUNT_CAPTURE), keyowner);
 555
 556         first = true;
 557         midpoint = '0 0 0';
 558         firstorigin = '0 0 0';
 559         lastorigin = '0 0 0';
 560         FOR_EACH_KH_KEY(key)
 561         {
 562                 vector thisorigin;
 563
 564                 thisorigin = kh_AttachedOrigin(key);
 565                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 566                 midpoint += thisorigin;
 567
 568                 if(!first)
 569                         te_lightning2(NULL, lastorigin, thisorigin);
 570                 lastorigin = thisorigin;
 571                 if(first)
 572                         firstorigin = thisorigin;
 573                 first = false;
 574         }
 575         if(NumTeams(kh_teams) > 2)
 576         {
 577                 te_lightning2(NULL, lastorigin, firstorigin);
 578         }
 579         midpoint = midpoint * (1 / NumTeams(kh_teams));
 580         te_customflash(midpoint, 1000, 1, Team_ColorRGB(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 581
 582         play2all(SND(KH_CAPTURE));
 583         kh_FinishRound();
 584 }
 585
 586 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 587 {
 588         entity key, attacker;
 589         float players;
 590         float keys;
 591         float f;
 592
 593         attacker = NULL;
 594         if(lostkey.pusher)
 595                 if(lostkey.pusher.team != teem)
 596                         if(IS_PLAYER(lostkey.pusher))
 597                                 attacker = lostkey.pusher;
 598
 599         players = keys = 0;
 600
 601         if(attacker)
 602         {
 603                 if(lostkey.kh_previous_owner)
 604                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 605                         // don't actually GIVE him the -nn points, just log
 606                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 607                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 608                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 609         }
 610         else
 611         {
 612                 float of, fragsleft, i, j, thisteam;
 613                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 614
 615                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != teem, LAMBDA(++players));
 616
 617                 FOR_EACH_KH_KEY(key)
 618                         if(key.owner && key.team != teem)
 619                                 ++keys;
 620
 621                 if(lostkey.kh_previous_owner)
 622                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 623                         // don't actually GIVE him the -nn points, just log
 624
 625                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 626                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 627
 628                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 629
 630                 FOR_EACH_KH_KEY(key)
 631                         if(key.owner && key.team != teem)
 632                         {
 633                                 f = DistributeEvenly_Get(of);
 634                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 635                         }
 636
 637                 fragsleft = DistributeEvenly_Get(players);
 638
 639                 // Now distribute these among all other teams...
 640                 j = NumTeams(kh_teams) - 1;
 641                 for(i = 0; i < NumTeams(kh_teams); ++i)
 642                 {
 643                         thisteam = kh_Team_ByID(i);
 644                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 645                                 continue;
 646
 647                         players = 0;
 648                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(++players));
 649
 650                         DistributeEvenly_Init(fragsleft, j);
 651                         fragsleft = DistributeEvenly_Get(j - 1);
 652                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 653
 654                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(
 655                                 f = DistributeEvenly_Get(1);
 656                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 657                         ));
 658
 659                         --j;
 660                 }
 661         }
 662
 663         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_ENT(lostkey, INFO_KEYHUNT_LOST), lostkey.kh_previous_owner.netname);
 664
 665         play2all(SND(KH_DESTROY));
 666         te_tarexplosion(lostkey.origin);
 667
 668         kh_FinishRound();
 669 }
 670
 671 void kh_Key_Think(entity this)  // runs all the time
 672 {
 673         if(intermission_running)
 674                 return;
 675
 676         if(this.owner)
 677         {
 678 #ifndef KH_PLAYER_USE_ATTACHMENT
 679                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 680                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 681 #endif
 682         }
 683
 684         // if in nodrop or time over, end the round
 685         if(!this.owner)
 686                 if(time > this.pain_finished)
 687                         kh_LoserTeam(this.team, this);
 688
 689         if(this.owner)
 690         if(kh_Key_AllOwnedByWhichTeam() != -1)
 691         {
 692                 if(this.siren_time < time)
 693                 {
 694                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 695                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 696                 }
 697
 698                 entity key;
 699                 vector p;
 700                 p = this.owner.origin;
 701                 FOR_EACH_KH_KEY(key)
 702                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 703                                 goto not_winning;
 704                 kh_WinnerTeam(this.team);
 705 LABEL(not_winning)
 706         }
 707
 708         if(kh_interferemsg_time && time > kh_interferemsg_time)
 709         {
 710                 kh_interferemsg_time = 0;
 711                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 712                         if(it.team == kh_interferemsg_team)
 713                                 if(it.kh_next)
 714                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 715                                 else
 716                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 717                         else
 718                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 719                 ));
 720         }
 721
 722         this.nextthink = time + 0.05;
 723 }
 724
 725 void key_reset(entity this)
 726 {
 727         kh_Key_AssignTo(this, NULL);
 728         kh_Key_Remove(this);
 729 }
 730
 731 const string STR_ITEM_KH_KEY = "item_kh_key";
 732 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 733 {
 734         entity key = spawn();
 735         key.count = i;
 736         key.classname = STR_ITEM_KH_KEY;
 737         settouch(key, kh_Key_Touch);
 738         setthink(key, kh_Key_Think);
 739         key.nextthink = time;
 740         key.items = IT_KEY1 | IT_KEY2;
 741         key.cnt = _angle;
 742         key.angles = '0 360 0' * random();
 743         key.event_damage = kh_Key_Damage;
 744         key.takedamage = DAMAGE_YES;
 745         key.modelindex = kh_key_dropped;
 746         key.model = "key";
 747         key.kh_dropperteam = 0;
 748         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 749         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 750         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 751         key.reset = key_reset;
 752
 753         switch(initial_owner.team)
 754         {
 755                 case NUM_TEAM_1:
 756                         key.netname = "^1red key";
 757                         break;
 758                 case NUM_TEAM_2:
 759                         key.netname = "^4blue key";
 760                         break;
 761                 case NUM_TEAM_3:
 762                         key.netname = "^3yellow key";
 763                         break;
 764                 case NUM_TEAM_4:
 765                         key.netname = "^6pink key";
 766                         break;
 767                 default:
 768                         key.netname = "NETGIER key";
 769                         break;
 770         }
 771
 772         // link into key list
 773         key.kh_worldkeynext = kh_worldkeylist;
 774         kh_worldkeylist = key;
 775
 776         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 777
 778         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 779         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 780
 781         kh_Key_AssignTo(key, initial_owner);
 782 }
 783
 784 // -1 when no team completely owns all keys yet
 785 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 786 {
 787         entity key;
 788         float teem;
 789         float keys;
 790
 791         teem = -1;
 792         keys = NumTeams(kh_teams);
 793         FOR_EACH_KH_KEY(key)
 794         {
 795                 if(!key.owner)
 796                         return -1;
 797                 if(teem == -1)
 798                         teem = key.team;
 799                 else if(teem != key.team)
 800                         return -1;
 801                 --keys;
 802         }
 803         if(keys != 0)
 804                 return -1;
 805         return teem;
 806 }
 807
 808 void kh_Key_DropOne(entity key)
 809 {
 810         // prevent collecting this one for some time
 811         entity player;
 812         player = key.owner;
 813
 814         key.kh_droptime = time;
 815         key.enemy = player;
 816
 817         kh_Scores_Event(player, key, "dropkey", 0, 0);
 818         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 819         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_ENT(key, INFO_KEYHUNT_DROP), player.netname);
 820
 821         kh_Key_AssignTo(key, NULL);
 822         makevectors(player.v_angle);
 823         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 824         key.pusher = NULL;
 825         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 826         key.kh_dropperteam = key.team;
 827
 828         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 829 }
 830
 831 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 832 {
 833         entity key;
 834         entity mypusher;
 835         if(player.kh_next)
 836         {
 837                 mypusher = NULL;
 838                 if(player.pusher)
 839                         if(time < player.pushltime)
 840                                 mypusher = player.pusher;
 841                 while((key = player.kh_next))
 842                 {
 843                         kh_Scores_Event(player, key, "losekey", 0, 0);
 844                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 845                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_ENT(key, INFO_KEYHUNT_LOST), player.netname);
 846                         kh_Key_AssignTo(key, NULL);
 847                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 848                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 849                         key.pusher = mypusher;
 850                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 851                         if(suicide)
 852                                 key.kh_dropperteam = player.team;
 853                 }
 854                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 855         }
 856 }
 857
 858 float kh_CheckPlayers(float num)
 859 {
 860         if(num < NumTeams(kh_teams))
 861         {
 862                 float t_team = kh_Team_ByID(num);
 863                 float players = 0;
 864                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 865                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == t_team)
 866                                 ++players;
 867                 ));
 868
 869                 if (!players) { return t_team; }
 870         }
 871         return 0;
 872 }
 873
 874 #define KH_READY_TEAMS() (!p1 + !p2 + ((NumTeams(kh_teams) >= 3) ? !p3 : p3) + ((NumTeams(kh_teams) >= 4) ? !p4 : p4))
 875 #define KH_READY_TEAMS_OK() (KH_READY_TEAMS() == NumTeams(kh_teams))
 876 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 877 {
 878         if(time < game_starttime)
 879         {
 880                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 881                 return;
 882         }
 883
 884         static float prev_missing_teams_mask;
 885         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 886         if(KH_READY_TEAMS_OK())
 887         {
 888                 if(prev_missing_teams_mask > 0)
 889                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 890                 prev_missing_teams_mask = -1;
 891                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 892                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 893         }
 894         else
 895         {
 896                 if(player_count == 0)
 897                 {
 898                         if(prev_missing_teams_mask > 0)
 899                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 900                         prev_missing_teams_mask = -1;
 901                 }
 902                 else
 903                 {
 904                         int missing_teams_mask = 0;
 905                         if(kh_teams & BIT(0))
 906                                 missing_teams_mask += boolean(p1) * 1;
 907                         if(kh_teams & BIT(1))
 908                                 missing_teams_mask += boolean(p2) * 2;
 909                         if(kh_teams & BIT(2))
 910                                 missing_teams_mask += boolean(p3) * 4;
 911                         if(kh_teams & BIT(3))
 912                                 missing_teams_mask += boolean(p4) * 8;
 913                         if(prev_missing_teams_mask != missing_teams_mask)
 914                         {
 915                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 916                                 prev_missing_teams_mask = missing_teams_mask;
 917                         }
 918                 }
 919                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 920         }
 921 }
 922
 923 void kh_EnableTrackingDevice()  // runs after each round
 924 {
 925         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 926         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 927
 928         kh_tracking_enabled = true;
 929 }
 930
 931 void kh_StartRound()  // runs at the start of each round
 932 {
 933         float i, players, teem;
 934
 935         if(time < game_starttime)
 936         {
 937                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 938                 return;
 939         }
 940
 941         float p1 = kh_CheckPlayers(0), p2 = kh_CheckPlayers(1), p3 = kh_CheckPlayers(2), p4 = kh_CheckPlayers(3);
 942         if(!KH_READY_TEAMS_OK())
 943         {
 944                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 945                 return;
 946         }
 947
 948         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 949         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 950
 951         for(i = 0; i < NumTeams(kh_teams); ++i)
 952         {
 953                 teem = kh_Team_ByID(i);
 954                 players = 0;
 955                 entity my_player = NULL;
 956                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 957                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 958                         {
 959                                 ++players;
 960                                 if(random() * players <= 1)
 961                                         my_player = it;
 962                         }
 963                 ));
 964                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 965         }
 966
 967         kh_tracking_enabled = false;
 968         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 969         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 970 }
 971
 972 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 973 {
 974         if(attacker == targ)
 975                 return f;
 976
 977         if(targ.kh_next)
 978         {
 979                 if(attacker.team == targ.team)
 980                 {
 981                         entity k;
 982                         float nk;
 983                         nk = 0;
 984                         for(k = targ.kh_next; k != NULL; k = k.kh_next)
 985                                 ++nk;
 986                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 987                 }
 988                 else
 989                 {
 990                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 991                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 992                         // the frag gets added later
 993                 }
 994         }
 995
 996         return f;
 997 }
 998
 999 void kh_Initialize()  // sets up th KH environment
1000 {
1001         // setup variables
1002         kh_teams = autocvar_g_keyhunt_teams_override;
1003         if(kh_teams < 2)
1004                 kh_teams = autocvar_g_keyhunt_teams;
1005         kh_teams = bound(2, kh_teams, 4);
1006
1007         int teams = 0;
1008         if(kh_teams >= 1) teams |= BIT(0);
1009         if(kh_teams >= 2) teams |= BIT(1);
1010         if(kh_teams >= 3) teams |= BIT(2);
1011         if(kh_teams >= 4) teams |= BIT(3);
1012
1013         kh_teams = teams; // now set it?
1014
1015         // make a KH entity for controlling the game
1016         kh_controller = spawn();
1017         setthink(kh_controller, kh_Controller_Think);
1018         kh_Controller_SetThink(0, kh_WaitForPlayers);
1019
1020         setmodel(kh_controller, MDL_KH_KEY);
1021         kh_key_dropped = kh_controller.modelindex;
1022         /*
1023         dprint(vtos(kh_controller.mins));
1024         dprint(vtos(kh_controller.maxs));
1025         dprint("\n");
1026         */
1027 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1028         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
1029         kh_key_carried = kh_controller.modelindex;
1030 #else
1031         kh_key_carried = kh_key_dropped;
1032 #endif
1033
1034         kh_controller.model = "";
1035         kh_controller.modelindex = 0;
1036
1037         kh_ScoreRules(kh_teams);
1038 }
1039
1040 void kh_finalize()
1041 {
1042         // to be called before intermission
1043         kh_FinishRound();
1044         delete(kh_controller);
1045         kh_controller = NULL;
1046 }
1047
1048 // legacy bot role
1049
1050 void(entity this) havocbot_role_kh_carrier;
1051 void(entity this) havocbot_role_kh_defense;
1052 void(entity this) havocbot_role_kh_offense;
1053 void(entity this) havocbot_role_kh_freelancer;
1054
1055
1056 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1057 {
1058         entity head;
1059         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1060         {
1061                 if(head.owner == this)
1062                         continue;
1063                 if(!kh_tracking_enabled)
1064                 {
1065                         // if it's carried by our team we know about it
1066                         // otherwise we have to see it to know about it
1067                         if(!head.owner || head.team != this.team)
1068                         {
1069                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1070                                 if (trace_fraction < 1 && trace_ent != head)
1071                                         continue; // skip what I can't see
1072                         }
1073                 }
1074                 if(!head.owner)
1075                         navigation_routerating(this, head, ratingscale_dropped * BOT_PICKUP_RATING_HIGH, 100000);
1076                 else if(head.team == this.team)
1077                         navigation_routerating(this, head.owner, ratingscale_team * BOT_PICKUP_RATING_HIGH, 100000);
1078                 else
1079                         navigation_routerating(this, head.owner, ratingscale_enemy * BOT_PICKUP_RATING_HIGH, 100000);
1080         }
1081
1082         havocbot_goalrating_items(this, 1, this.origin, 10000);
1083 }
1084
1085 void havocbot_role_kh_carrier(entity this)
1086 {
1087         if(IS_DEAD(this))
1088                 return;
1089
1090         if (!(this.kh_next))
1091         {
1092                 LOG_TRACE("changing role to freelancer");
1093                 this.havocbot_role = havocbot_role_kh_freelancer;
1094                 this.havocbot_role_timeout = 0;
1095                 return;
1096         }
1097
1098         if (this.bot_strategytime < time)
1099         {
1100                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1101                 navigation_goalrating_start(this);
1102
1103                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1104                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // bring home
1105                 else
1106                         havocbot_goalrating_kh(this, 4, 4, 1); // play defensively
1107
1108                 navigation_goalrating_end(this);
1109         }
1110 }
1111
1112 void havocbot_role_kh_defense(entity this)
1113 {
1114         if(IS_DEAD(this))
1115                 return;
1116
1117         if (this.kh_next)
1118         {
1119                 LOG_TRACE("changing role to carrier");
1120                 this.havocbot_role = havocbot_role_kh_carrier;
1121                 this.havocbot_role_timeout = 0;
1122                 return;
1123         }
1124
1125         if (!this.havocbot_role_timeout)
1126                 this.havocbot_role_timeout = time + random() * 10 + 20;
1127         if (time > this.havocbot_role_timeout)
1128         {
1129                 LOG_TRACE("changing role to freelancer");
1130                 this.havocbot_role = havocbot_role_kh_freelancer;
1131                 this.havocbot_role_timeout = 0;
1132                 return;
1133         }
1134
1135         if (this.bot_strategytime < time)
1136         {
1137                 float key_owner_team;
1138                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1139                 navigation_goalrating_start(this);
1140
1141                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1142                 if(key_owner_team == this.team)
1143                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend key carriers
1144                 else if(key_owner_team == -1)
1145                         havocbot_goalrating_kh(this, 4, 1, 0.1); // play defensively
1146                 else
1147                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1148
1149                 navigation_goalrating_end(this);
1150         }
1151 }
1152
1153 void havocbot_role_kh_offense(entity this)
1154 {
1155         if(IS_DEAD(this))
1156                 return;
1157
1158         if (this.kh_next)
1159         {
1160                 LOG_TRACE("changing role to carrier");
1161                 this.havocbot_role = havocbot_role_kh_carrier;
1162                 this.havocbot_role_timeout = 0;
1163                 return;
1164         }
1165
1166         if (!this.havocbot_role_timeout)
1167                 this.havocbot_role_timeout = time + random() * 10 + 20;
1168         if (time > this.havocbot_role_timeout)
1169         {
1170                 LOG_TRACE("changing role to freelancer");
1171                 this.havocbot_role = havocbot_role_kh_freelancer;
1172                 this.havocbot_role_timeout = 0;
1173                 return;
1174         }
1175
1176         if (this.bot_strategytime < time)
1177         {
1178                 float key_owner_team;
1179
1180                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1181                 navigation_goalrating_start(this);
1182
1183                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1184                 if(key_owner_team == this.team)
1185                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1186                 else if(key_owner_team == -1)
1187                         havocbot_goalrating_kh(this, 0.1, 1, 4); // play offensively
1188                 else
1189                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK! EMERGENCY!
1190
1191                 navigation_goalrating_end(this);
1192         }
1193 }
1194
1195 void havocbot_role_kh_freelancer(entity this)
1196 {
1197         if(IS_DEAD(this))
1198                 return;
1199
1200         if (this.kh_next)
1201         {
1202                 LOG_TRACE("changing role to carrier");
1203                 this.havocbot_role = havocbot_role_kh_carrier;
1204                 this.havocbot_role_timeout = 0;
1205                 return;
1206         }
1207
1208         if (!this.havocbot_role_timeout)
1209                 this.havocbot_role_timeout = time + random() * 10 + 10;
1210         if (time > this.havocbot_role_timeout)
1211         {
1212                 if (random() < 0.5)
1213                 {
1214                         LOG_TRACE("changing role to offense");
1215                         this.havocbot_role = havocbot_role_kh_offense;
1216                 }
1217                 else
1218                 {
1219                         LOG_TRACE("changing role to defense");
1220                         this.havocbot_role = havocbot_role_kh_defense;
1221                 }
1222                 this.havocbot_role_timeout = 0;
1223                 return;
1224         }
1225
1226         if (this.bot_strategytime < time)
1227         {
1228                 float key_owner_team;
1229
1230                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1231                 navigation_goalrating_start(this);
1232
1233                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1234                 if(key_owner_team == this.team)
1235                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1236                 else if(key_owner_team == -1)
1237                         havocbot_goalrating_kh(this, 1, 10, 4); // prefer dropped keys
1238                 else
1239                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1240
1241                 navigation_goalrating_end(this);
1242         }
1243 }
1244
1245
1246 // register this as a mutator
1247
1248 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1249 {
1250         entity player = M_ARGV(0, entity);
1251
1252         kh_Key_DropAll(player, true);
1253 }
1254
1255 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1256 {
1257         entity player = M_ARGV(0, entity);
1258
1259         kh_Key_DropAll(player, true);
1260 }
1261
1262 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1263 {
1264         entity frag_attacker = M_ARGV(1, entity);
1265         entity frag_target = M_ARGV(2, entity);
1266
1267         if(frag_target == frag_attacker)
1268                 kh_Key_DropAll(frag_target, true);
1269         else if(IS_PLAYER(frag_attacker))
1270                 kh_Key_DropAll(frag_target, false);
1271         else
1272                 kh_Key_DropAll(frag_target, true);
1273 }
1274
1275 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1276 {
1277         entity frag_attacker = M_ARGV(0, entity);
1278         entity frag_target = M_ARGV(1, entity);
1279         float frag_score = M_ARGV(2, float);
1280         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1281 }
1282
1283 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1284 {
1285         kh_finalize();
1286 }
1287
1288 MUTATOR_HOOKFUNCTION(kh, GetTeamCount, CBC_ORDER_EXCLUSIVE)
1289 {
1290         M_ARGV(0, float) = kh_teams;
1291 }
1292
1293 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1294 {
1295         entity spectatee = M_ARGV(0, entity);
1296         entity client = M_ARGV(1, entity);
1297
1298         client.kh_state = spectatee.kh_state;
1299 }
1300
1301 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1302 {
1303         entity player = M_ARGV(0, entity);
1304
1305         if(MUTATOR_RETURNVALUE == 0)
1306         {
1307                 entity k = player.kh_next;
1308                 if(k)
1309                 {
1310                         kh_Key_DropOne(k);
1311                         return true;
1312                 }
1313         }
1314 }
1315
1316 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1317 {
1318     entity bot = M_ARGV(0, entity);
1319
1320         if(IS_DEAD(bot))
1321                 return true;
1322
1323         float r = random() * 3;
1324         if (r < 1)
1325                 bot.havocbot_role = havocbot_role_kh_offense;
1326         else if (r < 2)
1327                 bot.havocbot_role = havocbot_role_kh_defense;
1328         else
1329                 bot.havocbot_role = havocbot_role_kh_freelancer;
1330
1331         return true;
1332 }
1333
1334 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1335 {
1336         entity frag_target = M_ARGV(0, entity);
1337
1338         kh_Key_DropAll(frag_target, false);
1339 }
1340
1341 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1342 {
1343         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
1344 }