6b293a0642de7dbc9219ad5284f4614ea4988d4b
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator / gamemode_lms.qc
1 #ifndef GAMEMODE_LMS_H
2 #define GAMEMODE_LMS_H
3
4 #define autocvar_g_lms_lives_override cvar("g_lms_lives_override")
5 void lms_Initialize();
6
7 REGISTER_MUTATOR(lms, false)
8 {
9         MUTATOR_ONADD
10         {
11                 if (time > 1) // game loads at time 1
12                         error("This is a game type and it cannot be added at runtime.");
13                 lms_Initialize();
14
15                 SetLimits(((!autocvar_g_lms_lives_override) ? -1 : autocvar_g_lms_lives_override), 0, -1, -1);
16         }
17
18         MUTATOR_ONROLLBACK_OR_REMOVE
19         {
20                 // we actually cannot roll back lms_Initialize here
21                 // BUT: we don't need to! If this gets called, adding always
22                 // succeeds.
23         }
24
25         MUTATOR_ONREMOVE
26         {
27                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
28                 return -1;
29         }
30
31         return 0;
32 }
33
34 // scoreboard stuff
35 const float SP_LMS_LIVES = 4;
36 const float SP_LMS_RANK = 5;
37
38 // lives related defs
39 float lms_lowest_lives;
40 float lms_next_place;
41 float LMS_NewPlayerLives();
42
43 #endif
44
45 #ifdef IMPLEMENTATION
46
47 #include "../../campaign.qh"
48 #include "../../command/cmd.qh"
49
50 int autocvar_g_lms_extra_lives;
51 bool autocvar_g_lms_join_anytime;
52 int autocvar_g_lms_last_join;
53 bool autocvar_g_lms_regenerate;
54
55 // main functions
56 float LMS_NewPlayerLives()
57 {
58         float fl;
59         fl = autocvar_fraglimit;
60         if(fl == 0)
61                 fl = 999;
62
63         // first player has left the game for dying too much? Nobody else can get in.
64         if(lms_lowest_lives < 1)
65                 return 0;
66
67         if(!autocvar_g_lms_join_anytime)
68                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
69                         return 0;
70
71         return bound(1, lms_lowest_lives, fl);
72 }
73
74 // LMS winning condition: game terminates if and only if there's at most one
75 // one player who's living lives. Top two scores being equal cancels the time
76 // limit.
77 float WinningCondition_LMS()
78 {
79         entity head, head2;
80         float have_player;
81         float have_players;
82         float l;
83
84         have_player = false;
85         have_players = false;
86         l = LMS_NewPlayerLives();
87
88         head = find(world, classname, "player");
89         if(head)
90                 have_player = true;
91         head2 = find(head, classname, "player");
92         if(head2)
93                 have_players = true;
94
95         if(have_player)
96         {
97                 // we have at least one player
98                 if(have_players)
99                 {
100                         // two or more active players - continue with the game
101                 }
102                 else
103                 {
104                         // exactly one player?
105
106                         ClearWinners();
107                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
108
109                         if(l)
110                         {
111                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
112                                 return WINNING_NO;
113                         }
114                         else
115                         {
116                                 // a winner!
117                                 // and assign him his first place
118                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
119                                 return WINNING_YES;
120                         }
121                 }
122         }
123         else
124         {
125                 // nobody is playing at all...
126                 if(l)
127                 {
128                         // wait for players...
129                 }
130                 else
131                 {
132                         // SNAFU (maybe a draw game?)
133                         ClearWinners();
134                         LOG_TRACE("No players, ending game.\n");
135                         return WINNING_YES;
136                 }
137         }
138
139         // When we get here, we have at least two players who are actually LIVING,
140         // now check if the top two players have equal score.
141         WinningConditionHelper();
142
143         ClearWinners();
144         if(WinningConditionHelper_winner)
145                 WinningConditionHelper_winner.winning = true;
146         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
147                 return WINNING_NEVER;
148
149         // Top two have different scores? Way to go for our beloved TIMELIMIT!
150         return WINNING_NO;
151 }
152
153 // mutator hooks
154 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
155 {
156         lms_lowest_lives = 999;
157         lms_next_place = player_count;
158
159         return false;
160 }
161
162 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
163 {SELFPARAM();
164         if(restart_mapalreadyrestarted || (time < game_starttime))
165         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(WITH(entity, self, it, PlayerScore_Add(it, SP_LMS_LIVES, LMS_NewPlayerLives()))));
166
167         return false;
168 }
169
170 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
171 {SELFPARAM();
172         // player is dead and becomes observer
173         // FIXME fix LMS scoring for new system
174         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
175         {
176                 self.classname = STR_OBSERVER;
177                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_NOLIVES);
178         }
179
180         return false;
181 }
182
183 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
184 {SELFPARAM();
185         self.respawn_flags |= RESPAWN_FORCE;
186
187         return false;
188 }
189
190 void lms_RemovePlayer(entity player)
191 {
192         // Only if the player cannot play at all
193         if(PlayerScore_Add(player, SP_LMS_RANK, 0) == 666)
194                 player.frags = FRAGS_SPECTATOR;
195         else
196                 player.frags = FRAGS_LMS_LOSER;
197
198         if(player.killcount != FRAGS_SPECTATOR)
199                 if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
200                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
201                 else
202                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
203 }
204
205 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
206 {SELFPARAM();
207         lms_RemovePlayer(self);
208         return false;
209 }
210
211 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
212 {SELFPARAM();
213         lms_RemovePlayer(self);
214         return false;
215 }
216
217 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
218 {SELFPARAM();
219         self.classname = STR_PLAYER;
220         campaign_bots_may_start = 1;
221
222         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
223         {
224                 PlayerScore_Add(self, SP_LMS_RANK, 666);
225                 self.frags = FRAGS_SPECTATOR;
226         }
227
228         return false;
229 }
230
231 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
232 {SELFPARAM();
233         if(self.deadflag == DEAD_DYING)
234                 self.deadflag = DEAD_RESPAWNING;
235
236         return false;
237 }
238
239 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
240 {
241         if(autocvar_g_lms_regenerate)
242                 return false;
243         return true;
244 }
245
246 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
247 {
248         // forbode!
249         return true;
250 }
251
252 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
253 {
254         // remove a life
255         float tl;
256         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
257         if(tl < lms_lowest_lives)
258                 lms_lowest_lives = tl;
259         if(tl <= 0)
260         {
261                 if(!lms_next_place)
262                         lms_next_place = player_count;
263                 else
264                         lms_next_place = min(lms_next_place, player_count);
265                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
266                 --lms_next_place;
267         }
268         frag_score = 0;
269
270         return true;
271 }
272
273 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
274 {
275         start_items &= ~IT_UNLIMITED_AMMO;
276         start_health       = warmup_start_health       = cvar("g_lms_start_health");
277         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
278         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
279         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
280         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
281         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
282         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
283         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
284
285         return false;
286 }
287
288 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
289 {
290         // don't clear player score
291         return true;
292 }
293
294 MUTATOR_HOOKFUNCTION(lms, FilterItem)
295 {SELFPARAM();
296         if(autocvar_g_lms_extra_lives)
297         if(self.itemdef == ITEM_ExtraLife)
298                 return false;
299
300         return true;
301 }
302
303 void lms_extralife()
304 {SELFPARAM();
305         StartItem(this, ITEM_ExtraLife);
306 }
307
308 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
309 {SELFPARAM();
310         if (!autocvar_g_powerups) return false;
311         if (!autocvar_g_lms_extra_lives) return false;
312
313         // Can't use .itemdef here
314         if (self.classname != "item_health_mega") return false;
315
316         entity e = spawn();
317         e.think = lms_extralife;
318
319         e.nextthink = time + 0.1;
320         e.spawnflags = self.spawnflags;
321         e.noalign = self.noalign;
322         setorigin(e, self.origin);
323
324         return true;
325 }
326
327 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
328 {SELFPARAM();
329         if(self.itemdef == ITEM_ExtraLife)
330         {
331                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
332                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
333                 return MUT_ITEMTOUCH_PICKUP;
334         }
335
336         return MUT_ITEMTOUCH_CONTINUE;
337 }
338
339 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
340 {
341         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
342                 ++bot_activerealplayers;
343                 ++bot_realplayers;
344         ));
345
346         return true;
347 }
348
349 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
350 {
351         if(self.lms_spectate_warning)
352         {
353                 // for the forfeit message...
354                 self.lms_spectate_warning = 2;
355                 // mark player as spectator
356                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
357         }
358         else
359         {
360                 self.lms_spectate_warning = 1;
361                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
362                 return MUT_SPECCMD_RETURN;
363         }
364         return MUT_SPECCMD_CONTINUE;
365 }
366
367 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
368 {
369         ret_float = WinningCondition_LMS();
370         return true;
371 }
372
373 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
374 {
375         want_allguns = true;
376         return false;
377 }
378
379 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
380 {
381         return true;
382 }
383
384 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
385 {
386         if(gameover)
387         if(score_field == SP_LMS_RANK)
388                 return true; // allow writing to this field in intermission as it is needed for newly joining players
389         return false;
390 }
391
392 // scoreboard stuff
393 void lms_ScoreRules()
394 {
395         ScoreRules_basics(0, 0, 0, false);
396         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
397         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
398         ScoreRules_basics_end();
399 }
400
401 void lms_Initialize()
402 {
403         lms_lowest_lives = 9999;
404         lms_next_place = 0;
405
406         lms_ScoreRules();
407 }
408
409
410 #endif