qcsrc/server/mutators/mutator/gamemode_lms.qc

   1 #include "gamemode_lms.qh"
   2 #ifndef GAMEMODE_LMS_H
   3 #define GAMEMODE_LMS_H
   4
   5 #define autocvar_g_lms_lives_override cvar("g_lms_lives_override")
   6 void lms_Initialize();
   7
   8 REGISTER_MUTATOR(lms, false)
   9 {
  10         MUTATOR_ONADD
  11         {
  12                 if (time > 1) // game loads at time 1
  13                         error("This is a game type and it cannot be added at runtime.");
  14                 lms_Initialize();
  15
  16                 SetLimits(((!autocvar_g_lms_lives_override) ? -1 : autocvar_g_lms_lives_override), 0, autocvar_timelimit_override, -1);
  17         }
  18
  19         MUTATOR_ONROLLBACK_OR_REMOVE
  20         {
  21                 // we actually cannot roll back lms_Initialize here
  22                 // BUT: we don't need to! If this gets called, adding always
  23                 // succeeds.
  24         }
  25
  26         MUTATOR_ONREMOVE
  27         {
  28                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  29                 return -1;
  30         }
  31
  32         return 0;
  33 }
  34
  35 // scoreboard stuff
  36 const float SP_LMS_LIVES = 4;
  37 const float SP_LMS_RANK = 5;
  38
  39 // lives related defs
  40 float lms_lowest_lives;
  41 float lms_next_place;
  42 float LMS_NewPlayerLives();
  43
  44 #endif
  45
  46 #ifdef IMPLEMENTATION
  47
  48 #include <common/mutators/mutator/instagib/items.qc>
  49 #include <server/campaign.qh>
  50 #include <server/command/cmd.qh>
  51
  52 int autocvar_g_lms_extra_lives;
  53 bool autocvar_g_lms_join_anytime;
  54 int autocvar_g_lms_last_join;
  55 bool autocvar_g_lms_regenerate;
  56
  57 // main functions
  58 float LMS_NewPlayerLives()
  59 {
  60         float fl;
  61         fl = autocvar_fraglimit;
  62         if(fl == 0)
  63                 fl = 999;
  64
  65         // first player has left the game for dying too much? Nobody else can get in.
  66         if(lms_lowest_lives < 1)
  67                 return 0;
  68
  69         if(!autocvar_g_lms_join_anytime)
  70                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  71                         return 0;
  72
  73         return bound(1, lms_lowest_lives, fl);
  74 }
  75
  76 void ClearWinners();
  77
  78 // LMS winning condition: game terminates if and only if there's at most one
  79 // one player who's living lives. Top two scores being equal cancels the time
  80 // limit.
  81 int WinningCondition_LMS()
  82 {
  83         entity head, head2;
  84         bool have_player = false;
  85         bool have_players = false;
  86
  87         int l = LMS_NewPlayerLives();
  88
  89         head = find(NULL, classname, STR_PLAYER);
  90         if(head)
  91                 have_player = true;
  92         head2 = find(head, classname, STR_PLAYER);
  93         if(head2)
  94                 have_players = true;
  95
  96         if(have_player)
  97         {
  98                 // we have at least one player
  99                 if(have_players)
 100                 {
 101                         // two or more active players - continue with the game
 102                 }
 103                 else
 104                 {
 105                         // exactly one player?
 106
 107                         ClearWinners();
 108                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
 109
 110                         if(l)
 111                         {
 112                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
 113                                 return WINNING_NO;
 114                         }
 115                         else
 116                         {
 117                                 // a winner!
 118                                 // and assign him his first place
 119                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
 120                                 return WINNING_YES;
 121                         }
 122                 }
 123         }
 124         else
 125         {
 126                 // nobody is playing at all...
 127                 if(l)
 128                 {
 129                         // wait for players...
 130                 }
 131                 else
 132                 {
 133                         // SNAFU (maybe a draw game?)
 134                         ClearWinners();
 135                         LOG_TRACE("No players, ending game.\n");
 136                         return WINNING_YES;
 137                 }
 138         }
 139
 140         // When we get here, we have at least two players who are actually LIVING,
 141         // now check if the top two players have equal score.
 142         WinningConditionHelper(NULL);
 143
 144         ClearWinners();
 145         if(WinningConditionHelper_winner)
 146                 WinningConditionHelper_winner.winning = true;
 147         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 148                 return WINNING_NEVER;
 149
 150         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 151         return WINNING_NO;
 152 }
 153
 154 // mutator hooks
 155 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 156 {
 157         lms_lowest_lives = 999;
 158         lms_next_place = player_count;
 159 }
 160
 161 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 162 {
 163         if(restart_mapalreadyrestarted || (time < game_starttime))
 164         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(PlayerScore_Add(it, SP_LMS_LIVES, LMS_NewPlayerLives())));
 165 }
 166
 167 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 168 {
 169         entity player = M_ARGV(0, entity);
 170
 171         // player is dead and becomes observer
 172         // FIXME fix LMS scoring for new system
 173         if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0)
 174         {
 175                 TRANSMUTE(Observer, player);
 176                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_LMS_NOLIVES);
 177         }
 178 }
 179
 180 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 181 {
 182         entity frag_target = M_ARGV(2, entity);
 183
 184         frag_target.respawn_flags |= RESPAWN_FORCE;
 185 }
 186
 187 void lms_RemovePlayer(entity player)
 188 {
 189         // Only if the player cannot play at all
 190         if(PlayerScore_Add(player, SP_LMS_RANK, 0) == 666)
 191                 player.frags = FRAGS_SPECTATOR;
 192         else
 193                 player.frags = FRAGS_LMS_LOSER;
 194
 195         if(player.killcount != FRAGS_SPECTATOR)
 196                 if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
 197                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 198                 else
 199                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 200 }
 201
 202 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 203 {
 204         entity player = M_ARGV(0, entity);
 205
 206         lms_RemovePlayer(player);
 207 }
 208
 209 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 210 {
 211     entity player = M_ARGV(0, entity);
 212
 213         lms_RemovePlayer(player);
 214         return true;  // prevent team reset
 215 }
 216
 217 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 218 {
 219         entity player = M_ARGV(0, entity);
 220
 221         TRANSMUTE(Player, player);
 222         campaign_bots_may_start = true;
 223
 224         if(PlayerScore_Add(player, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 225         {
 226                 PlayerScore_Add(player, SP_LMS_RANK, 666);
 227                 player.frags = FRAGS_SPECTATOR;
 228         }
 229 }
 230
 231 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 232 {
 233         entity player = M_ARGV(0, entity);
 234
 235         if(player.deadflag == DEAD_DYING)
 236                 player.deadflag = DEAD_RESPAWNING;
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 240 {
 241         if(autocvar_g_lms_regenerate)
 242                 return false;
 243         return true;
 244 }
 245
 246 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 247 {
 248         // forbode!
 249         return true;
 250 }
 251
 252 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 253 {
 254         entity frag_target = M_ARGV(1, entity);
 255
 256         // remove a life
 257         float tl;
 258         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 259         if(tl < lms_lowest_lives)
 260                 lms_lowest_lives = tl;
 261         if(tl <= 0)
 262         {
 263                 if(!lms_next_place)
 264                         lms_next_place = player_count;
 265                 else
 266                         lms_next_place = min(lms_next_place, player_count);
 267                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 268                 --lms_next_place;
 269         }
 270         M_ARGV(2, float) = 0;
 271
 272         return true;
 273 }
 274
 275 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 276 {
 277         start_items &= ~IT_UNLIMITED_AMMO;
 278         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 279         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 280         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 281         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 282         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 283         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 284         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 285         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 289 {
 290         // don't clear player score
 291         return true;
 292 }
 293
 294 MUTATOR_HOOKFUNCTION(lms, FilterItem)
 295 {
 296         entity item = M_ARGV(0, entity);
 297
 298         if(autocvar_g_lms_extra_lives)
 299         if(item.itemdef == ITEM_ExtraLife)
 300                 return false;
 301
 302         return true;
 303 }
 304
 305 void lms_extralife(entity this)
 306 {
 307         StartItem(this, ITEM_ExtraLife);
 308 }
 309
 310 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 311 {
 312         if (!autocvar_g_powerups) return false;
 313         if (!autocvar_g_lms_extra_lives) return false;
 314
 315         entity ent = M_ARGV(0, entity);
 316
 317         // Can't use .itemdef here
 318         if (ent.classname != "item_health_mega") return false;
 319
 320         entity e = spawn();
 321         setthink(e, lms_extralife);
 322
 323         e.nextthink = time + 0.1;
 324         e.spawnflags = ent.spawnflags;
 325         e.noalign = ent.noalign;
 326         setorigin(e, ent.origin);
 327
 328         return true;
 329 }
 330
 331 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 332 {
 333         entity item = M_ARGV(0, entity);
 334         entity toucher = M_ARGV(1, entity);
 335
 336         if(item.itemdef == ITEM_ExtraLife)
 337         {
 338                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_EXTRALIVES);
 339                 PlayerScore_Add(toucher, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 340                 return MUT_ITEMTOUCH_PICKUP;
 341         }
 342
 343         return MUT_ITEMTOUCH_CONTINUE;
 344 }
 345
 346 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 347 {
 348         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 349                 ++M_ARGV(0, int);
 350                 ++M_ARGV(1, int);
 351         ));
 352
 353         return true;
 354 }
 355
 356 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 357 {
 358     entity player = M_ARGV(0, entity);
 359
 360         if(player.lms_spectate_warning)
 361         {
 362                 // for the forfeit message...
 363                 player.lms_spectate_warning = 2;
 364                 // mark player as spectator
 365                 PlayerScore_Add(player, SP_LMS_RANK, 666 - PlayerScore_Add(player, SP_LMS_RANK, 0));
 366         }
 367         else
 368         {
 369                 player.lms_spectate_warning = 1;
 370                 sprint(player, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 371                 return MUT_SPECCMD_RETURN;
 372         }
 373         return MUT_SPECCMD_CONTINUE;
 374 }
 375
 376 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 377 {
 378         M_ARGV(0, float) = WinningCondition_LMS();
 379         return true;
 380 }
 381
 382 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
 383 {
 384         M_ARGV(2, bool) = true; // all weapons
 385 }
 386
 387 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 388 {
 389         return true;
 390 }
 391
 392 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 393 {
 394         if(gameover)
 395         if(M_ARGV(0, int) == SP_LMS_RANK) // score field
 396                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 397 }
 398
 399 // scoreboard stuff
 400 void lms_ScoreRules()
 401 {
 402         ScoreRules_basics(0, 0, 0, false);
 403         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 404         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 405         ScoreRules_basics_end();
 406 }
 407
 408 void lms_Initialize()
 409 {
 410         lms_lowest_lives = 9999;
 411         lms_next_place = 0;
 412
 413         lms_ScoreRules();
 414 }
 415
 416
 417 #endif