qcsrc/server/mutators/mutator/gamemode_keyhunt.qc

   1 #include "gamemode_keyhunt.qh"
   2
   3 float autocvar_g_balance_keyhunt_damageforcescale;
   4 float autocvar_g_balance_keyhunt_delay_collect;
   5 float autocvar_g_balance_keyhunt_delay_return;
   6 float autocvar_g_balance_keyhunt_delay_round;
   7 float autocvar_g_balance_keyhunt_delay_tracking;
   8 float autocvar_g_balance_keyhunt_dropvelocity;
   9 float autocvar_g_balance_keyhunt_maxdist;
  10 float autocvar_g_balance_keyhunt_protecttime;
  11
  12 int autocvar_g_balance_keyhunt_score_capture;
  13 int autocvar_g_balance_keyhunt_score_carrierfrag;
  14 int autocvar_g_balance_keyhunt_score_collect;
  15 int autocvar_g_balance_keyhunt_score_destroyed;
  16 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  17 int autocvar_g_balance_keyhunt_score_push;
  18 float autocvar_g_balance_keyhunt_throwvelocity;
  19
  20 int autocvar_g_keyhunt_teams;
  21 int autocvar_g_keyhunt_teams_override;
  22
  23 // #define KH_PLAYER_USE_ATTACHMENT
  24 // #define KH_PLAYER_USE_CARRIEDMODEL
  25
  26 #ifdef KH_PLAYER_USE_ATTACHMENT
  27 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  28 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  29 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  30 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  31 const string KH_PLAYER_ATTACHMENT_BONE = "";
  32 #else
  33 const float KH_KEY_ZSHIFT = 22;
  34 const float KH_KEY_XYDIST = 24;
  35 const float KH_KEY_XYSPEED = 45;
  36 #endif
  37 const float KH_KEY_WP_ZSHIFT = 20;
  38
  39 const vector KH_KEY_MIN = '-10 -10 -46';
  40 const vector KH_KEY_MAX = '10 10 3';
  41 const float KH_KEY_BRIGHTNESS = 2;
  42
  43 bool kh_no_radar_circles;
  44
  45 // kh_state
  46 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  47 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  48 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  49 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  50 .float kh_state = _STAT(KH_KEYS);
  51 .float siren_time;  //  time delay the siren
  52 //.float stuff_time;  //  time delay to stuffcmd a cvar
  53
  54 float kh_keystatus[17];
  55 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
  56 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  57 //for(i = 0; i < maxplayers; ++i)
  58 //      kh_keystatus[i] = "0";
  59
  60 float kh_Team_ByID(float t)
  61 {
  62         if(t == 0) return NUM_TEAM_1;
  63         if(t == 1) return NUM_TEAM_2;
  64         if(t == 2) return NUM_TEAM_3;
  65         if(t == 3) return NUM_TEAM_4;
  66         return 0;
  67 }
  68
  69 //entity kh_worldkeylist;
  70 .entity kh_worldkeynext;
  71 entity kh_controller;
  72 //float kh_tracking_enabled;
  73 float kh_teams;
  74 float kh_interferemsg_time, kh_interferemsg_team;
  75 .entity kh_next, kh_prev; // linked list
  76 .float kh_droptime;
  77 .float kh_dropperteam;
  78 .entity kh_previous_owner;
  79 .float kh_previous_owner_playerid;
  80
  81 float kh_key_dropped, kh_key_carried;
  82
  83 int kh_Key_AllOwnedByWhichTeam();
  84
  85 const float ST_KH_CAPS = 1;
  86 void kh_ScoreRules(int teams)
  87 {
  88         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, true);
  89         ScoreInfo_SetLabel_TeamScore(  ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  90         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  91         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSHES,    "pushes",    0);
  92         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYS,  "destroyed", SFL_LOWER_IS_BETTER);
  93         ScoreInfo_SetLabel_PlayerScore(SP_KH_PICKUPS,   "pickups",   0);
  94         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCKILLS,   "kckills",   0);
  95         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSSES,    "losses",    SFL_LOWER_IS_BETTER);
  96         ScoreRules_basics_end();
  97 }
  98
  99 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
 100 {
 101         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
 102                 if(!kh_tracking_enabled)
 103                         return false;
 104
 105         return true;
 106 }
 107
 108 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 109 {
 110         if(!kh_tracking_enabled)
 111                 return false;
 112         if(!this.owner)
 113                 return true;
 114         if(!this.owner.owner)
 115                 return true;
 116         return false;  // draw only when key is not owned
 117 }
 118
 119 void kh_update_state()
 120 {
 121         entity key;
 122         float s;
 123         float f;
 124
 125         s = 0;
 126         FOR_EACH_KH_KEY(key)
 127         {
 128                 if(key.owner)
 129                         f = key.team;
 130                 else
 131                         f = 30;
 132                 s |= pow(32, key.count) * f;
 133         }
 134
 135         FOREACH_CLIENT(true, LAMBDA(it.kh_state = s));
 136
 137         FOR_EACH_KH_KEY(key)
 138         {
 139                 if(key.owner)
 140                         key.owner.kh_state |= pow(32, key.count) * 31;
 141         }
 142         //print(ftos((nextent(NULL)).kh_state), "\n");
 143 }
 144
 145
 146
 147
 148 var kh_Think_t kh_Controller_Thinkfunc;
 149 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 150 {
 151         kh_Controller_Thinkfunc = func;
 152         kh_controller.cnt = ceil(t);
 153         if(t == 0)
 154                 kh_controller.nextthink = time; // force
 155 }
 156 void kh_WaitForPlayers();
 157 void kh_Controller_Think(entity this)  // called a lot
 158 {
 159         if(intermission_running)
 160                 return;
 161         if(this.cnt > 0)
 162         { if(getthink(this) != kh_WaitForPlayers) { this.cnt -= 1; } }
 163         else if(this.cnt == 0)
 164         {
 165                 this.cnt -= 1;
 166                 kh_Controller_Thinkfunc();
 167         }
 168         this.nextthink = time + 1;
 169 }
 170
 171 // frags f: take from cvar * f
 172 // frags 0: no frags
 173 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 174 {
 175         string s;
 176         if(intermission_running)
 177                 return;
 178
 179         if(frags_player)
 180                 UpdateFrags(player, frags_player);
 181
 182         if(key && key.owner && frags_owner)
 183                 UpdateFrags(key.owner, frags_owner);
 184
 185         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 186                 return;
 187
 188         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 189
 190         if(key && key.owner)
 191                 s = strcat(s, ":", ftos(key.owner.playerid));
 192         else
 193                 s = strcat(s, ":0");
 194
 195         s = strcat(s, ":", ftos(frags_owner), ":");
 196
 197         if(key)
 198                 s = strcat(s, key.netname);
 199
 200         GameLogEcho(s);
 201 }
 202
 203 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 204 {
 205         if(e.tag_entity)
 206         {
 207                 makevectors(e.tag_entity.angles);
 208                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 209         }
 210         else
 211                 return e.origin;
 212 }
 213
 214 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 215 {
 216 #ifdef KH_PLAYER_USE_ATTACHMENT
 217         entity first;
 218         first = key.owner.kh_next;
 219         if(key == first)
 220         {
 221                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 222                 if(key.kh_next)
 223                 {
 224                         setattachment(key.kh_next, key, "");
 225                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 226                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 227                         key.kh_next.angles = '0 0 0';
 228                 }
 229                 else
 230                         setorigin(key, KH_PLAYER_ATTACHMENT);
 231                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 232         }
 233         else
 234         {
 235                 setattachment(key, key.kh_prev, "");
 236                 if(key.kh_next)
 237                         setattachment(key.kh_next, key, "");
 238                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 239                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 240                 key.angles = '0 0 0';
 241         }
 242 #else
 243         setattachment(key, key.owner, "");
 244         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 245         key.angles_y -= key.owner.angles.y;
 246 #endif
 247         key.flags = 0;
 248         IL_REMOVE(g_items, key);
 249         key.solid = SOLID_NOT;
 250         set_movetype(key, MOVETYPE_NONE);
 251         key.team = key.owner.team;
 252         key.nextthink = time;
 253         key.damageforcescale = 0;
 254         key.takedamage = DAMAGE_NO;
 255         key.modelindex = kh_key_carried;
 256 }
 257
 258 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 259 {
 260 #ifdef KH_PLAYER_USE_ATTACHMENT
 261         entity first;
 262         first = key.owner.kh_next;
 263         if(key == first)
 264         {
 265                 if(key.kh_next)
 266                 {
 267                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 268                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 269                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 270                 }
 271         }
 272         else
 273         {
 274                 if(key.kh_next)
 275                         setattachment(key.kh_next, key.kh_prev, "");
 276                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 277         }
 278         // in any case:
 279         setattachment(key, NULL, "");
 280         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, NULL).z - KH_KEY_MIN_z));
 281         key.angles = key.owner.angles;
 282 #else
 283         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 284         setattachment(key, NULL, "");
 285         key.angles_y += key.owner.angles.y;
 286 #endif
 287         key.flags = FL_ITEM;
 288         IL_PUSH(g_items, key);
 289         key.solid = SOLID_TRIGGER;
 290         set_movetype(key, MOVETYPE_TOSS);
 291         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 292         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 293         key.takedamage = DAMAGE_YES;
 294         // let key.team stay
 295         key.modelindex = kh_key_dropped;
 296         key.kh_previous_owner = key.owner;
 297         key.kh_previous_owner_playerid = key.owner.playerid;
 298 }
 299
 300 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 301 {
 302         entity k;
 303         float ownerteam0, ownerteam;
 304         if(key.owner == player)
 305                 return;
 306
 307         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 308
 309         if(key.owner)
 310         {
 311                 kh_Key_Detach(key);
 312
 313                 // remove from linked list
 314                 if(key.kh_next)
 315                         key.kh_next.kh_prev = key.kh_prev;
 316                 key.kh_prev.kh_next = key.kh_next;
 317                 key.kh_next = NULL;
 318                 key.kh_prev = NULL;
 319
 320                 if(key.owner.kh_next == NULL)
 321                 {
 322                         // No longer a key carrier
 323                         if(!kh_no_radar_circles)
 324                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 325                         WaypointSprite_DetachCarrier(key.owner);
 326                 }
 327         }
 328
 329         key.owner = player;
 330
 331         if(player)
 332         {
 333                 // insert into linked list
 334                 key.kh_next = player.kh_next;
 335                 key.kh_prev = player;
 336                 player.kh_next = key;
 337                 if(key.kh_next)
 338                         key.kh_next.kh_prev = key;
 339
 340                 float i;
 341                 i = kh_keystatus[key.owner.playerid];
 342                         if(key.netname == "^1red key")
 343                                 i += 1;
 344                         if(key.netname == "^4blue key")
 345                                 i += 2;
 346                         if(key.netname == "^3yellow key")
 347                                 i += 4;
 348                         if(key.netname == "^6pink key")
 349                                 i += 8;
 350                 kh_keystatus[key.owner.playerid] = i;
 351
 352                 kh_Key_Attach(key);
 353
 354                 if(key.kh_next == NULL)
 355                 {
 356                         // player is now a key carrier
 357                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 358                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 359                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 360                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 361                         if(player.team == NUM_TEAM_1)
 362                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 363                         else if(player.team == NUM_TEAM_2)
 364                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 365                         else if(player.team == NUM_TEAM_3)
 366                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 367                         else if(player.team == NUM_TEAM_4)
 368                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 369                         if(!kh_no_radar_circles)
 370                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 371                 }
 372         }
 373
 374         // moved that here, also update if there's no player
 375         kh_update_state();
 376
 377         key.pusher = NULL;
 378
 379         ownerteam = kh_Key_AllOwnedByWhichTeam();
 380         if(ownerteam != ownerteam0)
 381         {
 382                 if(ownerteam != -1)
 383                 {
 384                         kh_interferemsg_time = time + 0.2;
 385                         kh_interferemsg_team = player.team;
 386
 387                         // audit all key carrier sprites, update them to RUN HERE
 388                         FOR_EACH_KH_KEY(k)
 389                         {
 390                                 if (!k.owner) continue;
 391                                 entity first = WP_Null;
 392                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 393                                 entity third = WP_Null;
 394                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 395                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 396                         }
 397                 }
 398                 else
 399                 {
 400                         kh_interferemsg_time = 0;
 401
 402                         // audit all key carrier sprites, update them to RUN HERE
 403                         FOR_EACH_KH_KEY(k)
 404                         {
 405                                 if (!k.owner) continue;
 406                                 entity first = WP_Null;
 407                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 408                                 entity third = WP_Null;
 409                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 410                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 411                         }
 412                 }
 413         }
 414 }
 415
 416 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 417 {
 418         if(this.owner)
 419                 return;
 420         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 421         {
 422                 // touching lava, or hurt trigger
 423                 // what shall we do?
 424                 // immediately return is bad
 425                 // maybe start a shorter countdown?
 426         }
 427         if(force == '0 0 0')
 428                 return;
 429         if(time > this.pushltime)
 430                 if(IS_PLAYER(attacker))
 431                         this.team = attacker.team;
 432 }
 433
 434 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 435 {
 436         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 437
 438         if(key.kh_dropperteam != player.team)
 439         {
 440                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 441                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 442         }
 443         key.kh_dropperteam = 0;
 444         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(key.team, INFO_KEYHUNT_PICKUP), player.netname);
 445
 446         kh_Key_AssignTo(key, player); // this also updates .kh_state
 447 }
 448
 449 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 450 {
 451         if(intermission_running)
 452                 return;
 453
 454         if(this.owner) // already carried
 455                 return;
 456
 457         if(ITEM_TOUCH_NEEDKILL())
 458         {
 459                 // touching sky, or nodrop
 460                 // what shall we do?
 461                 // immediately return is bad
 462                 // maybe start a shorter countdown?
 463         }
 464
 465         if (!IS_PLAYER(toucher))
 466                 return;
 467         if(IS_DEAD(toucher))
 468                 return;
 469         if(toucher == this.enemy)
 470                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 471                         return;  // you just dropped it!
 472         kh_Key_Collect(this, toucher);
 473 }
 474
 475 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 476 {
 477         entity o;
 478         o = key.owner;
 479         kh_Key_AssignTo(key, NULL);
 480         if(o) // it was attached
 481                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 482         else // it was dropped
 483                 WaypointSprite_DetachCarrier(key);
 484
 485         // remove key from key list
 486         if (kh_worldkeylist == key)
 487                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 488         else
 489         {
 490                 o = kh_worldkeylist;
 491                 while (o)
 492                 {
 493                         if (o.kh_worldkeynext == key)
 494                         {
 495                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 496                                 break;
 497                         }
 498                         o = o.kh_worldkeynext;
 499                 }
 500         }
 501
 502         delete(key);
 503
 504         kh_update_state();
 505 }
 506
 507 void kh_FinishRound()  // runs when a team captures the keys
 508 {
 509         // prepare next round
 510         kh_interferemsg_time = 0;
 511         entity key;
 512
 513         kh_no_radar_circles = true;
 514         FOR_EACH_KH_KEY(key)
 515                 kh_Key_Remove(key);
 516         kh_no_radar_circles = false;
 517
 518         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 519         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 520 }
 521
 522 void nades_GiveBonus(entity player, float score);
 523
 524 void kh_WinnerTeam(float teem)  // runs when a team wins // Samual: Teem?.... TEEM?!?! what the fuck is wrong with you people
 525 {
 526         // all key carriers get some points
 527         vector firstorigin, lastorigin, midpoint;
 528         float first;
 529         entity key;
 530         float score;
 531         score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 532         DistributeEvenly_Init(score, NumTeams(kh_teams));
 533         // twice the score for 3 team games, three times the score for 4 team games!
 534         // note: for a win by destroying the key, this should NOT be applied
 535         FOR_EACH_KH_KEY(key)
 536         {
 537                 float f;
 538                 f = DistributeEvenly_Get(1);
 539                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 540                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 541                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 542         }
 543
 544         first = true;
 545         string keyowner = "";
 546         FOR_EACH_KH_KEY(key)
 547                 if(key.owner.kh_next == key)
 548                 {
 549                         if(!first)
 550                                 keyowner = strcat(keyowner, ", ");
 551                         keyowner = key.owner.netname;
 552                         first = false;
 553                 }
 554
 555         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(teem, INFO_KEYHUNT_CAPTURE), keyowner);
 556
 557         first = true;
 558         midpoint = '0 0 0';
 559         firstorigin = '0 0 0';
 560         lastorigin = '0 0 0';
 561         FOR_EACH_KH_KEY(key)
 562         {
 563                 vector thisorigin;
 564
 565                 thisorigin = kh_AttachedOrigin(key);
 566                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 567                 midpoint += thisorigin;
 568
 569                 if(!first)
 570                         te_lightning2(NULL, lastorigin, thisorigin);
 571                 lastorigin = thisorigin;
 572                 if(first)
 573                         firstorigin = thisorigin;
 574                 first = false;
 575         }
 576         if(NumTeams(kh_teams) > 2)
 577         {
 578                 te_lightning2(NULL, lastorigin, firstorigin);
 579         }
 580         midpoint = midpoint * (1 / NumTeams(kh_teams));
 581         te_customflash(midpoint, 1000, 1, Team_ColorRGB(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 582
 583         play2all(SND(KH_CAPTURE));
 584         kh_FinishRound();
 585 }
 586
 587 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 588 {
 589         entity key, attacker;
 590         float players;
 591         float keys;
 592         float f;
 593
 594         attacker = NULL;
 595         if(lostkey.pusher)
 596                 if(lostkey.pusher.team != teem)
 597                         if(IS_PLAYER(lostkey.pusher))
 598                                 attacker = lostkey.pusher;
 599
 600         players = keys = 0;
 601
 602         if(attacker)
 603         {
 604                 if(lostkey.kh_previous_owner)
 605                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 606                         // don't actually GIVE him the -nn points, just log
 607                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 608                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 609                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 610         }
 611         else
 612         {
 613                 float of, fragsleft, i, j, thisteam;
 614                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 615
 616                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != teem, LAMBDA(++players));
 617
 618                 FOR_EACH_KH_KEY(key)
 619                         if(key.owner && key.team != teem)
 620                                 ++keys;
 621
 622                 if(lostkey.kh_previous_owner)
 623                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 624                         // don't actually GIVE him the -nn points, just log
 625
 626                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 627                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 628
 629                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 630
 631                 FOR_EACH_KH_KEY(key)
 632                         if(key.owner && key.team != teem)
 633                         {
 634                                 f = DistributeEvenly_Get(of);
 635                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 636                         }
 637
 638                 fragsleft = DistributeEvenly_Get(players);
 639
 640                 // Now distribute these among all other teams...
 641                 j = NumTeams(kh_teams) - 1;
 642                 for(i = 0; i < NumTeams(kh_teams); ++i)
 643                 {
 644                         thisteam = kh_Team_ByID(i);
 645                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 646                                 continue;
 647
 648                         players = 0;
 649                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(++players));
 650
 651                         DistributeEvenly_Init(fragsleft, j);
 652                         fragsleft = DistributeEvenly_Get(j - 1);
 653                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 654
 655                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(
 656                                 f = DistributeEvenly_Get(1);
 657                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 658                         ));
 659
 660                         --j;
 661                 }
 662         }
 663
 664         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(lostkey.team, INFO_KEYHUNT_LOST), lostkey.kh_previous_owner.netname);
 665
 666         play2all(SND(KH_DESTROY));
 667         te_tarexplosion(lostkey.origin);
 668
 669         kh_FinishRound();
 670 }
 671
 672 void kh_Key_Think(entity this)  // runs all the time
 673 {
 674         if(intermission_running)
 675                 return;
 676
 677         if(this.owner)
 678         {
 679 #ifndef KH_PLAYER_USE_ATTACHMENT
 680                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 681                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 682 #endif
 683         }
 684
 685         // if in nodrop or time over, end the round
 686         if(!this.owner)
 687                 if(time > this.pain_finished)
 688                         kh_LoserTeam(this.team, this);
 689
 690         if(this.owner)
 691         if(kh_Key_AllOwnedByWhichTeam() != -1)
 692         {
 693                 if(this.siren_time < time)
 694                 {
 695                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 696                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 697                 }
 698
 699                 entity key;
 700                 vector p;
 701                 p = this.owner.origin;
 702                 FOR_EACH_KH_KEY(key)
 703                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 704                                 goto not_winning;
 705                 kh_WinnerTeam(this.team);
 706 LABEL(not_winning)
 707         }
 708
 709         if(kh_interferemsg_time && time > kh_interferemsg_time)
 710         {
 711                 kh_interferemsg_time = 0;
 712                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 713                         if(it.team == kh_interferemsg_team)
 714                                 if(it.kh_next)
 715                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 716                                 else
 717                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 718                         else
 719                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 720                 ));
 721         }
 722
 723         this.nextthink = time + 0.05;
 724 }
 725
 726 void key_reset(entity this)
 727 {
 728         kh_Key_AssignTo(this, NULL);
 729         kh_Key_Remove(this);
 730 }
 731
 732 const string STR_ITEM_KH_KEY = "item_kh_key";
 733 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 734 {
 735         entity key = spawn();
 736         key.count = i;
 737         key.classname = STR_ITEM_KH_KEY;
 738         settouch(key, kh_Key_Touch);
 739         setthink(key, kh_Key_Think);
 740         key.nextthink = time;
 741         key.items = IT_KEY1 | IT_KEY2;
 742         key.cnt = _angle;
 743         key.angles = '0 360 0' * random();
 744         key.event_damage = kh_Key_Damage;
 745         key.takedamage = DAMAGE_YES;
 746         key.modelindex = kh_key_dropped;
 747         key.model = "key";
 748         key.kh_dropperteam = 0;
 749         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 750         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 751         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 752         key.reset = key_reset;
 753
 754         switch(initial_owner.team)
 755         {
 756                 case NUM_TEAM_1:
 757                         key.netname = "^1red key";
 758                         break;
 759                 case NUM_TEAM_2:
 760                         key.netname = "^4blue key";
 761                         break;
 762                 case NUM_TEAM_3:
 763                         key.netname = "^3yellow key";
 764                         break;
 765                 case NUM_TEAM_4:
 766                         key.netname = "^6pink key";
 767                         break;
 768                 default:
 769                         key.netname = "NETGIER key";
 770                         break;
 771         }
 772
 773         // link into key list
 774         key.kh_worldkeynext = kh_worldkeylist;
 775         kh_worldkeylist = key;
 776
 777         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 778
 779         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 780         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 781
 782         kh_Key_AssignTo(key, initial_owner);
 783 }
 784
 785 // -1 when no team completely owns all keys yet
 786 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 787 {
 788         entity key;
 789         int teem = -1;
 790         int keys = NumTeams(kh_teams);
 791         FOR_EACH_KH_KEY(key)
 792         {
 793                 if(!key.owner)
 794                         return -1;
 795                 if(teem == -1)
 796                         teem = key.team;
 797                 else if(teem != key.team)
 798                         return -1;
 799                 --keys;
 800         }
 801         if(keys != 0)
 802                 return -1;
 803         return teem;
 804 }
 805
 806 void kh_Key_DropOne(entity key)
 807 {
 808         // prevent collecting this one for some time
 809         entity player;
 810         player = key.owner;
 811
 812         key.kh_droptime = time;
 813         key.enemy = player;
 814
 815         kh_Scores_Event(player, key, "dropkey", 0, 0);
 816         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 817         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(key.team, INFO_KEYHUNT_DROP), player.netname);
 818
 819         kh_Key_AssignTo(key, NULL);
 820         makevectors(player.v_angle);
 821         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 822         key.pusher = NULL;
 823         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 824         key.kh_dropperteam = key.team;
 825
 826         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 827 }
 828
 829 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 830 {
 831         entity key;
 832         entity mypusher;
 833         if(player.kh_next)
 834         {
 835                 mypusher = NULL;
 836                 if(player.pusher)
 837                         if(time < player.pushltime)
 838                                 mypusher = player.pusher;
 839                 while((key = player.kh_next))
 840                 {
 841                         kh_Scores_Event(player, key, "losekey", 0, 0);
 842                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 843                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(key.team, INFO_KEYHUNT_LOST), player.netname);
 844                         kh_Key_AssignTo(key, NULL);
 845                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 846                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 847                         key.pusher = mypusher;
 848                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 849                         if(suicide)
 850                                 key.kh_dropperteam = player.team;
 851                 }
 852                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 853         }
 854 }
 855
 856 int kh_GetMissingTeams()
 857 {
 858         int missing_teams = 0;
 859         for(int i = 0; i < NumTeams(kh_teams); ++i)
 860         {
 861                 int teem = kh_Team_ByID(i);
 862                 int players = 0;
 863                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 864                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 865                                 ++players;
 866                 ));
 867                 if (!players)
 868                         missing_teams |= pow(2, i);
 869         }
 870         return missing_teams;
 871 }
 872
 873 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 874 {
 875         if(time < game_starttime)
 876         {
 877                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 878                 return;
 879         }
 880
 881         static int prev_missing_teams_mask;
 882         int missing_teams_mask = kh_GetMissingTeams();
 883         if(!missing_teams_mask)
 884         {
 885                 if(prev_missing_teams_mask > 0)
 886                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 887                 prev_missing_teams_mask = -1;
 888                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 889                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 890         }
 891         else
 892         {
 893                 if(player_count == 0)
 894                 {
 895                         if(prev_missing_teams_mask > 0)
 896                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 897                         prev_missing_teams_mask = -1;
 898                 }
 899                 else
 900                 {
 901                         if(prev_missing_teams_mask != missing_teams_mask)
 902                         {
 903                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 904                                 prev_missing_teams_mask = missing_teams_mask;
 905                         }
 906                 }
 907                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 908         }
 909 }
 910
 911 void kh_EnableTrackingDevice()  // runs after each round
 912 {
 913         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 914         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 915
 916         kh_tracking_enabled = true;
 917 }
 918
 919 void kh_StartRound()  // runs at the start of each round
 920 {
 921         int i, players, teem;
 922
 923         if(time < game_starttime)
 924         {
 925                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 926                 return;
 927         }
 928
 929         if(kh_GetMissingTeams())
 930         {
 931                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 932                 return;
 933         }
 934
 935         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 936         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 937
 938         for(i = 0; i < NumTeams(kh_teams); ++i)
 939         {
 940                 teem = kh_Team_ByID(i);
 941                 players = 0;
 942                 entity my_player = NULL;
 943                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 944                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 945                         {
 946                                 ++players;
 947                                 if(random() * players <= 1)
 948                                         my_player = it;
 949                         }
 950                 ));
 951                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 952         }
 953
 954         kh_tracking_enabled = false;
 955         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 956         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 957 }
 958
 959 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 960 {
 961         if(attacker == targ)
 962                 return f;
 963
 964         if(targ.kh_next)
 965         {
 966                 if(attacker.team == targ.team)
 967                 {
 968                         entity k;
 969                         float nk;
 970                         nk = 0;
 971                         for(k = targ.kh_next; k != NULL; k = k.kh_next)
 972                                 ++nk;
 973                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 974                 }
 975                 else
 976                 {
 977                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 978                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 979                         // the frag gets added later
 980                 }
 981         }
 982
 983         return f;
 984 }
 985
 986 void kh_Initialize()  // sets up th KH environment
 987 {
 988         // setup variables
 989         kh_teams = autocvar_g_keyhunt_teams_override;
 990         if(kh_teams < 2)
 991                 kh_teams = autocvar_g_keyhunt_teams;
 992         kh_teams = bound(2, kh_teams, 4);
 993
 994         int teams = 0;
 995         if(kh_teams >= 1) teams |= BIT(0);
 996         if(kh_teams >= 2) teams |= BIT(1);
 997         if(kh_teams >= 3) teams |= BIT(2);
 998         if(kh_teams >= 4) teams |= BIT(3);
 999
1000         kh_teams = teams; // now set it?
1001
1002         // make a KH entity for controlling the game
1003         kh_controller = spawn();
1004         setthink(kh_controller, kh_Controller_Think);
1005         kh_Controller_SetThink(0, kh_WaitForPlayers);
1006
1007         setmodel(kh_controller, MDL_KH_KEY);
1008         kh_key_dropped = kh_controller.modelindex;
1009         /*
1010         dprint(vtos(kh_controller.mins));
1011         dprint(vtos(kh_controller.maxs));
1012         dprint("\n");
1013         */
1014 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1015         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
1016         kh_key_carried = kh_controller.modelindex;
1017 #else
1018         kh_key_carried = kh_key_dropped;
1019 #endif
1020
1021         kh_controller.model = "";
1022         kh_controller.modelindex = 0;
1023
1024         kh_ScoreRules(kh_teams);
1025 }
1026
1027 void kh_finalize()
1028 {
1029         // to be called before intermission
1030         kh_FinishRound();
1031         delete(kh_controller);
1032         kh_controller = NULL;
1033 }
1034
1035 // legacy bot role
1036
1037 void(entity this) havocbot_role_kh_carrier;
1038 void(entity this) havocbot_role_kh_defense;
1039 void(entity this) havocbot_role_kh_offense;
1040 void(entity this) havocbot_role_kh_freelancer;
1041
1042
1043 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1044 {
1045         entity head;
1046         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1047         {
1048                 if(head.owner == this)
1049                         continue;
1050                 if(!kh_tracking_enabled)
1051                 {
1052                         // if it's carried by our team we know about it
1053                         // otherwise we have to see it to know about it
1054                         if(!head.owner || head.team != this.team)
1055                         {
1056                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1057                                 if (trace_fraction < 1 && trace_ent != head)
1058                                         continue; // skip what I can't see
1059                         }
1060                 }
1061                 if(!head.owner)
1062                         navigation_routerating(this, head, ratingscale_dropped * BOT_PICKUP_RATING_HIGH, 100000);
1063                 else if(head.team == this.team)
1064                         navigation_routerating(this, head.owner, ratingscale_team * BOT_PICKUP_RATING_HIGH, 100000);
1065                 else
1066                         navigation_routerating(this, head.owner, ratingscale_enemy * BOT_PICKUP_RATING_HIGH, 100000);
1067         }
1068
1069         havocbot_goalrating_items(this, 1, this.origin, 10000);
1070 }
1071
1072 void havocbot_role_kh_carrier(entity this)
1073 {
1074         if(IS_DEAD(this))
1075                 return;
1076
1077         if (!(this.kh_next))
1078         {
1079                 LOG_TRACE("changing role to freelancer");
1080                 this.havocbot_role = havocbot_role_kh_freelancer;
1081                 this.havocbot_role_timeout = 0;
1082                 return;
1083         }
1084
1085         if (this.bot_strategytime < time)
1086         {
1087                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1088                 navigation_goalrating_start(this);
1089
1090                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1091                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // bring home
1092                 else
1093                         havocbot_goalrating_kh(this, 4, 4, 1); // play defensively
1094
1095                 navigation_goalrating_end(this);
1096         }
1097 }
1098
1099 void havocbot_role_kh_defense(entity this)
1100 {
1101         if(IS_DEAD(this))
1102                 return;
1103
1104         if (this.kh_next)
1105         {
1106                 LOG_TRACE("changing role to carrier");
1107                 this.havocbot_role = havocbot_role_kh_carrier;
1108                 this.havocbot_role_timeout = 0;
1109                 return;
1110         }
1111
1112         if (!this.havocbot_role_timeout)
1113                 this.havocbot_role_timeout = time + random() * 10 + 20;
1114         if (time > this.havocbot_role_timeout)
1115         {
1116                 LOG_TRACE("changing role to freelancer");
1117                 this.havocbot_role = havocbot_role_kh_freelancer;
1118                 this.havocbot_role_timeout = 0;
1119                 return;
1120         }
1121
1122         if (this.bot_strategytime < time)
1123         {
1124                 float key_owner_team;
1125                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1126                 navigation_goalrating_start(this);
1127
1128                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1129                 if(key_owner_team == this.team)
1130                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend key carriers
1131                 else if(key_owner_team == -1)
1132                         havocbot_goalrating_kh(this, 4, 1, 0.1); // play defensively
1133                 else
1134                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1135
1136                 navigation_goalrating_end(this);
1137         }
1138 }
1139
1140 void havocbot_role_kh_offense(entity this)
1141 {
1142         if(IS_DEAD(this))
1143                 return;
1144
1145         if (this.kh_next)
1146         {
1147                 LOG_TRACE("changing role to carrier");
1148                 this.havocbot_role = havocbot_role_kh_carrier;
1149                 this.havocbot_role_timeout = 0;
1150                 return;
1151         }
1152
1153         if (!this.havocbot_role_timeout)
1154                 this.havocbot_role_timeout = time + random() * 10 + 20;
1155         if (time > this.havocbot_role_timeout)
1156         {
1157                 LOG_TRACE("changing role to freelancer");
1158                 this.havocbot_role = havocbot_role_kh_freelancer;
1159                 this.havocbot_role_timeout = 0;
1160                 return;
1161         }
1162
1163         if (this.bot_strategytime < time)
1164         {
1165                 float key_owner_team;
1166
1167                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1168                 navigation_goalrating_start(this);
1169
1170                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1171                 if(key_owner_team == this.team)
1172                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1173                 else if(key_owner_team == -1)
1174                         havocbot_goalrating_kh(this, 0.1, 1, 4); // play offensively
1175                 else
1176                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK! EMERGENCY!
1177
1178                 navigation_goalrating_end(this);
1179         }
1180 }
1181
1182 void havocbot_role_kh_freelancer(entity this)
1183 {
1184         if(IS_DEAD(this))
1185                 return;
1186
1187         if (this.kh_next)
1188         {
1189                 LOG_TRACE("changing role to carrier");
1190                 this.havocbot_role = havocbot_role_kh_carrier;
1191                 this.havocbot_role_timeout = 0;
1192                 return;
1193         }
1194
1195         if (!this.havocbot_role_timeout)
1196                 this.havocbot_role_timeout = time + random() * 10 + 10;
1197         if (time > this.havocbot_role_timeout)
1198         {
1199                 if (random() < 0.5)
1200                 {
1201                         LOG_TRACE("changing role to offense");
1202                         this.havocbot_role = havocbot_role_kh_offense;
1203                 }
1204                 else
1205                 {
1206                         LOG_TRACE("changing role to defense");
1207                         this.havocbot_role = havocbot_role_kh_defense;
1208                 }
1209                 this.havocbot_role_timeout = 0;
1210                 return;
1211         }
1212
1213         if (this.bot_strategytime < time)
1214         {
1215                 float key_owner_team;
1216
1217                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1218                 navigation_goalrating_start(this);
1219
1220                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1221                 if(key_owner_team == this.team)
1222                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1223                 else if(key_owner_team == -1)
1224                         havocbot_goalrating_kh(this, 1, 10, 4); // prefer dropped keys
1225                 else
1226                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1227
1228                 navigation_goalrating_end(this);
1229         }
1230 }
1231
1232
1233 // register this as a mutator
1234
1235 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1236 {
1237         entity player = M_ARGV(0, entity);
1238
1239         kh_Key_DropAll(player, true);
1240 }
1241
1242 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1243 {
1244         entity player = M_ARGV(0, entity);
1245
1246         kh_Key_DropAll(player, true);
1247 }
1248
1249 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1250 {
1251         entity frag_attacker = M_ARGV(1, entity);
1252         entity frag_target = M_ARGV(2, entity);
1253
1254         if(frag_target == frag_attacker)
1255                 kh_Key_DropAll(frag_target, true);
1256         else if(IS_PLAYER(frag_attacker))
1257                 kh_Key_DropAll(frag_target, false);
1258         else
1259                 kh_Key_DropAll(frag_target, true);
1260 }
1261
1262 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1263 {
1264         entity frag_attacker = M_ARGV(0, entity);
1265         entity frag_target = M_ARGV(1, entity);
1266         float frag_score = M_ARGV(2, float);
1267         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1268 }
1269
1270 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1271 {
1272         kh_finalize();
1273 }
1274
1275 MUTATOR_HOOKFUNCTION(kh, CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1276 {
1277         M_ARGV(0, float) = kh_teams;
1278 }
1279
1280 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1281 {
1282         entity spectatee = M_ARGV(0, entity);
1283         entity client = M_ARGV(1, entity);
1284
1285         client.kh_state = spectatee.kh_state;
1286 }
1287
1288 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1289 {
1290         entity player = M_ARGV(0, entity);
1291
1292         if(MUTATOR_RETURNVALUE == 0)
1293         {
1294                 entity k = player.kh_next;
1295                 if(k)
1296                 {
1297                         kh_Key_DropOne(k);
1298                         return true;
1299                 }
1300         }
1301 }
1302
1303 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1304 {
1305     entity bot = M_ARGV(0, entity);
1306
1307         if(IS_DEAD(bot))
1308                 return true;
1309
1310         float r = random() * 3;
1311         if (r < 1)
1312                 bot.havocbot_role = havocbot_role_kh_offense;
1313         else if (r < 2)
1314                 bot.havocbot_role = havocbot_role_kh_defense;
1315         else
1316                 bot.havocbot_role = havocbot_role_kh_freelancer;
1317
1318         return true;
1319 }
1320
1321 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1322 {
1323         entity frag_target = M_ARGV(0, entity);
1324
1325         kh_Key_DropAll(frag_target, false);
1326 }
1327
1328 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1329 {
1330         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
1331 }